lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.008001; # probably works with earlier versions but I'm not supporting them
   7               # (patches would, of course, be welcome)
   8
   9 use File::Spec ();
  10 use File::Path ();
  11 use Carp ();
  12 use Config;
  13
  14 our $VERSION = '1.006007'; # 1.6.7
  15
  16 our @KNOWN_FLAGS = qw(--self-contained);
  17
  18 sub import {
  19   my ($class, @args) = @_;
  20
  21   # Remember what PERL5LIB was when we started
  22   my $perl5lib = $ENV{PERL5LIB} || '';
  23
  24   my %arg_store;
  25   for my $arg (@args) {
  26     # check for lethal dash first to stop processing before causing problems
  27     if ($arg =~ /−/) {
  28       die <<'DEATH';
  29 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  30 These are *not* the traditional -- dashes that software recognizes. You
  31 probably got these by copy-pasting from the perldoc for this module as
  32 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  33 terminal, but can happen elsewhere too. Please try again after replacing the
  34 dashes with normal minus signs.
  35 DEATH
  36     }
  37     elsif(grep { $arg eq $_ } @KNOWN_FLAGS) {
  38       (my $flag = $arg) =~ s/--//;
  39       $arg_store{$flag} = 1;
  40     }
  41     elsif($arg =~ /^--/) {
  42       die "Unknown import argument: $arg";
  43     }
  44     else {
  45       # assume that what's left is a path
  46       $arg_store{path} = $arg;
  47     }
  48   }
  49
  50   if($arg_store{'self-contained'}) {
  51     die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  52   }
  53
  54   $arg_store{path} = $class->resolve_path($arg_store{path});
  55   $class->setup_local_lib_for($arg_store{path});
  56
  57   for (@INC) { # Untaint @INC
  58     next if ref; # Skip entry if it is an ARRAY, CODE, blessed, etc.
  59     m/(.*)/ and $_ = $1;
  60   }
  61 }
  62
  63 sub pipeline;
  64
  65 sub pipeline {
  66   my @methods = @_;
  67   my $last = pop(@methods);
  68   if (@methods) {
  69     \sub {
  70       my ($obj, @args) = @_;
  71       $obj->${pipeline @methods}(
  72         $obj->$last(@args)
  73       );
  74     };
  75   } else {
  76     \sub {
  77       shift->$last(@_);
  78     };
  79   }
  80 }
  81
  82 =begin testing
  83
  84 #:: test pipeline
  85
  86 package local::lib;
  87
  88 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
  89 my $foo = bless({}, 'Foo');
  90 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
  91
  92 =end testing
  93
  94 =cut
  95
  96 sub _uniq {
  97     my %seen;
  98     grep { ! $seen{$_}++ } @_;
  99 }
 100
 101 sub resolve_path {
 102   my ($class, $path) = @_;
 103   $class->${pipeline qw(
 104     resolve_relative_path
 105     resolve_home_path
 106     resolve_empty_path
 107   )}($path);
 108 }
 109
 110 sub resolve_empty_path {
 111   my ($class, $path) = @_;
 112   if (defined $path) {
 113     $path;
 114   } else {
 115     '~/perl5';
 116   }
 117 }
 118
 119 =begin testing
 120
 121 #:: test classmethod setup
 122
 123 my $c = 'local::lib';
 124
 125 =end testing
 126
 127 =begin testing
 128
 129 #:: test classmethod
 130
 131 is($c->resolve_empty_path, '~/perl5');
 132 is($c->resolve_empty_path('foo'), 'foo');
 133
 134 =end testing
 135
 136 =cut
 137
 138 sub resolve_home_path {
 139   my ($class, $path) = @_;
 140   return $path unless ($path =~ /^~/);
 141   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 142   my $tried_file_homedir;
 143   my $homedir = do {
 144     if (eval { require File::HomeDir } && $File::HomeDir::VERSION >= 0.65) {
 145       $tried_file_homedir = 1;
 146       if (defined $user) {
 147         File::HomeDir->users_home($user);
 148       } else {
 149         File::HomeDir->my_home;
 150       }
 151     } else {
 152       if (defined $user) {
 153         (getpwnam $user)[7];
 154       } else {
 155         if (defined $ENV{HOME}) {
 156           $ENV{HOME};
 157         } else {
 158           (getpwuid $<)[7];
 159         }
 160       }
 161     }
 162   };
 163   unless (defined $homedir) {
 164     Carp::croak(
 165       "Couldn't resolve homedir for "
 166       .(defined $user ? $user : 'current user')
 167       .($tried_file_homedir ? '' : ' - consider installing File::HomeDir')
 168     );
 169   }
 170   $path =~ s/^~[^\/]*/$homedir/;
 171   $path;
 172 }
 173
 174 sub resolve_relative_path {
 175   my ($class, $path) = @_;
 176   $path = File::Spec->rel2abs($path);
 177 }
 178
 179 =begin testing
 180
 181 #:: test classmethod
 182
 183 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 184 is($c->resolve_relative_path('bar'),'FOObar');
 185
 186 =end testing
 187
 188 =cut
 189
 190 sub setup_local_lib_for {
 191   my ($class, $path) = @_;
 192   $path = $class->ensure_dir_structure_for($path);
 193   if ($0 eq '-') {
 194     $class->print_environment_vars_for($path);
 195     exit 0;
 196   } else {
 197     $class->setup_env_hash_for($path);
 198     @INC = _uniq(split($Config{path_sep}, $ENV{PERL5LIB}), @INC);
 199   }
 200 }
 201
 202 sub install_base_bin_path {
 203   my ($class, $path) = @_;
 204   File::Spec->catdir($path, 'bin');
 205 }
 206
 207 sub install_base_perl_path {
 208   my ($class, $path) = @_;
 209   File::Spec->catdir($path, 'lib', 'perl5');
 210 }
 211
 212 sub install_base_arch_path {
 213   my ($class, $path) = @_;
 214   File::Spec->catdir($class->install_base_perl_path($path), $Config{archname});
 215 }
 216
 217 sub ensure_dir_structure_for {
 218   my ($class, $path) = @_;
 219   unless (-d $path) {
 220     warn "Attempting to create directory ${path}\n";
 221   }
 222   File::Path::mkpath($path);
 223   # Need to have the path exist to make a short name for it, so
 224   # converting to a short name here.
 225   $path = Win32::GetShortPathName($path) if $^O eq 'MSWin32';
 226
 227   return $path;
 228 }
 229
 230 sub INTERPOLATE_ENV () { 1 }
 231 sub LITERAL_ENV     () { 0 }
 232
 233 sub print_environment_vars_for {
 234   my ($class, $path) = @_;
 235   my @envs = $class->build_environment_vars_for($path, LITERAL_ENV);
 236   my $out = '';
 237
 238   # rather basic csh detection, goes on the assumption that something won't
 239   # call itself csh unless it really is. also, default to bourne in the
 240   # pathological situation where a user doesn't have $ENV{SHELL} defined.
 241   # note also that shells with funny names, like zoid, are assumed to be
 242   # bourne.
 243   my $shellbin = 'sh';
 244   if(defined $ENV{'SHELL'}) {
 245       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 246       $shellbin = $shell_bin_path_parts[-1];
 247   }
 248   my $shelltype = do {
 249       local $_ = $shellbin;
 250       if(/csh/) {
 251           'csh'
 252       } else {
 253           'bourne'
 254       }
 255   };
 256
 257   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 258   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 259       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 260       $shellbin = $shell_bin_path_parts[-1];
 261          $shelltype = do {
 262                  local $_ = $shellbin;
 263                  if(/command\.com/) {
 264                          'win32'
 265                  } elsif(/cmd\.exe/) {
 266                          'win32'
 267                  } elsif(/4nt\.exe/) {
 268                          'win32'
 269                  } else {
 270                          $shelltype
 271                  }
 272          };
 273   }
 274
 275   while (@envs) {
 276     my ($name, $value) = (shift(@envs), shift(@envs));
 277     $value =~ s/(\\")/\\$1/g;
 278     $out .= $class->${\"build_${shelltype}_env_declaration"}($name, $value);
 279   }
 280   print $out;
 281 }
 282
 283 # simple routines that take two arguments: an %ENV key and a value. return
 284 # strings that are suitable for passing directly to the relevant shell to set
 285 # said key to said value.
 286 sub build_bourne_env_declaration {
 287   my $class = shift;
 288   my($name, $value) = @_;
 289   return qq{export ${name}="${value}"\n};
 290 }
 291
 292 sub build_csh_env_declaration {
 293   my $class = shift;
 294   my($name, $value) = @_;
 295   return qq{setenv ${name} "${value}"\n};
 296 }
 297
 298 sub build_win32_env_declaration {
 299   my $class = shift;
 300   my($name, $value) = @_;
 301   return qq{set ${name}=${value}\n};
 302 }
 303
 304 sub setup_env_hash_for {
 305   my ($class, $path) = @_;
 306   my %envs = $class->build_environment_vars_for($path, INTERPOLATE_ENV);
 307   @ENV{keys %envs} = values %envs;
 308 }
 309
 310 sub build_environment_vars_for {
 311   my ($class, $path, $interpolate) = @_;
 312   return (
 313     PERL_MB_OPT => "--install_base ${path}",
 314     PERL_MM_OPT => "INSTALL_BASE=${path}",
 315     PERL5LIB => join($Config{path_sep},
 316                   $class->install_base_arch_path($path),
 317                   $class->install_base_perl_path($path),
 318                   (($ENV{PERL5LIB}||()) ?
 319                     ($interpolate == INTERPOLATE_ENV
 320                       ? ($ENV{PERL5LIB})
 321                       : (($^O ne 'MSWin32') ? '$PERL5LIB' : '%PERL5LIB%' ))
 322                     : ())
 323                 ),
 324     PATH => join($Config{path_sep},
 325               $class->install_base_bin_path($path),
 326               ($interpolate == INTERPOLATE_ENV
 327                 ? ($ENV{PATH}||())
 328                 : (($^O ne 'MSWin32') ? '$PATH' : '%PATH%' ))
 329              ),
 330   )
 331 }
 332
 333 =begin testing
 334
 335 #:: test classmethod
 336
 337 File::Path::rmtree('t/var/splat');
 338
 339 $c->ensure_dir_structure_for('t/var/splat');
 340
 341 ok(-d 't/var/splat');
 342
 343 =end testing
 344
 345 =encoding utf8
 346
 347 =head1 NAME
 348
 349 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 350
 351 =head1 SYNOPSIS
 352
 353 In code -
 354
 355   use local::lib; # sets up a local lib at ~/perl5
 356
 357   use local::lib '~/foo'; # same, but ~/foo
 358
 359   # Or...
 360   use FindBin;
 361   use local::lib "$FindBin::Bin/../support";  # app-local support library
 362
 363 From the shell -
 364
 365   # Install LWP and its missing dependencies to the '~/perl5' directory
 366   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 367
 368   # Just print out useful shell commands
 369   $ perl -Mlocal::lib
 370   export PERL_MB_OPT='--install_base /home/username/perl5'
 371   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl'
 372   export PERL5LIB='/home/username/perl/lib/perl5:/home/username/perl/lib/perl5/i386-linux'
 373   export PATH="/home/username/perl/bin:$PATH"
 374
 375 =head2 The bootstrapping technique
 376
 377 A typical way to install local::lib is using what is known as the
 378 "bootstrapping" technique.  You would do this if your system administrator
 379 hasn't already installed local::lib.  In this case, you'll need to install
 380 local::lib in your home directory.
 381
 382 If you do have administrative privileges, you will still want to set up your
 383 environment variables, as discussed in step 4. Without this, you would still
 384 install the modules into the system CPAN installation and also your Perl scripts
 385 will not use the lib/ path you bootstrapped with local::lib.
 386
 387 By default local::lib installs itself and the CPAN modules into ~/perl5.
 388
 389 Windows users must also see L</Differences when using this module under Win32>.
 390
 391 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 392 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 393 or administrator.  Unpack the file in your home directory or in any other
 394 convenient location.
 395
 396 2. Run this:
 397
 398   perl Makefile.PL --bootstrap
 399
 400 If the system asks you whether it should automatically configure as much
 401 as possible, you would typically answer yes.
 402
 403 In order to install local::lib into a directory other than the default, you need
 404 to specify the name of the directory when you call bootstrap, as follows:
 405
 406   perl Makefile.PL --bootstrap=~/foo
 407
 408 3. Run this: (local::lib assumes you have make installed on your system)
 409
 410   make test && make install
 411
 412 4. Now we need to setup the appropriate environment variables, so that Perl
 413 starts using our newly generated lib/ directory. If you are using bash or
 414 any other Bourne shells, you can add this to your shell startup script this
 415 way:
 416
 417   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 418
 419 If you are using C shell, you can do this as follows:
 420
 421   /bin/csh
 422   echo $SHELL
 423   /bin/csh
 424   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 425
 426 If you passed to bootstrap a directory other than default, you also need to give that as
 427 import parameter to the call of the local::lib module like this way:
 428
 429   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 430
 431 After writing your shell configuration file, be sure to re-read it to get the
 432 changed settings into your current shell's environment. Bourne shells use
 433 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 434
 435 If you're on a slower machine, or are operating under draconian disk space
 436 limitations, you can disable the automatic generation of manpages from POD when
 437 installing modules by using the C<--no-manpages> argument when bootstrapping:
 438
 439   perl Makefile.PL --bootstrap --no-manpages
 440
 441 To avoid doing several bootstrap for several Perl module environments on the
 442 same account, for example if you use it for several different deployed
 443 applications independently, you can use one bootstrapped local::lib
 444 installation to install modules in different directories directly this way:
 445
 446   cd ~/mydir1
 447   perl -Mlocal::lib=./
 448   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 449   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 450   perl -MCPAN -e install ...    ### whatever modules you want
 451   cd ../mydir2
 452   ... REPEAT ...
 453
 454 For multiple environments for multiple apps you may need to include a modified
 455 version of the C<< use FindBin >> instructions in the "In code" sample above.
 456 If you did something like the above, you have a set of Perl modules at C<<
 457 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 458 you need to tell it where to find the modules you installed for it at C<<
 459 ~/mydir1/lib >>.
 460
 461 In C<< ~/mydir1/scripts/myscript.pl >>:
 462
 463   use strict;
 464   use warnings;
 465   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 466   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 467
 468 Put this before any BEGIN { ... } blocks that require the modules you installed.
 469
 470 =head2 Differences when using this module under Win32
 471
 472 To set up the proper environment variables for your current session of
 473 C<CMD.exe>, you can use this:
 474
 475   C:\>perl -Mlocal::lib
 476   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 477   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 478   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5;C:\DOCUME~1\ADMINI~1\perl5\lib\perl5\MSWin32-x86-multi-thread
 479   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 480
 481   ### To set the environment for this shell alone
 482   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\temp.bat
 483   ### instead of $(perl -Mlocal::lib=./)
 484
 485 If you want the environment entries to persist, you'll need to add then to the
 486 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 487
 488 The "~" is translated to the user's profile directory (the directory named for
 489 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 490 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 491 directory is translated to a short name (which means the directory must exist)
 492 and the subdirectories are created.
 493
 494 =head1 RATIONALE
 495
 496 The version of a Perl package on your machine is not always the version you
 497 need.  Obviously, the best thing to do would be to update to the version you
 498 need.  However, you might be in a situation where you're prevented from doing
 499 this.  Perhaps you don't have system administrator privileges; or perhaps you
 500 are using a package management system such as Debian, and nobody has yet gotten
 501 around to packaging up the version you need.
 502
 503 local::lib solves this problem by allowing you to create your own directory of
 504 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 505 be within your own home directory).  The existing system Perl installation is
 506 not affected; you simply invoke Perl with special options so that Perl uses the
 507 packages in your own local package directory rather than the system packages.
 508 local::lib arranges things so that your locally installed version of the Perl
 509 packages takes precedence over the system installation.
 510
 511 If you are using a package management system (such as Debian), you don't need to
 512 worry about Debian and CPAN stepping on each other's toes.  Your local version
 513 of the packages will be written to an entirely separate directory from those
 514 installed by Debian.
 515
 516 =head1 DESCRIPTION
 517
 518 This module provides a quick, convenient way of bootstrapping a user-local Perl
 519 module library located within the user's home directory. It also constructs and
 520 prints out for the user the list of environment variables using the syntax
 521 appropriate for the user's current shell (as specified by the C<SHELL>
 522 environment variable), suitable for directly adding to one's shell
 523 configuration file.
 524
 525 More generally, local::lib allows for the bootstrapping and usage of a
 526 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 527 easier to ship an application with an app-specific copy of a Perl module, or
 528 collection of modules. Useful in cases like when an upstream maintainer hasn't
 529 applied a patch to a module of theirs that you need for your application.
 530
 531 On import, local::lib sets the following environment variables to appropriate
 532 values:
 533
 534 =over 4
 535
 536 =item PERL_MB_OPT
 537
 538 =item PERL_MM_OPT
 539
 540 =item PERL5LIB
 541
 542 =item PATH
 543
 544 PATH is appended to, rather than clobbered.
 545
 546 =back
 547
 548 These values are then available for reference by any code after import.
 549
 550 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 551
 552 See L<lib::core::only> for one way to do this - but note that
 553 there are a number of caveats, and the best approach is always to perform a
 554 build against a clean perl (i.e. site and vendor as close to empty as possible).
 555
 556 =head1 METHODS
 557
 558 =head2 ensure_dir_structure_for
 559
 560 =over 4
 561
 562 =item Arguments: $path
 563
 564 =item Return value: None
 565
 566 =back
 567
 568 Attempts to create the given path, and all required parent directories. Throws
 569 an exception on failure.
 570
 571 =head2 print_environment_vars_for
 572
 573 =over 4
 574
 575 =item Arguments: $path
 576
 577 =item Return value: None
 578
 579 =back
 580
 581 Prints to standard output the variables listed above, properly set to use the
 582 given path as the base directory.
 583
 584 =head2 build_environment_vars_for
 585
 586 =over 4
 587
 588 =item Arguments: $path, $interpolate
 589
 590 =item Return value: \%environment_vars
 591
 592 =back
 593
 594 Returns a hash with the variables listed above, properly set to use the
 595 given path as the base directory.
 596
 597 =head2 setup_env_hash_for
 598
 599 =over 4
 600
 601 =item Arguments: $path
 602
 603 =item Return value: None
 604
 605 =back
 606
 607 Constructs the C<%ENV> keys for the given path, by calling
 608 L</build_environment_vars_for>.
 609
 610 =head2 install_base_perl_path
 611
 612 =over 4
 613
 614 =item Arguments: $path
 615
 616 =item Return value: $install_base_perl_path
 617
 618 =back
 619
 620 Returns a path describing where to install the Perl modules for this local
 621 library installation. Appends the directories C<lib> and C<perl5> to the given
 622 path.
 623
 624 =head2 install_base_arch_path
 625
 626 =over 4
 627
 628 =item Arguments: $path
 629
 630 =item Return value: $install_base_arch_path
 631
 632 =back
 633
 634 Returns a path describing where to install the architecture-specific Perl
 635 modules for this local library installation. Based on the
 636 L</install_base_perl_path> method's return value, and appends the value of
 637 C<$Config{archname}>.
 638
 639 =head2 install_base_bin_path
 640
 641 =over 4
 642
 643 =item Arguments: $path
 644
 645 =item Return value: $install_base_bin_path
 646
 647 =back
 648
 649 Returns a path describing where to install the executable programs for this
 650 local library installation. Based on the L</install_base_perl_path> method's
 651 return value, and appends the directory C<bin>.
 652
 653 =head2 resolve_empty_path
 654
 655 =over 4
 656
 657 =item Arguments: $path
 658
 659 =item Return value: $base_path
 660
 661 =back
 662
 663 Builds and returns the base path into which to set up the local module
 664 installation. Defaults to C<~/perl5>.
 665
 666 =head2 resolve_home_path
 667
 668 =over 4
 669
 670 =item Arguments: $path
 671
 672 =item Return value: $home_path
 673
 674 =back
 675
 676 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 677 for this purpose. If no definite answer is available, throws an exception.
 678
 679 =head2 resolve_relative_path
 680
 681 =over 4
 682
 683 =item Arguments: $path
 684
 685 =item Return value: $absolute_path
 686
 687 =back
 688
 689 Translates the given path into an absolute path.
 690
 691 =head2 resolve_path
 692
 693 =over 4
 694
 695 =item Arguments: $path
 696
 697 =item Return value: $absolute_path
 698
 699 =back
 700
 701 Calls the following in a pipeline, passing the result from the previous to the
 702 next, in an attempt to find where to configure the environment for a local
 703 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 704 L</resolve_relative_path>. Passes the given path argument to
 705 L</resolve_empty_path> which then returns a result that is passed to
 706 L</resolve_home_path>, which then has its result passed to
 707 L</resolve_relative_path>. The result of this final call is returned from
 708 L</resolve_path>.
 709
 710 =head1 A WARNING ABOUT UNINST=1
 711
 712 Be careful about using local::lib in combination with "make install UNINST=1".
 713 The idea of this feature is that will uninstall an old version of a module
 714 before installing a new one. However it lacks a safety check that the old
 715 version and the new version will go in the same directory. Used in combination
 716 with local::lib, you can potentially delete a globally accessible version of a
 717 module while installing the new version in a local place. Only combine "make
 718 install UNINST=1" and local::lib if you understand these possible consequences.
 719
 720 =head1 LIMITATIONS
 721
 722 The perl toolchain is unable to handle directory names with spaces in it,
 723 so you cant put your local::lib bootstrap into a directory with spaces. What
 724 you can do is moving your local::lib to a directory with spaces B<after> you
 725 installed all modules inside your local::lib bootstrap. But be aware that you
 726 cant update or install CPAN modules after the move.
 727
 728 Rather basic shell detection. Right now anything with csh in its name is
 729 assumed to be a C shell or something compatible, and everything else is assumed
 730 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 731 not set, a Bourne-compatible shell is assumed.
 732
 733 Bootstrap is a hack and will use CPAN.pm for ExtUtils::MakeMaker even if you
 734 have CPANPLUS installed.
 735
 736 Kills any existing PERL5LIB, PERL_MM_OPT or PERL_MB_OPT.
 737
 738 Should probably auto-fixup CPAN config if not already done.
 739
 740 Patches very much welcome for any of the above.
 741
 742 On Win32 systems, does not have a way to write the created environment variables
 743 to the registry, so that they can persist through a reboot.
 744
 745 =head1 TROUBLESHOOTING
 746
 747 If you've configured local::lib to install CPAN modules somewhere in to your
 748 home directory, and at some point later you try to install a module with C<cpan
 749 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
 750 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
 751 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
 752 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
 753 you've somehow lost your updated ExtUtils::MakeMaker module.
 754
 755 To remedy this situation, rerun the bootstrapping procedure documented above.
 756
 757 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
 758
 759 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
 760
 761 =head1 ENVIRONMENT
 762
 763 =over 4
 764
 765 =item SHELL
 766
 767 =item COMSPEC
 768
 769 local::lib looks at the user's C<SHELL> environment variable when printing out
 770 commands to add to the shell configuration file.
 771
 772 On Win32 systems, C<COMSPEC> is also examined.
 773
 774 =back
 775
 776 =head1 SUPPORT
 777
 778 IRC:
 779
 780     Join #local-lib on irc.perl.org.
 781
 782 =head1 AUTHOR
 783
 784 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
 785
 786 auto_install fixes kindly sponsored by http://www.takkle.com/
 787
 788 =head1 CONTRIBUTORS
 789
 790 Patches to correctly output commands for csh style shells, as well as some
 791 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
 792
 793 Doc patches for a custom local::lib directory, more cleanups in the english
 794 documentation and a L<german documentation|POD2::DE::local::lib> contributed by Torsten Raudssus
 795 <torsten@raudssus.de>.
 796
 797 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
 798 things will install properly, submitted a fix for the bug causing problems with
 799 writing Makefiles during bootstrapping, contributed an example program, and
 800 submitted yet another fix to ensure that local::lib can install and bootstrap
 801 properly. Many, many thanks!
 802
 803 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
 804 section. Many thanks!
 805
 806 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
 807
 808 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
 809 by a patch from Marco Emilio Poleggi.
 810
 811 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
 812 '--self-contained' option.
 813
 814 Documentation patches to make win32 usage clearer by
 815 David Mertens <dcmertens.perl@gmail.com> (run4flat).
 816
 817 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc patches contributed by Breno
 818 G. de Oliveira <garu@cpan.org>.
 819
 820 =head1 COPYRIGHT
 821
 822 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
 823 listed above.
 824
 825 =head1 LICENSE
 826
 827 This library is free software and may be distributed under the same terms
 828 as perl itself.
 829
 830 =cut
 831
 832 1;