lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '1.008026'; # 1.8.26
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16
  17   my @steps;
  18   my %opts;
  19
  20   while (@args) {
  21     my $arg = shift @args;
  22     # check for lethal dash first to stop processing before causing problems
  23     # the fancy dash is U+2212 or \xE2\x88\x92
  24     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  25       die <<'DEATH';
  26 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  27 These are *not* the traditional -- dashes that software recognizes. You
  28 probably got these by copy-pasting from the perldoc for this module as
  29 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  30 terminal, but can happen elsewhere too. Please try again after replacing the
  31 dashes with normal minus signs.
  32 DEATH
  33     }
  34     elsif ($arg eq '--self-contained') {
  35       die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  36     }
  37     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  38       my $path = defined $1 ? $1 : shift @args;
  39       push @steps, ['deactivate', $path];
  40     }
  41     elsif ( $arg eq '--deactivate-all' ) {
  42       push @steps, ['deactivate_all'];
  43     }
  44     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  45       my $shell = defined $1 ? $1 : shift @args;
  46       $opts{shelltype} = $shell;
  47     }
  48     elsif ( $arg eq '--no-create' ) {
  49       $opts{no_create} = 1;
  50     }
  51     elsif ( $arg =~ /^--/ ) {
  52       die "Unknown import argument: $arg";
  53     }
  54     else {
  55       push @steps, ['activate', $arg];
  56     }
  57   }
  58   if (!@steps) {
  59     push @steps, ['activate', undef];
  60   }
  61
  62   my $self = $class->new(%opts);
  63
  64   for (@steps) {
  65     my ($method, @args) = @$_;
  66     $self = $self->$method(@args);
  67   }
  68
  69   if ($0 eq '-') {
  70     $self->print_environment_vars_for;
  71     exit 0;
  72   }
  73   else {
  74     $self->setup_local_lib_for;
  75   }
  76 }
  77
  78 sub new {
  79   my $class = shift;
  80   bless {@_}, $class;
  81 }
  82
  83 sub clone {
  84   my $self = shift;
  85   bless {%$self, @_}, ref $self;
  86 }
  87
  88 sub inc { $_[0]->{inc}     ||= \@INC }
  89 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
  90 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
  91 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
  92 sub extra { $_[0]->{extra} ||= {} }
  93 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
  94 sub no_create { $_[0]->{no_create} }
  95
  96 my $_archname = $Config{archname};
  97 my $_version  = $Config{version};
  98 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
  99 my $_path_sep = $Config{path_sep};
 100
 101 sub _as_list {
 102   my $list = shift;
 103   grep length, map {
 104     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 105       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 106                         : ()
 107     )
 108   } ref $list ? @$list : $list;
 109 }
 110 sub _remove_from {
 111   my ($list, @remove) = @_;
 112   my %remove = map { $_ => 1 } @remove;
 113   grep !$remove{$_}, _as_list($list);
 114 }
 115
 116 my @_lib_subdirs = (
 117   [$_version, $_archname],
 118   [$_version],
 119   [$_archname],
 120   (@_inc_version_list ? \@_inc_version_list : ()),
 121   [],
 122 );
 123
 124 sub install_base_bin_path {
 125   my ($class, $path) = @_;
 126   return File::Spec->catdir($path, 'bin');
 127 }
 128 sub install_base_perl_path {
 129   my ($class, $path) = @_;
 130   return File::Spec->catdir($path, 'lib', 'perl5');
 131 }
 132 sub install_base_arch_path {
 133   my ($class, $path) = @_;
 134   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 135 }
 136
 137 sub lib_paths_for {
 138   my ($class, $path) = @_;
 139   my $base = $class->install_base_perl_path($path);
 140   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 141 }
 142
 143 sub _mm_escape_path {
 144   my $path = shift;
 145   $path =~ s/\\/\\\\\\\\/g;
 146   if ($path =~ s/ /\\ /g) {
 147     $path = qq{"\\"$path\\""};
 148   }
 149   return $path;
 150 }
 151
 152 sub _mb_escape_path {
 153   my $path = shift;
 154   $path =~ s/\\/\\\\/g;
 155   return qq{"$path"};
 156 }
 157
 158 sub installer_options_for {
 159   my ($class, $path) = @_;
 160   return {
 161     PERL_MM_OPT => defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 162     PERL_MB_OPT => defined $path ? "--install_base "._mb_escape_path($path) : undef,
 163   };
 164 }
 165
 166 sub active_paths {
 167   my ($self) = @_;
 168   $self = ref $self ? $self : $self->new;
 169
 170   return grep {
 171     # screen out entries that aren't actually reflected in @INC
 172     my $active_ll = $self->install_base_perl_path($_);
 173     grep { $_ eq $active_ll } @{$self->inc};
 174   } _as_list($self->roots);
 175 }
 176
 177
 178 sub deactivate {
 179   my ($self, $path) = @_;
 180   $self = $self->new unless ref $self;
 181   $path = $self->resolve_path($path);
 182
 183   my @active_lls = $self->active_paths;
 184
 185   if (!grep { $_ eq $path } @active_lls) {
 186     warn "Tried to deactivate inactive local::lib '$path'\n";
 187     return;
 188   }
 189
 190   my %args = (
 191     bins  => [ _remove_from($self->bins,  $self->install_base_bin_path($path)) ],
 192     libs  => [ _remove_from($self->libs,  $self->install_base_perl_path($path)) ],
 193     inc   => [ _remove_from($self->inc,   $self->lib_paths_for($path)) ],
 194     roots => [ _remove_from($self->roots, $path) ],
 195   );
 196
 197   $args{extra} = $self->installer_options_for($args{roots}[0]);
 198
 199   $self->clone(%args);
 200 }
 201
 202 sub deactivate_all {
 203   my ($self) = @_;
 204   $self = $self->new unless ref $self;
 205
 206   my @active_lls = $self->active_paths;
 207
 208   my %args = (
 209     bins => [ _remove_from($self->bins,
 210       map $self->install_base_bin_path($_), @active_lls) ],
 211     libs => [ _remove_from($self->libs,
 212       map $self->install_base_perl_path($_), @active_lls) ],
 213     inc => [ _remove_from($self->inc,
 214       map $self->lib_paths_for($_), @active_lls) ],
 215     roots => [ _remove_from($self->roots, @active_lls) ],
 216   );
 217
 218   $args{extra} = $self->installer_options_for(undef);
 219
 220   $self->clone(%args);
 221 }
 222
 223 sub activate {
 224   my ($self, $path) = @_;
 225   $self = $self->new unless ref $self;
 226   $path = $self->resolve_path($path);
 227   $self->ensure_dir_structure_for($path)
 228     unless $self->no_create;
 229
 230   my @active_lls = $self->active_paths;
 231
 232   if (grep { $_ eq $path } @active_lls) {
 233     $self = $self->deactivate($path);
 234   }
 235
 236   my %args = (
 237     bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 238     libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 239     inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 240     roots => [ $path, @{$self->roots} ],
 241   );
 242
 243   $args{extra} = $self->installer_options_for($path);
 244
 245   $self->clone(%args);
 246 }
 247
 248 sub _legacy {
 249   my ($self, $path) = @_;
 250   $self = $self->new unless ref $self;
 251   if (defined $path) {
 252     $self = $self->activate($path);
 253   }
 254   $self;
 255 }
 256
 257 sub build_environment_vars_for {
 258   my ($self) = _legacy(@_);
 259   (
 260     PATH                => join($_path_sep, _as_list($self->bins)),
 261     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 262     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 263     %{$self->extra},
 264   );
 265 }
 266
 267 sub setup_local_lib_for {
 268   my ($self) = _legacy(@_);
 269   $self->setup_env_hash_for;
 270   @INC = @{$self->inc};
 271 }
 272
 273 sub setup_env_hash_for {
 274   my $self = shift;
 275   my %env = $self->build_environment_vars_for(@_);
 276   for my $key (keys %env) {
 277     if (defined $env{$key}) {
 278       $ENV{$key} = $env{$key};
 279     }
 280     else {
 281       delete $ENV{$key};
 282     }
 283   }
 284 }
 285
 286 sub print_environment_vars_for {
 287   my $self = shift;
 288   print $self->environment_vars_string_for(@_);
 289 }
 290
 291 sub environment_vars_string_for {
 292   my $self = _legacy(@_);
 293
 294   my $build_method = 'build_' . $self->shelltype . '_env_declaration';
 295
 296   my @envs = (
 297     PATH                => $self->bins,
 298     PERL5LIB            => $self->libs,
 299     PERL_LOCAL_LIB_ROOT => $self->roots,
 300     %{$self->extra},
 301   );
 302   my $out = '';
 303   while (@envs) {
 304     my ($name, $value) = (shift(@envs), shift(@envs));
 305     if (
 306         ref $value
 307         && @$value == 1
 308         && ref $value->[0]
 309         && ref $value->[0] eq 'SCALAR'
 310         && ${$value->[0]} eq $name) {
 311       next;
 312     }
 313     if (!ref $value
 314         && $value eq $ENV{$name}) {
 315       next;
 316     }
 317     $out .= $self->$build_method($name, $value);
 318   }
 319   return $out;
 320 }
 321
 322 sub build_bourne_env_declaration {
 323   my ($class, $name, $args) = @_;
 324   my $value = $class->_interpolate($args);
 325   $value =~ s/"/\\"/g
 326     if defined $value;
 327   return defined($value) ? qq{export ${name}="${value}"\n} : qq{unset ${name}\n};
 328 }
 329 sub build_csh_env_declaration {
 330   my ($class, $name, $args) = @_;
 331   my ($value, @vars) = $class->_interpolate($args);
 332   @vars = grep { $_ ne $name || defined $value } @vars;
 333   $value =~ s/"/"\\""/g
 334     if defined $value;
 335   join '',
 336     (map qq{if ! \$?$_ setenv $_ "";\n}, @vars),
 337     (defined($value)
 338       ? qq{setenv $name "$value";\n}
 339       : qq{unsetenv $name;\n});
 340 }
 341 sub build_cmd_env_declaration {
 342   my ($class, $name, $args) = @_;
 343   my $value = $class->_interpolate($args, '%', '%');
 344   $value =~ s/"/\\"/g
 345     if defined $value;
 346   return qq{set $name=} . (defined($value) ? qq{"$value"} : '') . "\n";
 347 }
 348 sub build_powershell_env_declaration {
 349   my ($class, $name, $args) = @_;
 350   my $value = $class->_interpolate($args, '$env:');
 351   if (defined $value) {
 352     $value =~ s/"/\\"/g;
 353     return qq{\$env:$name = "$value"\n};
 354   }
 355   return "Remove-Item Env:\\$name\n";
 356 }
 357
 358
 359 sub _interpolate {
 360   my ($class, $args, $start, $end) = @_;
 361   return
 362     unless defined $args;
 363   return $args
 364     unless ref $args;
 365   return
 366     unless @$args;
 367   $start = '$' unless defined $start;
 368   $end = '' unless defined $end;
 369   my @vars;
 370   my $string = join($Config{path_sep}, map {
 371     (ref $_ && ref $_ eq 'SCALAR') ? do { push @vars, $$_; $start.$$_.$end }
 372       : $_
 373   } @$args);
 374   return wantarray ? ($string, @vars) : $string;
 375 }
 376
 377 sub pipeline;
 378
 379 sub pipeline {
 380   my @methods = @_;
 381   my $last = pop(@methods);
 382   if (@methods) {
 383     \sub {
 384       my ($obj, @args) = @_;
 385       $obj->${pipeline @methods}(
 386         $obj->$last(@args)
 387       );
 388     };
 389   } else {
 390     \sub {
 391       shift->$last(@_);
 392     };
 393   }
 394 }
 395
 396 =begin testing
 397
 398 #:: test pipeline
 399
 400 package local::lib;
 401
 402 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 403 my $foo = bless({}, 'Foo');
 404 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 405
 406 =end testing
 407
 408 =cut
 409
 410 sub resolve_path {
 411   my ($class, $path) = @_;
 412
 413   $path = $class->${pipeline qw(
 414     resolve_relative_path
 415     resolve_home_path
 416     resolve_empty_path
 417   )}($path);
 418
 419   $path = Win32::GetShortPathName($path)
 420     if $^O eq 'MSWin32';
 421
 422   $path;
 423 }
 424
 425 sub resolve_empty_path {
 426   my ($class, $path) = @_;
 427   if (defined $path) {
 428     $path;
 429   } else {
 430     '~/perl5';
 431   }
 432 }
 433
 434 =begin testing
 435
 436 #:: test classmethod setup
 437
 438 my $c = 'local::lib';
 439
 440 =end testing
 441
 442 =begin testing
 443
 444 #:: test classmethod
 445
 446 is($c->resolve_empty_path, '~/perl5');
 447 is($c->resolve_empty_path('foo'), 'foo');
 448
 449 =end testing
 450
 451 =cut
 452
 453 sub resolve_home_path {
 454   my ($class, $path) = @_;
 455   return $path unless ($path =~ /^~/);
 456   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 457   my $homedir = do {
 458     if (!defined $user && defined $ENV{HOME}) {
 459       $ENV{HOME}
 460     }
 461     else {
 462       require File::Glob;
 463       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 464     }
 465   };
 466   unless (defined $homedir) {
 467     require Carp;
 468     Carp::croak(
 469       "Couldn't resolve homedir for "
 470       .(defined $user ? $user : 'current user')
 471     );
 472   }
 473   $path =~ s/^~[^\/]*/$homedir/;
 474   $path;
 475 }
 476
 477 sub resolve_relative_path {
 478   my ($class, $path) = @_;
 479   $path = File::Spec->rel2abs($path);
 480 }
 481
 482 =begin testing
 483
 484 #:: test classmethod
 485
 486 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 487 is($c->resolve_relative_path('bar'),'FOObar');
 488
 489 =end testing
 490
 491 =cut
 492
 493 sub ensure_dir_structure_for {
 494   my ($class, $path) = @_;
 495   unless (-d $path) {
 496     warn "Attempting to create directory ${path}\n";
 497   }
 498   require File::Basename;
 499   my @dirs;
 500   while(!-d $path) {
 501     push @dirs, $path;
 502     $path = File::Basename::dirname($path);
 503   }
 504   mkdir $_ for reverse @dirs;
 505   return;
 506 }
 507
 508 =begin testing
 509
 510 #:: test classmethod
 511
 512 File::Path::rmtree('t/var/splat');
 513
 514 $c->ensure_dir_structure_for('t/var/splat');
 515
 516 ok(-d 't/var/splat');
 517
 518 =end testing
 519
 520 =cut
 521
 522 sub guess_shelltype {
 523   my $shellbin = 'sh';
 524   if(defined $ENV{'SHELL'}) {
 525       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 526       $shellbin = $shell_bin_path_parts[-1];
 527   }
 528   my $shelltype = do {
 529       local $_ = $shellbin;
 530       if(/csh/) {
 531           'csh'
 532       } else {
 533           'bourne'
 534       }
 535   };
 536
 537   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 538   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 539       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 540       $shellbin = $shell_bin_path_parts[-1];
 541          $shelltype = do {
 542                  local $_ = $shellbin;
 543                  if(/command\.com/) {
 544                          'cmd'
 545                  } elsif(/cmd\.exe/) {
 546                          'cmd'
 547                  } elsif(/4nt\.exe/) {
 548                          'cmd'
 549                  } else {
 550                          $shelltype
 551                  }
 552          };
 553   }
 554   return $shelltype;
 555 }
 556
 557 1;
 558 __END__
 559
 560 =encoding utf8
 561
 562 =head1 NAME
 563
 564 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 565
 566 =head1 SYNOPSIS
 567
 568 In code -
 569
 570   use local::lib; # sets up a local lib at ~/perl5
 571
 572   use local::lib '~/foo'; # same, but ~/foo
 573
 574   # Or...
 575   use FindBin;
 576   use local::lib "$FindBin::Bin/../support";  # app-local support library
 577
 578 From the shell -
 579
 580   # Install LWP and its missing dependencies to the '~/perl5' directory
 581   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 582
 583   # Just print out useful shell commands
 584   $ perl -Mlocal::lib
 585   export PERL_MB_OPT='--install_base /home/username/perl5'
 586   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 587   export PERL5LIB="/home/username/perl5/lib/perl5"
 588   export PATH="/home/username/perl5/bin:$PATH"
 589
 590 =head2 The bootstrapping technique
 591
 592 A typical way to install local::lib is using what is known as the
 593 "bootstrapping" technique.  You would do this if your system administrator
 594 hasn't already installed local::lib.  In this case, you'll need to install
 595 local::lib in your home directory.
 596
 597 Even if you do have administrative privileges, you will still want to set up your
 598 environment variables, as discussed in step 4. Without this, you would still
 599 install the modules into the system CPAN installation and also your Perl scripts
 600 will not use the lib/ path you bootstrapped with local::lib.
 601
 602 By default local::lib installs itself and the CPAN modules into ~/perl5.
 603
 604 Windows users must also see L</Differences when using this module under Win32>.
 605
 606 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 607 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 608 or administrator.  Unpack the file in your home directory or in any other
 609 convenient location.
 610
 611 2. Run this:
 612
 613   perl Makefile.PL --bootstrap
 614
 615 If the system asks you whether it should automatically configure as much
 616 as possible, you would typically answer yes.
 617
 618 In order to install local::lib into a directory other than the default, you need
 619 to specify the name of the directory when you call bootstrap, as follows:
 620
 621   perl Makefile.PL --bootstrap=~/foo
 622
 623 3. Run this: (local::lib assumes you have make installed on your system)
 624
 625   make test && make install
 626
 627 4. Now we need to setup the appropriate environment variables, so that Perl
 628 starts using our newly generated lib/ directory. If you are using bash or
 629 any other Bourne shells, you can add this to your shell startup script this
 630 way:
 631
 632   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 633
 634 If you are using C shell, you can do this as follows:
 635
 636   /bin/csh
 637   echo $SHELL
 638   /bin/csh
 639   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 640
 641 If you passed to bootstrap a directory other than default, you also need to
 642 give that as import parameter to the call of the local::lib module like this
 643 way:
 644
 645   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 646
 647 After writing your shell configuration file, be sure to re-read it to get the
 648 changed settings into your current shell's environment. Bourne shells use
 649 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 650
 651 If you're on a slower machine, or are operating under draconian disk space
 652 limitations, you can disable the automatic generation of manpages from POD when
 653 installing modules by using the C<--no-manpages> argument when bootstrapping:
 654
 655   perl Makefile.PL --bootstrap --no-manpages
 656
 657 To avoid doing several bootstrap for several Perl module environments on the
 658 same account, for example if you use it for several different deployed
 659 applications independently, you can use one bootstrapped local::lib
 660 installation to install modules in different directories directly this way:
 661
 662   cd ~/mydir1
 663   perl -Mlocal::lib=./
 664   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 665   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 666   perl -MCPAN -e install ...    ### whatever modules you want
 667   cd ../mydir2
 668   ... REPEAT ...
 669
 670 If you are working with several C<local::lib> environments, you may want to
 671 remove some of them from the current environment without disturbing the others.
 672 You can deactivate one environment like this (using bourne sh):
 673
 674   eval $(perl -Mlocal::lib=--deactivate,~/path)
 675
 676 which will generate and run the commands needed to remove C<~/path> from your
 677 various search paths. Whichever environment was B<activated most recently> will
 678 remain the target for module installations. That is, if you activate
 679 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 680 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 681 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 682 installed in C<~/pathB> because pathB was activated later.
 683
 684 You can also ask C<local::lib> to clean itself completely out of the current
 685 shell's environment with the C<--deactivate-all> option.
 686 For multiple environments for multiple apps you may need to include a modified
 687 version of the C<< use FindBin >> instructions in the "In code" sample above.
 688 If you did something like the above, you have a set of Perl modules at C<<
 689 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 690 you need to tell it where to find the modules you installed for it at C<<
 691 ~/mydir1/lib >>.
 692
 693 In C<< ~/mydir1/scripts/myscript.pl >>:
 694
 695   use strict;
 696   use warnings;
 697   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 698   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 699
 700 Put this before any BEGIN { ... } blocks that require the modules you installed.
 701
 702 =head2 Differences when using this module under Win32
 703
 704 To set up the proper environment variables for your current session of
 705 C<CMD.exe>, you can use this:
 706
 707   C:\>perl -Mlocal::lib
 708   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 709   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 710   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 711   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 712
 713   ### To set the environment for this shell alone
 714   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 715   ### instead of $(perl -Mlocal::lib=./)
 716
 717 If you want the environment entries to persist, you'll need to add then to the
 718 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 719
 720 The "~" is translated to the user's profile directory (the directory named for
 721 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 722 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 723 directory is translated to a short name (which means the directory must exist)
 724 and the subdirectories are created.
 725
 726 =head1 RATIONALE
 727
 728 The version of a Perl package on your machine is not always the version you
 729 need.  Obviously, the best thing to do would be to update to the version you
 730 need.  However, you might be in a situation where you're prevented from doing
 731 this.  Perhaps you don't have system administrator privileges; or perhaps you
 732 are using a package management system such as Debian, and nobody has yet gotten
 733 around to packaging up the version you need.
 734
 735 local::lib solves this problem by allowing you to create your own directory of
 736 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 737 be within your own home directory).  The existing system Perl installation is
 738 not affected; you simply invoke Perl with special options so that Perl uses the
 739 packages in your own local package directory rather than the system packages.
 740 local::lib arranges things so that your locally installed version of the Perl
 741 packages takes precedence over the system installation.
 742
 743 If you are using a package management system (such as Debian), you don't need to
 744 worry about Debian and CPAN stepping on each other's toes.  Your local version
 745 of the packages will be written to an entirely separate directory from those
 746 installed by Debian.
 747
 748 =head1 DESCRIPTION
 749
 750 This module provides a quick, convenient way of bootstrapping a user-local Perl
 751 module library located within the user's home directory. It also constructs and
 752 prints out for the user the list of environment variables using the syntax
 753 appropriate for the user's current shell (as specified by the C<SHELL>
 754 environment variable), suitable for directly adding to one's shell
 755 configuration file.
 756
 757 More generally, local::lib allows for the bootstrapping and usage of a
 758 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 759 easier to ship an application with an app-specific copy of a Perl module, or
 760 collection of modules. Useful in cases like when an upstream maintainer hasn't
 761 applied a patch to a module of theirs that you need for your application.
 762
 763 On import, local::lib sets the following environment variables to appropriate
 764 values:
 765
 766 =over 4
 767
 768 =item PERL_MB_OPT
 769
 770 =item PERL_MM_OPT
 771
 772 =item PERL5LIB
 773
 774 =item PATH
 775
 776 =back
 777
 778 When possible, these will be appended to instead of overwritten entirely.
 779
 780 These values are then available for reference by any code after import.
 781
 782 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 783
 784 See L<lib::core::only> for one way to do this - but note that
 785 there are a number of caveats, and the best approach is always to perform a
 786 build against a clean perl (i.e. site and vendor as close to empty as possible).
 787
 788 =head1 OPTIONS
 789
 790 Options are values that can be passed to the C<local::lib> import besides the
 791 directory to use. They are specified as C<use local::lib '--option'[, path];>
 792 or C<perl -Mlocal::lib=--option[,path]>.
 793
 794 =head2 --deactivate
 795
 796 Remove the chosen path (or the default path) from the module search paths if it
 797 was added by C<local::lib>, instead of adding it.
 798
 799 =head2 --deactivate-all
 800
 801 Remove all directories that were added to search paths by C<local::lib> from the
 802 search paths.
 803
 804 =head2 --shelltype
 805
 806 Specify the shell type to use for output.  By default, the shell will be
 807 detected based on the environment.  Should be one of: C<bourne>, C<csh>,
 808 C<cmd>, or C<powershell>.
 809
 810 =head2 --no-create
 811
 812 Prevents C<local::lib> from creating directories when activating dirs.  This is
 813 likely to cause issues on Win32 systems.
 814
 815 =head1 METHODS
 816
 817 =head2 ensure_dir_structure_for
 818
 819 =over 4
 820
 821 =item Arguments: $path
 822
 823 =item Return value: None
 824
 825 =back
 826
 827 Attempts to create the given path, and all required parent directories. Throws
 828 an exception on failure.
 829
 830 =head2 print_environment_vars_for
 831
 832 =over 4
 833
 834 =item Arguments: $path
 835
 836 =item Return value: None
 837
 838 =back
 839
 840 Prints to standard output the variables listed above, properly set to use the
 841 given path as the base directory.
 842
 843 =head2 build_environment_vars_for
 844
 845 =over 4
 846
 847 =item Arguments: $path
 848
 849 =item Return value: %environment_vars
 850
 851 =back
 852
 853 Returns a hash with the variables listed above, properly set to use the
 854 given path as the base directory.
 855
 856 =head2 setup_env_hash_for
 857
 858 =over 4
 859
 860 =item Arguments: $path
 861
 862 =item Return value: None
 863
 864 =back
 865
 866 Constructs the C<%ENV> keys for the given path, by calling
 867 L</build_environment_vars_for>.
 868
 869 =head2 active_paths
 870
 871 =over 4
 872
 873 =item Arguments: None
 874
 875 =item Return value: @paths
 876
 877 =back
 878
 879 Returns a list of active C<local::lib> paths, according to the
 880 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 881 what is really in C<@INC>.
 882
 883 =head2 install_base_perl_path
 884
 885 =over 4
 886
 887 =item Arguments: $path
 888
 889 =item Return value: $install_base_perl_path
 890
 891 =back
 892
 893 Returns a path describing where to install the Perl modules for this local
 894 library installation. Appends the directories C<lib> and C<perl5> to the given
 895 path.
 896
 897 =head2 install_base_bin_path
 898
 899 =over 4
 900
 901 =item Arguments: $path
 902
 903 =item Return value: $install_base_bin_path
 904
 905 =back
 906
 907 Returns a path describing where to install the executable programs for this
 908 local library installation. Appends the directory C<bin> to the given path.
 909
 910 =head2 resolve_empty_path
 911
 912 =over 4
 913
 914 =item Arguments: $path
 915
 916 =item Return value: $base_path
 917
 918 =back
 919
 920 Builds and returns the base path into which to set up the local module
 921 installation. Defaults to C<~/perl5>.
 922
 923 =head2 resolve_home_path
 924
 925 =over 4
 926
 927 =item Arguments: $path
 928
 929 =item Return value: $home_path
 930
 931 =back
 932
 933 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 934 for this purpose. If no definite answer is available, throws an exception.
 935
 936 =head2 resolve_relative_path
 937
 938 =over 4
 939
 940 =item Arguments: $path
 941
 942 =item Return value: $absolute_path
 943
 944 =back
 945
 946 Translates the given path into an absolute path.
 947
 948 =head2 resolve_path
 949
 950 =over 4
 951
 952 =item Arguments: $path
 953
 954 =item Return value: $absolute_path
 955
 956 =back
 957
 958 Calls the following in a pipeline, passing the result from the previous to the
 959 next, in an attempt to find where to configure the environment for a local
 960 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 961 L</resolve_relative_path>. Passes the given path argument to
 962 L</resolve_empty_path> which then returns a result that is passed to
 963 L</resolve_home_path>, which then has its result passed to
 964 L</resolve_relative_path>. The result of this final call is returned from
 965 L</resolve_path>.
 966
 967 =head1 A WARNING ABOUT UNINST=1
 968
 969 Be careful about using local::lib in combination with "make install UNINST=1".
 970 The idea of this feature is that will uninstall an old version of a module
 971 before installing a new one. However it lacks a safety check that the old
 972 version and the new version will go in the same directory. Used in combination
 973 with local::lib, you can potentially delete a globally accessible version of a
 974 module while installing the new version in a local place. Only combine "make
 975 install UNINST=1" and local::lib if you understand these possible consequences.
 976
 977 =head1 LIMITATIONS
 978
 979 =over 4
 980
 981 =item * Directory names with spaces in them are not well supported by the perl
 982 toolchain and the programs it uses.  Pure-perl distributions should support
 983 spaces, but problems are more likely with dists that require compilation. A
 984 workaround you can do is moving your local::lib to a directory with spaces
 985 B<after> you installed all modules inside your local::lib bootstrap. But be
 986 aware that you can't update or install CPAN modules after the move.
 987
 988 =item * Rather basic shell detection. Right now anything with csh in its name is
 989 assumed to be a C shell or something compatible, and everything else is assumed
 990 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 991 not set, a Bourne-compatible shell is assumed.
 992
 993 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
 994
 995 =item * Should probably auto-fixup CPAN config if not already done.
 996
 997 =back
 998
 999 Patches very much welcome for any of the above.
1000
1001 =over 4
1002
1003 =item * On Win32 systems, does not have a way to write the created environment
1004 variables to the registry, so that they can persist through a reboot.
1005
1006 =back
1007
1008 =head1 TROUBLESHOOTING
1009
1010 If you've configured local::lib to install CPAN modules somewhere in to your
1011 home directory, and at some point later you try to install a module with C<cpan
1012 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1013 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1014 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1015 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1016 you've somehow lost your updated ExtUtils::MakeMaker module.
1017
1018 To remedy this situation, rerun the bootstrapping procedure documented above.
1019
1020 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1021
1022 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1023
1024 =head1 ENVIRONMENT
1025
1026 =over 4
1027
1028 =item SHELL
1029
1030 =item COMSPEC
1031
1032 local::lib looks at the user's C<SHELL> environment variable when printing out
1033 commands to add to the shell configuration file.
1034
1035 On Win32 systems, C<COMSPEC> is also examined.
1036
1037 =back
1038
1039 =head1 SEE ALSO
1040
1041 =over 4
1042
1043 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1044
1045 =back
1046
1047 =head1 SUPPORT
1048
1049 IRC:
1050
1051     Join #local-lib on irc.perl.org.
1052
1053 =head1 AUTHOR
1054
1055 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1056
1057 auto_install fixes kindly sponsored by http://www.takkle.com/
1058
1059 =head1 CONTRIBUTORS
1060
1061 Patches to correctly output commands for csh style shells, as well as some
1062 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1063
1064 Doc patches for a custom local::lib directory, more cleanups in the english
1065 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1066 Torsten Raudssus <torsten@raudssus.de>.
1067
1068 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1069 things will install properly, submitted a fix for the bug causing problems with
1070 writing Makefiles during bootstrapping, contributed an example program, and
1071 submitted yet another fix to ensure that local::lib can install and bootstrap
1072 properly. Many, many thanks!
1073
1074 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1075 section. Many thanks!
1076
1077 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1078
1079 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1080 by a patch from Marco Emilio Poleggi.
1081
1082 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1083 '--self-contained' option.
1084
1085 Documentation patches to make win32 usage clearer by
1086 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1087
1088 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1089 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1090
1091 Improvements to stacking multiple local::lib dirs and removing them from the
1092 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1093
1094 Patch for Carp version mismatch contributed by Hakim Cassimally
1095 <osfameron@cpan.org>.
1096
1097 =head1 COPYRIGHT
1098
1099 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1100 listed above.
1101
1102 =head1 LICENSE
1103
1104 This is free software; you can redistribute it and/or modify it under
1105 the same terms as the Perl 5 programming language system itself.
1106
1107 =cut