lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '2.000004'; # 2.0.4
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16   push @args, @ARGV
  17     if $0 eq '-';
  18
  19   my @steps;
  20   my %opts;
  21   my $shelltype;
  22
  23   while (@args) {
  24     my $arg = shift @args;
  25     # check for lethal dash first to stop processing before causing problems
  26     # the fancy dash is U+2212 or \xE2\x88\x92
  27     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  28       die <<'DEATH';
  29 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  30 These are *not* the traditional -- dashes that software recognizes. You
  31 probably got these by copy-pasting from the perldoc for this module as
  32 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  33 terminal, but can happen elsewhere too. Please try again after replacing the
  34 dashes with normal minus signs.
  35 DEATH
  36     }
  37     elsif ($arg eq '--self-contained') {
  38       die <<'DEATH';
  39 FATAL: The local::lib --self-contained flag has never worked reliably and the
  40 original author, Mark Stosberg, was unable or unwilling to maintain it. As
  41 such, this flag has been removed from the local::lib codebase in order to
  42 prevent misunderstandings and potentially broken builds. The local::lib authors
  43 recommend that you look at the lib::core::only module shipped with this
  44 distribution in order to create a more robust environment that is equivalent to
  45 what --self-contained provided (although quite possibly not what you originally
  46 thought it provided due to the poor quality of the documentation, for which we
  47 apologise).
  48 DEATH
  49     }
  50     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  51       my $path = defined $1 ? $1 : shift @args;
  52       push @steps, ['deactivate', $path];
  53     }
  54     elsif ( $arg eq '--deactivate-all' ) {
  55       push @steps, ['deactivate_all'];
  56     }
  57     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  58       $shelltype = defined $1 ? $1 : shift @args;
  59     }
  60     elsif ( $arg eq '--no-create' ) {
  61       $opts{no_create} = 1;
  62     }
  63     elsif ( $arg =~ /^--/ ) {
  64       die "Unknown import argument: $arg";
  65     }
  66     else {
  67       push @steps, ['activate', $arg];
  68     }
  69   }
  70   if (!@steps) {
  71     push @steps, ['activate', undef];
  72   }
  73
  74   my $self = $class->new(%opts);
  75
  76   for (@steps) {
  77     my ($method, @args) = @$_;
  78     $self = $self->$method(@args);
  79   }
  80
  81   if ($0 eq '-') {
  82     print $self->environment_vars_string($shelltype);
  83     exit 0;
  84   }
  85   else {
  86     $self->setup_local_lib;
  87   }
  88 }
  89
  90 sub new {
  91   my $class = shift;
  92   bless {@_}, $class;
  93 }
  94
  95 sub clone {
  96   my $self = shift;
  97   bless {%$self, @_}, ref $self;
  98 }
  99
 100 sub inc { $_[0]->{inc}     ||= \@INC }
 101 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
 102 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
 103 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
 104 sub extra { $_[0]->{extra} ||= {} }
 105 sub no_create { $_[0]->{no_create} }
 106
 107 my $_archname = $Config{archname};
 108 my $_version  = $Config{version};
 109 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
 110 my $_path_sep = $Config{path_sep};
 111
 112 sub _as_list {
 113   my $list = shift;
 114   grep length, map {
 115     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 116       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 117                         : ()
 118     )
 119   } ref $list ? @$list : $list;
 120 }
 121 sub _remove_from {
 122   my ($list, @remove) = @_;
 123   return @$list
 124     if !@remove;
 125   my %remove = map { $_ => 1 } @remove;
 126   grep !$remove{$_}, _as_list($list);
 127 }
 128
 129 my @_lib_subdirs = (
 130   [$_version, $_archname],
 131   [$_version],
 132   [$_archname],
 133   (@_inc_version_list ? \@_inc_version_list : ()),
 134   [],
 135 );
 136
 137 sub install_base_bin_path {
 138   my ($class, $path) = @_;
 139   return File::Spec->catdir($path, 'bin');
 140 }
 141 sub install_base_perl_path {
 142   my ($class, $path) = @_;
 143   return File::Spec->catdir($path, 'lib', 'perl5');
 144 }
 145 sub install_base_arch_path {
 146   my ($class, $path) = @_;
 147   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 148 }
 149
 150 sub lib_paths_for {
 151   my ($class, $path) = @_;
 152   my $base = $class->install_base_perl_path($path);
 153   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 154 }
 155
 156 sub _mm_escape_path {
 157   my $path = shift;
 158   $path =~ s/\\/\\\\\\\\/g;
 159   if ($path =~ s/ /\\ /g) {
 160     $path = qq{"\\"$path\\""};
 161   }
 162   return $path;
 163 }
 164
 165 sub _mb_escape_path {
 166   my $path = shift;
 167   $path =~ s/\\/\\\\/g;
 168   return qq{"$path"};
 169 }
 170
 171 sub installer_options_for {
 172   my ($class, $path) = @_;
 173   return (
 174     PERL_MM_OPT =>
 175       defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 176     PERL_MB_OPT =>
 177       defined $path ? "--install_base "._mb_escape_path($path) : undef,
 178   );
 179 }
 180
 181 sub active_paths {
 182   my ($self) = @_;
 183   $self = ref $self ? $self : $self->new;
 184
 185   return grep {
 186     # screen out entries that aren't actually reflected in @INC
 187     my $active_ll = $self->install_base_perl_path($_);
 188     grep { $_ eq $active_ll } @{$self->inc};
 189   } _as_list($self->roots);
 190 }
 191
 192
 193 sub deactivate {
 194   my ($self, $path) = @_;
 195   $self = $self->new unless ref $self;
 196   $path = $self->resolve_path($path);
 197   $path = $self->normalize_path($path);
 198
 199   my @active_lls = $self->active_paths;
 200
 201   if (!grep { $_ eq $path } @active_lls) {
 202     warn "Tried to deactivate inactive local::lib '$path'\n";
 203     return $self;
 204   }
 205
 206   my %args = (
 207     bins  => [ _remove_from($self->bins,
 208       $self->install_base_bin_path($path)) ],
 209     libs  => [ _remove_from($self->libs,
 210       $self->install_base_perl_path($path)) ],
 211     inc   => [ _remove_from($self->inc,
 212       $self->lib_paths_for($path)) ],
 213     roots => [ _remove_from($self->roots, $path) ],
 214   );
 215
 216   $args{extra} = { $self->installer_options_for($args{roots}[0]) };
 217
 218   $self->clone(%args);
 219 }
 220
 221 sub deactivate_all {
 222   my ($self) = @_;
 223   $self = $self->new unless ref $self;
 224
 225   my @active_lls = $self->active_paths;
 226
 227   my %args;
 228   if (@active_lls) {
 229     %args = (
 230       bins => [ _remove_from($self->bins,
 231         map $self->install_base_bin_path($_), @active_lls) ],
 232       libs => [ _remove_from($self->libs,
 233         map $self->install_base_perl_path($_), @active_lls) ],
 234       inc => [ _remove_from($self->inc,
 235         map $self->lib_paths_for($_), @active_lls) ],
 236       roots => [ _remove_from($self->roots, @active_lls) ],
 237     );
 238   }
 239
 240   $args{extra} = { $self->installer_options_for(undef) };
 241
 242   $self->clone(%args);
 243 }
 244
 245 sub activate {
 246   my ($self, $path) = @_;
 247   $self = $self->new unless ref $self;
 248   $path = $self->resolve_path($path);
 249   $self->ensure_dir_structure_for($path)
 250     unless $self->no_create;
 251
 252   $path = $self->normalize_path($path);
 253
 254   my @active_lls = $self->active_paths;
 255
 256   if (grep { $_ eq $path } @active_lls[1 .. $#active_lls]) {
 257     $self = $self->deactivate($path);
 258   }
 259
 260   my %args;
 261   if (!@active_lls || $active_lls[0] ne $path) {
 262     %args = (
 263       bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 264       libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 265       inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 266       roots => [ $path, @{$self->roots} ],
 267     );
 268   }
 269
 270   $args{extra} = { $self->installer_options_for($path) };
 271
 272   $self->clone(%args);
 273 }
 274
 275 sub normalize_path {
 276   my ($self, $path) = @_;
 277   $path = ( Win32::GetShortPathName($path) || $path )
 278     if $^O eq 'MSWin32';
 279   return $path;
 280 }
 281
 282 sub build_environment_vars_for {
 283   my $self = $_[0]->new->activate($_[1]);
 284   $self->build_environment_vars;
 285 }
 286 sub build_environment_vars {
 287   my $self = shift;
 288   (
 289     PATH                => join($_path_sep, _as_list($self->bins)),
 290     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 291     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 292     %{$self->extra},
 293   );
 294 }
 295
 296 sub setup_local_lib_for {
 297   my $self = $_[0]->new->activate($_[1]);
 298   $self->setup_local_lib;
 299 }
 300
 301 sub setup_local_lib {
 302   my $self = shift;
 303   $self->setup_env_hash;
 304   @INC = @{$self->inc};
 305 }
 306
 307 sub setup_env_hash_for {
 308   my $self = $_[0]->new->activate($_[1]);
 309   $self->setup_env_hash;
 310 }
 311 sub setup_env_hash {
 312   my $self = shift;
 313   my %env = $self->build_environment_vars;
 314   for my $key (keys %env) {
 315     if (defined $env{$key}) {
 316       $ENV{$key} = $env{$key};
 317     }
 318     else {
 319       delete $ENV{$key};
 320     }
 321   }
 322 }
 323
 324 sub print_environment_vars_for {
 325   print $_[0]->environment_vars_string_for(@_[1..$#_]);
 326 }
 327
 328 sub environment_vars_string_for {
 329   my $self = $_[0]->new->activate($_[1]);
 330   $self->environment_vars_string;
 331 }
 332 sub environment_vars_string {
 333   my ($self, $shelltype) = @_;
 334
 335   $shelltype ||= $self->guess_shelltype;
 336
 337   my $build_method = "build_${shelltype}_env_declaration";
 338
 339   my @envs = (
 340     PATH                => $self->bins,
 341     PERL5LIB            => $self->libs,
 342     PERL_LOCAL_LIB_ROOT => $self->roots,
 343     %{$self->extra},
 344   );
 345   my $out = '';
 346   while (@envs) {
 347     my ($name, $value) = (shift(@envs), shift(@envs));
 348     if (
 349         ref $value
 350         && @$value == 1
 351         && ref $value->[0]
 352         && ref $value->[0] eq 'SCALAR'
 353         && ${$value->[0]} eq $name) {
 354       next;
 355     }
 356     if (
 357         !ref $value
 358         and defined $value
 359           ? (defined $ENV{$name} && $value eq $ENV{$name})
 360           : !defined $ENV{$name}
 361     ) {
 362       next;
 363     }
 364     $out .= $self->$build_method($name, $value);
 365   }
 366   my $wrap_method = "wrap_${shelltype}_output";
 367   if ($self->can($wrap_method)) {
 368     return $self->$wrap_method($out);
 369   }
 370   return $out;
 371 }
 372
 373 sub build_bourne_env_declaration {
 374   my ($class, $name, $args) = @_;
 375   my $value = $class->_interpolate($args, '$%s', '"', '\\%s');
 376
 377   if (!defined $value) {
 378     return qq{unset $name;\n};
 379   }
 380
 381   $value =~ s/(^|\G|$_path_sep)\$$name$_path_sep/$1\$$name\${$name+$_path_sep}/g;
 382   $value =~ s/$_path_sep\$$name$/\${$name+$_path_sep}\$$name/;
 383
 384   qq{${name}="$value";\nexport ${name};\n}
 385 }
 386
 387 sub build_csh_env_declaration {
 388   my ($class, $name, $args) = @_;
 389   my ($value, @vars) = $class->_interpolate($args, '$%s', '"', '"\\%s"');
 390   if (!defined $value) {
 391     return qq{unsetenv $name;\n};
 392   }
 393
 394   my $out = '';
 395   for my $var (@vars) {
 396     $out .= qq{if ! \$?$name setenv $name '';\n};
 397   }
 398
 399   my $value_without = $value;
 400   if ($value_without =~ s/(?:^|$_path_sep)\$$name(?:$_path_sep|$)//g) {
 401     $out .= qq{if "\$$name" != '' setenv $name "$value";\n};
 402     $out .= qq{if "\$$name" == '' };
 403   }
 404   $out .= qq{setenv $name "$value_without";\n};
 405   return $out;
 406 }
 407
 408 sub build_cmd_env_declaration {
 409   my ($class, $name, $args) = @_;
 410   my $value = $class->_interpolate($args, '%%%s%%', qr([()!^"<>&|]), '^%s');
 411   if (!$value) {
 412     return qq{\@set $name=\n};
 413   }
 414
 415   my $out = '';
 416   my $value_without = $value;
 417   if ($value_without =~ s/(?:^|$_path_sep)%$name%(?:$_path_sep|$)//g) {
 418     $out .= qq{\@if not "%$name%"=="" set $name=$value\n};
 419     $out .= qq{\@if "%$name%"=="" };
 420   }
 421   $out .= qq{\@set $name=$value_without\n};
 422   return $out;
 423 }
 424
 425 sub build_powershell_env_declaration {
 426   my ($class, $name, $args) = @_;
 427   my $value = $class->_interpolate($args, '$env:%s', '"', '`%s');
 428
 429   if (!$value) {
 430     return qq{Remove-Item -ErrorAction 0 Env:\\$name;\n};
 431   }
 432
 433   my $maybe_path_sep = qq{\$(if("\$env:$name"-eq""){""}else{"$_path_sep"})};
 434   $value =~ s/(^|\G|$_path_sep)\$env:$name$_path_sep/$1\$env:$name"+$maybe_path_sep+"/g;
 435   $value =~ s/$_path_sep\$env:$name$/"+$maybe_path_sep+\$env:$name+"/;
 436
 437   qq{\$env:$name = \$("$value");\n};
 438 }
 439 sub wrap_powershell_output {
 440   my ($class, $out) = @_;
 441   return $out || " \n";
 442 }
 443
 444 sub build_fish_env_declaration {
 445   my ($class, $name, $args) = @_;
 446   my $value = $class->_interpolate($args, '$%s', '"', '\\%s');
 447   if (!defined $value) {
 448     return qq{set -e $name;\n};
 449   }
 450   $value =~ s/$_path_sep/ /g;
 451   qq{set -x $name $value;\n};
 452 }
 453
 454 sub _interpolate {
 455   my ($class, $args, $var_pat, $escape, $escape_pat) = @_;
 456   return
 457     unless defined $args;
 458   my @args = ref $args ? @$args : $args;
 459   return
 460     unless @args;
 461   my @vars = map { $$_ } grep { ref $_ eq 'SCALAR' } @args;
 462   my $string = join $_path_sep, map {
 463     ref $_ eq 'SCALAR' ? sprintf($var_pat, $$_) : do {
 464       s/($escape)/sprintf($escape_pat, $1)/ge; $_;
 465     };
 466   } @args;
 467   return wantarray ? ($string, \@vars) : $string;
 468 }
 469
 470 sub pipeline;
 471
 472 sub pipeline {
 473   my @methods = @_;
 474   my $last = pop(@methods);
 475   if (@methods) {
 476     \sub {
 477       my ($obj, @args) = @_;
 478       $obj->${pipeline @methods}(
 479         $obj->$last(@args)
 480       );
 481     };
 482   } else {
 483     \sub {
 484       shift->$last(@_);
 485     };
 486   }
 487 }
 488
 489 sub resolve_path {
 490   my ($class, $path) = @_;
 491
 492   $path = $class->${pipeline qw(
 493     resolve_relative_path
 494     resolve_home_path
 495     resolve_empty_path
 496   )}($path);
 497
 498   $path;
 499 }
 500
 501 sub resolve_empty_path {
 502   my ($class, $path) = @_;
 503   if (defined $path) {
 504     $path;
 505   } else {
 506     '~/perl5';
 507   }
 508 }
 509
 510 sub resolve_home_path {
 511   my ($class, $path) = @_;
 512   return $path unless ($path =~ /^~/);
 513   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 514   my $homedir = do {
 515     if (!defined $user && defined $ENV{HOME}) {
 516       $ENV{HOME}
 517     }
 518     else {
 519       require File::Glob;
 520       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 521     }
 522   };
 523   unless (defined $homedir) {
 524     require Carp;
 525     Carp::croak(
 526       "Couldn't resolve homedir for "
 527       .(defined $user ? $user : 'current user')
 528     );
 529   }
 530   $path =~ s/^~[^\/]*/$homedir/;
 531   $path;
 532 }
 533
 534 sub resolve_relative_path {
 535   my ($class, $path) = @_;
 536   $path = File::Spec->rel2abs($path);
 537 }
 538
 539 sub ensure_dir_structure_for {
 540   my ($class, $path) = @_;
 541   unless (-d $path) {
 542     warn "Attempting to create directory ${path}\n";
 543   }
 544   require File::Basename;
 545   my @dirs;
 546   while(!-d $path) {
 547     push @dirs, $path;
 548     $path = File::Basename::dirname($path);
 549   }
 550   mkdir $_ for reverse @dirs;
 551   return;
 552 }
 553
 554 sub guess_shelltype {
 555   my $shellbin
 556     = defined $ENV{SHELL}
 557       ? (File::Spec->splitpath($ENV{SHELL}))[-1]
 558     : ( $^O eq 'MSWin32' && exists $ENV{'!EXITCODE'} )
 559       ? 'bash'
 560     : ( $^O eq 'MSWin32' && $ENV{PROMPT} && $ENV{COMSPEC} )
 561       ? (File::Spec->splitpath($ENV{COMSPEC}))[-1]
 562     : ( $^O eq 'MSWin32' && !$ENV{PROMPT} )
 563       ? 'powershell.exe'
 564     : 'sh';
 565
 566   for ($shellbin) {
 567     return
 568         /csh$/                   ? 'csh'
 569       : /fish/                   ? 'fish'
 570       : /command(?:\.com)?$/i    ? 'cmd'
 571       : /cmd(?:\.exe)?$/i        ? 'cmd'
 572       : /4nt(?:\.exe)?$/i        ? 'cmd'
 573       : /powershell(?:\.exe)?$/i ? 'powershell'
 574                                  : 'bourne';
 575   }
 576 }
 577
 578 1;
 579 __END__
 580
 581 =encoding utf8
 582
 583 =head1 NAME
 584
 585 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 586
 587 =head1 SYNOPSIS
 588
 589 In code -
 590
 591   use local::lib; # sets up a local lib at ~/perl5
 592
 593   use local::lib '~/foo'; # same, but ~/foo
 594
 595   # Or...
 596   use FindBin;
 597   use local::lib "$FindBin::Bin/../support";  # app-local support library
 598
 599 From the shell -
 600
 601   # Install LWP and its missing dependencies to the '~/perl5' directory
 602   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 603
 604   # Just print out useful shell commands
 605   $ perl -Mlocal::lib
 606   export PERL_MB_OPT='--install_base /home/username/perl5'
 607   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 608   export PERL5LIB="/home/username/perl5/lib/perl5"
 609   export PATH="/home/username/perl5/bin:$PATH"
 610
 611 From a .bashrc file -
 612
 613   [ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)"
 614
 615 =head2 The bootstrapping technique
 616
 617 A typical way to install local::lib is using what is known as the
 618 "bootstrapping" technique.  You would do this if your system administrator
 619 hasn't already installed local::lib.  In this case, you'll need to install
 620 local::lib in your home directory.
 621
 622 Even if you do have administrative privileges, you will still want to set up your
 623 environment variables, as discussed in step 4. Without this, you would still
 624 install the modules into the system CPAN installation and also your Perl scripts
 625 will not use the lib/ path you bootstrapped with local::lib.
 626
 627 By default local::lib installs itself and the CPAN modules into ~/perl5.
 628
 629 Windows users must also see L</Differences when using this module under Win32>.
 630
 631 =over 4
 632
 633 =item 1.
 634
 635 Download and unpack the local::lib tarball from CPAN (search for "Download"
 636 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 637 or administrator.  Unpack the file in your home directory or in any other
 638 convenient location.
 639
 640 =item 2.
 641
 642 Run this:
 643
 644   perl Makefile.PL --bootstrap
 645
 646 If the system asks you whether it should automatically configure as much
 647 as possible, you would typically answer yes.
 648
 649 In order to install local::lib into a directory other than the default, you need
 650 to specify the name of the directory when you call bootstrap, as follows:
 651
 652   perl Makefile.PL --bootstrap=~/foo
 653
 654 =item 3.
 655
 656 Run this: (local::lib assumes you have make installed on your system)
 657
 658   make test && make install
 659
 660 =item 4.
 661
 662 Now we need to setup the appropriate environment variables, so that Perl
 663 starts using our newly generated lib/ directory. If you are using bash or
 664 any other Bourne shells, you can add this to your shell startup script this
 665 way:
 666
 667   echo '[ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)"' >>~/.bashrc
 668
 669 If you are using C shell, you can do this as follows:
 670
 671   /bin/csh
 672   echo $SHELL
 673   /bin/csh
 674   echo 'eval `perl -I$HOME/perl5/lib/perl5 -Mlocal::lib`' >> ~/.cshrc
 675
 676 If you passed to bootstrap a directory other than default, you also need to
 677 give that as import parameter to the call of the local::lib module like this
 678 way:
 679
 680   echo '[ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)"' >>~/.bashrc
 681
 682 After writing your shell configuration file, be sure to re-read it to get the
 683 changed settings into your current shell's environment. Bourne shells use
 684 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 685
 686 =back
 687
 688 If you're on a slower machine, or are operating under draconian disk space
 689 limitations, you can disable the automatic generation of manpages from POD when
 690 installing modules by using the C<--no-manpages> argument when bootstrapping:
 691
 692   perl Makefile.PL --bootstrap --no-manpages
 693
 694 To avoid doing several bootstrap for several Perl module environments on the
 695 same account, for example if you use it for several different deployed
 696 applications independently, you can use one bootstrapped local::lib
 697 installation to install modules in different directories directly this way:
 698
 699   cd ~/mydir1
 700   perl -Mlocal::lib=./
 701   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 702   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 703   perl -MCPAN -e install ...    ### whatever modules you want
 704   cd ../mydir2
 705   ... REPEAT ...
 706
 707 When used in a C<.bashrc> file, it is recommended that you protect against
 708 re-activating a directory in a sub-shell.  This can be done by checking the
 709 C<$SHLVL> variable as shown in synopsis.  Without this, sub-shells created by
 710 the user or other programs will override changes made to the parent shell's
 711 environment.
 712
 713 If you are working with several C<local::lib> environments, you may want to
 714 remove some of them from the current environment without disturbing the others.
 715 You can deactivate one environment like this (using bourne sh):
 716
 717   eval $(perl -Mlocal::lib=--deactivate,~/path)
 718
 719 which will generate and run the commands needed to remove C<~/path> from your
 720 various search paths. Whichever environment was B<activated most recently> will
 721 remain the target for module installations. That is, if you activate
 722 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 723 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 724 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 725 installed in C<~/pathB> because pathB was activated later.
 726
 727 You can also ask C<local::lib> to clean itself completely out of the current
 728 shell's environment with the C<--deactivate-all> option.
 729 For multiple environments for multiple apps you may need to include a modified
 730 version of the C<< use FindBin >> instructions in the "In code" sample above.
 731 If you did something like the above, you have a set of Perl modules at C<<
 732 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 733 you need to tell it where to find the modules you installed for it at C<<
 734 ~/mydir1/lib >>.
 735
 736 In C<< ~/mydir1/scripts/myscript.pl >>:
 737
 738   use strict;
 739   use warnings;
 740   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 741   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 742
 743 Put this before any BEGIN { ... } blocks that require the modules you installed.
 744
 745 =head2 Differences when using this module under Win32
 746
 747 To set up the proper environment variables for your current session of
 748 C<CMD.exe>, you can use this:
 749
 750   C:\>perl -Mlocal::lib
 751   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 752   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 753   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 754   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 755
 756   ### To set the environment for this shell alone
 757   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 758   ### instead of $(perl -Mlocal::lib=./)
 759
 760 If you want the environment entries to persist, you'll need to add them to the
 761 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 762
 763 The "~" is translated to the user's profile directory (the directory named for
 764 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 765 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 766 directory is translated to a short name (which means the directory must exist)
 767 and the subdirectories are created.
 768
 769 =head3 PowerShell
 770
 771 local::lib also supports PowerShell, and can be used with the
 772 C<Invoke-Expression> cmdlet.
 773
 774   Invoke-Expression "$(perl -Mlocal::lib)"
 775
 776 =head1 RATIONALE
 777
 778 The version of a Perl package on your machine is not always the version you
 779 need.  Obviously, the best thing to do would be to update to the version you
 780 need.  However, you might be in a situation where you're prevented from doing
 781 this.  Perhaps you don't have system administrator privileges; or perhaps you
 782 are using a package management system such as Debian, and nobody has yet gotten
 783 around to packaging up the version you need.
 784
 785 local::lib solves this problem by allowing you to create your own directory of
 786 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 787 be within your own home directory).  The existing system Perl installation is
 788 not affected; you simply invoke Perl with special options so that Perl uses the
 789 packages in your own local package directory rather than the system packages.
 790 local::lib arranges things so that your locally installed version of the Perl
 791 packages takes precedence over the system installation.
 792
 793 If you are using a package management system (such as Debian), you don't need to
 794 worry about Debian and CPAN stepping on each other's toes.  Your local version
 795 of the packages will be written to an entirely separate directory from those
 796 installed by Debian.
 797
 798 =head1 DESCRIPTION
 799
 800 This module provides a quick, convenient way of bootstrapping a user-local Perl
 801 module library located within the user's home directory. It also constructs and
 802 prints out for the user the list of environment variables using the syntax
 803 appropriate for the user's current shell (as specified by the C<SHELL>
 804 environment variable), suitable for directly adding to one's shell
 805 configuration file.
 806
 807 More generally, local::lib allows for the bootstrapping and usage of a
 808 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 809 easier to ship an application with an app-specific copy of a Perl module, or
 810 collection of modules. Useful in cases like when an upstream maintainer hasn't
 811 applied a patch to a module of theirs that you need for your application.
 812
 813 On import, local::lib sets the following environment variables to appropriate
 814 values:
 815
 816 =over 4
 817
 818 =item PERL_MB_OPT
 819
 820 =item PERL_MM_OPT
 821
 822 =item PERL5LIB
 823
 824 =item PATH
 825
 826 =item PERL_LOCAL_LIB_ROOT
 827
 828 =back
 829
 830 When possible, these will be appended to instead of overwritten entirely.
 831
 832 These values are then available for reference by any code after import.
 833
 834 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 835
 836 See L<lib::core::only> for one way to do this - but note that
 837 there are a number of caveats, and the best approach is always to perform a
 838 build against a clean perl (i.e. site and vendor as close to empty as possible).
 839
 840 =head1 IMPORT OPTIONS
 841
 842 Options are values that can be passed to the C<local::lib> import besides the
 843 directory to use. They are specified as C<use local::lib '--option'[, path];>
 844 or C<perl -Mlocal::lib=--option[,path]>.
 845
 846 =head2 --deactivate
 847
 848 Remove the chosen path (or the default path) from the module search paths if it
 849 was added by C<local::lib>, instead of adding it.
 850
 851 =head2 --deactivate-all
 852
 853 Remove all directories that were added to search paths by C<local::lib> from the
 854 search paths.
 855
 856 =head2 --shelltype
 857
 858 Specify the shell type to use for output.  By default, the shell will be
 859 detected based on the environment.  Should be one of: C<bourne>, C<csh>,
 860 C<cmd>, or C<powershell>.
 861
 862 =head2 --no-create
 863
 864 Prevents C<local::lib> from creating directories when activating dirs.  This is
 865 likely to cause issues on Win32 systems.
 866
 867 =head1 CLASS METHODS
 868
 869 =head2 ensure_dir_structure_for
 870
 871 =over 4
 872
 873 =item Arguments: $path
 874
 875 =item Return value: None
 876
 877 =back
 878
 879 Attempts to create the given path, and all required parent directories. Throws
 880 an exception on failure.
 881
 882 =head2 print_environment_vars_for
 883
 884 =over 4
 885
 886 =item Arguments: $path
 887
 888 =item Return value: None
 889
 890 =back
 891
 892 Prints to standard output the variables listed above, properly set to use the
 893 given path as the base directory.
 894
 895 =head2 build_environment_vars_for
 896
 897 =over 4
 898
 899 =item Arguments: $path
 900
 901 =item Return value: %environment_vars
 902
 903 =back
 904
 905 Returns a hash with the variables listed above, properly set to use the
 906 given path as the base directory.
 907
 908 =head2 setup_env_hash_for
 909
 910 =over 4
 911
 912 =item Arguments: $path
 913
 914 =item Return value: None
 915
 916 =back
 917
 918 Constructs the C<%ENV> keys for the given path, by calling
 919 L</build_environment_vars_for>.
 920
 921 =head2 active_paths
 922
 923 =over 4
 924
 925 =item Arguments: None
 926
 927 =item Return value: @paths
 928
 929 =back
 930
 931 Returns a list of active C<local::lib> paths, according to the
 932 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 933 what is really in C<@INC>.
 934
 935 =head2 install_base_perl_path
 936
 937 =over 4
 938
 939 =item Arguments: $path
 940
 941 =item Return value: $install_base_perl_path
 942
 943 =back
 944
 945 Returns a path describing where to install the Perl modules for this local
 946 library installation. Appends the directories C<lib> and C<perl5> to the given
 947 path.
 948
 949 =head2 lib_paths_for
 950
 951 =over 4
 952
 953 =item Arguments: $path
 954
 955 =item Return value: @lib_paths
 956
 957 =back
 958
 959 Returns the list of paths perl will search for libraries, given a base path.
 960 This includes the base path itself, the architecture specific subdirectory, and
 961 perl version specific subdirectories.  These paths may not all exist.
 962
 963 =head2 install_base_bin_path
 964
 965 =over 4
 966
 967 =item Arguments: $path
 968
 969 =item Return value: $install_base_bin_path
 970
 971 =back
 972
 973 Returns a path describing where to install the executable programs for this
 974 local library installation. Appends the directory C<bin> to the given path.
 975
 976 =head2 installer_options_for
 977
 978 =over 4
 979
 980 =item Arguments: $path
 981
 982 =item Return value: %installer_env_vars
 983
 984 =back
 985
 986 Returns a hash of environment variables that should be set to cause
 987 installation into the given path.
 988
 989 =head2 resolve_empty_path
 990
 991 =over 4
 992
 993 =item Arguments: $path
 994
 995 =item Return value: $base_path
 996
 997 =back
 998
 999 Builds and returns the base path into which to set up the local module
1000 installation. Defaults to C<~/perl5>.
1001
1002 =head2 resolve_home_path
1003
1004 =over 4
1005
1006 =item Arguments: $path
1007
1008 =item Return value: $home_path
1009
1010 =back
1011
1012 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
1013 for this purpose. If no definite answer is available, throws an exception.
1014
1015 =head2 resolve_relative_path
1016
1017 =over 4
1018
1019 =item Arguments: $path
1020
1021 =item Return value: $absolute_path
1022
1023 =back
1024
1025 Translates the given path into an absolute path.
1026
1027 =head2 resolve_path
1028
1029 =over 4
1030
1031 =item Arguments: $path
1032
1033 =item Return value: $absolute_path
1034
1035 =back
1036
1037 Calls the following in a pipeline, passing the result from the previous to the
1038 next, in an attempt to find where to configure the environment for a local
1039 library installation: L</resolve_empty_path>, L</resolve_home_path>,
1040 L</resolve_relative_path>. Passes the given path argument to
1041 L</resolve_empty_path> which then returns a result that is passed to
1042 L</resolve_home_path>, which then has its result passed to
1043 L</resolve_relative_path>. The result of this final call is returned from
1044 L</resolve_path>.
1045
1046 =head1 OBJECT INTERFACE
1047
1048 =head2 new
1049
1050 =over 4
1051
1052 =item Arguments: %attributes
1053
1054 =item Return value: $local_lib
1055
1056 =back
1057
1058 Constructs a new C<local::lib> object, representing the current state of
1059 C<@INC> and the relevant environment variables.
1060
1061 =head1 ATTRIBUTES
1062
1063 =head2 roots
1064
1065 An arrayref representing active C<local::lib> directories.
1066
1067 =head2 inc
1068
1069 An arrayref representing C<@INC>.
1070
1071 =head2 libs
1072
1073 An arrayref representing the PERL5LIB environment variable.
1074
1075 =head2 bins
1076
1077 An arrayref representing the PATH environment variable.
1078
1079 =head2 extra
1080
1081 A hashref of extra environment variables (e.g. C<PERL_MM_OPT> and
1082 C<PERL_MB_OPT>)
1083
1084 =head2 no_create
1085
1086 If set, C<local::lib> will not try to create directories when activating them.
1087
1088 =head1 OBJECT METHODS
1089
1090 =head2 clone
1091
1092 =over 4
1093
1094 =item Arguments: %attributes
1095
1096 =item Return value: $local_lib
1097
1098 =back
1099
1100 Constructs a new C<local::lib> object based on the existing one, overriding the
1101 specified attributes.
1102
1103 =head2 activate
1104
1105 =over 4
1106
1107 =item Arguments: $path
1108
1109 =item Return value: $new_local_lib
1110
1111 =back
1112
1113 Constructs a new instance with the specified path active.
1114
1115 =head2 deactivate
1116
1117 =over 4
1118
1119 =item Arguments: $path
1120
1121 =item Return value: $new_local_lib
1122
1123 =back
1124
1125 Constructs a new instance with the specified path deactivated.
1126
1127 =head2 deactivate_all
1128
1129 =over 4
1130
1131 =item Arguments: None
1132
1133 =item Return value: $new_local_lib
1134
1135 =back
1136
1137 Constructs a new instance with all C<local::lib> directories deactivated.
1138
1139 =head2 environment_vars_string
1140
1141 =over 4
1142
1143 =item Arguments: [ $shelltype ]
1144
1145 =item Return value: $shell_env_string
1146
1147 =back
1148
1149 Returns a string to set up the C<local::lib>, meant to be run by a shell.
1150
1151 =head2 build_environment_vars
1152
1153 =over 4
1154
1155 =item Arguments: None
1156
1157 =item Return value: %environment_vars
1158
1159 =back
1160
1161 Returns a hash with the variables listed above, properly set to use the
1162 given path as the base directory.
1163
1164 =head2 setup_env_hash
1165
1166 =over 4
1167
1168 =item Arguments: None
1169
1170 =item Return value: None
1171
1172 =back
1173
1174 Constructs the C<%ENV> keys for the given path, by calling
1175 L</build_environment_vars>.
1176
1177 =head2 setup_local_lib
1178
1179 Constructs the C<%ENV> hash using L</setup_env_hash>, and set up C<@INC>.
1180
1181 =head1 A WARNING ABOUT UNINST=1
1182
1183 Be careful about using local::lib in combination with "make install UNINST=1".
1184 The idea of this feature is that will uninstall an old version of a module
1185 before installing a new one. However it lacks a safety check that the old
1186 version and the new version will go in the same directory. Used in combination
1187 with local::lib, you can potentially delete a globally accessible version of a
1188 module while installing the new version in a local place. Only combine "make
1189 install UNINST=1" and local::lib if you understand these possible consequences.
1190
1191 =head1 LIMITATIONS
1192
1193 =over 4
1194
1195 =item * Directory names with spaces in them are not well supported by the perl
1196 toolchain and the programs it uses.  Pure-perl distributions should support
1197 spaces, but problems are more likely with dists that require compilation. A
1198 workaround you can do is moving your local::lib to a directory with spaces
1199 B<after> you installed all modules inside your local::lib bootstrap. But be
1200 aware that you can't update or install CPAN modules after the move.
1201
1202 =item * Rather basic shell detection. Right now anything with csh in its name is
1203 assumed to be a C shell or something compatible, and everything else is assumed
1204 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
1205 not set, a Bourne-compatible shell is assumed.
1206
1207 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
1208
1209 =item * Should probably auto-fixup CPAN config if not already done.
1210
1211 =item * local::lib loads L<File::Spec>.  When used to set shell variables,
1212 this isn't a problem.  When used inside a perl script, any L<File::Spec>
1213 version inside the local::lib will be ignored.  A workaround for this is using
1214 C<use lib "$ENV{HOME}/perl5/lib/perl5";> inside the script instead of using
1215 C<local::lib> directly.
1216
1217 =item * Conflicts with L<ExtUtils::MakeMaker>'s C<PREFIX> option.
1218 C<local::lib> uses the C<INSTALL_BASE> option, as it has more predictable and
1219 sane behavior.  If something attempts to use the C<PREFIX> option when running
1220 a F<Makefile.PL>, L<ExtUtils::MakeMaker> will refuse to run, as the two
1221 options conflict.  This can be worked around by temporarily unsetting the
1222 C<PERL_MM_OPT> environment variable.
1223
1224 =item * Conflicts with L<Module::Build>'s C<--prefix> option.  Similar to the
1225 previous limitation, but any C<--prefix> option specified will be ignored.
1226 This can be worked around by temporarily unsetting the C<PERL_MB_OPT>
1227 environment variable.
1228
1229 =back
1230
1231 Patches very much welcome for any of the above.
1232
1233 =over 4
1234
1235 =item * On Win32 systems, does not have a way to write the created environment
1236 variables to the registry, so that they can persist through a reboot.
1237
1238 =back
1239
1240 =head1 TROUBLESHOOTING
1241
1242 If you've configured local::lib to install CPAN modules somewhere in to your
1243 home directory, and at some point later you try to install a module with C<cpan
1244 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1245 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1246 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1247 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1248 you've somehow lost your updated ExtUtils::MakeMaker module.
1249
1250 To remedy this situation, rerun the bootstrapping procedure documented above.
1251
1252 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1253
1254 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1255
1256 =head1 ENVIRONMENT
1257
1258 =over 4
1259
1260 =item SHELL
1261
1262 =item COMSPEC
1263
1264 local::lib looks at the user's C<SHELL> environment variable when printing out
1265 commands to add to the shell configuration file.
1266
1267 On Win32 systems, C<COMSPEC> is also examined.
1268
1269 =back
1270
1271 =head1 SEE ALSO
1272
1273 =over 4
1274
1275 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1276
1277 =back
1278
1279 =head1 SUPPORT
1280
1281 IRC:
1282
1283     Join #local-lib on irc.perl.org.
1284
1285 =head1 AUTHOR
1286
1287 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1288
1289 auto_install fixes kindly sponsored by http://www.takkle.com/
1290
1291 =head1 CONTRIBUTORS
1292
1293 Patches to correctly output commands for csh style shells, as well as some
1294 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1295
1296 Doc patches for a custom local::lib directory, more cleanups in the english
1297 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1298 Torsten Raudssus <torsten@raudssus.de>.
1299
1300 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1301 things will install properly, submitted a fix for the bug causing problems with
1302 writing Makefiles during bootstrapping, contributed an example program, and
1303 submitted yet another fix to ensure that local::lib can install and bootstrap
1304 properly. Many, many thanks!
1305
1306 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1307 section. Many thanks!
1308
1309 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1310
1311 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1312 by a patch from Marco Emilio Poleggi.
1313
1314 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1315 '--self-contained' option.
1316
1317 Documentation patches to make win32 usage clearer by
1318 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1319
1320 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1321 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1322
1323 Improvements to stacking multiple local::lib dirs and removing them from the
1324 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1325
1326 Patch for Carp version mismatch contributed by Hakim Cassimally
1327 <osfameron@cpan.org>.
1328
1329 Rewrite of internals and numerous bug fixes and added features contributed by
1330 Graham Knop <haarg@haarg.org>.
1331
1332 =head1 COPYRIGHT
1333
1334 Copyright (c) 2007 - 2013 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1335 listed above.
1336
1337 =head1 LICENSE
1338
1339 This is free software; you can redistribute it and/or modify it under
1340 the same terms as the Perl 5 programming language system itself.
1341
1342 =cut