lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.008001; # probably works with earlier versions but I'm not supporting them
   7               # (patches would, of course, be welcome)
   8
   9 use File::Spec ();
  10 use File::Path ();
  11 use Config;
  12
  13 our $VERSION = '1.008007'; # 1.8.4
  14
  15 our @KNOWN_FLAGS = qw(--self-contained --deactivate --deactivate-all);
  16
  17 sub DEACTIVATE_ONE () { 1 }
  18 sub DEACTIVATE_ALL () { 2 }
  19
  20 sub INTERPOLATE_ENV () { 1 }
  21 sub LITERAL_ENV     () { 0 }
  22
  23 sub import {
  24   my ($class, @args) = @_;
  25
  26   # Remember what PERL5LIB was when we started
  27   my $perl5lib = $ENV{PERL5LIB} || '';
  28
  29   my %arg_store;
  30   for my $arg (@args) {
  31     # check for lethal dash first to stop processing before causing problems
  32     if ($arg =~ /−/) {
  33       die <<'DEATH';
  34 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  35 These are *not* the traditional -- dashes that software recognizes. You
  36 probably got these by copy-pasting from the perldoc for this module as
  37 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  38 terminal, but can happen elsewhere too. Please try again after replacing the
  39 dashes with normal minus signs.
  40 DEATH
  41     }
  42     elsif(grep { $arg eq $_ } @KNOWN_FLAGS) {
  43       (my $flag = $arg) =~ s/--//;
  44       $arg_store{$flag} = 1;
  45     }
  46     elsif($arg =~ /^--/) {
  47       die "Unknown import argument: $arg";
  48     }
  49     else {
  50       # assume that what's left is a path
  51       $arg_store{path} = $arg;
  52     }
  53   }
  54
  55   if($arg_store{'self-contained'}) {
  56     die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  57   }
  58
  59   my $deactivating = 0;
  60   if ($arg_store{deactivate}) {
  61     $deactivating = DEACTIVATE_ONE;
  62   }
  63   if ($arg_store{'deactivate-all'}) {
  64     $deactivating = DEACTIVATE_ALL;
  65   }
  66
  67   $arg_store{path} = $class->resolve_path($arg_store{path});
  68   $class->setup_local_lib_for($arg_store{path}, $deactivating);
  69
  70   for (@INC) { # Untaint @INC
  71     next if ref; # Skip entry if it is an ARRAY, CODE, blessed, etc.
  72     m/(.*)/ and $_ = $1;
  73   }
  74 }
  75
  76 sub pipeline;
  77
  78 sub pipeline {
  79   my @methods = @_;
  80   my $last = pop(@methods);
  81   if (@methods) {
  82     \sub {
  83       my ($obj, @args) = @_;
  84       $obj->${pipeline @methods}(
  85         $obj->$last(@args)
  86       );
  87     };
  88   } else {
  89     \sub {
  90       shift->$last(@_);
  91     };
  92   }
  93 }
  94
  95 =begin testing
  96
  97 #:: test pipeline
  98
  99 package local::lib;
 100
 101 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 102 my $foo = bless({}, 'Foo');
 103 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 104
 105 =end testing
 106
 107 =cut
 108
 109 sub _uniq {
 110     my %seen;
 111     grep { ! $seen{$_}++ } @_;
 112 }
 113
 114 sub resolve_path {
 115   my ($class, $path) = @_;
 116   $class->${pipeline qw(
 117     resolve_relative_path
 118     resolve_home_path
 119     resolve_empty_path
 120   )}($path);
 121 }
 122
 123 sub resolve_empty_path {
 124   my ($class, $path) = @_;
 125   if (defined $path) {
 126     $path;
 127   } else {
 128     '~/perl5';
 129   }
 130 }
 131
 132 =begin testing
 133
 134 #:: test classmethod setup
 135
 136 my $c = 'local::lib';
 137
 138 =end testing
 139
 140 =begin testing
 141
 142 #:: test classmethod
 143
 144 is($c->resolve_empty_path, '~/perl5');
 145 is($c->resolve_empty_path('foo'), 'foo');
 146
 147 =end testing
 148
 149 =cut
 150
 151 sub resolve_home_path {
 152   my ($class, $path) = @_;
 153   return $path unless ($path =~ /^~/);
 154   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 155   my $tried_file_homedir;
 156   my $homedir = do {
 157     if (eval { require File::HomeDir } && $File::HomeDir::VERSION >= 0.65) {
 158       $tried_file_homedir = 1;
 159       if (defined $user) {
 160         File::HomeDir->users_home($user);
 161       } else {
 162         File::HomeDir->my_home;
 163       }
 164     } else {
 165       if (defined $user) {
 166         (getpwnam $user)[7];
 167       } else {
 168         if (defined $ENV{HOME}) {
 169           $ENV{HOME};
 170         } else {
 171           (getpwuid $<)[7];
 172         }
 173       }
 174     }
 175   };
 176   unless (defined $homedir) {
 177     require Carp;
 178     Carp::croak(
 179       "Couldn't resolve homedir for "
 180       .(defined $user ? $user : 'current user')
 181       .($tried_file_homedir ? '' : ' - consider installing File::HomeDir')
 182     );
 183   }
 184   $path =~ s/^~[^\/]*/$homedir/;
 185   $path;
 186 }
 187
 188 sub resolve_relative_path {
 189   my ($class, $path) = @_;
 190   $path = File::Spec->rel2abs($path);
 191 }
 192
 193 =begin testing
 194
 195 #:: test classmethod
 196
 197 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 198 is($c->resolve_relative_path('bar'),'FOObar');
 199
 200 =end testing
 201
 202 =cut
 203
 204 sub setup_local_lib_for {
 205   my ($class, $path, $deactivating) = @_;
 206
 207   my $interpolate = LITERAL_ENV;
 208   my @active_lls = $class->active_paths;
 209
 210   $path = $class->ensure_dir_structure_for($path);
 211
 212   if (! $deactivating) {
 213     if (@active_lls && $active_lls[-1] eq $path) {
 214       exit 0 if $0 eq '-';
 215       return; # Asked to add what's already at the top of the stack
 216     } elsif (grep { $_ eq $path} @active_lls) {
 217       # Asked to add a dir that's lower in the stack -- so we remove it from
 218       # where it is, and then add it back at the top.
 219       $class->setup_env_hash_for($path, DEACTIVATE_ONE);
 220       # Which means we can no longer output "PERL5LIB=...:$PERL5LIB" stuff
 221       # anymore because we're taking something *out*.
 222       $interpolate = INTERPOLATE_ENV;
 223     }
 224   }
 225
 226   if ($0 eq '-') {
 227     $class->print_environment_vars_for($path, $deactivating, $interpolate);
 228     exit 0;
 229   } else {
 230     $class->setup_env_hash_for($path, $deactivating);
 231     @INC = _uniq(split($Config{path_sep}, $ENV{PERL5LIB}), @INC);
 232   }
 233 }
 234
 235 sub install_base_bin_path {
 236   my ($class, $path) = @_;
 237   File::Spec->catdir($path, 'bin');
 238 }
 239
 240 sub install_base_perl_path {
 241   my ($class, $path) = @_;
 242   File::Spec->catdir($path, 'lib', 'perl5');
 243 }
 244
 245 sub install_base_arch_path {
 246   my ($class, $path) = @_;
 247   File::Spec->catdir($class->install_base_perl_path($path), $Config{archname});
 248 }
 249
 250 sub ensure_dir_structure_for {
 251   my ($class, $path) = @_;
 252   unless (-d $path) {
 253     warn "Attempting to create directory ${path}\n";
 254   }
 255   File::Path::mkpath($path);
 256   # Need to have the path exist to make a short name for it, so
 257   # converting to a short name here.
 258   $path = Win32::GetShortPathName($path) if $^O eq 'MSWin32';
 259
 260   return $path;
 261 }
 262
 263 sub guess_shelltype {
 264   my $shellbin = 'sh';
 265   if(defined $ENV{'SHELL'}) {
 266       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 267       $shellbin = $shell_bin_path_parts[-1];
 268   }
 269   my $shelltype = do {
 270       local $_ = $shellbin;
 271       if(/csh/) {
 272           'csh'
 273       } else {
 274           'bourne'
 275       }
 276   };
 277
 278   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 279   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 280       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 281       $shellbin = $shell_bin_path_parts[-1];
 282          $shelltype = do {
 283                  local $_ = $shellbin;
 284                  if(/command\.com/) {
 285                          'win32'
 286                  } elsif(/cmd\.exe/) {
 287                          'win32'
 288                  } elsif(/4nt\.exe/) {
 289                          'win32'
 290                  } else {
 291                          $shelltype
 292                  }
 293          };
 294   }
 295   return $shelltype;
 296 }
 297
 298 sub print_environment_vars_for {
 299   my ($class, $path, $deactivating, $interpolate) = @_;
 300   print $class->environment_vars_string_for($path, $deactivating, $interpolate);
 301 }
 302
 303 sub environment_vars_string_for {
 304   my ($class, $path, $deactivating, $interpolate) = @_;
 305   my @envs = $class->build_environment_vars_for($path, $deactivating, $interpolate);
 306   my $out = '';
 307
 308   # rather basic csh detection, goes on the assumption that something won't
 309   # call itself csh unless it really is. also, default to bourne in the
 310   # pathological situation where a user doesn't have $ENV{SHELL} defined.
 311   # note also that shells with funny names, like zoid, are assumed to be
 312   # bourne.
 313
 314   my $shelltype = $class->guess_shelltype;
 315
 316   while (@envs) {
 317     my ($name, $value) = (shift(@envs), shift(@envs));
 318     $value =~ s/(\\")/\\$1/g if defined $value;
 319     $out .= $class->${\"build_${shelltype}_env_declaration"}($name, $value);
 320   }
 321   return $out;
 322 }
 323
 324 # simple routines that take two arguments: an %ENV key and a value. return
 325 # strings that are suitable for passing directly to the relevant shell to set
 326 # said key to said value.
 327 sub build_bourne_env_declaration {
 328   my $class = shift;
 329   my($name, $value) = @_;
 330   return defined($value) ? qq{export ${name}="${value}";\n} : qq{unset ${name};\n};
 331 }
 332
 333 sub build_csh_env_declaration {
 334   my $class = shift;
 335   my($name, $value) = @_;
 336   return defined($value) ? qq{setenv ${name} "${value}"\n} : qq{unsetenv ${name}\n};
 337 }
 338
 339 sub build_win32_env_declaration {
 340   my $class = shift;
 341   my($name, $value) = @_;
 342   return defined($value) ? qq{set ${name}=${value}\n} : qq{set ${name}=\n};
 343 }
 344
 345 sub setup_env_hash_for {
 346   my ($class, $path, $deactivating) = @_;
 347   my %envs = $class->build_environment_vars_for($path, $deactivating, INTERPOLATE_ENV);
 348   @ENV{keys %envs} = values %envs;
 349 }
 350
 351 sub build_environment_vars_for {
 352   my ($class, $path, $deactivating, $interpolate) = @_;
 353
 354   if ($deactivating == DEACTIVATE_ONE) {
 355     return $class->build_deactivate_environment_vars_for($path, $interpolate);
 356   } elsif ($deactivating == DEACTIVATE_ALL) {
 357     return $class->build_deact_all_environment_vars_for($path, $interpolate);
 358   } else {
 359     return $class->build_activate_environment_vars_for($path, $interpolate);
 360   }
 361 }
 362
 363 # Build an environment value for a variable like PATH from a list of paths.
 364 # References to existing variables are given as references to the variable name.
 365 # Duplicates are removed.
 366 #
 367 # options:
 368 # - interpolate: INTERPOLATE_ENV/LITERAL_ENV
 369 # - exists: paths are included only if they exist (default: interpolate == INTERPOLATE_ENV)
 370 # - filter: function to apply to each path do decide if it must be included
 371 # - empty: the value to return in the case of empty value
 372 my %ENV_LIST_VALUE_DEFAULTS = (
 373     interpolate => INTERPOLATE_ENV,
 374     exists => undef,
 375     filter => sub { 1 },
 376     empty => undef,
 377 );
 378 sub _env_list_value(%@) {
 379   my $options = shift;
 380   die(sprintf "unknown option '$_' at %s line %u\n", (caller)[1..2])
 381     for grep { !exists $ENV_LIST_VALUE_DEFAULTS{$_} } keys %$options;
 382   my %options = (%ENV_LIST_VALUE_DEFAULTS, %{ $options });
 383   $options{exists} = $options{interpolate} == INTERPOLATE_ENV
 384     unless defined $options{exists};
 385
 386   my %seen;
 387
 388   my $value = join($Config{path_sep}, map {
 389       ref $_ ? ($^O eq 'MSWin32' ? "%${$_}%" : "\$${$_}") : $_
 390     } grep {
 391       ref $_ || (defined $_
 392                  && length($_) > 0
 393                  && !$seen{$_}++
 394                  && $options{filter}->($_)
 395                  && (!$options{exists} || -e $_))
 396     } map {
 397       if (ref $_ eq 'SCALAR' && $options{interpolate} == INTERPOLATE_ENV) {
 398         exists $ENV{${$_}} ? (split /\Q$Config{path_sep}/, $ENV{${$_}}) : ()
 399       } else {
 400         $_
 401       }
 402     } @_);
 403   return length($value) ? $value : $options{empty};
 404 }
 405
 406 sub build_activate_environment_vars_for {
 407   my ($class, $path, $interpolate) = @_;
 408   return (
 409     PERL_LOCAL_LIB_ROOT =>
 410             _env_list_value(
 411               { interpolate => $interpolate, exists => 0, empty => '' },
 412               \'PERL_LOCAL_LIB_ROOT',
 413               $path,
 414             ),
 415     PERL_MB_OPT => "--install_base ${path}",
 416     PERL_MM_OPT => "INSTALL_BASE=${path}",
 417     PERL5LIB =>
 418             _env_list_value(
 419               { interpolate => $interpolate, exists => 0, empty => '' },
 420               $class->install_base_arch_path($path),
 421               $class->install_base_perl_path($path),
 422               \'PERL5LIB',
 423             ),
 424     PATH => _env_list_value(
 425               { interpolate => $interpolate, exists => 0, empty => '' },
 426               \'PATH',
 427             ),
 428   )
 429 }
 430
 431 sub active_paths {
 432   my ($class) = @_;
 433
 434   return () unless defined $ENV{PERL_LOCAL_LIB_ROOT};
 435   return split /\Q$Config{path_sep}/, $ENV{PERL_LOCAL_LIB_ROOT};
 436 }
 437
 438 sub build_deactivate_environment_vars_for {
 439   my ($class, $path, $interpolate) = @_;
 440
 441   my @active_lls = $class->active_paths;
 442
 443   if (!grep { $_ eq $path } @active_lls) {
 444     warn "Tried to deactivate inactive local::lib '$path'\n";
 445     return ();
 446   }
 447
 448   my $perl_path = $class->install_base_perl_path($path);
 449   my $arch_path = $class->install_base_arch_path($path);
 450   my $bin_path = $class->install_base_bin_path($path);
 451
 452
 453   my %env = (
 454     PERL_LOCAL_LIB_ROOT => _env_list_value(
 455       {
 456         exists => 0,
 457       },
 458       grep { $_ ne $path } @active_lls
 459     ),
 460     PERL5LIB => _env_list_value(
 461       {
 462         exists => 0,
 463         filter => sub {
 464           $_ ne $perl_path && $_ ne $arch_path
 465         },
 466       },
 467       \'PERL5LIB',
 468     ),
 469     PATH => _env_list_value(
 470       {
 471         exists => 0,
 472         filter => sub { $_ ne $bin_path },
 473       },
 474       \'PATH',
 475     ),
 476   );
 477
 478   # If removing ourselves from the "top of the stack", set install paths to
 479   # correspond with the new top of stack.
 480   if ($active_lls[-1] eq $path) {
 481     if (@active_lls > 1) {
 482       my $new_top = $active_lls[-2];
 483       %env = (%env,
 484         PERL_MB_OPT => "--install_base ${new_top}",
 485         PERL_MM_OPT => "INSTALL_BASE=${new_top}",
 486       );
 487     } else {
 488       %env = (%env,
 489         PERL_MB_OPT => undef,
 490         PERL_MM_OPT => undef,
 491       );
 492     }
 493   }
 494
 495   return %env;
 496 }
 497
 498 sub build_deact_all_environment_vars_for {
 499   my ($class, $path, $interpolate) = @_;
 500
 501   my @active_lls = $class->active_paths;
 502
 503   my %perl_paths = map { (
 504       $class->install_base_perl_path($_) => 1,
 505       $class->install_base_arch_path($_) => 1
 506     ) } @active_lls;
 507   my %bin_paths = map { (
 508       $class->install_base_bin_path($_) => 1,
 509     ) } @active_lls;
 510
 511   my %env = (
 512     PERL_LOCAL_LIB_ROOT => undef,
 513     PERL_MM_OPT => undef,
 514     PERL_MB_OPT => undef,
 515     PERL5LIB => _env_list_value(
 516       {
 517         exists => 0,
 518         filter => sub {
 519           ! scalar grep { exists $perl_paths{$_} } $_[0]
 520         },
 521       },
 522       \'PERL5LIB'
 523     ),
 524     PATH => _env_list_value(
 525       {
 526         exists => 0,
 527         filter => sub {
 528           ! scalar grep { exists $bin_paths{$_} } $_[0]
 529         },
 530       },
 531       \'PATH'
 532     ),
 533   );
 534
 535   return %env;
 536 }
 537
 538 =begin testing
 539
 540 #:: test classmethod
 541
 542 File::Path::rmtree('t/var/splat');
 543
 544 $c->ensure_dir_structure_for('t/var/splat');
 545
 546 ok(-d 't/var/splat');
 547
 548 =end testing
 549
 550 =encoding utf8
 551
 552 =head1 NAME
 553
 554 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 555
 556 =head1 SYNOPSIS
 557
 558 In code -
 559
 560   use local::lib; # sets up a local lib at ~/perl5
 561
 562   use local::lib '~/foo'; # same, but ~/foo
 563
 564   # Or...
 565   use FindBin;
 566   use local::lib "$FindBin::Bin/../support";  # app-local support library
 567
 568 From the shell -
 569
 570   # Install LWP and its missing dependencies to the '~/perl5' directory
 571   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 572
 573   # Just print out useful shell commands
 574   $ perl -Mlocal::lib
 575   export PERL_MB_OPT='--install_base /home/username/perl5'
 576   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 577   export PERL5LIB='/home/username/perl5/lib/perl5/i386-linux:/home/username/perl5/lib/perl5'
 578   export PATH="/home/username/perl5/bin:$PATH"
 579
 580 =head2 The bootstrapping technique
 581
 582 A typical way to install local::lib is using what is known as the
 583 "bootstrapping" technique.  You would do this if your system administrator
 584 hasn't already installed local::lib.  In this case, you'll need to install
 585 local::lib in your home directory.
 586
 587 If you do have administrative privileges, you will still want to set up your
 588 environment variables, as discussed in step 4. Without this, you would still
 589 install the modules into the system CPAN installation and also your Perl scripts
 590 will not use the lib/ path you bootstrapped with local::lib.
 591
 592 By default local::lib installs itself and the CPAN modules into ~/perl5.
 593
 594 Windows users must also see L</Differences when using this module under Win32>.
 595
 596 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 597 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 598 or administrator.  Unpack the file in your home directory or in any other
 599 convenient location.
 600
 601 2. Run this:
 602
 603   perl Makefile.PL --bootstrap
 604
 605 If the system asks you whether it should automatically configure as much
 606 as possible, you would typically answer yes.
 607
 608 In order to install local::lib into a directory other than the default, you need
 609 to specify the name of the directory when you call bootstrap, as follows:
 610
 611   perl Makefile.PL --bootstrap=~/foo
 612
 613 3. Run this: (local::lib assumes you have make installed on your system)
 614
 615   make test && make install
 616
 617 4. Now we need to setup the appropriate environment variables, so that Perl
 618 starts using our newly generated lib/ directory. If you are using bash or
 619 any other Bourne shells, you can add this to your shell startup script this
 620 way:
 621
 622   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 623
 624 If you are using C shell, you can do this as follows:
 625
 626   /bin/csh
 627   echo $SHELL
 628   /bin/csh
 629   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 630
 631 If you passed to bootstrap a directory other than default, you also need to give that as
 632 import parameter to the call of the local::lib module like this way:
 633
 634   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 635
 636 After writing your shell configuration file, be sure to re-read it to get the
 637 changed settings into your current shell's environment. Bourne shells use
 638 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 639
 640 If you're on a slower machine, or are operating under draconian disk space
 641 limitations, you can disable the automatic generation of manpages from POD when
 642 installing modules by using the C<--no-manpages> argument when bootstrapping:
 643
 644   perl Makefile.PL --bootstrap --no-manpages
 645
 646 To avoid doing several bootstrap for several Perl module environments on the
 647 same account, for example if you use it for several different deployed
 648 applications independently, you can use one bootstrapped local::lib
 649 installation to install modules in different directories directly this way:
 650
 651   cd ~/mydir1
 652   perl -Mlocal::lib=./
 653   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 654   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 655   perl -MCPAN -e install ...    ### whatever modules you want
 656   cd ../mydir2
 657   ... REPEAT ...
 658
 659 If you are working with several C<local::lib> environments, you may want to
 660 remove some of them from the current environment without disturbing the others.
 661 You can deactivate one environment like this (using bourne sh):
 662
 663   eval $(perl -Mlocal::lib=--deactivate,~/path)
 664
 665 which will generate and run the commands needed to remove C<~/path> from your
 666 various search paths. Whichever environment was B<activated most recently> will
 667 remain the target for module installations. That is, if you activate
 668 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 669 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 670 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 671 installed in C<~/pathB> because pathB was activated later.
 672
 673 You can also ask C<local::lib> to clean itself completely out of the current
 674 shell's environment with the C<--deactivate-all> option.
 675 For multiple environments for multiple apps you may need to include a modified
 676 version of the C<< use FindBin >> instructions in the "In code" sample above.
 677 If you did something like the above, you have a set of Perl modules at C<<
 678 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 679 you need to tell it where to find the modules you installed for it at C<<
 680 ~/mydir1/lib >>.
 681
 682 In C<< ~/mydir1/scripts/myscript.pl >>:
 683
 684   use strict;
 685   use warnings;
 686   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 687   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 688
 689 Put this before any BEGIN { ... } blocks that require the modules you installed.
 690
 691 =head2 Differences when using this module under Win32
 692
 693 To set up the proper environment variables for your current session of
 694 C<CMD.exe>, you can use this:
 695
 696   C:\>perl -Mlocal::lib
 697   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 698   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 699   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5;C:\DOCUME~1\ADMINI~1\perl5\lib\perl5\MSWin32-x86-multi-thread
 700   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 701
 702   ### To set the environment for this shell alone
 703   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 704   ### instead of $(perl -Mlocal::lib=./)
 705
 706 If you want the environment entries to persist, you'll need to add then to the
 707 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 708
 709 The "~" is translated to the user's profile directory (the directory named for
 710 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 711 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 712 directory is translated to a short name (which means the directory must exist)
 713 and the subdirectories are created.
 714
 715 =head1 RATIONALE
 716
 717 The version of a Perl package on your machine is not always the version you
 718 need.  Obviously, the best thing to do would be to update to the version you
 719 need.  However, you might be in a situation where you're prevented from doing
 720 this.  Perhaps you don't have system administrator privileges; or perhaps you
 721 are using a package management system such as Debian, and nobody has yet gotten
 722 around to packaging up the version you need.
 723
 724 local::lib solves this problem by allowing you to create your own directory of
 725 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 726 be within your own home directory).  The existing system Perl installation is
 727 not affected; you simply invoke Perl with special options so that Perl uses the
 728 packages in your own local package directory rather than the system packages.
 729 local::lib arranges things so that your locally installed version of the Perl
 730 packages takes precedence over the system installation.
 731
 732 If you are using a package management system (such as Debian), you don't need to
 733 worry about Debian and CPAN stepping on each other's toes.  Your local version
 734 of the packages will be written to an entirely separate directory from those
 735 installed by Debian.
 736
 737 =head1 DESCRIPTION
 738
 739 This module provides a quick, convenient way of bootstrapping a user-local Perl
 740 module library located within the user's home directory. It also constructs and
 741 prints out for the user the list of environment variables using the syntax
 742 appropriate for the user's current shell (as specified by the C<SHELL>
 743 environment variable), suitable for directly adding to one's shell
 744 configuration file.
 745
 746 More generally, local::lib allows for the bootstrapping and usage of a
 747 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 748 easier to ship an application with an app-specific copy of a Perl module, or
 749 collection of modules. Useful in cases like when an upstream maintainer hasn't
 750 applied a patch to a module of theirs that you need for your application.
 751
 752 On import, local::lib sets the following environment variables to appropriate
 753 values:
 754
 755 =over 4
 756
 757 =item PERL_MB_OPT
 758
 759 =item PERL_MM_OPT
 760
 761 =item PERL5LIB
 762
 763 =item PATH
 764
 765 PATH is appended to, rather than clobbered.
 766
 767 =back
 768
 769 These values are then available for reference by any code after import.
 770
 771 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 772
 773 See L<lib::core::only> for one way to do this - but note that
 774 there are a number of caveats, and the best approach is always to perform a
 775 build against a clean perl (i.e. site and vendor as close to empty as possible).
 776
 777 =head1 OPTIONS
 778
 779 Options are values that can be passed to the C<local::lib> import besides the
 780 directory to use. They are specified as C<use local::lib '--option'[, path];>
 781 or C<perl -Mlocal::lib=--option[,path]>.
 782
 783 =head2 --deactivate
 784
 785 Remove the chosen path (or the default path) from the module search paths if it
 786 was added by C<local::lib>, instead of adding it.
 787
 788 =head2 --deactivate-all
 789
 790 Remove all directories that were added to search paths by C<local::lib> from the
 791 search paths.
 792
 793 =head1 METHODS
 794
 795 =head2 ensure_dir_structure_for
 796
 797 =over 4
 798
 799 =item Arguments: $path
 800
 801 =item Return value: None
 802
 803 =back
 804
 805 Attempts to create the given path, and all required parent directories. Throws
 806 an exception on failure.
 807
 808 =head2 print_environment_vars_for
 809
 810 =over 4
 811
 812 =item Arguments: $path
 813
 814 =item Return value: None
 815
 816 =back
 817
 818 Prints to standard output the variables listed above, properly set to use the
 819 given path as the base directory.
 820
 821 =head2 build_environment_vars_for
 822
 823 =over 4
 824
 825 =item Arguments: $path, $interpolate
 826
 827 =item Return value: \%environment_vars
 828
 829 =back
 830
 831 Returns a hash with the variables listed above, properly set to use the
 832 given path as the base directory.
 833
 834 =head2 setup_env_hash_for
 835
 836 =over 4
 837
 838 =item Arguments: $path
 839
 840 =item Return value: None
 841
 842 =back
 843
 844 Constructs the C<%ENV> keys for the given path, by calling
 845 L</build_environment_vars_for>.
 846
 847 =head2 active_paths
 848
 849 =over 4
 850
 851 =item Arguments: None
 852
 853 =item Return value: @paths
 854
 855 =back
 856
 857 Returns a list of active C<local::lib> paths, according to the
 858 C<PERL_LOCAL_LIB_ROOT> environment variable.
 859
 860 =head2 install_base_perl_path
 861
 862 =over 4
 863
 864 =item Arguments: $path
 865
 866 =item Return value: $install_base_perl_path
 867
 868 =back
 869
 870 Returns a path describing where to install the Perl modules for this local
 871 library installation. Appends the directories C<lib> and C<perl5> to the given
 872 path.
 873
 874 =head2 install_base_arch_path
 875
 876 =over 4
 877
 878 =item Arguments: $path
 879
 880 =item Return value: $install_base_arch_path
 881
 882 =back
 883
 884 Returns a path describing where to install the architecture-specific Perl
 885 modules for this local library installation. Based on the
 886 L</install_base_perl_path> method's return value, and appends the value of
 887 C<$Config{archname}>.
 888
 889 =head2 install_base_bin_path
 890
 891 =over 4
 892
 893 =item Arguments: $path
 894
 895 =item Return value: $install_base_bin_path
 896
 897 =back
 898
 899 Returns a path describing where to install the executable programs for this
 900 local library installation. Based on the L</install_base_perl_path> method's
 901 return value, and appends the directory C<bin>.
 902
 903 =head2 resolve_empty_path
 904
 905 =over 4
 906
 907 =item Arguments: $path
 908
 909 =item Return value: $base_path
 910
 911 =back
 912
 913 Builds and returns the base path into which to set up the local module
 914 installation. Defaults to C<~/perl5>.
 915
 916 =head2 resolve_home_path
 917
 918 =over 4
 919
 920 =item Arguments: $path
 921
 922 =item Return value: $home_path
 923
 924 =back
 925
 926 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 927 for this purpose. If no definite answer is available, throws an exception.
 928
 929 =head2 resolve_relative_path
 930
 931 =over 4
 932
 933 =item Arguments: $path
 934
 935 =item Return value: $absolute_path
 936
 937 =back
 938
 939 Translates the given path into an absolute path.
 940
 941 =head2 resolve_path
 942
 943 =over 4
 944
 945 =item Arguments: $path
 946
 947 =item Return value: $absolute_path
 948
 949 =back
 950
 951 Calls the following in a pipeline, passing the result from the previous to the
 952 next, in an attempt to find where to configure the environment for a local
 953 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 954 L</resolve_relative_path>. Passes the given path argument to
 955 L</resolve_empty_path> which then returns a result that is passed to
 956 L</resolve_home_path>, which then has its result passed to
 957 L</resolve_relative_path>. The result of this final call is returned from
 958 L</resolve_path>.
 959
 960 =head1 A WARNING ABOUT UNINST=1
 961
 962 Be careful about using local::lib in combination with "make install UNINST=1".
 963 The idea of this feature is that will uninstall an old version of a module
 964 before installing a new one. However it lacks a safety check that the old
 965 version and the new version will go in the same directory. Used in combination
 966 with local::lib, you can potentially delete a globally accessible version of a
 967 module while installing the new version in a local place. Only combine "make
 968 install UNINST=1" and local::lib if you understand these possible consequences.
 969
 970 =head1 LIMITATIONS
 971
 972 The perl toolchain is unable to handle directory names with spaces in it,
 973 so you cant put your local::lib bootstrap into a directory with spaces. What
 974 you can do is moving your local::lib to a directory with spaces B<after> you
 975 installed all modules inside your local::lib bootstrap. But be aware that you
 976 cant update or install CPAN modules after the move.
 977
 978 Rather basic shell detection. Right now anything with csh in its name is
 979 assumed to be a C shell or something compatible, and everything else is assumed
 980 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 981 not set, a Bourne-compatible shell is assumed.
 982
 983 Bootstrap is a hack and will use CPAN.pm for ExtUtils::MakeMaker even if you
 984 have CPANPLUS installed.
 985
 986 Kills any existing PERL5LIB, PERL_MM_OPT or PERL_MB_OPT.
 987
 988 Should probably auto-fixup CPAN config if not already done.
 989
 990 Patches very much welcome for any of the above.
 991
 992 On Win32 systems, does not have a way to write the created environment variables
 993 to the registry, so that they can persist through a reboot.
 994
 995 =head1 TROUBLESHOOTING
 996
 997 If you've configured local::lib to install CPAN modules somewhere in to your
 998 home directory, and at some point later you try to install a module with C<cpan
 999 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1000 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1001 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1002 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1003 you've somehow lost your updated ExtUtils::MakeMaker module.
1004
1005 To remedy this situation, rerun the bootstrapping procedure documented above.
1006
1007 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1008
1009 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1010
1011 =head1 ENVIRONMENT
1012
1013 =over 4
1014
1015 =item SHELL
1016
1017 =item COMSPEC
1018
1019 local::lib looks at the user's C<SHELL> environment variable when printing out
1020 commands to add to the shell configuration file.
1021
1022 On Win32 systems, C<COMSPEC> is also examined.
1023
1024 =back
1025
1026 =head1 SUPPORT
1027
1028 IRC:
1029
1030     Join #local-lib on irc.perl.org.
1031
1032 =head1 AUTHOR
1033
1034 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1035
1036 auto_install fixes kindly sponsored by http://www.takkle.com/
1037
1038 =head1 CONTRIBUTORS
1039
1040 Patches to correctly output commands for csh style shells, as well as some
1041 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1042
1043 Doc patches for a custom local::lib directory, more cleanups in the english
1044 documentation and a L<german documentation|POD2::DE::local::lib> contributed by Torsten Raudssus
1045 <torsten@raudssus.de>.
1046
1047 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1048 things will install properly, submitted a fix for the bug causing problems with
1049 writing Makefiles during bootstrapping, contributed an example program, and
1050 submitted yet another fix to ensure that local::lib can install and bootstrap
1051 properly. Many, many thanks!
1052
1053 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1054 section. Many thanks!
1055
1056 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1057
1058 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1059 by a patch from Marco Emilio Poleggi.
1060
1061 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1062 '--self-contained' option.
1063
1064 Documentation patches to make win32 usage clearer by
1065 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1066
1067 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc patches contributed by Breno
1068 G. de Oliveira <garu@cpan.org>.
1069
1070 Improvements to stacking multiple local::lib dirs and removing them from the
1071 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1072
1073 Patch for Carp version mismatch contributed by Hakim Cassimally <osfameron@cpan.org>.
1074
1075 =head1 COPYRIGHT
1076
1077 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1078 listed above.
1079
1080 =head1 LICENSE
1081
1082 This library is free software and may be distributed under the same terms
1083 as perl itself.
1084
1085 =cut
1086
1087 1;