lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.008001; # probably works with earlier versions but I'm not supporting them
   7               # (patches would, of course, be welcome)
   8
   9 use File::Spec ();
  10 use File::Path ();
  11 use Carp ();
  12 use Config;
  13
  14 our $VERSION = '1.007000'; # 1.7.0
  15
  16 our @KNOWN_FLAGS = qw(--self-contained);
  17
  18 sub import {
  19   my ($class, @args) = @_;
  20
  21   # Remember what PERL5LIB was when we started
  22   my $perl5lib = $ENV{PERL5LIB} || '';
  23
  24   my %arg_store;
  25   for my $arg (@args) {
  26     # check for lethal dash first to stop processing before causing problems
  27     if ($arg =~ /−/) {
  28       die <<'DEATH';
  29 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  30 These are *not* the traditional -- dashes that software recognizes. You
  31 probably got these by copy-pasting from the perldoc for this module as
  32 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  33 terminal, but can happen elsewhere too. Please try again after replacing the
  34 dashes with normal minus signs.
  35 DEATH
  36     }
  37     elsif(grep { $arg eq $_ } @KNOWN_FLAGS) {
  38       (my $flag = $arg) =~ s/--//;
  39       $arg_store{$flag} = 1;
  40     }
  41     elsif($arg =~ /^--/) {
  42       die "Unknown import argument: $arg";
  43     }
  44     else {
  45       # assume that what's left is a path
  46       $arg_store{path} = $arg;
  47     }
  48   }
  49
  50   if($arg_store{'self-contained'}) {
  51     die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  52   }
  53
  54   $arg_store{path} = $class->resolve_path($arg_store{path});
  55   $class->setup_local_lib_for($arg_store{path});
  56
  57   for (@INC) { # Untaint @INC
  58     next if ref; # Skip entry if it is an ARRAY, CODE, blessed, etc.
  59     m/(.*)/ and $_ = $1;
  60   }
  61 }
  62
  63 sub pipeline;
  64
  65 sub pipeline {
  66   my @methods = @_;
  67   my $last = pop(@methods);
  68   if (@methods) {
  69     \sub {
  70       my ($obj, @args) = @_;
  71       $obj->${pipeline @methods}(
  72         $obj->$last(@args)
  73       );
  74     };
  75   } else {
  76     \sub {
  77       shift->$last(@_);
  78     };
  79   }
  80 }
  81
  82 =begin testing
  83
  84 #:: test pipeline
  85
  86 package local::lib;
  87
  88 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
  89 my $foo = bless({}, 'Foo');
  90 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
  91
  92 =end testing
  93
  94 =cut
  95
  96 sub _uniq {
  97     my %seen;
  98     grep { ! $seen{$_}++ } @_;
  99 }
 100
 101 sub resolve_path {
 102   my ($class, $path) = @_;
 103   $class->${pipeline qw(
 104     resolve_relative_path
 105     resolve_home_path
 106     resolve_empty_path
 107   )}($path);
 108 }
 109
 110 sub resolve_empty_path {
 111   my ($class, $path) = @_;
 112   if (defined $path) {
 113     $path;
 114   } else {
 115     '~/perl5';
 116   }
 117 }
 118
 119 =begin testing
 120
 121 #:: test classmethod setup
 122
 123 my $c = 'local::lib';
 124
 125 =end testing
 126
 127 =begin testing
 128
 129 #:: test classmethod
 130
 131 is($c->resolve_empty_path, '~/perl5');
 132 is($c->resolve_empty_path('foo'), 'foo');
 133
 134 =end testing
 135
 136 =cut
 137
 138 sub resolve_home_path {
 139   my ($class, $path) = @_;
 140   return $path unless ($path =~ /^~/);
 141   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 142   my $tried_file_homedir;
 143   my $homedir = do {
 144     if (eval { require File::HomeDir } && $File::HomeDir::VERSION >= 0.65) {
 145       $tried_file_homedir = 1;
 146       if (defined $user) {
 147         File::HomeDir->users_home($user);
 148       } else {
 149         File::HomeDir->my_home;
 150       }
 151     } else {
 152       if (defined $user) {
 153         (getpwnam $user)[7];
 154       } else {
 155         if (defined $ENV{HOME}) {
 156           $ENV{HOME};
 157         } else {
 158           (getpwuid $<)[7];
 159         }
 160       }
 161     }
 162   };
 163   unless (defined $homedir) {
 164     Carp::croak(
 165       "Couldn't resolve homedir for "
 166       .(defined $user ? $user : 'current user')
 167       .($tried_file_homedir ? '' : ' - consider installing File::HomeDir')
 168     );
 169   }
 170   $path =~ s/^~[^\/]*/$homedir/;
 171   $path;
 172 }
 173
 174 sub resolve_relative_path {
 175   my ($class, $path) = @_;
 176   $path = File::Spec->rel2abs($path);
 177 }
 178
 179 =begin testing
 180
 181 #:: test classmethod
 182
 183 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 184 is($c->resolve_relative_path('bar'),'FOObar');
 185
 186 =end testing
 187
 188 =cut
 189
 190 sub setup_local_lib_for {
 191   my ($class, $path) = @_;
 192   $path = $class->ensure_dir_structure_for($path);
 193   if ($0 eq '-') {
 194     $class->print_environment_vars_for($path);
 195     exit 0;
 196   } else {
 197     $class->setup_env_hash_for($path);
 198     @INC = _uniq(split($Config{path_sep}, $ENV{PERL5LIB}), @INC);
 199   }
 200 }
 201
 202 sub install_base_bin_path {
 203   my ($class, $path) = @_;
 204   File::Spec->catdir($path, 'bin');
 205 }
 206
 207 sub install_base_perl_path {
 208   my ($class, $path) = @_;
 209   File::Spec->catdir($path, 'lib', 'perl5');
 210 }
 211
 212 sub install_base_arch_path {
 213   my ($class, $path) = @_;
 214   File::Spec->catdir($class->install_base_perl_path($path), $Config{archname});
 215 }
 216
 217 sub ensure_dir_structure_for {
 218   my ($class, $path) = @_;
 219   unless (-d $path) {
 220     warn "Attempting to create directory ${path}\n";
 221   }
 222   File::Path::mkpath($path);
 223   # Need to have the path exist to make a short name for it, so
 224   # converting to a short name here.
 225   $path = Win32::GetShortPathName($path) if $^O eq 'MSWin32';
 226
 227   return $path;
 228 }
 229
 230 sub INTERPOLATE_ENV () { 1 }
 231 sub LITERAL_ENV     () { 0 }
 232
 233 sub guess_shelltype {
 234   my $shellbin = 'sh';
 235   if(defined $ENV{'SHELL'}) {
 236       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 237       $shellbin = $shell_bin_path_parts[-1];
 238   }
 239   my $shelltype = do {
 240       local $_ = $shellbin;
 241       if(/csh/) {
 242           'csh'
 243       } else {
 244           'bourne'
 245       }
 246   };
 247
 248   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 249   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 250       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 251       $shellbin = $shell_bin_path_parts[-1];
 252          $shelltype = do {
 253                  local $_ = $shellbin;
 254                  if(/command\.com/) {
 255                          'win32'
 256                  } elsif(/cmd\.exe/) {
 257                          'win32'
 258                  } elsif(/4nt\.exe/) {
 259                          'win32'
 260                  } else {
 261                          $shelltype
 262                  }
 263          };
 264   }
 265   return $shelltype;
 266 }
 267
 268 sub print_environment_vars_for {
 269   my ($class, $path) = @_;
 270   my @envs = $class->build_environment_vars_for($path, LITERAL_ENV);
 271   my $out = '';
 272
 273   # rather basic csh detection, goes on the assumption that something won't
 274   # call itself csh unless it really is. also, default to bourne in the
 275   # pathological situation where a user doesn't have $ENV{SHELL} defined.
 276   # note also that shells with funny names, like zoid, are assumed to be
 277   # bourne.
 278
 279   my $shelltype = $class->guess_shelltype;
 280
 281   while (@envs) {
 282     my ($name, $value) = (shift(@envs), shift(@envs));
 283     $value =~ s/(\\")/\\$1/g;
 284     $out .= $class->${\"build_${shelltype}_env_declaration"}($name, $value);
 285   }
 286   print $out;
 287 }
 288
 289 # simple routines that take two arguments: an %ENV key and a value. return
 290 # strings that are suitable for passing directly to the relevant shell to set
 291 # said key to said value.
 292 sub build_bourne_env_declaration {
 293   my $class = shift;
 294   my($name, $value) = @_;
 295   return qq{export ${name}="${value}"\n};
 296 }
 297
 298 sub build_csh_env_declaration {
 299   my $class = shift;
 300   my($name, $value) = @_;
 301   return qq{setenv ${name} "${value}"\n};
 302 }
 303
 304 sub build_win32_env_declaration {
 305   my $class = shift;
 306   my($name, $value) = @_;
 307   return qq{set ${name}=${value}\n};
 308 }
 309
 310 sub setup_env_hash_for {
 311   my ($class, $path) = @_;
 312   my %envs = $class->build_environment_vars_for($path, INTERPOLATE_ENV);
 313   @ENV{keys %envs} = values %envs;
 314 }
 315
 316 sub build_environment_vars_for {
 317   my ($class, $path, $interpolate) = @_;
 318   return (
 319     PERL_MB_OPT => "--install_base ${path}",
 320     PERL_MM_OPT => "INSTALL_BASE=${path}",
 321     PERL5LIB => join($Config{path_sep},
 322                   $class->install_base_arch_path($path),
 323                   $class->install_base_perl_path($path),
 324                   (($ENV{PERL5LIB}||()) ?
 325                     ($interpolate == INTERPOLATE_ENV
 326                       ? ($ENV{PERL5LIB})
 327                       : (($^O ne 'MSWin32') ? '$PERL5LIB' : '%PERL5LIB%' ))
 328                     : ())
 329                 ),
 330     PATH => join($Config{path_sep},
 331               $class->install_base_bin_path($path),
 332               ($interpolate == INTERPOLATE_ENV
 333                 ? ($ENV{PATH}||())
 334                 : (($^O ne 'MSWin32') ? '$PATH' : '%PATH%' ))
 335              ),
 336   )
 337 }
 338
 339 =begin testing
 340
 341 #:: test classmethod
 342
 343 File::Path::rmtree('t/var/splat');
 344
 345 $c->ensure_dir_structure_for('t/var/splat');
 346
 347 ok(-d 't/var/splat');
 348
 349 =end testing
 350
 351 =encoding utf8
 352
 353 =head1 NAME
 354
 355 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 356
 357 =head1 SYNOPSIS
 358
 359 In code -
 360
 361   use local::lib; # sets up a local lib at ~/perl5
 362
 363   use local::lib '~/foo'; # same, but ~/foo
 364
 365   # Or...
 366   use FindBin;
 367   use local::lib "$FindBin::Bin/../support";  # app-local support library
 368
 369 From the shell -
 370
 371   # Install LWP and its missing dependencies to the '~/perl5' directory
 372   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 373
 374   # Just print out useful shell commands
 375   $ perl -Mlocal::lib
 376   export PERL_MB_OPT='--install_base /home/username/perl5'
 377   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 378   export PERL5LIB='/home/username/perl5/lib/perl5/i386-linux:/home/username/perl5/lib/perl5'
 379   export PATH="/home/username/perl5/bin:$PATH"
 380
 381 =head2 The bootstrapping technique
 382
 383 A typical way to install local::lib is using what is known as the
 384 "bootstrapping" technique.  You would do this if your system administrator
 385 hasn't already installed local::lib.  In this case, you'll need to install
 386 local::lib in your home directory.
 387
 388 If you do have administrative privileges, you will still want to set up your
 389 environment variables, as discussed in step 4. Without this, you would still
 390 install the modules into the system CPAN installation and also your Perl scripts
 391 will not use the lib/ path you bootstrapped with local::lib.
 392
 393 By default local::lib installs itself and the CPAN modules into ~/perl5.
 394
 395 Windows users must also see L</Differences when using this module under Win32>.
 396
 397 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 398 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 399 or administrator.  Unpack the file in your home directory or in any other
 400 convenient location.
 401
 402 2. Run this:
 403
 404   perl Makefile.PL --bootstrap
 405
 406 If the system asks you whether it should automatically configure as much
 407 as possible, you would typically answer yes.
 408
 409 In order to install local::lib into a directory other than the default, you need
 410 to specify the name of the directory when you call bootstrap, as follows:
 411
 412   perl Makefile.PL --bootstrap=~/foo
 413
 414 3. Run this: (local::lib assumes you have make installed on your system)
 415
 416   make test && make install
 417
 418 4. Now we need to setup the appropriate environment variables, so that Perl
 419 starts using our newly generated lib/ directory. If you are using bash or
 420 any other Bourne shells, you can add this to your shell startup script this
 421 way:
 422
 423   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 424
 425 If you are using C shell, you can do this as follows:
 426
 427   /bin/csh
 428   echo $SHELL
 429   /bin/csh
 430   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 431
 432 If you passed to bootstrap a directory other than default, you also need to give that as
 433 import parameter to the call of the local::lib module like this way:
 434
 435   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 436
 437 After writing your shell configuration file, be sure to re-read it to get the
 438 changed settings into your current shell's environment. Bourne shells use
 439 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 440
 441 If you're on a slower machine, or are operating under draconian disk space
 442 limitations, you can disable the automatic generation of manpages from POD when
 443 installing modules by using the C<--no-manpages> argument when bootstrapping:
 444
 445   perl Makefile.PL --bootstrap --no-manpages
 446
 447 To avoid doing several bootstrap for several Perl module environments on the
 448 same account, for example if you use it for several different deployed
 449 applications independently, you can use one bootstrapped local::lib
 450 installation to install modules in different directories directly this way:
 451
 452   cd ~/mydir1
 453   perl -Mlocal::lib=./
 454   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 455   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 456   perl -MCPAN -e install ...    ### whatever modules you want
 457   cd ../mydir2
 458   ... REPEAT ...
 459
 460 For multiple environments for multiple apps you may need to include a modified
 461 version of the C<< use FindBin >> instructions in the "In code" sample above.
 462 If you did something like the above, you have a set of Perl modules at C<<
 463 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 464 you need to tell it where to find the modules you installed for it at C<<
 465 ~/mydir1/lib >>.
 466
 467 In C<< ~/mydir1/scripts/myscript.pl >>:
 468
 469   use strict;
 470   use warnings;
 471   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 472   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 473
 474 Put this before any BEGIN { ... } blocks that require the modules you installed.
 475
 476 =head2 Differences when using this module under Win32
 477
 478 To set up the proper environment variables for your current session of
 479 C<CMD.exe>, you can use this:
 480
 481   C:\>perl -Mlocal::lib
 482   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 483   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 484   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5;C:\DOCUME~1\ADMINI~1\perl5\lib\perl5\MSWin32-x86-multi-thread
 485   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 486
 487   ### To set the environment for this shell alone
 488   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\temp.bat
 489   ### instead of $(perl -Mlocal::lib=./)
 490
 491 If you want the environment entries to persist, you'll need to add then to the
 492 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 493
 494 The "~" is translated to the user's profile directory (the directory named for
 495 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 496 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 497 directory is translated to a short name (which means the directory must exist)
 498 and the subdirectories are created.
 499
 500 =head1 RATIONALE
 501
 502 The version of a Perl package on your machine is not always the version you
 503 need.  Obviously, the best thing to do would be to update to the version you
 504 need.  However, you might be in a situation where you're prevented from doing
 505 this.  Perhaps you don't have system administrator privileges; or perhaps you
 506 are using a package management system such as Debian, and nobody has yet gotten
 507 around to packaging up the version you need.
 508
 509 local::lib solves this problem by allowing you to create your own directory of
 510 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 511 be within your own home directory).  The existing system Perl installation is
 512 not affected; you simply invoke Perl with special options so that Perl uses the
 513 packages in your own local package directory rather than the system packages.
 514 local::lib arranges things so that your locally installed version of the Perl
 515 packages takes precedence over the system installation.
 516
 517 If you are using a package management system (such as Debian), you don't need to
 518 worry about Debian and CPAN stepping on each other's toes.  Your local version
 519 of the packages will be written to an entirely separate directory from those
 520 installed by Debian.
 521
 522 =head1 DESCRIPTION
 523
 524 This module provides a quick, convenient way of bootstrapping a user-local Perl
 525 module library located within the user's home directory. It also constructs and
 526 prints out for the user the list of environment variables using the syntax
 527 appropriate for the user's current shell (as specified by the C<SHELL>
 528 environment variable), suitable for directly adding to one's shell
 529 configuration file.
 530
 531 More generally, local::lib allows for the bootstrapping and usage of a
 532 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 533 easier to ship an application with an app-specific copy of a Perl module, or
 534 collection of modules. Useful in cases like when an upstream maintainer hasn't
 535 applied a patch to a module of theirs that you need for your application.
 536
 537 On import, local::lib sets the following environment variables to appropriate
 538 values:
 539
 540 =over 4
 541
 542 =item PERL_MB_OPT
 543
 544 =item PERL_MM_OPT
 545
 546 =item PERL5LIB
 547
 548 =item PATH
 549
 550 PATH is appended to, rather than clobbered.
 551
 552 =back
 553
 554 These values are then available for reference by any code after import.
 555
 556 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 557
 558 See L<lib::core::only> for one way to do this - but note that
 559 there are a number of caveats, and the best approach is always to perform a
 560 build against a clean perl (i.e. site and vendor as close to empty as possible).
 561
 562 =head1 METHODS
 563
 564 =head2 ensure_dir_structure_for
 565
 566 =over 4
 567
 568 =item Arguments: $path
 569
 570 =item Return value: None
 571
 572 =back
 573
 574 Attempts to create the given path, and all required parent directories. Throws
 575 an exception on failure.
 576
 577 =head2 print_environment_vars_for
 578
 579 =over 4
 580
 581 =item Arguments: $path
 582
 583 =item Return value: None
 584
 585 =back
 586
 587 Prints to standard output the variables listed above, properly set to use the
 588 given path as the base directory.
 589
 590 =head2 build_environment_vars_for
 591
 592 =over 4
 593
 594 =item Arguments: $path, $interpolate
 595
 596 =item Return value: \%environment_vars
 597
 598 =back
 599
 600 Returns a hash with the variables listed above, properly set to use the
 601 given path as the base directory.
 602
 603 =head2 setup_env_hash_for
 604
 605 =over 4
 606
 607 =item Arguments: $path
 608
 609 =item Return value: None
 610
 611 =back
 612
 613 Constructs the C<%ENV> keys for the given path, by calling
 614 L</build_environment_vars_for>.
 615
 616 =head2 install_base_perl_path
 617
 618 =over 4
 619
 620 =item Arguments: $path
 621
 622 =item Return value: $install_base_perl_path
 623
 624 =back
 625
 626 Returns a path describing where to install the Perl modules for this local
 627 library installation. Appends the directories C<lib> and C<perl5> to the given
 628 path.
 629
 630 =head2 install_base_arch_path
 631
 632 =over 4
 633
 634 =item Arguments: $path
 635
 636 =item Return value: $install_base_arch_path
 637
 638 =back
 639
 640 Returns a path describing where to install the architecture-specific Perl
 641 modules for this local library installation. Based on the
 642 L</install_base_perl_path> method's return value, and appends the value of
 643 C<$Config{archname}>.
 644
 645 =head2 install_base_bin_path
 646
 647 =over 4
 648
 649 =item Arguments: $path
 650
 651 =item Return value: $install_base_bin_path
 652
 653 =back
 654
 655 Returns a path describing where to install the executable programs for this
 656 local library installation. Based on the L</install_base_perl_path> method's
 657 return value, and appends the directory C<bin>.
 658
 659 =head2 resolve_empty_path
 660
 661 =over 4
 662
 663 =item Arguments: $path
 664
 665 =item Return value: $base_path
 666
 667 =back
 668
 669 Builds and returns the base path into which to set up the local module
 670 installation. Defaults to C<~/perl5>.
 671
 672 =head2 resolve_home_path
 673
 674 =over 4
 675
 676 =item Arguments: $path
 677
 678 =item Return value: $home_path
 679
 680 =back
 681
 682 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 683 for this purpose. If no definite answer is available, throws an exception.
 684
 685 =head2 resolve_relative_path
 686
 687 =over 4
 688
 689 =item Arguments: $path
 690
 691 =item Return value: $absolute_path
 692
 693 =back
 694
 695 Translates the given path into an absolute path.
 696
 697 =head2 resolve_path
 698
 699 =over 4
 700
 701 =item Arguments: $path
 702
 703 =item Return value: $absolute_path
 704
 705 =back
 706
 707 Calls the following in a pipeline, passing the result from the previous to the
 708 next, in an attempt to find where to configure the environment for a local
 709 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 710 L</resolve_relative_path>. Passes the given path argument to
 711 L</resolve_empty_path> which then returns a result that is passed to
 712 L</resolve_home_path>, which then has its result passed to
 713 L</resolve_relative_path>. The result of this final call is returned from
 714 L</resolve_path>.
 715
 716 =head1 A WARNING ABOUT UNINST=1
 717
 718 Be careful about using local::lib in combination with "make install UNINST=1".
 719 The idea of this feature is that will uninstall an old version of a module
 720 before installing a new one. However it lacks a safety check that the old
 721 version and the new version will go in the same directory. Used in combination
 722 with local::lib, you can potentially delete a globally accessible version of a
 723 module while installing the new version in a local place. Only combine "make
 724 install UNINST=1" and local::lib if you understand these possible consequences.
 725
 726 =head1 LIMITATIONS
 727
 728 The perl toolchain is unable to handle directory names with spaces in it,
 729 so you cant put your local::lib bootstrap into a directory with spaces. What
 730 you can do is moving your local::lib to a directory with spaces B<after> you
 731 installed all modules inside your local::lib bootstrap. But be aware that you
 732 cant update or install CPAN modules after the move.
 733
 734 Rather basic shell detection. Right now anything with csh in its name is
 735 assumed to be a C shell or something compatible, and everything else is assumed
 736 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 737 not set, a Bourne-compatible shell is assumed.
 738
 739 Bootstrap is a hack and will use CPAN.pm for ExtUtils::MakeMaker even if you
 740 have CPANPLUS installed.
 741
 742 Kills any existing PERL5LIB, PERL_MM_OPT or PERL_MB_OPT.
 743
 744 Should probably auto-fixup CPAN config if not already done.
 745
 746 Patches very much welcome for any of the above.
 747
 748 On Win32 systems, does not have a way to write the created environment variables
 749 to the registry, so that they can persist through a reboot.
 750
 751 =head1 TROUBLESHOOTING
 752
 753 If you've configured local::lib to install CPAN modules somewhere in to your
 754 home directory, and at some point later you try to install a module with C<cpan
 755 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
 756 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
 757 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
 758 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
 759 you've somehow lost your updated ExtUtils::MakeMaker module.
 760
 761 To remedy this situation, rerun the bootstrapping procedure documented above.
 762
 763 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
 764
 765 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
 766
 767 =head1 ENVIRONMENT
 768
 769 =over 4
 770
 771 =item SHELL
 772
 773 =item COMSPEC
 774
 775 local::lib looks at the user's C<SHELL> environment variable when printing out
 776 commands to add to the shell configuration file.
 777
 778 On Win32 systems, C<COMSPEC> is also examined.
 779
 780 =back
 781
 782 =head1 SUPPORT
 783
 784 IRC:
 785
 786     Join #local-lib on irc.perl.org.
 787
 788 =head1 AUTHOR
 789
 790 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
 791
 792 auto_install fixes kindly sponsored by http://www.takkle.com/
 793
 794 =head1 CONTRIBUTORS
 795
 796 Patches to correctly output commands for csh style shells, as well as some
 797 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
 798
 799 Doc patches for a custom local::lib directory, more cleanups in the english
 800 documentation and a L<german documentation|POD2::DE::local::lib> contributed by Torsten Raudssus
 801 <torsten@raudssus.de>.
 802
 803 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
 804 things will install properly, submitted a fix for the bug causing problems with
 805 writing Makefiles during bootstrapping, contributed an example program, and
 806 submitted yet another fix to ensure that local::lib can install and bootstrap
 807 properly. Many, many thanks!
 808
 809 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
 810 section. Many thanks!
 811
 812 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
 813
 814 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
 815 by a patch from Marco Emilio Poleggi.
 816
 817 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
 818 '--self-contained' option.
 819
 820 Documentation patches to make win32 usage clearer by
 821 David Mertens <dcmertens.perl@gmail.com> (run4flat).
 822
 823 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc patches contributed by Breno
 824 G. de Oliveira <garu@cpan.org>.
 825
 826 =head1 COPYRIGHT
 827
 828 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
 829 listed above.
 830
 831 =head1 LICENSE
 832
 833 This library is free software and may be distributed under the same terms
 834 as perl itself.
 835
 836 =cut
 837
 838 1;