lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '2.000004'; # 2.0.4
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16   push @args, @ARGV
  17     if $0 eq '-';
  18
  19   my @steps;
  20   my %opts;
  21   my $shelltype;
  22
  23   while (@args) {
  24     my $arg = shift @args;
  25     # check for lethal dash first to stop processing before causing problems
  26     # the fancy dash is U+2212 or \xE2\x88\x92
  27     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  28       die <<'DEATH';
  29 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  30 These are *not* the traditional -- dashes that software recognizes. You
  31 probably got these by copy-pasting from the perldoc for this module as
  32 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  33 terminal, but can happen elsewhere too. Please try again after replacing the
  34 dashes with normal minus signs.
  35 DEATH
  36     }
  37     elsif ($arg eq '--self-contained') {
  38       die <<'DEATH';
  39 FATAL: The local::lib --self-contained flag has never worked reliably and the
  40 original author, Mark Stosberg, was unable or unwilling to maintain it. As
  41 such, this flag has been removed from the local::lib codebase in order to
  42 prevent misunderstandings and potentially broken builds. The local::lib authors
  43 recommend that you look at the lib::core::only module shipped with this
  44 distribution in order to create a more robust environment that is equivalent to
  45 what --self-contained provided (although quite possibly not what you originally
  46 thought it provided due to the poor quality of the documentation, for which we
  47 apologise).
  48 DEATH
  49     }
  50     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  51       my $path = defined $1 ? $1 : shift @args;
  52       push @steps, ['deactivate', $path];
  53     }
  54     elsif ( $arg eq '--deactivate-all' ) {
  55       push @steps, ['deactivate_all'];
  56     }
  57     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  58       $shelltype = defined $1 ? $1 : shift @args;
  59     }
  60     elsif ( $arg eq '--no-create' ) {
  61       $opts{no_create} = 1;
  62     }
  63     elsif ( $arg =~ /^--/ ) {
  64       die "Unknown import argument: $arg";
  65     }
  66     else {
  67       push @steps, ['activate', $arg];
  68     }
  69   }
  70   if (!@steps) {
  71     push @steps, ['activate', undef];
  72   }
  73
  74   my $self = $class->new(%opts);
  75
  76   for (@steps) {
  77     my ($method, @args) = @$_;
  78     $self = $self->$method(@args);
  79   }
  80
  81   if ($0 eq '-') {
  82     print $self->environment_vars_string($shelltype);
  83     exit 0;
  84   }
  85   else {
  86     $self->setup_local_lib;
  87   }
  88 }
  89
  90 sub new {
  91   my $class = shift;
  92   bless {@_}, $class;
  93 }
  94
  95 sub clone {
  96   my $self = shift;
  97   bless {%$self, @_}, ref $self;
  98 }
  99
 100 sub inc { $_[0]->{inc}     ||= \@INC }
 101 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
 102 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
 103 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
 104 sub extra { $_[0]->{extra} ||= {} }
 105 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
 106 sub no_create { $_[0]->{no_create} }
 107
 108 my $_archname = $Config{archname};
 109 my $_version  = $Config{version};
 110 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
 111 my $_path_sep = $Config{path_sep};
 112
 113 sub _as_list {
 114   my $list = shift;
 115   grep length, map {
 116     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 117       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 118                         : ()
 119     )
 120   } ref $list ? @$list : $list;
 121 }
 122 sub _remove_from {
 123   my ($list, @remove) = @_;
 124   return @$list
 125     if !@remove;
 126   my %remove = map { $_ => 1 } @remove;
 127   grep !$remove{$_}, _as_list($list);
 128 }
 129
 130 my @_lib_subdirs = (
 131   [$_version, $_archname],
 132   [$_version],
 133   [$_archname],
 134   (@_inc_version_list ? \@_inc_version_list : ()),
 135   [],
 136 );
 137
 138 sub install_base_bin_path {
 139   my ($class, $path) = @_;
 140   return File::Spec->catdir($path, 'bin');
 141 }
 142 sub install_base_perl_path {
 143   my ($class, $path) = @_;
 144   return File::Spec->catdir($path, 'lib', 'perl5');
 145 }
 146 sub install_base_arch_path {
 147   my ($class, $path) = @_;
 148   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 149 }
 150
 151 sub lib_paths_for {
 152   my ($class, $path) = @_;
 153   my $base = $class->install_base_perl_path($path);
 154   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 155 }
 156
 157 sub _mm_escape_path {
 158   my $path = shift;
 159   $path =~ s/\\/\\\\\\\\/g;
 160   if ($path =~ s/ /\\ /g) {
 161     $path = qq{"\\"$path\\""};
 162   }
 163   return $path;
 164 }
 165
 166 sub _mb_escape_path {
 167   my $path = shift;
 168   $path =~ s/\\/\\\\/g;
 169   return qq{"$path"};
 170 }
 171
 172 sub installer_options_for {
 173   my ($class, $path) = @_;
 174   return (
 175     PERL_MM_OPT =>
 176       defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 177     PERL_MB_OPT =>
 178       defined $path ? "--install_base "._mb_escape_path($path) : undef,
 179   );
 180 }
 181
 182 sub active_paths {
 183   my ($self) = @_;
 184   $self = ref $self ? $self : $self->new;
 185
 186   return grep {
 187     # screen out entries that aren't actually reflected in @INC
 188     my $active_ll = $self->install_base_perl_path($_);
 189     grep { $_ eq $active_ll } @{$self->inc};
 190   } _as_list($self->roots);
 191 }
 192
 193
 194 sub deactivate {
 195   my ($self, $path) = @_;
 196   $self = $self->new unless ref $self;
 197   $path = $self->resolve_path($path);
 198   $path = $self->normalize_path($path);
 199
 200   my @active_lls = $self->active_paths;
 201
 202   if (!grep { $_ eq $path } @active_lls) {
 203     warn "Tried to deactivate inactive local::lib '$path'\n";
 204     return $self;
 205   }
 206
 207   my %args = (
 208     bins  => [ _remove_from($self->bins,
 209       $self->install_base_bin_path($path)) ],
 210     libs  => [ _remove_from($self->libs,
 211       $self->install_base_perl_path($path)) ],
 212     inc   => [ _remove_from($self->inc,
 213       $self->lib_paths_for($path)) ],
 214     roots => [ _remove_from($self->roots, $path) ],
 215   );
 216
 217   $args{extra} = { $self->installer_options_for($args{roots}[0]) };
 218
 219   $self->clone(%args);
 220 }
 221
 222 sub deactivate_all {
 223   my ($self) = @_;
 224   $self = $self->new unless ref $self;
 225
 226   my @active_lls = $self->active_paths;
 227
 228   my %args;
 229   if (@active_lls) {
 230     %args = (
 231       bins => [ _remove_from($self->bins,
 232         map $self->install_base_bin_path($_), @active_lls) ],
 233       libs => [ _remove_from($self->libs,
 234         map $self->install_base_perl_path($_), @active_lls) ],
 235       inc => [ _remove_from($self->inc,
 236         map $self->lib_paths_for($_), @active_lls) ],
 237       roots => [ _remove_from($self->roots, @active_lls) ],
 238     );
 239   }
 240
 241   $args{extra} = { $self->installer_options_for(undef) };
 242
 243   $self->clone(%args);
 244 }
 245
 246 sub activate {
 247   my ($self, $path) = @_;
 248   $self = $self->new unless ref $self;
 249   $path = $self->resolve_path($path);
 250   $self->ensure_dir_structure_for($path)
 251     unless $self->no_create;
 252
 253   $path = $self->normalize_path($path);
 254
 255   my @active_lls = $self->active_paths;
 256
 257   if (grep { $_ eq $path } @active_lls[1 .. $#active_lls]) {
 258     $self = $self->deactivate($path);
 259   }
 260
 261   my %args;
 262   if (!@active_lls || $active_lls[0] ne $path) {
 263     %args = (
 264       bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 265       libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 266       inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 267       roots => [ $path, @{$self->roots} ],
 268     );
 269   }
 270
 271   $args{extra} = { $self->installer_options_for($path) };
 272
 273   $self->clone(%args);
 274 }
 275
 276 sub normalize_path {
 277   my ($self, $path) = @_;
 278   $path = ( Win32::GetShortPathName($path) || $path )
 279     if $^O eq 'MSWin32';
 280   return $path;
 281 }
 282
 283 sub build_environment_vars_for {
 284   my $self = $_[0]->new->activate($_[1]);
 285   $self->build_environment_vars;
 286 }
 287 sub build_environment_vars {
 288   my $self = shift;
 289   (
 290     PATH                => join($_path_sep, _as_list($self->bins)),
 291     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 292     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 293     %{$self->extra},
 294   );
 295 }
 296
 297 sub setup_local_lib_for {
 298   my $self = $_[0]->new->activate($_[1]);
 299   $self->setup_local_lib;
 300 }
 301
 302 sub setup_local_lib {
 303   my $self = shift;
 304   $self->setup_env_hash;
 305   @INC = @{$self->inc};
 306 }
 307
 308 sub setup_env_hash_for {
 309   my $self = $_[0]->new->activate($_[1]);
 310   $self->setup_env_hash;
 311 }
 312 sub setup_env_hash {
 313   my $self = shift;
 314   my %env = $self->build_environment_vars;
 315   for my $key (keys %env) {
 316     if (defined $env{$key}) {
 317       $ENV{$key} = $env{$key};
 318     }
 319     else {
 320       delete $ENV{$key};
 321     }
 322   }
 323 }
 324
 325 sub print_environment_vars_for {
 326   print $_[0]->environment_vars_string_for(@_[1..$#_]);
 327 }
 328
 329 sub environment_vars_string_for {
 330   my $self = $_[0]->new->activate($_[1]);
 331   $self->environment_vars_string;
 332 }
 333 sub environment_vars_string {
 334   my ($self, $shelltype) = @_;
 335
 336   $shelltype ||= $self->guess_shelltype;
 337
 338   my $build_method = "build_${shelltype}_env_declaration";
 339
 340   my @envs = (
 341     PATH                => $self->bins,
 342     PERL5LIB            => $self->libs,
 343     PERL_LOCAL_LIB_ROOT => $self->roots,
 344     %{$self->extra},
 345   );
 346   my $out = '';
 347   while (@envs) {
 348     my ($name, $value) = (shift(@envs), shift(@envs));
 349     if (
 350         ref $value
 351         && @$value == 1
 352         && ref $value->[0]
 353         && ref $value->[0] eq 'SCALAR'
 354         && ${$value->[0]} eq $name) {
 355       next;
 356     }
 357     if (
 358         !ref $value
 359         and defined $value
 360           ? (defined $ENV{$name} && $value eq $ENV{$name})
 361           : !defined $ENV{$name}
 362     ) {
 363       next;
 364     }
 365     $out .= $self->$build_method($name, $value);
 366   }
 367   my $wrap_method = 'wrap_' . $self->shelltype . '_output';
 368   if ($self->can($wrap_method)) {
 369     return $self->$wrap_method($out);
 370   }
 371   return $out;
 372 }
 373
 374 sub build_bourne_env_declaration {
 375   my ($class, $name, $args) = @_;
 376   my $value = $class->_interpolate($args, '$%s', '"', '\\%s');
 377
 378   if (!defined $value) {
 379     return qq{unset $name;\n};
 380   }
 381
 382   $value =~ s/(^|\G|$_path_sep)\$$name$_path_sep/$1\$$name\${$name+$_path_sep}/g;
 383   $value =~ s/$_path_sep\$$name$/\${$name+$_path_sep}\$$name/;
 384
 385   qq{${name}="$value";\nexport ${name};\n}
 386 }
 387
 388 sub build_csh_env_declaration {
 389   my ($class, $name, $args) = @_;
 390   my ($value, @vars) = $class->_interpolate($args, '$%s', '"', '"\\%s"');
 391   if (!defined $value) {
 392     return qq{unsetenv $name;\n};
 393   }
 394
 395   my $out = '';
 396   for my $var (@vars) {
 397     $out .= qq{if ! \$?$name setenv $name '';\n};
 398   }
 399
 400   my $value_without = $value;
 401   if ($value_without =~ s/(?:^|$_path_sep)\$$name(?:$_path_sep|$)//g) {
 402     $out .= qq{if "\$$name" != '' setenv $name "$value";\n};
 403     $out .= qq{if "\$$name" == '' };
 404   }
 405   $out .= qq{setenv $name "$value_without";\n};
 406   return $out;
 407 }
 408
 409 sub build_cmd_env_declaration {
 410   my ($class, $name, $args) = @_;
 411   my $value = $class->_interpolate($args, '%%%s%%', qr([()!^"<>&|]), '^%s');
 412   if (!$value) {
 413     return qq{\@set $name=\n};
 414   }
 415
 416   my $out = '';
 417   my $value_without = $value;
 418   if ($value_without =~ s/(?:^|$_path_sep)%$name%(?:$_path_sep|$)//g) {
 419     $out .= qq{\@if not "%$name%"=="" set $name=$value\n};
 420     $out .= qq{\@if "%$name%"=="" };
 421   }
 422   $out .= qq{\@set $name=$value_without\n};
 423   return $out;
 424 }
 425
 426 sub build_powershell_env_declaration {
 427   my ($class, $name, $args) = @_;
 428   my $value = $class->_interpolate($args, '$env:%s', '"', '`%s');
 429
 430   if (!$value) {
 431     return qq{Remove-Item -ErrorAction 0 Env:\\$name;\n};
 432   }
 433
 434   my $maybe_path_sep = qq{\$(if("\$env:$name"-eq""){""}else{"$_path_sep"})};
 435   $value =~ s/(^|\G|$_path_sep)\$env:$name$_path_sep/$1\$env:$name"+$maybe_path_sep+"/g;
 436   $value =~ s/$_path_sep\$env:$name$/"+$maybe_path_sep+\$env:$name+"/;
 437
 438   qq{\$env:$name = \$("$value");\n};
 439 }
 440 sub wrap_powershell_output {
 441   my ($class, $out) = @_;
 442   return $out || " \n";
 443 }
 444
 445 sub build_fish_env_declaration {
 446   my ($class, $name, $args) = @_;
 447   my $value = $class->_interpolate($args, '$%s', '"', '\\%s');
 448   if (!defined $value) {
 449     return qq{set -e $name;\n};
 450   }
 451   $value =~ s/$_path_sep/ /g;
 452   qq{set -x $name $value;\n};
 453 }
 454
 455 sub _interpolate {
 456   my ($class, $args, $var_pat, $escape, $escape_pat) = @_;
 457   return
 458     unless defined $args;
 459   my @args = ref $args ? @$args : $args;
 460   return
 461     unless @args;
 462   my @vars = map { $$_ } grep { ref $_ eq 'SCALAR' } @args;
 463   my $string = join $_path_sep, map {
 464     ref $_ eq 'SCALAR' ? sprintf($var_pat, $$_) : do {
 465       s/($escape)/sprintf($escape_pat, $1)/ge; $_;
 466     };
 467   } @args;
 468   return wantarray ? ($string, \@vars) : $string;
 469 }
 470
 471 sub pipeline;
 472
 473 sub pipeline {
 474   my @methods = @_;
 475   my $last = pop(@methods);
 476   if (@methods) {
 477     \sub {
 478       my ($obj, @args) = @_;
 479       $obj->${pipeline @methods}(
 480         $obj->$last(@args)
 481       );
 482     };
 483   } else {
 484     \sub {
 485       shift->$last(@_);
 486     };
 487   }
 488 }
 489
 490 sub resolve_path {
 491   my ($class, $path) = @_;
 492
 493   $path = $class->${pipeline qw(
 494     resolve_relative_path
 495     resolve_home_path
 496     resolve_empty_path
 497   )}($path);
 498
 499   $path;
 500 }
 501
 502 sub resolve_empty_path {
 503   my ($class, $path) = @_;
 504   if (defined $path) {
 505     $path;
 506   } else {
 507     '~/perl5';
 508   }
 509 }
 510
 511 sub resolve_home_path {
 512   my ($class, $path) = @_;
 513   return $path unless ($path =~ /^~/);
 514   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 515   my $homedir = do {
 516     if (!defined $user && defined $ENV{HOME}) {
 517       $ENV{HOME}
 518     }
 519     else {
 520       require File::Glob;
 521       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 522     }
 523   };
 524   unless (defined $homedir) {
 525     require Carp;
 526     Carp::croak(
 527       "Couldn't resolve homedir for "
 528       .(defined $user ? $user : 'current user')
 529     );
 530   }
 531   $path =~ s/^~[^\/]*/$homedir/;
 532   $path;
 533 }
 534
 535 sub resolve_relative_path {
 536   my ($class, $path) = @_;
 537   $path = File::Spec->rel2abs($path);
 538 }
 539
 540 sub ensure_dir_structure_for {
 541   my ($class, $path) = @_;
 542   unless (-d $path) {
 543     warn "Attempting to create directory ${path}\n";
 544   }
 545   require File::Basename;
 546   my @dirs;
 547   while(!-d $path) {
 548     push @dirs, $path;
 549     $path = File::Basename::dirname($path);
 550   }
 551   mkdir $_ for reverse @dirs;
 552   return;
 553 }
 554
 555 sub guess_shelltype {
 556   my $shellbin
 557     = defined $ENV{SHELL}
 558       ? (File::Spec->splitpath($ENV{SHELL}))[-1]
 559     : ( $^O eq 'MSWin32' && exists $ENV{'!EXITCODE'} )
 560       ? 'bash'
 561     : ( $^O eq 'MSWin32' && $ENV{PROMPT} && $ENV{COMSPEC} )
 562       ? (File::Spec->splitpath($ENV{COMSPEC}))[-1]
 563     : ( $^O eq 'MSWin32' && !$ENV{PROMPT} )
 564       ? 'powershell.exe'
 565     : 'sh';
 566
 567   for ($shellbin) {
 568     return
 569         /csh$/                   ? 'csh'
 570       : /fish/                   ? 'fish'
 571       : /command(?:\.com)?$/i    ? 'cmd'
 572       : /cmd(?:\.exe)?$/i        ? 'cmd'
 573       : /4nt(?:\.exe)?$/i        ? 'cmd'
 574       : /powershell(?:\.exe)?$/i ? 'powershell'
 575                                  : 'bourne';
 576   }
 577 }
 578
 579 1;
 580 __END__
 581
 582 =encoding utf8
 583
 584 =head1 NAME
 585
 586 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 587
 588 =head1 SYNOPSIS
 589
 590 In code -
 591
 592   use local::lib; # sets up a local lib at ~/perl5
 593
 594   use local::lib '~/foo'; # same, but ~/foo
 595
 596   # Or...
 597   use FindBin;
 598   use local::lib "$FindBin::Bin/../support";  # app-local support library
 599
 600 From the shell -
 601
 602   # Install LWP and its missing dependencies to the '~/perl5' directory
 603   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 604
 605   # Just print out useful shell commands
 606   $ perl -Mlocal::lib
 607   export PERL_MB_OPT='--install_base /home/username/perl5'
 608   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 609   export PERL5LIB="/home/username/perl5/lib/perl5"
 610   export PATH="/home/username/perl5/bin:$PATH"
 611
 612 From a .bashrc file -
 613
 614   [ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)"
 615
 616 =head2 The bootstrapping technique
 617
 618 A typical way to install local::lib is using what is known as the
 619 "bootstrapping" technique.  You would do this if your system administrator
 620 hasn't already installed local::lib.  In this case, you'll need to install
 621 local::lib in your home directory.
 622
 623 Even if you do have administrative privileges, you will still want to set up your
 624 environment variables, as discussed in step 4. Without this, you would still
 625 install the modules into the system CPAN installation and also your Perl scripts
 626 will not use the lib/ path you bootstrapped with local::lib.
 627
 628 By default local::lib installs itself and the CPAN modules into ~/perl5.
 629
 630 Windows users must also see L</Differences when using this module under Win32>.
 631
 632 =over 4
 633
 634 =item 1.
 635
 636 Download and unpack the local::lib tarball from CPAN (search for "Download"
 637 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 638 or administrator.  Unpack the file in your home directory or in any other
 639 convenient location.
 640
 641 =item 2.
 642
 643 Run this:
 644
 645   perl Makefile.PL --bootstrap
 646
 647 If the system asks you whether it should automatically configure as much
 648 as possible, you would typically answer yes.
 649
 650 In order to install local::lib into a directory other than the default, you need
 651 to specify the name of the directory when you call bootstrap, as follows:
 652
 653   perl Makefile.PL --bootstrap=~/foo
 654
 655 =item 3.
 656
 657 Run this: (local::lib assumes you have make installed on your system)
 658
 659   make test && make install
 660
 661 =item 4.
 662
 663 Now we need to setup the appropriate environment variables, so that Perl
 664 starts using our newly generated lib/ directory. If you are using bash or
 665 any other Bourne shells, you can add this to your shell startup script this
 666 way:
 667
 668   echo '[ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)"' >>~/.bashrc
 669
 670 If you are using C shell, you can do this as follows:
 671
 672   /bin/csh
 673   echo $SHELL
 674   /bin/csh
 675   echo 'eval `perl -I$HOME/perl5/lib/perl5 -Mlocal::lib`' >> ~/.cshrc
 676
 677 If you passed to bootstrap a directory other than default, you also need to
 678 give that as import parameter to the call of the local::lib module like this
 679 way:
 680
 681   echo '[ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)"' >>~/.bashrc
 682
 683 After writing your shell configuration file, be sure to re-read it to get the
 684 changed settings into your current shell's environment. Bourne shells use
 685 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 686
 687 =back
 688
 689 If you're on a slower machine, or are operating under draconian disk space
 690 limitations, you can disable the automatic generation of manpages from POD when
 691 installing modules by using the C<--no-manpages> argument when bootstrapping:
 692
 693   perl Makefile.PL --bootstrap --no-manpages
 694
 695 To avoid doing several bootstrap for several Perl module environments on the
 696 same account, for example if you use it for several different deployed
 697 applications independently, you can use one bootstrapped local::lib
 698 installation to install modules in different directories directly this way:
 699
 700   cd ~/mydir1
 701   perl -Mlocal::lib=./
 702   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 703   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 704   perl -MCPAN -e install ...    ### whatever modules you want
 705   cd ../mydir2
 706   ... REPEAT ...
 707
 708 When used in a C<.bashrc> file, it is recommended that you protect against
 709 re-activating a directory in a sub-shell.  This can be done by checking the
 710 C<$SHLVL> variable as shown in synopsis.  Without this, sub-shells created by
 711 the user or other programs will override changes made to the parent shell's
 712 environment.
 713
 714 If you are working with several C<local::lib> environments, you may want to
 715 remove some of them from the current environment without disturbing the others.
 716 You can deactivate one environment like this (using bourne sh):
 717
 718   eval $(perl -Mlocal::lib=--deactivate,~/path)
 719
 720 which will generate and run the commands needed to remove C<~/path> from your
 721 various search paths. Whichever environment was B<activated most recently> will
 722 remain the target for module installations. That is, if you activate
 723 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 724 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 725 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 726 installed in C<~/pathB> because pathB was activated later.
 727
 728 You can also ask C<local::lib> to clean itself completely out of the current
 729 shell's environment with the C<--deactivate-all> option.
 730 For multiple environments for multiple apps you may need to include a modified
 731 version of the C<< use FindBin >> instructions in the "In code" sample above.
 732 If you did something like the above, you have a set of Perl modules at C<<
 733 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 734 you need to tell it where to find the modules you installed for it at C<<
 735 ~/mydir1/lib >>.
 736
 737 In C<< ~/mydir1/scripts/myscript.pl >>:
 738
 739   use strict;
 740   use warnings;
 741   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 742   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 743
 744 Put this before any BEGIN { ... } blocks that require the modules you installed.
 745
 746 =head2 Differences when using this module under Win32
 747
 748 To set up the proper environment variables for your current session of
 749 C<CMD.exe>, you can use this:
 750
 751   C:\>perl -Mlocal::lib
 752   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 753   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 754   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 755   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 756
 757   ### To set the environment for this shell alone
 758   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 759   ### instead of $(perl -Mlocal::lib=./)
 760
 761 If you want the environment entries to persist, you'll need to add them to the
 762 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 763
 764 The "~" is translated to the user's profile directory (the directory named for
 765 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 766 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 767 directory is translated to a short name (which means the directory must exist)
 768 and the subdirectories are created.
 769
 770 =head3 PowerShell
 771
 772 local::lib also supports PowerShell, and can be used with the
 773 C<Invoke-Expression> cmdlet.
 774
 775   Invoke-Expression "$(perl -Mlocal::lib)"
 776
 777 =head1 RATIONALE
 778
 779 The version of a Perl package on your machine is not always the version you
 780 need.  Obviously, the best thing to do would be to update to the version you
 781 need.  However, you might be in a situation where you're prevented from doing
 782 this.  Perhaps you don't have system administrator privileges; or perhaps you
 783 are using a package management system such as Debian, and nobody has yet gotten
 784 around to packaging up the version you need.
 785
 786 local::lib solves this problem by allowing you to create your own directory of
 787 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 788 be within your own home directory).  The existing system Perl installation is
 789 not affected; you simply invoke Perl with special options so that Perl uses the
 790 packages in your own local package directory rather than the system packages.
 791 local::lib arranges things so that your locally installed version of the Perl
 792 packages takes precedence over the system installation.
 793
 794 If you are using a package management system (such as Debian), you don't need to
 795 worry about Debian and CPAN stepping on each other's toes.  Your local version
 796 of the packages will be written to an entirely separate directory from those
 797 installed by Debian.
 798
 799 =head1 DESCRIPTION
 800
 801 This module provides a quick, convenient way of bootstrapping a user-local Perl
 802 module library located within the user's home directory. It also constructs and
 803 prints out for the user the list of environment variables using the syntax
 804 appropriate for the user's current shell (as specified by the C<SHELL>
 805 environment variable), suitable for directly adding to one's shell
 806 configuration file.
 807
 808 More generally, local::lib allows for the bootstrapping and usage of a
 809 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 810 easier to ship an application with an app-specific copy of a Perl module, or
 811 collection of modules. Useful in cases like when an upstream maintainer hasn't
 812 applied a patch to a module of theirs that you need for your application.
 813
 814 On import, local::lib sets the following environment variables to appropriate
 815 values:
 816
 817 =over 4
 818
 819 =item PERL_MB_OPT
 820
 821 =item PERL_MM_OPT
 822
 823 =item PERL5LIB
 824
 825 =item PATH
 826
 827 =item PERL_LOCAL_LIB_ROOT
 828
 829 =back
 830
 831 When possible, these will be appended to instead of overwritten entirely.
 832
 833 These values are then available for reference by any code after import.
 834
 835 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 836
 837 See L<lib::core::only> for one way to do this - but note that
 838 there are a number of caveats, and the best approach is always to perform a
 839 build against a clean perl (i.e. site and vendor as close to empty as possible).
 840
 841 =head1 IMPORT OPTIONS
 842
 843 Options are values that can be passed to the C<local::lib> import besides the
 844 directory to use. They are specified as C<use local::lib '--option'[, path];>
 845 or C<perl -Mlocal::lib=--option[,path]>.
 846
 847 =head2 --deactivate
 848
 849 Remove the chosen path (or the default path) from the module search paths if it
 850 was added by C<local::lib>, instead of adding it.
 851
 852 =head2 --deactivate-all
 853
 854 Remove all directories that were added to search paths by C<local::lib> from the
 855 search paths.
 856
 857 =head2 --shelltype
 858
 859 Specify the shell type to use for output.  By default, the shell will be
 860 detected based on the environment.  Should be one of: C<bourne>, C<csh>,
 861 C<cmd>, or C<powershell>.
 862
 863 =head2 --no-create
 864
 865 Prevents C<local::lib> from creating directories when activating dirs.  This is
 866 likely to cause issues on Win32 systems.
 867
 868 =head1 CLASS METHODS
 869
 870 =head2 ensure_dir_structure_for
 871
 872 =over 4
 873
 874 =item Arguments: $path
 875
 876 =item Return value: None
 877
 878 =back
 879
 880 Attempts to create the given path, and all required parent directories. Throws
 881 an exception on failure.
 882
 883 =head2 print_environment_vars_for
 884
 885 =over 4
 886
 887 =item Arguments: $path
 888
 889 =item Return value: None
 890
 891 =back
 892
 893 Prints to standard output the variables listed above, properly set to use the
 894 given path as the base directory.
 895
 896 =head2 build_environment_vars_for
 897
 898 =over 4
 899
 900 =item Arguments: $path
 901
 902 =item Return value: %environment_vars
 903
 904 =back
 905
 906 Returns a hash with the variables listed above, properly set to use the
 907 given path as the base directory.
 908
 909 =head2 setup_env_hash_for
 910
 911 =over 4
 912
 913 =item Arguments: $path
 914
 915 =item Return value: None
 916
 917 =back
 918
 919 Constructs the C<%ENV> keys for the given path, by calling
 920 L</build_environment_vars_for>.
 921
 922 =head2 active_paths
 923
 924 =over 4
 925
 926 =item Arguments: None
 927
 928 =item Return value: @paths
 929
 930 =back
 931
 932 Returns a list of active C<local::lib> paths, according to the
 933 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 934 what is really in C<@INC>.
 935
 936 =head2 install_base_perl_path
 937
 938 =over 4
 939
 940 =item Arguments: $path
 941
 942 =item Return value: $install_base_perl_path
 943
 944 =back
 945
 946 Returns a path describing where to install the Perl modules for this local
 947 library installation. Appends the directories C<lib> and C<perl5> to the given
 948 path.
 949
 950 =head2 lib_paths_for
 951
 952 =over 4
 953
 954 =item Arguments: $path
 955
 956 =item Return value: @lib_paths
 957
 958 =back
 959
 960 Returns the list of paths perl will search for libraries, given a base path.
 961 This includes the base path itself, the architecture specific subdirectory, and
 962 perl version specific subdirectories.  These paths may not all exist.
 963
 964 =head2 install_base_bin_path
 965
 966 =over 4
 967
 968 =item Arguments: $path
 969
 970 =item Return value: $install_base_bin_path
 971
 972 =back
 973
 974 Returns a path describing where to install the executable programs for this
 975 local library installation. Appends the directory C<bin> to the given path.
 976
 977 =head2 installer_options_for
 978
 979 =over 4
 980
 981 =item Arguments: $path
 982
 983 =item Return value: %installer_env_vars
 984
 985 =back
 986
 987 Returns a hash of environment variables that should be set to cause
 988 installation into the given path.
 989
 990 =head2 resolve_empty_path
 991
 992 =over 4
 993
 994 =item Arguments: $path
 995
 996 =item Return value: $base_path
 997
 998 =back
 999
1000 Builds and returns the base path into which to set up the local module
1001 installation. Defaults to C<~/perl5>.
1002
1003 =head2 resolve_home_path
1004
1005 =over 4
1006
1007 =item Arguments: $path
1008
1009 =item Return value: $home_path
1010
1011 =back
1012
1013 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
1014 for this purpose. If no definite answer is available, throws an exception.
1015
1016 =head2 resolve_relative_path
1017
1018 =over 4
1019
1020 =item Arguments: $path
1021
1022 =item Return value: $absolute_path
1023
1024 =back
1025
1026 Translates the given path into an absolute path.
1027
1028 =head2 resolve_path
1029
1030 =over 4
1031
1032 =item Arguments: $path
1033
1034 =item Return value: $absolute_path
1035
1036 =back
1037
1038 Calls the following in a pipeline, passing the result from the previous to the
1039 next, in an attempt to find where to configure the environment for a local
1040 library installation: L</resolve_empty_path>, L</resolve_home_path>,
1041 L</resolve_relative_path>. Passes the given path argument to
1042 L</resolve_empty_path> which then returns a result that is passed to
1043 L</resolve_home_path>, which then has its result passed to
1044 L</resolve_relative_path>. The result of this final call is returned from
1045 L</resolve_path>.
1046
1047 =head1 OBJECT INTERFACE
1048
1049 =head2 new
1050
1051 =over 4
1052
1053 =item Arguments: %attributes
1054
1055 =item Return value: $local_lib
1056
1057 =back
1058
1059 Constructs a new C<local::lib> object, representing the current state of
1060 C<@INC> and the relevant environment variables.
1061
1062 =head1 ATTRIBUTES
1063
1064 =head2 roots
1065
1066 An arrayref representing active C<local::lib> directories.
1067
1068 =head2 inc
1069
1070 An arrayref representing C<@INC>.
1071
1072 =head2 libs
1073
1074 An arrayref representing the PERL5LIB environment variable.
1075
1076 =head2 bins
1077
1078 An arrayref representing the PATH environment variable.
1079
1080 =head2 extra
1081
1082 A hashref of extra environment variables (e.g. C<PERL_MM_OPT> and
1083 C<PERL_MB_OPT>)
1084
1085 =head2 no_create
1086
1087 If set, C<local::lib> will not try to create directories when activating them.
1088
1089 =head1 OBJECT METHODS
1090
1091 =head2 clone
1092
1093 =over 4
1094
1095 =item Arguments: %attributes
1096
1097 =item Return value: $local_lib
1098
1099 =back
1100
1101 Constructs a new C<local::lib> object based on the existing one, overriding the
1102 specified attributes.
1103
1104 =head2 activate
1105
1106 =over 4
1107
1108 =item Arguments: $path
1109
1110 =item Return value: $new_local_lib
1111
1112 =back
1113
1114 Constructs a new instance with the specified path active.
1115
1116 =head2 deactivate
1117
1118 =over 4
1119
1120 =item Arguments: $path
1121
1122 =item Return value: $new_local_lib
1123
1124 =back
1125
1126 Constructs a new instance with the specified path deactivated.
1127
1128 =head2 deactivate_all
1129
1130 =over 4
1131
1132 =item Arguments: None
1133
1134 =item Return value: $new_local_lib
1135
1136 =back
1137
1138 Constructs a new instance with all C<local::lib> directories deactivated.
1139
1140 =head2 environment_vars_string
1141
1142 =over 4
1143
1144 =item Arguments: [ $shelltype ]
1145
1146 =item Return value: $shell_env_string
1147
1148 =back
1149
1150 Returns a string to set up the C<local::lib>, meant to be run by a shell.
1151
1152 =head2 build_environment_vars
1153
1154 =over 4
1155
1156 =item Arguments: None
1157
1158 =item Return value: %environment_vars
1159
1160 =back
1161
1162 Returns a hash with the variables listed above, properly set to use the
1163 given path as the base directory.
1164
1165 =head2 setup_env_hash
1166
1167 =over 4
1168
1169 =item Arguments: None
1170
1171 =item Return value: None
1172
1173 =back
1174
1175 Constructs the C<%ENV> keys for the given path, by calling
1176 L</build_environment_vars>.
1177
1178 =head2 setup_local_lib
1179
1180 Constructs the C<%ENV> hash using L</setup_env_hash>, and set up C<@INC>.
1181
1182 =head1 A WARNING ABOUT UNINST=1
1183
1184 Be careful about using local::lib in combination with "make install UNINST=1".
1185 The idea of this feature is that will uninstall an old version of a module
1186 before installing a new one. However it lacks a safety check that the old
1187 version and the new version will go in the same directory. Used in combination
1188 with local::lib, you can potentially delete a globally accessible version of a
1189 module while installing the new version in a local place. Only combine "make
1190 install UNINST=1" and local::lib if you understand these possible consequences.
1191
1192 =head1 LIMITATIONS
1193
1194 =over 4
1195
1196 =item * Directory names with spaces in them are not well supported by the perl
1197 toolchain and the programs it uses.  Pure-perl distributions should support
1198 spaces, but problems are more likely with dists that require compilation. A
1199 workaround you can do is moving your local::lib to a directory with spaces
1200 B<after> you installed all modules inside your local::lib bootstrap. But be
1201 aware that you can't update or install CPAN modules after the move.
1202
1203 =item * Rather basic shell detection. Right now anything with csh in its name is
1204 assumed to be a C shell or something compatible, and everything else is assumed
1205 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
1206 not set, a Bourne-compatible shell is assumed.
1207
1208 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
1209
1210 =item * Should probably auto-fixup CPAN config if not already done.
1211
1212 =item * local::lib loads L<File::Spec>.  When used to set shell variables,
1213 this isn't a problem.  When used inside a perl script, any L<File::Spec>
1214 version inside the local::lib will be ignored.  A workaround for this is using
1215 C<use lib "$ENV{HOME}/perl5/lib/perl5";> inside the script instead of using
1216 C<local::lib> directly.
1217
1218 =item * Conflicts with L<ExtUtils::MakeMaker>'s C<PREFIX> option.
1219 C<local::lib> uses the C<INSTALL_BASE> option, as it has more predictable and
1220 sane behavior.  If something attempts to use the C<PREFIX> option when running
1221 a F<Makefile.PL>, L<ExtUtils::MakeMaker> will refuse to run, as the two
1222 options conflict.  This can be worked around by temporarily unsetting the
1223 C<PERL_MM_OPT> environment variable.
1224
1225 =item * Conflicts with L<Module::Build>'s C<--prefix> option.  Similar to the
1226 previous limitation, but any C<--prefix> option specified will be ignored.
1227 This can be worked around by temporarily unsetting the C<PERL_MB_OPT>
1228 environment variable.
1229
1230 =back
1231
1232 Patches very much welcome for any of the above.
1233
1234 =over 4
1235
1236 =item * On Win32 systems, does not have a way to write the created environment
1237 variables to the registry, so that they can persist through a reboot.
1238
1239 =back
1240
1241 =head1 TROUBLESHOOTING
1242
1243 If you've configured local::lib to install CPAN modules somewhere in to your
1244 home directory, and at some point later you try to install a module with C<cpan
1245 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1246 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1247 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1248 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1249 you've somehow lost your updated ExtUtils::MakeMaker module.
1250
1251 To remedy this situation, rerun the bootstrapping procedure documented above.
1252
1253 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1254
1255 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1256
1257 =head1 ENVIRONMENT
1258
1259 =over 4
1260
1261 =item SHELL
1262
1263 =item COMSPEC
1264
1265 local::lib looks at the user's C<SHELL> environment variable when printing out
1266 commands to add to the shell configuration file.
1267
1268 On Win32 systems, C<COMSPEC> is also examined.
1269
1270 =back
1271
1272 =head1 SEE ALSO
1273
1274 =over 4
1275
1276 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1277
1278 =back
1279
1280 =head1 SUPPORT
1281
1282 IRC:
1283
1284     Join #local-lib on irc.perl.org.
1285
1286 =head1 AUTHOR
1287
1288 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1289
1290 auto_install fixes kindly sponsored by http://www.takkle.com/
1291
1292 =head1 CONTRIBUTORS
1293
1294 Patches to correctly output commands for csh style shells, as well as some
1295 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1296
1297 Doc patches for a custom local::lib directory, more cleanups in the english
1298 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1299 Torsten Raudssus <torsten@raudssus.de>.
1300
1301 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1302 things will install properly, submitted a fix for the bug causing problems with
1303 writing Makefiles during bootstrapping, contributed an example program, and
1304 submitted yet another fix to ensure that local::lib can install and bootstrap
1305 properly. Many, many thanks!
1306
1307 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1308 section. Many thanks!
1309
1310 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1311
1312 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1313 by a patch from Marco Emilio Poleggi.
1314
1315 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1316 '--self-contained' option.
1317
1318 Documentation patches to make win32 usage clearer by
1319 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1320
1321 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1322 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1323
1324 Improvements to stacking multiple local::lib dirs and removing them from the
1325 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1326
1327 Patch for Carp version mismatch contributed by Hakim Cassimally
1328 <osfameron@cpan.org>.
1329
1330 Rewrite of internals and numerous bug fixes and added features contributed by
1331 Graham Knop <haarg@haarg.org>.
1332
1333 =head1 COPYRIGHT
1334
1335 Copyright (c) 2007 - 2013 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1336 listed above.
1337
1338 =head1 LICENSE
1339
1340 This is free software; you can redistribute it and/or modify it under
1341 the same terms as the Perl 5 programming language system itself.
1342
1343 =cut