lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '1.008026'; # 1.8.26
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16
  17   my @steps;
  18   my %opts;
  19
  20   while (@args) {
  21     my $arg = shift @args;
  22     # check for lethal dash first to stop processing before causing problems
  23     # the fancy dash is U+2212 or \xE2\x88\x92
  24     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  25       die <<'DEATH';
  26 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  27 These are *not* the traditional -- dashes that software recognizes. You
  28 probably got these by copy-pasting from the perldoc for this module as
  29 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  30 terminal, but can happen elsewhere too. Please try again after replacing the
  31 dashes with normal minus signs.
  32 DEATH
  33     }
  34     elsif ($arg eq '--self-contained') {
  35       die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  36     }
  37     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  38       my $path = defined $1 ? $1 : shift @args;
  39       push @steps, ['deactivate', $path];
  40     }
  41     elsif ( $arg eq '--deactivate-all' ) {
  42       push @steps, ['deactivate_all'];
  43     }
  44     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  45       my $shell = defined $1 ? $1 : shift @args;
  46       $opts{shelltype} = $shell;
  47     }
  48     elsif ( $arg eq '--no-create' ) {
  49       $opts{no_create} = 1;
  50     }
  51     elsif ( $arg =~ /^--/ ) {
  52       die "Unknown import argument: $arg";
  53     }
  54     else {
  55       push @steps, ['activate', $arg];
  56     }
  57   }
  58   if (!@steps) {
  59     push @steps, ['activate', undef];
  60   }
  61
  62   my $self = $class->new(%opts);
  63
  64   for (@steps) {
  65     my ($method, @args) = @$_;
  66     $self = $self->$method(@args);
  67   }
  68
  69   if ($0 eq '-') {
  70     $self->print_environment_vars_for;
  71     exit 0;
  72   }
  73   else {
  74     $self->setup_local_lib_for;
  75   }
  76 }
  77
  78 sub new {
  79   my $class = shift;
  80   bless {@_}, $class;
  81 }
  82
  83 sub clone {
  84   my $self = shift;
  85   bless {%$self, @_}, ref $self;
  86 }
  87
  88 sub inc { $_[0]->{inc}     ||= \@INC }
  89 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
  90 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
  91 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
  92 sub extra { $_[0]->{extra} ||= {} }
  93 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
  94 sub no_create { $_[0]->{no_create} }
  95
  96 my $_archname = $Config{archname};
  97 my $_version  = $Config{version};
  98 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
  99 my $_path_sep = $Config{path_sep};
 100
 101 sub _as_list {
 102   my $list = shift;
 103   grep length, map {
 104     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 105       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 106                         : ()
 107     )
 108   } ref $list ? @$list : $list;
 109 }
 110 sub _remove_from {
 111   my ($list, @remove) = @_;
 112   return @$list
 113     if !@remove;
 114   my %remove = map { $_ => 1 } @remove;
 115   grep !$remove{$_}, _as_list($list);
 116 }
 117
 118 my @_lib_subdirs = (
 119   [$_version, $_archname],
 120   [$_version],
 121   [$_archname],
 122   (@_inc_version_list ? \@_inc_version_list : ()),
 123   [],
 124 );
 125
 126 sub install_base_bin_path {
 127   my ($class, $path) = @_;
 128   return File::Spec->catdir($path, 'bin');
 129 }
 130 sub install_base_perl_path {
 131   my ($class, $path) = @_;
 132   return File::Spec->catdir($path, 'lib', 'perl5');
 133 }
 134 sub install_base_arch_path {
 135   my ($class, $path) = @_;
 136   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 137 }
 138
 139 sub lib_paths_for {
 140   my ($class, $path) = @_;
 141   my $base = $class->install_base_perl_path($path);
 142   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 143 }
 144
 145 sub _mm_escape_path {
 146   my $path = shift;
 147   $path =~ s/\\/\\\\\\\\/g;
 148   if ($path =~ s/ /\\ /g) {
 149     $path = qq{"\\"$path\\""};
 150   }
 151   return $path;
 152 }
 153
 154 sub _mb_escape_path {
 155   my $path = shift;
 156   $path =~ s/\\/\\\\/g;
 157   return qq{"$path"};
 158 }
 159
 160 sub installer_options_for {
 161   my ($class, $path) = @_;
 162   return {
 163     PERL_MM_OPT => defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 164     PERL_MB_OPT => defined $path ? "--install_base "._mb_escape_path($path) : undef,
 165   };
 166 }
 167
 168 sub active_paths {
 169   my ($self) = @_;
 170   $self = ref $self ? $self : $self->new;
 171
 172   return grep {
 173     # screen out entries that aren't actually reflected in @INC
 174     my $active_ll = $self->install_base_perl_path($_);
 175     grep { $_ eq $active_ll } @{$self->inc};
 176   } _as_list($self->roots);
 177 }
 178
 179
 180 sub deactivate {
 181   my ($self, $path) = @_;
 182   $self = $self->new unless ref $self;
 183   $path = $self->resolve_path($path);
 184
 185   my @active_lls = $self->active_paths;
 186
 187   if (!grep { $_ eq $path } @active_lls) {
 188     warn "Tried to deactivate inactive local::lib '$path'\n";
 189     return $self;
 190   }
 191
 192   my %args = (
 193     bins  => [ _remove_from($self->bins,  $self->install_base_bin_path($path)) ],
 194     libs  => [ _remove_from($self->libs,  $self->install_base_perl_path($path)) ],
 195     inc   => [ _remove_from($self->inc,   $self->lib_paths_for($path)) ],
 196     roots => [ _remove_from($self->roots, $path) ],
 197   );
 198
 199   $args{extra} = $self->installer_options_for($args{roots}[0]);
 200
 201   $self->clone(%args);
 202 }
 203
 204 sub deactivate_all {
 205   my ($self) = @_;
 206   $self = $self->new unless ref $self;
 207
 208   my @active_lls = $self->active_paths;
 209
 210   my %args;
 211   if (@active_lls) {
 212     %args = (
 213       bins => [ _remove_from($self->bins,
 214         map $self->install_base_bin_path($_), @active_lls) ],
 215       libs => [ _remove_from($self->libs,
 216         map $self->install_base_perl_path($_), @active_lls) ],
 217       inc => [ _remove_from($self->inc,
 218         map $self->lib_paths_for($_), @active_lls) ],
 219       roots => [ _remove_from($self->roots, @active_lls) ],
 220     );
 221   }
 222
 223   $args{extra} = $self->installer_options_for(undef);
 224
 225   $self->clone(%args);
 226 }
 227
 228 sub activate {
 229   my ($self, $path) = @_;
 230   $self = $self->new unless ref $self;
 231   $path = $self->resolve_path($path);
 232   $self->ensure_dir_structure_for($path)
 233     unless $self->no_create;
 234
 235   $path = ( Win32::GetShortPathName($path) || $path )
 236     if $^O eq 'MSWin32';
 237
 238   my @active_lls = $self->active_paths;
 239
 240   if (grep { $_ eq $path } @active_lls[1 .. $#active_lls]) {
 241     $self = $self->deactivate($path);
 242   }
 243
 244   my %args;
 245   if (!@active_lls || $active_lls[0] ne $path) {
 246     %args = (
 247       bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 248       libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 249       inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 250       roots => [ $path, @{$self->roots} ],
 251     );
 252   }
 253
 254   $args{extra} = $self->installer_options_for($path);
 255
 256   $self->clone(%args);
 257 }
 258
 259 sub _legacy {
 260   my ($self, $path) = @_;
 261   $self = $self->new unless ref $self;
 262   if (defined $path) {
 263     $self = $self->activate($path);
 264   }
 265   $self;
 266 }
 267
 268 sub build_environment_vars_for {
 269   my ($self) = _legacy(@_);
 270   (
 271     PATH                => join($_path_sep, _as_list($self->bins)),
 272     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 273     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 274     %{$self->extra},
 275   );
 276 }
 277
 278 sub setup_local_lib_for {
 279   my ($self) = _legacy(@_);
 280   $self->setup_env_hash_for;
 281   @INC = @{$self->inc};
 282 }
 283
 284 sub setup_env_hash_for {
 285   my $self = shift;
 286   my %env = $self->build_environment_vars_for(@_);
 287   for my $key (keys %env) {
 288     if (defined $env{$key}) {
 289       $ENV{$key} = $env{$key};
 290     }
 291     else {
 292       delete $ENV{$key};
 293     }
 294   }
 295 }
 296
 297 sub print_environment_vars_for {
 298   my $self = shift;
 299   print $self->environment_vars_string_for(@_);
 300 }
 301
 302 sub environment_vars_string_for {
 303   my $self = _legacy(@_);
 304
 305   my $build_method = 'build_' . $self->shelltype . '_env_declaration';
 306
 307   my @envs = (
 308     PATH                => $self->bins,
 309     PERL5LIB            => $self->libs,
 310     PERL_LOCAL_LIB_ROOT => $self->roots,
 311     %{$self->extra},
 312   );
 313   my $out = '';
 314   while (@envs) {
 315     my ($name, $value) = (shift(@envs), shift(@envs));
 316     if (
 317         ref $value
 318         && @$value == 1
 319         && ref $value->[0]
 320         && ref $value->[0] eq 'SCALAR'
 321         && ${$value->[0]} eq $name) {
 322       next;
 323     }
 324     if (
 325         !ref $value
 326         and defined $value
 327           ? (defined $ENV{$name} && $value eq $ENV{$name})
 328           : !defined $ENV{$name}
 329     ) {
 330       next;
 331     }
 332     $out .= $self->$build_method($name, $value);
 333   }
 334   my $wrap_method = 'wrap_' . $self->shelltype . '_output';
 335   if ($self->can($wrap_method)) {
 336     return $self->$wrap_method($out);
 337   }
 338   return $out;
 339 }
 340
 341 sub build_bourne_env_declaration {
 342   my ($class, $name, $args) = @_;
 343   my $value = $class->_interpolate($args);
 344   my $joined;
 345   for (@$value) {
 346     if (!defined $joined) {
 347       $joined = $_;
 348     }
 349     elsif ($_ eq "\$$name") {
 350       $joined .= "\${$name+$Config{path_sep}}$_";
 351     }
 352     else {
 353       $joined .= "$Config{path_sep}$_";
 354     }
 355   }
 356   defined $value
 357     ? qq{export ${name}="$joined";\n}
 358     : qq{unset ${name};\n};
 359 }
 360 sub build_csh_env_declaration {
 361   my ($class, $name, $args) = @_;
 362   my ($value, @vars) = $class->_interpolate($args, undef, undef, '"', qq{"\\"});
 363
 364   my $out = '';
 365   if (@vars) {
 366     $out = qq{if \$?$name };
 367   }
 368   $out .= defined $value ? qq{setenv $name "}.join($Config{path_sep},@$value).qq{";\n} : qq{unsetenv $name;\n};
 369   if (@vars) {
 370     my $no_var = $class->_interpolate([ grep { !ref } @$args ], undef, undef, '"', qq{"\\"});
 371     if (defined $no_var) {
 372       $out .= qq{if ! \$?$name setenv $name "}.join($Config{path_sep},@$no_var).qq{";\n};
 373     }
 374   }
 375   $out;
 376 }
 377 sub build_cmd_env_declaration {
 378   my ($class, $name, $args) = @_;
 379   my $value = $class->_interpolate($args, '%', '%', qr([()!^"<>&|]), '^');
 380   defined $value
 381     ? qq{\@set $name=}.join($Config{path_sep},@$value).qq{\n}
 382     : qq{\@set $name=\n};
 383 }
 384 sub build_powershell_env_declaration {
 385   my ($class, $name, $args) = @_;
 386   my $value = $class->_interpolate($args, '$env:', '', '"', '`');
 387   defined $value
 388     ? qq{\$env:$name = "}.join($Config{path_sep},@$value).qq{";\n}
 389     : "Remove-Item Env:\\$name;\n";
 390 }
 391 sub wrap_powershell_output {
 392   my ($class, $out) = @_;
 393   return $out || " \n";
 394 }
 395
 396
 397 sub _interpolate {
 398   my ($class, $args, $start, $end, $escape, $escape_char) = @_;
 399   return
 400     unless defined $args;
 401   $args = [ $args ]
 402     unless ref $args;
 403   return
 404     unless @$args;
 405   $start = '$' unless defined $start;
 406   $end = '' unless defined $end;
 407   $escape = '"' unless defined $escape;
 408   $escape_char = "\\" unless defined $escape_char;
 409   my @vars;
 410   my $string = [ map {
 411     if (ref $_ && ref $_ eq 'SCALAR') {
 412       push @vars, $$_;
 413       $start.$$_.$end;
 414     }
 415     else {
 416       my $str = $_;
 417       $str =~ s/($escape)/$escape_char$1/g;
 418       $str;
 419     }
 420   } @$args ];
 421   return wantarray ? ($string, @vars) : $string;
 422 }
 423
 424 sub pipeline;
 425
 426 sub pipeline {
 427   my @methods = @_;
 428   my $last = pop(@methods);
 429   if (@methods) {
 430     \sub {
 431       my ($obj, @args) = @_;
 432       $obj->${pipeline @methods}(
 433         $obj->$last(@args)
 434       );
 435     };
 436   } else {
 437     \sub {
 438       shift->$last(@_);
 439     };
 440   }
 441 }
 442
 443 =begin testing
 444
 445 #:: test pipeline
 446
 447 package local::lib;
 448
 449 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 450 my $foo = bless({}, 'Foo');
 451 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 452
 453 =end testing
 454
 455 =cut
 456
 457 sub resolve_path {
 458   my ($class, $path) = @_;
 459
 460   $path = $class->${pipeline qw(
 461     resolve_relative_path
 462     resolve_home_path
 463     resolve_empty_path
 464   )}($path);
 465
 466   $path;
 467 }
 468
 469 sub resolve_empty_path {
 470   my ($class, $path) = @_;
 471   if (defined $path) {
 472     $path;
 473   } else {
 474     '~/perl5';
 475   }
 476 }
 477
 478 =begin testing
 479
 480 #:: test classmethod setup
 481
 482 my $c = 'local::lib';
 483
 484 =end testing
 485
 486 =begin testing
 487
 488 #:: test classmethod
 489
 490 is($c->resolve_empty_path, '~/perl5');
 491 is($c->resolve_empty_path('foo'), 'foo');
 492
 493 =end testing
 494
 495 =cut
 496
 497 sub resolve_home_path {
 498   my ($class, $path) = @_;
 499   return $path unless ($path =~ /^~/);
 500   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 501   my $homedir = do {
 502     if (!defined $user && defined $ENV{HOME}) {
 503       $ENV{HOME}
 504     }
 505     else {
 506       require File::Glob;
 507       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 508     }
 509   };
 510   unless (defined $homedir) {
 511     require Carp;
 512     Carp::croak(
 513       "Couldn't resolve homedir for "
 514       .(defined $user ? $user : 'current user')
 515     );
 516   }
 517   $path =~ s/^~[^\/]*/$homedir/;
 518   $path;
 519 }
 520
 521 sub resolve_relative_path {
 522   my ($class, $path) = @_;
 523   $path = File::Spec->rel2abs($path);
 524 }
 525
 526 =begin testing
 527
 528 #:: test classmethod
 529
 530 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 531 is($c->resolve_relative_path('bar'),'FOObar');
 532
 533 =end testing
 534
 535 =cut
 536
 537 sub ensure_dir_structure_for {
 538   my ($class, $path) = @_;
 539   unless (-d $path) {
 540     warn "Attempting to create directory ${path}\n";
 541   }
 542   require File::Basename;
 543   my @dirs;
 544   while(!-d $path) {
 545     push @dirs, $path;
 546     $path = File::Basename::dirname($path);
 547   }
 548   mkdir $_ for reverse @dirs;
 549   return;
 550 }
 551
 552 =begin testing
 553
 554 #:: test classmethod
 555
 556 File::Path::rmtree('t/var/splat');
 557
 558 $c->ensure_dir_structure_for('t/var/splat');
 559
 560 ok(-d 't/var/splat');
 561
 562 =end testing
 563
 564 =cut
 565
 566 sub guess_shelltype {
 567   my $shellbin
 568     = defined $ENV{SHELL}
 569       ? (File::Spec->splitpath($ENV{SHELL}))[-1]
 570     : ( $^O eq 'MSWin32' && exists $ENV{'!EXITCODE'} )
 571       ? 'bash'
 572     : ( $^O eq 'MSWin32' && $ENV{PROMPT} && $ENV{COMSPEC} )
 573       ? (File::Spec->splitpath($ENV{COMSPEC}))[-1]
 574     : ( $^O eq 'MSWin32' && !$ENV{PROMPT} )
 575       ? 'powershell.exe'
 576     : 'sh';
 577
 578   for ($shellbin) {
 579     return
 580         /csh/             ? 'csh'
 581       : /command\.com/    ? 'cmd'
 582       : /cmd\.exe/        ? 'cmd'
 583       : /4nt\.exe/        ? 'cmd'
 584       : /powershell\.exe/ ? 'powershell'
 585                           : 'bourne';
 586   }
 587 }
 588
 589 1;
 590 __END__
 591
 592 =encoding utf8
 593
 594 =head1 NAME
 595
 596 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 597
 598 =head1 SYNOPSIS
 599
 600 In code -
 601
 602   use local::lib; # sets up a local lib at ~/perl5
 603
 604   use local::lib '~/foo'; # same, but ~/foo
 605
 606   # Or...
 607   use FindBin;
 608   use local::lib "$FindBin::Bin/../support";  # app-local support library
 609
 610 From the shell -
 611
 612   # Install LWP and its missing dependencies to the '~/perl5' directory
 613   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 614
 615   # Just print out useful shell commands
 616   $ perl -Mlocal::lib
 617   export PERL_MB_OPT='--install_base /home/username/perl5'
 618   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 619   export PERL5LIB="/home/username/perl5/lib/perl5"
 620   export PATH="/home/username/perl5/bin:$PATH"
 621
 622 =head2 The bootstrapping technique
 623
 624 A typical way to install local::lib is using what is known as the
 625 "bootstrapping" technique.  You would do this if your system administrator
 626 hasn't already installed local::lib.  In this case, you'll need to install
 627 local::lib in your home directory.
 628
 629 Even if you do have administrative privileges, you will still want to set up your
 630 environment variables, as discussed in step 4. Without this, you would still
 631 install the modules into the system CPAN installation and also your Perl scripts
 632 will not use the lib/ path you bootstrapped with local::lib.
 633
 634 By default local::lib installs itself and the CPAN modules into ~/perl5.
 635
 636 Windows users must also see L</Differences when using this module under Win32>.
 637
 638 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 639 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 640 or administrator.  Unpack the file in your home directory or in any other
 641 convenient location.
 642
 643 2. Run this:
 644
 645   perl Makefile.PL --bootstrap
 646
 647 If the system asks you whether it should automatically configure as much
 648 as possible, you would typically answer yes.
 649
 650 In order to install local::lib into a directory other than the default, you need
 651 to specify the name of the directory when you call bootstrap, as follows:
 652
 653   perl Makefile.PL --bootstrap=~/foo
 654
 655 3. Run this: (local::lib assumes you have make installed on your system)
 656
 657   make test && make install
 658
 659 4. Now we need to setup the appropriate environment variables, so that Perl
 660 starts using our newly generated lib/ directory. If you are using bash or
 661 any other Bourne shells, you can add this to your shell startup script this
 662 way:
 663
 664   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 665
 666 If you are using C shell, you can do this as follows:
 667
 668   /bin/csh
 669   echo $SHELL
 670   /bin/csh
 671   echo 'eval `perl -I$HOME/perl5/lib/perl5 -Mlocal::lib`' >> ~/.cshrc
 672
 673 If you passed to bootstrap a directory other than default, you also need to
 674 give that as import parameter to the call of the local::lib module like this
 675 way:
 676
 677   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 678
 679 After writing your shell configuration file, be sure to re-read it to get the
 680 changed settings into your current shell's environment. Bourne shells use
 681 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 682
 683 If you're on a slower machine, or are operating under draconian disk space
 684 limitations, you can disable the automatic generation of manpages from POD when
 685 installing modules by using the C<--no-manpages> argument when bootstrapping:
 686
 687   perl Makefile.PL --bootstrap --no-manpages
 688
 689 To avoid doing several bootstrap for several Perl module environments on the
 690 same account, for example if you use it for several different deployed
 691 applications independently, you can use one bootstrapped local::lib
 692 installation to install modules in different directories directly this way:
 693
 694   cd ~/mydir1
 695   perl -Mlocal::lib=./
 696   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 697   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 698   perl -MCPAN -e install ...    ### whatever modules you want
 699   cd ../mydir2
 700   ... REPEAT ...
 701
 702 If you are working with several C<local::lib> environments, you may want to
 703 remove some of them from the current environment without disturbing the others.
 704 You can deactivate one environment like this (using bourne sh):
 705
 706   eval $(perl -Mlocal::lib=--deactivate,~/path)
 707
 708 which will generate and run the commands needed to remove C<~/path> from your
 709 various search paths. Whichever environment was B<activated most recently> will
 710 remain the target for module installations. That is, if you activate
 711 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 712 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 713 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 714 installed in C<~/pathB> because pathB was activated later.
 715
 716 You can also ask C<local::lib> to clean itself completely out of the current
 717 shell's environment with the C<--deactivate-all> option.
 718 For multiple environments for multiple apps you may need to include a modified
 719 version of the C<< use FindBin >> instructions in the "In code" sample above.
 720 If you did something like the above, you have a set of Perl modules at C<<
 721 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 722 you need to tell it where to find the modules you installed for it at C<<
 723 ~/mydir1/lib >>.
 724
 725 In C<< ~/mydir1/scripts/myscript.pl >>:
 726
 727   use strict;
 728   use warnings;
 729   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 730   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 731
 732 Put this before any BEGIN { ... } blocks that require the modules you installed.
 733
 734 =head2 Differences when using this module under Win32
 735
 736 To set up the proper environment variables for your current session of
 737 C<CMD.exe>, you can use this:
 738
 739   C:\>perl -Mlocal::lib
 740   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 741   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 742   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 743   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 744
 745   ### To set the environment for this shell alone
 746   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 747   ### instead of $(perl -Mlocal::lib=./)
 748
 749 If you want the environment entries to persist, you'll need to add them to the
 750 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 751
 752 The "~" is translated to the user's profile directory (the directory named for
 753 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 754 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 755 directory is translated to a short name (which means the directory must exist)
 756 and the subdirectories are created.
 757
 758 =head3 PowerShell
 759
 760 local::lib also supports PowerShell, and an be used with the
 761 C<Invoke-Expression> cmdlet.
 762
 763   Invoke-Expression "$(perl -Mlocal::lib)"
 764
 765 =head1 RATIONALE
 766
 767 The version of a Perl package on your machine is not always the version you
 768 need.  Obviously, the best thing to do would be to update to the version you
 769 need.  However, you might be in a situation where you're prevented from doing
 770 this.  Perhaps you don't have system administrator privileges; or perhaps you
 771 are using a package management system such as Debian, and nobody has yet gotten
 772 around to packaging up the version you need.
 773
 774 local::lib solves this problem by allowing you to create your own directory of
 775 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 776 be within your own home directory).  The existing system Perl installation is
 777 not affected; you simply invoke Perl with special options so that Perl uses the
 778 packages in your own local package directory rather than the system packages.
 779 local::lib arranges things so that your locally installed version of the Perl
 780 packages takes precedence over the system installation.
 781
 782 If you are using a package management system (such as Debian), you don't need to
 783 worry about Debian and CPAN stepping on each other's toes.  Your local version
 784 of the packages will be written to an entirely separate directory from those
 785 installed by Debian.
 786
 787 =head1 DESCRIPTION
 788
 789 This module provides a quick, convenient way of bootstrapping a user-local Perl
 790 module library located within the user's home directory. It also constructs and
 791 prints out for the user the list of environment variables using the syntax
 792 appropriate for the user's current shell (as specified by the C<SHELL>
 793 environment variable), suitable for directly adding to one's shell
 794 configuration file.
 795
 796 More generally, local::lib allows for the bootstrapping and usage of a
 797 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 798 easier to ship an application with an app-specific copy of a Perl module, or
 799 collection of modules. Useful in cases like when an upstream maintainer hasn't
 800 applied a patch to a module of theirs that you need for your application.
 801
 802 On import, local::lib sets the following environment variables to appropriate
 803 values:
 804
 805 =over 4
 806
 807 =item PERL_MB_OPT
 808
 809 =item PERL_MM_OPT
 810
 811 =item PERL5LIB
 812
 813 =item PATH
 814
 815 =back
 816
 817 When possible, these will be appended to instead of overwritten entirely.
 818
 819 These values are then available for reference by any code after import.
 820
 821 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 822
 823 See L<lib::core::only> for one way to do this - but note that
 824 there are a number of caveats, and the best approach is always to perform a
 825 build against a clean perl (i.e. site and vendor as close to empty as possible).
 826
 827 =head1 OPTIONS
 828
 829 Options are values that can be passed to the C<local::lib> import besides the
 830 directory to use. They are specified as C<use local::lib '--option'[, path];>
 831 or C<perl -Mlocal::lib=--option[,path]>.
 832
 833 =head2 --deactivate
 834
 835 Remove the chosen path (or the default path) from the module search paths if it
 836 was added by C<local::lib>, instead of adding it.
 837
 838 =head2 --deactivate-all
 839
 840 Remove all directories that were added to search paths by C<local::lib> from the
 841 search paths.
 842
 843 =head2 --shelltype
 844
 845 Specify the shell type to use for output.  By default, the shell will be
 846 detected based on the environment.  Should be one of: C<bourne>, C<csh>,
 847 C<cmd>, or C<powershell>.
 848
 849 =head2 --no-create
 850
 851 Prevents C<local::lib> from creating directories when activating dirs.  This is
 852 likely to cause issues on Win32 systems.
 853
 854 =head1 METHODS
 855
 856 =head2 ensure_dir_structure_for
 857
 858 =over 4
 859
 860 =item Arguments: $path
 861
 862 =item Return value: None
 863
 864 =back
 865
 866 Attempts to create the given path, and all required parent directories. Throws
 867 an exception on failure.
 868
 869 =head2 print_environment_vars_for
 870
 871 =over 4
 872
 873 =item Arguments: $path
 874
 875 =item Return value: None
 876
 877 =back
 878
 879 Prints to standard output the variables listed above, properly set to use the
 880 given path as the base directory.
 881
 882 =head2 build_environment_vars_for
 883
 884 =over 4
 885
 886 =item Arguments: $path
 887
 888 =item Return value: %environment_vars
 889
 890 =back
 891
 892 Returns a hash with the variables listed above, properly set to use the
 893 given path as the base directory.
 894
 895 =head2 setup_env_hash_for
 896
 897 =over 4
 898
 899 =item Arguments: $path
 900
 901 =item Return value: None
 902
 903 =back
 904
 905 Constructs the C<%ENV> keys for the given path, by calling
 906 L</build_environment_vars_for>.
 907
 908 =head2 active_paths
 909
 910 =over 4
 911
 912 =item Arguments: None
 913
 914 =item Return value: @paths
 915
 916 =back
 917
 918 Returns a list of active C<local::lib> paths, according to the
 919 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 920 what is really in C<@INC>.
 921
 922 =head2 install_base_perl_path
 923
 924 =over 4
 925
 926 =item Arguments: $path
 927
 928 =item Return value: $install_base_perl_path
 929
 930 =back
 931
 932 Returns a path describing where to install the Perl modules for this local
 933 library installation. Appends the directories C<lib> and C<perl5> to the given
 934 path.
 935
 936 =head2 install_base_bin_path
 937
 938 =over 4
 939
 940 =item Arguments: $path
 941
 942 =item Return value: $install_base_bin_path
 943
 944 =back
 945
 946 Returns a path describing where to install the executable programs for this
 947 local library installation. Appends the directory C<bin> to the given path.
 948
 949 =head2 resolve_empty_path
 950
 951 =over 4
 952
 953 =item Arguments: $path
 954
 955 =item Return value: $base_path
 956
 957 =back
 958
 959 Builds and returns the base path into which to set up the local module
 960 installation. Defaults to C<~/perl5>.
 961
 962 =head2 resolve_home_path
 963
 964 =over 4
 965
 966 =item Arguments: $path
 967
 968 =item Return value: $home_path
 969
 970 =back
 971
 972 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 973 for this purpose. If no definite answer is available, throws an exception.
 974
 975 =head2 resolve_relative_path
 976
 977 =over 4
 978
 979 =item Arguments: $path
 980
 981 =item Return value: $absolute_path
 982
 983 =back
 984
 985 Translates the given path into an absolute path.
 986
 987 =head2 resolve_path
 988
 989 =over 4
 990
 991 =item Arguments: $path
 992
 993 =item Return value: $absolute_path
 994
 995 =back
 996
 997 Calls the following in a pipeline, passing the result from the previous to the
 998 next, in an attempt to find where to configure the environment for a local
 999 library installation: L</resolve_empty_path>, L</resolve_home_path>,
1000 L</resolve_relative_path>. Passes the given path argument to
1001 L</resolve_empty_path> which then returns a result that is passed to
1002 L</resolve_home_path>, which then has its result passed to
1003 L</resolve_relative_path>. The result of this final call is returned from
1004 L</resolve_path>.
1005
1006 =head1 A WARNING ABOUT UNINST=1
1007
1008 Be careful about using local::lib in combination with "make install UNINST=1".
1009 The idea of this feature is that will uninstall an old version of a module
1010 before installing a new one. However it lacks a safety check that the old
1011 version and the new version will go in the same directory. Used in combination
1012 with local::lib, you can potentially delete a globally accessible version of a
1013 module while installing the new version in a local place. Only combine "make
1014 install UNINST=1" and local::lib if you understand these possible consequences.
1015
1016 =head1 LIMITATIONS
1017
1018 =over 4
1019
1020 =item * Directory names with spaces in them are not well supported by the perl
1021 toolchain and the programs it uses.  Pure-perl distributions should support
1022 spaces, but problems are more likely with dists that require compilation. A
1023 workaround you can do is moving your local::lib to a directory with spaces
1024 B<after> you installed all modules inside your local::lib bootstrap. But be
1025 aware that you can't update or install CPAN modules after the move.
1026
1027 =item * Rather basic shell detection. Right now anything with csh in its name is
1028 assumed to be a C shell or something compatible, and everything else is assumed
1029 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
1030 not set, a Bourne-compatible shell is assumed.
1031
1032 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
1033
1034 =item * Should probably auto-fixup CPAN config if not already done.
1035
1036 =back
1037
1038 Patches very much welcome for any of the above.
1039
1040 =over 4
1041
1042 =item * On Win32 systems, does not have a way to write the created environment
1043 variables to the registry, so that they can persist through a reboot.
1044
1045 =back
1046
1047 =head1 TROUBLESHOOTING
1048
1049 If you've configured local::lib to install CPAN modules somewhere in to your
1050 home directory, and at some point later you try to install a module with C<cpan
1051 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1052 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1053 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1054 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1055 you've somehow lost your updated ExtUtils::MakeMaker module.
1056
1057 To remedy this situation, rerun the bootstrapping procedure documented above.
1058
1059 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1060
1061 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1062
1063 =head1 ENVIRONMENT
1064
1065 =over 4
1066
1067 =item SHELL
1068
1069 =item COMSPEC
1070
1071 local::lib looks at the user's C<SHELL> environment variable when printing out
1072 commands to add to the shell configuration file.
1073
1074 On Win32 systems, C<COMSPEC> is also examined.
1075
1076 =back
1077
1078 =head1 SEE ALSO
1079
1080 =over 4
1081
1082 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1083
1084 =back
1085
1086 =head1 SUPPORT
1087
1088 IRC:
1089
1090     Join #local-lib on irc.perl.org.
1091
1092 =head1 AUTHOR
1093
1094 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1095
1096 auto_install fixes kindly sponsored by http://www.takkle.com/
1097
1098 =head1 CONTRIBUTORS
1099
1100 Patches to correctly output commands for csh style shells, as well as some
1101 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1102
1103 Doc patches for a custom local::lib directory, more cleanups in the english
1104 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1105 Torsten Raudssus <torsten@raudssus.de>.
1106
1107 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1108 things will install properly, submitted a fix for the bug causing problems with
1109 writing Makefiles during bootstrapping, contributed an example program, and
1110 submitted yet another fix to ensure that local::lib can install and bootstrap
1111 properly. Many, many thanks!
1112
1113 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1114 section. Many thanks!
1115
1116 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1117
1118 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1119 by a patch from Marco Emilio Poleggi.
1120
1121 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1122 '--self-contained' option.
1123
1124 Documentation patches to make win32 usage clearer by
1125 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1126
1127 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1128 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1129
1130 Improvements to stacking multiple local::lib dirs and removing them from the
1131 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1132
1133 Patch for Carp version mismatch contributed by Hakim Cassimally
1134 <osfameron@cpan.org>.
1135
1136 =head1 COPYRIGHT
1137
1138 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1139 listed above.
1140
1141 =head1 LICENSE
1142
1143 This is free software; you can redistribute it and/or modify it under
1144 the same terms as the Perl 5 programming language system itself.
1145
1146 =cut