Makefile.PL

   1 use strict;
   2 use warnings;
   3 use File::Spec;
   4 use Cwd;
   5 use vars qw($bootstrapping $bootstrapping_args $no_manpages);
   6 use Config;
   7
   8 # Solaris (and possibly other Unices) have a tar in /usr/bin that, among
   9 # other things, does not understand @LongLink. This can cause
  10 # extraction to look like it succeeded, but it actually failed (because
  11 # the error message for the @LongLink failure scrolled offscreen).
  12 # Therefore, given the fact that GNU tar is the most widespread tar available,
  13 # and it actually supports the feature we want (I'd bet it originated in GNU
  14 # tar, but I digress), we'll look for GNU tar. If we don't find it, and the
  15 # user hasn't pointed us to a suitable tar, we'll bomb and tell them what to
  16 # do.
  17
  18 my $have_gtar = 0;
  19 if($^O eq 'solaris') {
  20   $have_gtar = 0;
  21   for my $env_path (split /:/, $ENV{PATH}) {
  22     $have_gtar = 1 if -x File::Spec->catfile($env_path, 'gtar');
  23   }
  24 } else {
  25   $have_gtar = 1;
  26 }
  27 if(exists $ENV{PERL_LL_TAR}) {
  28   $have_gtar ||= -x $ENV{PERL_LL_TAR};
  29 }
  30
  31 die <<'DEATH' unless $have_gtar;
  32 You are using Solaris (or another traditional Unix) that does not provide a sane
  33 tar, capable of dealing with the output of GNU tar. Please either set the
  34 PERL_LL_TAR environment variable to the location of a version of tar that
  35 understands the @LongLink convention or put a binary named gtar somewhere on
  36 your PATH.
  37 DEATH
  38
  39 my $cwd;
  40 BEGIN {
  41   $cwd = Cwd::cwd();
  42   # watch out for fancy dashes. these can wind up in our @ARGV if the user is
  43   # copypasting the bootstrap command from the POD displayed e.g. by perldoc
  44   # on a Mac OS X terminal. since no software recognizes and handles these
  45   # dashes, it's better to die loudly telling the user exactly what happened
  46   # so they don't make the same mistake again rather than being the only
  47   # program in the universe that works with them.
  48   # the fancy dash is U+2212 or \xE2\x88\x92
  49   if(grep { /\xE2\x88\x92/ } @ARGV or grep { /−/ } @ARGV) {
  50       die <<'DEATH';
  51 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  52 These are *not* the traditional -- dashes that software recognizes. You
  53 probably got these by copy-pasting from the perldoc for this module as
  54 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  55 terminal, but can happen elsewhere too. Please try again after replacing the
  56 dashes with normal minus signs.
  57 DEATH
  58   }
  59   if (my ($x) = grep { /^--bootstrap(?:=.*)?$/ } @ARGV) {
  60     @ARGV = grep { !/^--bootstrap(?:=.*)?$/ } @ARGV;
  61     $bootstrapping = 1;
  62     if(my ($x) = grep { /^--no-manpages/ } @ARGV) {
  63       $no_manpages = 1;
  64       @ARGV = grep { !/^--no-manpages/ } @ARGV;
  65     }
  66     my ($path) = $x =~ /^--bootstrap(?:=(.*))?$/;
  67     my @args = $path ? $path : ();
  68
  69     {
  70       local @INC = @INC;
  71       unshift(@INC, 'lib');
  72       require local::lib;
  73     }
  74
  75     local::lib->import(@args);
  76
  77     my @libs = map { "-I$_" } split $Config{path_sep}, $ENV{PERL5LIB};
  78     $bootstrapping_args = "@libs";
  79     push(@ARGV,$ENV{PERL_MM_OPT});
  80     push(@ARGV, @libs);
  81
  82     # <mst> GODDAMN makepl_arg INSTALLDIRS=site
  83     # <mst> we must set PERL_AUTOINSTALL_PREFER_CPAN too
  84     $ENV{PERL_AUTOINSTALL_PREFER_CPAN} = 1;
  85
  86     system($^X, '-MExtUtils::MakeMaker 6.74', '-e1');
  87     my $eumm = $? >> 8;
  88
  89     system($^X, '-MExtUtils::Install 1.43', '-e1');
  90     my $eui = $? >> 8;
  91
  92     system($^X, '-MModule::Build 0.36', '-e1');
  93     my $mb = $? >> 8;
  94
  95     system($^X, '-MCPAN 1.82', '-e1');
  96     my $cpan = $? >> 8;
  97     my $cpan_command = '';
  98
  99     my $did_cpan_config = 0;
 100     my $cpan_config_command =
 101       'my $done; require ExtUtils::MakeMaker;
 102        my $orig = ExtUtils::MakeMaker->can("prompt");
 103        *ExtUtils::MakeMaker::prompt = sub ($;$) {
 104          if (!$done && $_[0] =~ /manual configuration/) {
 105            $done++;
 106            return "no";
 107          }
 108          return $orig->(@_);
 109        };
 110        # not yet -- apeiron, 2010-03-10
 111        #$CPAN::Config->{urllist} = ["http://cpan.shadowcatprojects.net"];
 112        # <mst> all bootstrapped fine on one DH account
 113        # <mst> on another, it tries to install man stuff into /usr/local
 114        # <mst> cannot for the life of me figure out why
 115        # <mst> (same fucking server as well)
 116        # <mst> GOT THE BASTARD
 117        # <mst> ExtUtils::ParseXS uses Module::Build
 118        # <mst> but Module::Build depends on it
 119        # <mst> so you need to set prefer_installer MM
 120        # <mst> so cpan uses EU::ParseXS Makefile.PL
 121        # <mst> since we already got EUMM, *that* works
 122        $CPAN::Config->{prefer_installer} = "EUMM";
 123        CPAN::Config->load;
 124        unless ($done || -w $CPAN::Config->{keep_source_where}) {
 125          my $save = $CPAN::Config->{urllist};
 126          delete @{$CPAN::Config}{keys %$CPAN::Config};
 127          $CPAN::Config->{urllist} = $save;
 128          CPAN::Config->init;
 129        }';
 130
 131     $ENV{PERL_MM_USE_DEFAULT} = 1;
 132
 133     # XXX - remove the force on EUMM once its test suite survive PERL_MM_OPT
 134
 135     if ($eumm) { # non-zero exit
 136       $cpan_command .= 'force("install","ExtUtils::MakeMaker"); ';
 137     }
 138     if ($eui) {
 139       $cpan_command .= 'install("ExtUtils::Install"); ';
 140     }
 141     if ($mb) {
 142       $cpan_command .= 'install("Module::Build"); ';
 143     }
 144     if ($cpan) {
 145       $cpan_command .= 'force("install","CPAN"); ';
 146     }
 147     if(length $cpan_command) {
 148       system($^X, '-MCPAN', '-e', $cpan_config_command);
 149       $did_cpan_config++;
 150       system($^X, '-MCPAN', '-e', $cpan_command);
 151     }
 152     if ($cpan) {
 153       system($^X, '-MCPAN', '-e', 'CPAN::Config->load; CPAN::Config->commit;');
 154     }
 155     if($no_manpages) {
 156       # if we call this code directly, the changes get written to
 157       # $BOOTSTRAP/lib/perl5/CPAN/Config.pm, not where the user expects them to
 158       # be in their ~/.cpan/CPAN/MyConfig.pm.
 159       system($^X, '-MCPAN', '-e', $cpan_config_command)
 160         unless $did_cpan_config;
 161       system($^X, '-MCPAN',
 162         '-e',
 163         q[CPAN::HandleConfig->load;],
 164         '-e',
 165         q[$CPAN::Config->{makepl_arg}  = ] .
 166           q['INSTALLMAN1DIR=none INSTALLMAN3DIR=none';],
 167         '-e',
 168         q[$CPAN::Config->{buildpl_arg} = ] .
 169           q['--install_path libdoc="" --install_path bindoc=""';],
 170         '-e',
 171         q[CPAN::Config->commit;],
 172       );
 173     }
 174
 175     chdir($cwd);
 176   }
 177 }
 178
 179 require ExtUtils::MakeMaker;
 180 ExtUtils::MakeMaker->import;
 181 (do 'maint/Makefile.PL.include' or die $@) unless -f 'META.yml';
 182
 183 my %CONFIGURE_DEPS = ();
 184 my %BUILD_DEPS = ();
 185 my %TEST_DEPS = (
 186   'Test::More'  => 0,
 187 );
 188 my %RUN_DEPS = (
 189   'ExtUtils::MakeMaker' => '6.74', # version PERL_MM_OPT is shell parsed
 190   'ExtUtils::Install'   => '1.43', # version INSTALL_BASE was added
 191   'Module::Build'       => '0.36', # PERL_MB_OPT
 192   'CPAN'                => '1.82', # sudo support + CPAN::HandleConfig
 193 );
 194
 195 my %extra_info = (
 196   'meta-spec' => { version => 2 },
 197   resources => {
 198     repository => {
 199       # r/w: p5sagit@git.shadowcat.co.uk:local-lib.git
 200       url => 'git://git.shadowcat.co.uk/p5sagit/local-lib.git',
 201       web => 'http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/local-lib.git',
 202       type => 'git',
 203     },
 204     x_IRC => 'irc://irc.perl.org/#local-lib',
 205     bugtracker => {
 206       web => 'https://rt.cpan.org/Public/Dist/Display.html?Name=local-lib',
 207       mailto => 'bug-local-lib@rt.cpan.org',
 208     },
 209     license => [ 'http://dev.perl.org/licenses/' ],
 210   },
 211   prereqs => {
 212     runtime   => { requires => { perl => '5.8.1' } },
 213   },
 214 );
 215
 216 if ($bootstrapping) {
 217   no warnings 'once';
 218 *MY::postamble = sub {
 219   <<"END";
 220 PERL     += $bootstrapping_args
 221 FULLPERL += $bootstrapping_args
 222 END
 223   }
 224 }
 225
 226 # don't bother fixing CPAN.pm if bootstrapped from cpanminus
 227 if ($ENV{PERL5_CPANM_IS_RUNNING}) {
 228     delete $RUN_DEPS{CPAN};
 229 }
 230 else {
 231     # No, really. See
 232     # https://rt.cpan.org/Public/Bug/Display.html?id=23735
 233     # for why CPAN now sets the CPANPLUS env var.
 234     # trouble is this means we can't auto_install(_now) CPAN itself
 235     # without this beautiful hack
 236
 237     my $no_cpanplus_env = !exists $ENV{PERL5_CPANPLUS_IS_RUNNING};
 238     my $no_cpan_env = !exists $ENV{PERL5_CPAN_IS_RUNNING};
 239     require CPAN;
 240     delete $ENV{PERL5_CPANPLUS_IS_RUNNING} if $no_cpanplus_env;
 241     delete $ENV{PERL5_CPAN_IS_RUNNING} if $no_cpan_env;
 242
 243     # and make sure that the user doesn't have any existing CPAN config that'll
 244     # cause us problems for the next few steps.
 245     local $@;
 246     eval { require CPAN::HandleConfig; };
 247     # Need newish CPAN.pm for this, ergo skip it if that version of CPAN isn't
 248     # installed yet.
 249     # It will already be installed by the time we reach here if bootstrapping,
 250     # otherwise, if we're running from CPAN then it will be installed soon
 251     # enough, and we'll come back here..
 252     if (!$@ ) {
 253         CPAN::HandleConfig->require_myconfig_or_config;
 254         if ( $CPAN::Config ) {
 255             for my $setting (qw(
 256               makepl_arg make_install_arg
 257               mbuild_arg mbuild_install_arg mbuildpl_arg
 258             )) {
 259                 my $value = $CPAN::Config->{$setting} or next;
 260                 if ($setting =~ /^make/
 261                   ? $value =~ /(?:PREFIX|INSTALL_BASE)/
 262                   : $value =~ /(?:--prefix|--install_base)/
 263                 ) {
 264                     die <<"DEATH";
 265 WHOA THERE! It looks like you've got $CPAN::Config->{$setting} set in
 266 your CPAN config. This is known to cause problems with local::lib. Please
 267 either remove this setting or clear out your .cpan directory.
 268 DEATH
 269                 }
 270             }
 271         }
 272     }
 273     else {
 274         my $error = $@;
 275         require CPAN;
 276         # Explode if it looks like requiring CPAN::HandleConfig should
 277         # have worked, but didn't.
 278         die($error) if $CPAN::VERSION >= $RUN_DEPS{CPAN};
 279     }
 280 }
 281 chdir($cwd);
 282
 283 @{$extra_info{prereqs}{runtime}{requires}}{keys %RUN_DEPS} = values %RUN_DEPS;
 284
 285 # have to do this since old EUMM dev releases miss the eval $VERSION line
 286 my $eumm_version = eval $ExtUtils::MakeMaker::VERSION;
 287 my $mymeta_works = $eumm_version >= 6.57_07;
 288 my $mymeta = $eumm_version >= 6.57_02;
 289
 290 my $has_test_requires = $eumm_version >= 6.63_03;
 291
 292 my $has_meta_v2 = $eumm_version >= 6.57_10;
 293 if (! $has_meta_v2) {
 294   %extra_info = ();
 295 }
 296 if (not $has_test_requires) {
 297   %BUILD_DEPS = (%BUILD_DEPS, %TEST_DEPS);
 298   %TEST_DEPS = ();
 299 }
 300 if (not $mymeta_works) {
 301   %RUN_DEPS = (%RUN_DEPS, %BUILD_DEPS);
 302   %BUILD_DEPS = ();
 303 }
 304
 305 WriteMakefile(
 306   NAME => 'local::lib',
 307   VERSION_FROM => 'lib/local/lib.pm',
 308   CONFIGURE_REQUIRES => \%CONFIGURE_DEPS,
 309   PREREQ_PM => {
 310     %RUN_DEPS,
 311   },
 312   keys %BUILD_DEPS ? ( BUILD_REQUIRES => \%BUILD_DEPS ) : (),
 313   keys %TEST_DEPS ? ( TEST_REQUIRES => \%TEST_DEPS ) : (),
 314   META_ADD => \%extra_info,
 315   META_MERGE => {
 316     no_index => {
 317       directory => [ 'xt' ]
 318     },
 319   },
 320   ($mymeta && !$mymeta_works ? (NO_MYMETA => 1) : ()),
 321   LICENSE => 'perl',
 322 );