Makefile.PL

   1 use strict;
   2 use warnings;
   3 use File::Spec;
   4 use Cwd;
   5 use vars qw($bootstrapping $bootstrapping_args);
   6 use Config;
   7
   8 my $cwd;
   9 BEGIN {
  10   $cwd = Cwd::cwd();
  11   # watch out for fancy dashes. these can wind up in our @ARGV if the user is
  12   # copypasting the bootstrap command from the POD displayed e.g. by perldoc
  13   # on a Mac OS X terminal. since no software recognizes and handles these
  14   # dashes, it's better to die loudly telling the user exactly what happened
  15   # so they don't make the same mistake again rather than being the only
  16   # program in the universe that works with them.
  17   if(grep { /−/ } @ARGV) {
  18       die <<'DEATH';
  19 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  20 These are *not* the traditional -- dashes that software recognizes. You
  21 probably got these by copy-pasting from the perldoc for this module as
  22 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  23 terminal, but can happen elsewhere too. Please try again after replacing the
  24 dashes with normal minus signs.
  25 DEATH
  26   }
  27   if (my ($x) = grep { /^--bootstrap(?:=.*)?$/ } @ARGV) {
  28     @ARGV = grep { !/^--bootstrap(?:=.*)?$/ } @ARGV;
  29     $bootstrapping = 1;
  30     my ($path) = $x =~ /^--bootstrap(?:=(.*))?$/;
  31     my @args = $path ? $path : ();
  32
  33     {
  34       local @INC = @INC;
  35       unshift(@INC, 'lib');
  36       require local::lib;
  37     }
  38
  39     local::lib->import(@args);
  40
  41     my @libs = map { "-I$_" } split $Config{path_sep}, $ENV{PERL5LIB};
  42     $bootstrapping_args = "@libs";
  43     push(@ARGV,$ENV{PERL_MM_OPT});
  44     push(@ARGV, @libs);
  45
  46     system($^X, '-MExtUtils::MakeMaker 6.31', '-e1');
  47     my $eumm = $? >> 8;
  48
  49     system($^X, '-MCPAN 1.80', '-e1');
  50     my $cpan = $? >> 8;
  51     my $cpan_command = '';
  52
  53     system($^X, '-MCPAN', '-e',
  54       'my $done; require ExtUtils::MakeMaker;
  55        my $orig = ExtUtils::MakeMaker->can("prompt");
  56        *ExtUtils::MakeMaker::prompt = sub ($;$) {
  57          if (!$done && $_[0] =~ /manual configuration/) {
  58            $done++;
  59            return "no";
  60          }
  61          return $orig->(@_);
  62        };
  63        CPAN::Config->load;
  64        unless ($done || -w $CPAN::Config->{keep_source_where}) {
  65          my $save = $CPAN::Config->{urllist};
  66          delete @{$CPAN::Config}{keys %$CPAN::Config};
  67          $CPAN::Config->{urllist} = $save;
  68          CPAN::Config->init;
  69        }'
  70     );
  71
  72     $ENV{PERL_MM_USE_DEFAULT} = 1;
  73
  74     # XXX - remove the force on EUMM once its test suite survive PERL_MM_OPT
  75
  76     if ($eumm) { # non-zero exit
  77       $cpan_command .= 'force("install","ExtUtils::MakeMaker"); ';
  78     }
  79     if ($cpan) {
  80       $cpan_command .= 'force("install","CPAN"); ';
  81     }
  82     if(length $cpan_command) {
  83       system($^X, '-MCPAN', '-e', $cpan_command);
  84     }
  85     if ($cpan) {
  86       system($^X, '-MCPAN', '-e', 'CPAN::Config->load; CPAN::Config->commit;');
  87     }
  88
  89     chdir($cwd);
  90   }
  91 }
  92
  93 use inc::Module::Install;
  94
  95 name 'local-lib';
  96 all_from 'lib/local/lib.pm';
  97
  98 requires 'ExtUtils::MakeMaker' => '6.31'; # version INSTALL_BASE was added
  99 requires 'ExtUtils::CBuilder'; # this and ParseXS are needed for MB C_support
 100 requires 'ExtUtils::ParseXS';
 101 requires 'Module::Build' => '0.28'; # lib -> lib/perl5 change
 102 my $required_CPAN = '1.80';
 103 requires 'CPAN' => $required_CPAN; # sudo support + CPAN::HandleConfig
 104
 105 # No, really. See
 106 # https://rt.cpan.org/Public/Bug/Display.html?id=23735
 107 # for why CPAN now sets the CPANPLUS env var.
 108 # trouble is this means we can't auto_install(_now) CPAN itself
 109 # without this beautiful hack
 110
 111 my $no_cpanplus_env = !exists $ENV{PERL5_CPANPLUS_IS_RUNNING};
 112 my $no_cpan_env = !exists $ENV{PERL5_CPAN_IS_RUNNING};
 113 require CPAN;
 114 delete $ENV{PERL5_CPANPLUS_IS_RUNNING} if $no_cpanplus_env;
 115 delete $ENV{PERL5_CPAN_IS_RUNNING} if $no_cpan_env;
 116
 117 # and make sure that the user doesn't have any existing CPAN config that'll
 118 # cause us problems for the next few steps.
 119 {
 120     local $@;
 121     eval { require CPAN::HandleConfig; };
 122     # Need newish CPAN.pm for this, ergo skip it if that version of CPAN isn't
 123     # installed yet.
 124     # It will already be installed by the time we reach here if bootstrapping,
 125     # otherwise, if we're running from CPAN then it will be installed soon
 126     # enough, and we'll come back here..
 127     if (!$@) {
 128         CPAN::HandleConfig->load;
 129         for my $eumm_setting ( qw/makepl_arg make_install_arg/ ) {
 130             if ($CPAN::Config->{$eumm_setting} =~ /(?:PREFIX|INSTALL_BASE)/) {
 131                 die "Possibly invalid config detected in $eumm_setting: " . $CPAN::Config->{$eumm_setting};
 132             }
 133         }
 134
 135         for my $mb_setting (qw/mbuild_arg mbuild_install_arg mbuildpl_arg/) {
 136             if ($CPAN::Config->{$mb_setting} =~ /(?:--prefix|--install_base)/) {
 137                 die "Possibly invalid config detected in $mb_setting: " . $CPAN::Config->{$mb_setting};
 138             }
 139         }
 140     }
 141     else {
 142         my $error = $@;
 143         require CPAN;
 144         # Explode if it looks like requiring CPAN::HandleConfig should
 145         # have worked, but didn't.
 146         die($error) if $CPAN::VERSION >= $required_CPAN;
 147     }
 148 }
 149
 150 if ($bootstrapping) {
 151   auto_install_now;
 152   postamble <<"END";
 153 PERL     += $bootstrapping_args
 154 FULLPERL += $bootstrapping_args
 155 END
 156 } else {
 157   auto_install;
 158 }
 159 chdir($cwd);
 160 WriteAll;