Makefile.PL

   1 use strict;
   2 use warnings;
   3 use File::Spec;
   4 use Cwd;
   5 use vars qw($bootstrapping $bootstrapping_args $no_manpages);
   6 use Config;
   7
   8 # Solaris (and possibly other Unices) have a tar in /usr/bin that, among
   9 # other things, does not understand @LongLink. This can cause
  10 # extraction to look like it succeeded, but it actually failed (because
  11 # the error message for the @LongLink failure scrolled offscreen).
  12 # Therefore, given the fact that GNU tar is the most widespread tar available,
  13 # and it actually supports the feature we want (I'd bet it originated in GNU
  14 # tar, but I digress), we'll look for GNU tar. If we don't find it, and the
  15 # user hasn't pointed us to a suitable tar, we'll bomb and tell them what to
  16 # do.
  17
  18 my $have_gtar = 0;
  19 if($^O eq 'solaris') {
  20   $have_gtar = 0;
  21   for my $env_path (split /:/, $ENV{PATH}) {
  22     $have_gtar = 1 if -x File::Spec->catfile($env_path, 'gtar');
  23   }
  24 } else {
  25   $have_gtar = 1;
  26 }
  27 if(exists $ENV{PERL_LL_TAR}) {
  28   $have_gtar ||= -x $ENV{PERL_LL_TAR};
  29 }
  30
  31 die <<'DEATH' unless $have_gtar;
  32 You are using Solaris (or another traditional Unix) that does not provide a sane
  33 tar, capable of dealing with the output of GNU tar. Please either set the
  34 PERL_LL_TAR environment variable to the location of a version of tar that
  35 understands the @LongLink convention or put a binary named gtar somewhere on
  36 your PATH.
  37 DEATH
  38
  39 my $cwd;
  40 BEGIN {
  41   $cwd = Cwd::cwd();
  42   # watch out for fancy dashes. these can wind up in our @ARGV if the user is
  43   # copypasting the bootstrap command from the POD displayed e.g. by perldoc
  44   # on a Mac OS X terminal. since no software recognizes and handles these
  45   # dashes, it's better to die loudly telling the user exactly what happened
  46   # so they don't make the same mistake again rather than being the only
  47   # program in the universe that works with them.
  48   if(grep { /−/ } @ARGV) {
  49       die <<'DEATH';
  50 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  51 These are *not* the traditional -- dashes that software recognizes. You
  52 probably got these by copy-pasting from the perldoc for this module as
  53 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  54 terminal, but can happen elsewhere too. Please try again after replacing the
  55 dashes with normal minus signs.
  56 DEATH
  57   }
  58   if (my ($x) = grep { /^--bootstrap(?:=.*)?$/ } @ARGV) {
  59     @ARGV = grep { !/^--bootstrap(?:=.*)?$/ } @ARGV;
  60     $bootstrapping = 1;
  61     if(my ($x) = grep { /^--no-manpages/ } @ARGV) {
  62       $no_manpages = 1;
  63       @ARGV = grep { !/^--no-manpages/ } @ARGV;
  64     }
  65     my ($path) = $x =~ /^--bootstrap(?:=(.*))?$/;
  66     my @args = $path ? $path : ();
  67
  68     {
  69       local @INC = @INC;
  70       unshift(@INC, 'lib');
  71       require local::lib;
  72     }
  73
  74     local::lib->import(@args);
  75
  76     my @libs = map { "-I$_" } split $Config{path_sep}, $ENV{PERL5LIB};
  77     $bootstrapping_args = "@libs";
  78     push(@ARGV,$ENV{PERL_MM_OPT});
  79     push(@ARGV, @libs);
  80
  81     # <mst> GODDAMN makepl_arg INSTALLDIRS=site
  82     # <mst> we must set PERL_AUTOINSTALL_PREFER_CPAN too
  83     $ENV{PERL_AUTOINSTALL_PREFER_CPAN} = 1;
  84
  85     system($^X, '-MExtUtils::MakeMaker 6.31', '-e1');
  86     my $eumm = $? >> 8;
  87
  88     system($^X, '-MExtUtils::Install 1.43', '-e1');
  89     my $eui = $? >> 8;
  90
  91     system($^X, '-MCPAN 1.82', '-e1');
  92     my $cpan = $? >> 8;
  93     my $cpan_command = '';
  94
  95     system($^X, '-MCPAN', '-e',
  96       'my $done; require ExtUtils::MakeMaker;
  97        my $orig = ExtUtils::MakeMaker->can("prompt");
  98        *ExtUtils::MakeMaker::prompt = sub ($;$) {
  99          if (!$done && $_[0] =~ /manual configuration/) {
 100            $done++;
 101            return "no";
 102          }
 103          return $orig->(@_);
 104        };
 105        # not yet -- apeiron, 2010-03-10
 106        #$CPAN::Config->{urllist} = ["http://cpan.shadowcatprojects.net"];
 107        # <mst> all bootstrapped fine on one DH account
 108        # <mst> on another, it tries to install man stuff into /usr/local
 109        # <mst> cannot for the life of me figure out why
 110        # <mst> (same fucking server as well)
 111        # <mst> GOT THE BASTARD
 112        # <mst> ExtUtils::ParseXS uses Module::Build
 113        # <mst> but Module::Build depends on it
 114        # <mst> so you need to set prefer_installer MM
 115        # <mst> so cpan uses EU::ParseXS Makefile.PL
 116        # <mst> since we already got EUMM, *that* works
 117        $CPAN::Config->{prefer_installer} = "EUMM";
 118        CPAN::Config->load;
 119        unless ($done || -w $CPAN::Config->{keep_source_where}) {
 120          my $save = $CPAN::Config->{urllist};
 121          delete @{$CPAN::Config}{keys %$CPAN::Config};
 122          $CPAN::Config->{urllist} = $save;
 123          CPAN::Config->init;
 124        }'
 125     );
 126
 127     $ENV{PERL_MM_USE_DEFAULT} = 1;
 128
 129     # XXX - remove the force on EUMM once its test suite survive PERL_MM_OPT
 130
 131     if ($eumm) { # non-zero exit
 132       $cpan_command .= 'force("install","ExtUtils::MakeMaker"); ';
 133     }
 134     if ($eui) {
 135       $cpan_command .= 'install("ExtUtils::Install"); ';
 136     }
 137     if ($cpan) {
 138       $cpan_command .= 'force("install","CPAN"); ';
 139     }
 140     if(length $cpan_command) {
 141       system($^X, '-MCPAN', '-e', $cpan_command);
 142     }
 143     if ($cpan) {
 144       system($^X, '-MCPAN', '-e', 'CPAN::Config->load; CPAN::Config->commit;');
 145     }
 146     if($no_manpages) {
 147       # if we call this code directly, the changes get written to
 148       # $BOOTSTRAP/lib/perl5/CPAN/Config.pm, not where the user expects them to
 149       # be in their ~/.cpan/CPAN/MyConfig.pm.
 150       system($^X, '-MCPAN',
 151         '-e',
 152         q[CPAN::HandleConfig->load;],
 153         '-e',
 154         q[$CPAN::Config->{makepl_arg}  = ] .
 155           q['INSTALLMAN1DIR=none INSTALLMAN3DIR=none';],
 156         '-e',
 157         q[$CPAN::Config->{buildpl_arg} = ] .
 158           q['--install_path libdoc="" --install_path bindoc=""';],
 159         '-e',
 160         q[CPAN::Config->commit;],
 161       );
 162     }
 163
 164     chdir($cwd);
 165   }
 166 }
 167
 168 use inc::Module::Install;
 169
 170 name 'local-lib';
 171 all_from 'lib/local/lib.pm';
 172
 173 requires 'ExtUtils::MakeMaker' => '6.31'; # version INSTALL_BASE was added
 174 requires 'ExtUtils::Install' => '1.43'; # ditto
 175 requires 'ExtUtils::CBuilder'; # this and ParseXS are needed for MB C_support
 176 requires 'ExtUtils::ParseXS';
 177 requires 'Module::Build' => '0.28'; # lib -> lib/perl5 change
 178 my $required_CPAN = '1.82';
 179 requires 'CPAN' => $required_CPAN; # sudo support + CPAN::HandleConfig
 180
 181 # No, really. See
 182 # https://rt.cpan.org/Public/Bug/Display.html?id=23735
 183 # for why CPAN now sets the CPANPLUS env var.
 184 # trouble is this means we can't auto_install(_now) CPAN itself
 185 # without this beautiful hack
 186
 187 my $no_cpanplus_env = !exists $ENV{PERL5_CPANPLUS_IS_RUNNING};
 188 my $no_cpan_env = !exists $ENV{PERL5_CPAN_IS_RUNNING};
 189 require CPAN;
 190 delete $ENV{PERL5_CPANPLUS_IS_RUNNING} if $no_cpanplus_env;
 191 delete $ENV{PERL5_CPAN_IS_RUNNING} if $no_cpan_env;
 192
 193 # and make sure that the user doesn't have any existing CPAN config that'll
 194 # cause us problems for the next few steps.
 195 {
 196     local $@;
 197     eval { require CPAN::HandleConfig; };
 198     # Need newish CPAN.pm for this, ergo skip it if that version of CPAN isn't
 199     # installed yet.
 200     # It will already be installed by the time we reach here if bootstrapping,
 201     # otherwise, if we're running from CPAN then it will be installed soon
 202     # enough, and we'll come back here..
 203     if (!$@) {
 204         CPAN::HandleConfig->load;
 205         for my $eumm_setting ( qw/makepl_arg make_install_arg/ ) {
 206             if ($CPAN::Config->{$eumm_setting} =~ /(?:PREFIX|INSTALL_BASE)/) {
 207                 die <<"DEATH";
 208 WHOA THERE! It looks like you've got $CPAN::Config->{$eumm_setting} set. This is
 209 known to cause problems with local::lib. Please either remove this setting or
 210 clear out your .cpan directory.
 211 DEATH
 212             }
 213         }
 214
 215         for my $mb_setting (qw/mbuild_arg mbuild_install_arg mbuildpl_arg/) {
 216             if ($CPAN::Config->{$mb_setting} =~ /(?:--prefix|--install_base)/) {
 217                 die <<"DEATH";
 218 WHOA THERE! It looks like you've got $CPAN::Config->{$mb_setting} set. This is
 219 known to cause problems with local::lib. Please either remove this setting or
 220 clear out your .cpan directory.
 221 DEATH
 222             }
 223         }
 224     }
 225     else {
 226         my $error = $@;
 227         require CPAN;
 228         # Explode if it looks like requiring CPAN::HandleConfig should
 229         # have worked, but didn't.
 230         die($error) if $CPAN::VERSION >= $required_CPAN;
 231     }
 232 }
 233
 234 if ($bootstrapping) {
 235   auto_install_now;
 236   postamble <<"END";
 237 PERL     += $bootstrapping_args
 238 FULLPERL += $bootstrapping_args
 239 END
 240 } else {
 241   auto_install;
 242 }
 243 chdir($cwd);
 244 WriteAll;