Commit | Line | Data |
b5cc15f7 |
1 | use strict; |
2 | use warnings; |
3 | |
4 | package local::lib; |
5 | |
387f8022 |
6 | use 5.006; |
b5cc15f7 |
7 | |
8 | use File::Spec (); |
b5cc15f7 |
9 | use Config; |
10 | |
7c0e6b54 |
11 | our $VERSION = '1.008026'; # 1.8.26 |
d04dfa50 |
12 | $VERSION = eval $VERSION; |
1f8043c8 |
13 | |
b5cc15f7 |
14 | sub import { |
0fb70b9a |
15 | my ($class, @args) = @_; |
16 | |
e4b5a839 |
17 | my @steps; |
e4892f2b |
18 | |
e4b5a839 |
19 | while (@args) { |
20 | my $arg = shift @args; |
b9c94c15 |
21 | # check for lethal dash first to stop processing before causing problems |
5eff9c24 |
22 | # the fancy dash is U+2212 or \xE2\x88\x92 |
23 | if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) { |
d4dbe584 |
24 | die <<'DEATH'; |
25 | WHOA THERE! It looks like you've got some fancy dashes in your commandline! |
26 | These are *not* the traditional -- dashes that software recognizes. You |
27 | probably got these by copy-pasting from the perldoc for this module as |
28 | rendered by a UTF8-capable formatter. This most typically happens on an OS X |
29 | terminal, but can happen elsewhere too. Please try again after replacing the |
30 | dashes with normal minus signs. |
31 | DEATH |
b9c94c15 |
32 | } |
e4b5a839 |
33 | elsif ($arg eq '--self-contained') { |
34 | die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n"; |
35 | } |
939821af |
36 | elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) { |
37 | my $path = defined $1 ? $1 : shift @args; |
e4b5a839 |
38 | push @steps, ['deactivate', $path]; |
b9c94c15 |
39 | } |
e4b5a839 |
40 | elsif ( $arg eq '--deactivate-all' ) { |
41 | push @steps, ['deactivate_all']; |
42 | } |
43 | elsif ( $arg =~ /^--/ ) { |
b9c94c15 |
44 | die "Unknown import argument: $arg"; |
45 | } |
46 | else { |
e4b5a839 |
47 | push @steps, ['activate', $arg]; |
b9c94c15 |
48 | } |
d4dbe584 |
49 | } |
e4b5a839 |
50 | if (!@steps) { |
51 | push @steps, ['activate', undef]; |
52 | } |
53 | |
54 | my $self = $class->new; |
55 | |
56 | for (@steps) { |
57 | my ($method, @args) = @$_; |
58 | $self = $self->$method(@args); |
59 | } |
60 | |
61 | if ($0 eq '-') { |
62 | $self->print_environment_vars_for; |
63 | exit 0; |
64 | } |
65 | else { |
66 | $self->setup_local_lib_for; |
67 | } |
68 | } |
69 | |
70 | sub new { |
71 | my $class = shift; |
72 | bless {@_}, $class; |
73 | } |
74 | |
75 | sub clone { |
76 | my $self = shift; |
77 | bless {%$self, @_}, ref $self; |
78 | } |
79 | |
80 | sub inc { $_[0]->{inc} ||= \@INC } |
81 | sub libs { $_[0]->{libs} ||= [ \'PERL5LIB' ] } |
82 | sub bins { $_[0]->{bins} ||= [ \'PATH' ] } |
83 | sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] } |
84 | sub extra { $_[0]->{extra} ||= {} } |
85 | sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype } |
86 | |
87 | my $_archname = $Config{archname}; |
88 | my $_version = $Config{version}; |
89 | my @_inc_version_list = reverse split / /, $Config{inc_version_list}; |
90 | my $_path_sep = $Config{path_sep}; |
91 | |
92 | sub _as_list { |
93 | my $list = shift; |
94 | grep length, map { |
95 | !(ref $_ && ref $_ eq 'SCALAR') ? $_ : ( |
96 | defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_}) |
97 | : () |
98 | ) |
99 | } ref $list ? @$list : $list; |
100 | } |
101 | sub _remove_from { |
102 | my ($list, @remove) = @_; |
103 | my %remove = map { $_ => 1 } @remove; |
104 | grep !$remove{$_}, _as_list($list); |
105 | } |
106 | |
107 | my @_lib_subdirs = ( |
108 | [$_version, $_archname], |
109 | [$_version], |
110 | [$_archname], |
111 | (@_inc_version_list ? \@_inc_version_list : ()), |
112 | [], |
113 | ); |
114 | |
115 | sub install_base_bin_path { |
116 | my ($class, $path) = @_; |
117 | return File::Spec->catdir($path, 'bin'); |
118 | } |
119 | sub install_base_perl_path { |
120 | my ($class, $path) = @_; |
121 | return File::Spec->catdir($path, 'lib', 'perl5'); |
122 | } |
123 | sub install_base_arch_path { |
124 | my ($class, $path) = @_; |
125 | File::Spec->catdir($class->install_base_perl_path($path), $_archname); |
126 | } |
127 | |
128 | sub lib_paths_for { |
129 | my ($class, $path) = @_; |
130 | my $base = $class->install_base_perl_path($path); |
131 | return map { File::Spec->catdir($base, @$_) } @_lib_subdirs; |
132 | } |
133 | |
134 | sub _mm_escape_path { |
135 | my $path = shift; |
136 | $path =~ s/\\/\\\\\\\\/g; |
137 | if ($path =~ s/ /\\ /g) { |
138 | $path = qq{"\\"$path\\""}; |
139 | } |
140 | return $path; |
141 | } |
142 | |
143 | sub _mb_escape_path { |
144 | my $path = shift; |
145 | $path =~ s/\\/\\\\/g; |
146 | return qq{"$path"}; |
147 | } |
148 | |
149 | sub installer_options_for { |
150 | my ($class, $path) = @_; |
151 | return { |
152 | PERL_MM_OPT => defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef, |
153 | PERL_MB_OPT => defined $path ? "--install_base "._mb_escape_path($path) : undef, |
154 | }; |
155 | } |
b9c94c15 |
156 | |
e4b5a839 |
157 | sub active_paths { |
158 | my ($self) = @_; |
159 | $self = ref $self ? $self : $self->new; |
160 | |
161 | return grep { |
162 | # screen out entries that aren't actually reflected in @INC |
163 | my $active_ll = $self->install_base_perl_path($_); |
164 | grep { $_ eq $active_ll } @{$self->inc}; |
165 | } _as_list($self->roots); |
166 | } |
167 | |
168 | |
169 | sub deactivate { |
170 | my ($self, $path) = @_; |
171 | $self = $self->new unless ref $self; |
172 | $path = $self->resolve_path($path); |
173 | |
174 | my @active_lls = $self->active_paths; |
175 | |
176 | if (!grep { $_ eq $path } @active_lls) { |
177 | warn "Tried to deactivate inactive local::lib '$path'\n"; |
178 | return; |
0fb70b9a |
179 | } |
b9c94c15 |
180 | |
e4b5a839 |
181 | my %args = ( |
182 | bins => [ _remove_from($self->bins, $self->install_base_bin_path($path)) ], |
183 | libs => [ _remove_from($self->libs, $self->install_base_perl_path($path)) ], |
184 | inc => [ _remove_from($self->inc, $self->lib_paths_for($path)) ], |
185 | roots => [ _remove_from($self->roots, $path) ], |
186 | ); |
187 | |
188 | $args{extra} = $self->installer_options_for($args{roots}[0]); |
189 | |
190 | $self->clone(%args); |
191 | } |
192 | |
193 | sub deactivate_all { |
194 | my ($self) = @_; |
195 | $self = $self->new unless ref $self; |
196 | |
197 | my @active_lls = $self->active_paths; |
198 | |
199 | my %args = ( |
200 | bins => [ _remove_from($self->bins, |
201 | map $self->install_base_bin_path($_), @active_lls) ], |
202 | libs => [ _remove_from($self->libs, |
203 | map $self->install_base_perl_path($_), @active_lls) ], |
204 | inc => [ _remove_from($self->inc, |
205 | map $self->lib_paths_for($_), @active_lls) ], |
206 | roots => [ _remove_from($self->roots, @active_lls) ], |
207 | ); |
208 | |
209 | $args{extra} = $self->installer_options_for(undef); |
210 | |
211 | $self->clone(%args); |
212 | } |
213 | |
214 | sub activate { |
215 | my ($self, $path) = @_; |
216 | $self = $self->new unless ref $self; |
217 | $path = $self->resolve_path($path); |
218 | $self->ensure_dir_structure_for($path); |
219 | |
220 | my @active_lls = $self->active_paths; |
221 | |
222 | if (grep { $_ eq $path } @active_lls) { |
223 | $self = $self->deactivate($path); |
15f79556 |
224 | } |
e4b5a839 |
225 | |
226 | my %args = ( |
227 | bins => [ $self->install_base_bin_path($path), @{$self->bins} ], |
228 | libs => [ $self->install_base_perl_path($path), @{$self->libs} ], |
229 | inc => [ $self->lib_paths_for($path), @{$self->inc} ], |
230 | roots => [ $path, @{$self->roots} ], |
231 | ); |
232 | |
233 | $args{extra} = $self->installer_options_for($path); |
234 | |
235 | $self->clone(%args); |
236 | } |
237 | |
238 | sub _legacy { |
239 | my ($self, $path, $deactivating) = @_; |
240 | $self = $self->new unless ref $self; |
241 | $self = $self->${\($deactivating ? 'deactivate' : 'activate')}($path) if defined $path; |
242 | $self; |
243 | } |
244 | |
245 | sub build_environment_vars_for { |
246 | my ($self) = _legacy(@_); |
247 | ( |
248 | PATH => join($_path_sep, _as_list($self->bins)), |
249 | PERL5LIB => join($_path_sep, _as_list($self->libs)), |
250 | PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)), |
251 | %{$self->extra}, |
252 | ); |
253 | } |
254 | |
255 | sub setup_local_lib_for { |
256 | my ($self) = _legacy(@_); |
257 | $self->setup_env_hash_for; |
258 | @INC = @{$self->inc}; |
259 | } |
260 | |
261 | sub setup_env_hash_for { |
262 | my $self = shift; |
263 | my %env = $self->build_environment_vars_for(@_); |
264 | for my $key (keys %env) { |
265 | if (defined $env{$key}) { |
266 | $ENV{$key} = $env{$key}; |
267 | } |
268 | else { |
269 | delete $ENV{$key}; |
270 | } |
15f79556 |
271 | } |
e4b5a839 |
272 | } |
15f79556 |
273 | |
e4b5a839 |
274 | sub print_environment_vars_for { |
275 | my $self = shift; |
276 | print $self->environment_vars_string_for(@_); |
277 | } |
278 | |
279 | sub environment_vars_string_for { |
280 | my $self = _legacy(@_); |
281 | |
282 | my $build_method = 'build_' . $self->shelltype . '_env_declaration'; |
283 | |
284 | my @envs = ( |
285 | PATH => $self->bins, |
286 | PERL5LIB => $self->libs, |
287 | PERL_LOCAL_LIB_ROOT => $self->roots, |
288 | %{$self->extra}, |
289 | ); |
290 | my $out = ''; |
291 | while (@envs) { |
292 | my ($name, $value) = (shift(@envs), shift(@envs)); |
293 | if ( |
294 | ref $value |
295 | && @$value == 1 |
296 | && ref $value->[0] |
297 | && ref $value->[0] eq 'SCALAR' |
298 | && ${$value->[0]} eq $name) { |
299 | next; |
300 | } |
301 | $out .= $self->$build_method($name, $value); |
302 | } |
303 | return $out; |
304 | } |
305 | |
306 | sub build_bourne_env_declaration { |
307 | my ($class, $name, $args) = @_; |
308 | my $value = $class->_interpolate($args); |
309 | $value =~ s/"/\\"/g |
310 | if defined $value; |
311 | return defined($value) ? qq{export ${name}="${value}"\n} : qq{unset ${name}\n}; |
312 | } |
313 | sub build_csh_env_declaration { |
314 | my ($class, $name, $args) = @_; |
315 | my ($value, @vars) = $class->_interpolate($args); |
316 | @vars = grep { $_ ne $name || defined $value } @vars; |
317 | $value =~ s/"/"\\""/g |
318 | if defined $value; |
319 | join '', |
320 | (map qq{if ! \$?$_ setenv $_ "";\n}, @vars), |
321 | (defined($value) |
322 | ? qq{setenv $name "$value";\n} |
323 | : qq{unsetenv $name;\n}); |
324 | } |
325 | sub build_cmd_env_declaration { |
326 | my ($class, $name, $args) = @_; |
327 | my $value = $class->_interpolate($args, '%', '%'); |
328 | $value =~ s/"/\\"/g |
329 | if defined $value; |
330 | return defined($value) ? qq{set ${name} "${value}"\n} : qq{set ${name}=\n}; |
331 | } |
332 | |
333 | sub _interpolate { |
334 | my ($class, $args, $start, $end) = @_; |
335 | return |
336 | unless defined $args; |
337 | return $args |
338 | unless ref $args; |
339 | return |
340 | unless @$args; |
341 | $start = '$' unless defined $start; |
342 | $end = '' unless defined $end; |
343 | my @vars; |
344 | my $string = join($Config{path_sep}, map { |
345 | (ref $_ && ref $_ eq 'SCALAR') ? do { push @vars, $$_; $start.$$_.$end } |
346 | : $_ |
347 | } @$args); |
348 | return wantarray ? ($string, @vars) : $string; |
b5cc15f7 |
349 | } |
350 | |
5b94dce5 |
351 | sub pipeline; |
b5cc15f7 |
352 | |
5b94dce5 |
353 | sub pipeline { |
b5cc15f7 |
354 | my @methods = @_; |
355 | my $last = pop(@methods); |
356 | if (@methods) { |
357 | \sub { |
358 | my ($obj, @args) = @_; |
5b94dce5 |
359 | $obj->${pipeline @methods}( |
b5cc15f7 |
360 | $obj->$last(@args) |
361 | ); |
362 | }; |
363 | } else { |
364 | \sub { |
365 | shift->$last(@_); |
366 | }; |
367 | } |
368 | } |
369 | |
275c9dae |
370 | =begin testing |
371 | |
372 | #:: test pipeline |
b5cc15f7 |
373 | |
374 | package local::lib; |
375 | |
376 | { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } } |
8522f4d5 |
377 | my $foo = bless({}, 'Foo'); |
4c375968 |
378 | Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15); |
b5cc15f7 |
379 | |
275c9dae |
380 | =end testing |
381 | |
b5cc15f7 |
382 | =cut |
383 | |
384 | sub resolve_path { |
385 | my ($class, $path) = @_; |
e4b5a839 |
386 | |
387 | $path = $class->${pipeline qw( |
b5cc15f7 |
388 | resolve_relative_path |
389 | resolve_home_path |
390 | resolve_empty_path |
391 | )}($path); |
e4b5a839 |
392 | |
393 | $path = Win32::GetShortPathName($path) |
394 | if $^O eq 'MSWin32'; |
395 | |
396 | $path; |
b5cc15f7 |
397 | } |
398 | |
399 | sub resolve_empty_path { |
400 | my ($class, $path) = @_; |
401 | if (defined $path) { |
402 | $path; |
403 | } else { |
404 | '~/perl5'; |
405 | } |
406 | } |
407 | |
275c9dae |
408 | =begin testing |
409 | |
410 | #:: test classmethod setup |
b5cc15f7 |
411 | |
412 | my $c = 'local::lib'; |
413 | |
275c9dae |
414 | =end testing |
415 | |
416 | =begin testing |
b5cc15f7 |
417 | |
275c9dae |
418 | #:: test classmethod |
b5cc15f7 |
419 | |
420 | is($c->resolve_empty_path, '~/perl5'); |
421 | is($c->resolve_empty_path('foo'), 'foo'); |
422 | |
275c9dae |
423 | =end testing |
424 | |
b5cc15f7 |
425 | =cut |
426 | |
427 | sub resolve_home_path { |
428 | my ($class, $path) = @_; |
429 | return $path unless ($path =~ /^~/); |
430 | my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us' |
b5cc15f7 |
431 | my $homedir = do { |
5c957a4b |
432 | if (!defined $user && defined $ENV{HOME}) { |
433 | $ENV{HOME} |
434 | } |
435 | else { |
436 | require File::Glob; |
437 | File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE()); |
b5cc15f7 |
438 | } |
439 | }; |
440 | unless (defined $homedir) { |
cd3eb741 |
441 | require Carp; |
b5cc15f7 |
442 | Carp::croak( |
443 | "Couldn't resolve homedir for " |
444 | .(defined $user ? $user : 'current user') |
b5cc15f7 |
445 | ); |
446 | } |
447 | $path =~ s/^~[^\/]*/$homedir/; |
448 | $path; |
449 | } |
450 | |
451 | sub resolve_relative_path { |
452 | my ($class, $path) = @_; |
53699c99 |
453 | $path = File::Spec->rel2abs($path); |
b5cc15f7 |
454 | } |
455 | |
275c9dae |
456 | =begin testing |
457 | |
458 | #:: test classmethod |
b5cc15f7 |
459 | |
460 | local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; }; |
461 | is($c->resolve_relative_path('bar'),'FOObar'); |
462 | |
275c9dae |
463 | =end testing |
464 | |
b5cc15f7 |
465 | =cut |
466 | |
b5cc15f7 |
467 | sub ensure_dir_structure_for { |
468 | my ($class, $path) = @_; |
469 | unless (-d $path) { |
470 | warn "Attempting to create directory ${path}\n"; |
471 | } |
5c957a4b |
472 | require File::Basename; |
473 | my @dirs; |
474 | while(!-d $path) { |
475 | push @dirs, $path; |
476 | $path = File::Basename::dirname($path); |
477 | } |
478 | mkdir $_ for reverse @dirs; |
479 | return; |
b5cc15f7 |
480 | } |
481 | |
0d6470a5 |
482 | =begin testing |
483 | |
484 | #:: test classmethod |
485 | |
486 | File::Path::rmtree('t/var/splat'); |
487 | |
488 | $c->ensure_dir_structure_for('t/var/splat'); |
489 | |
490 | ok(-d 't/var/splat'); |
491 | |
492 | =end testing |
493 | |
494 | =cut |
495 | |
c4e3c83b |
496 | sub guess_shelltype { |
0353dbc0 |
497 | my $shellbin = 'sh'; |
498 | if(defined $ENV{'SHELL'}) { |
499 | my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'}); |
500 | $shellbin = $shell_bin_path_parts[-1]; |
501 | } |
1bc71e56 |
502 | my $shelltype = do { |
503 | local $_ = $shellbin; |
b42496e0 |
504 | if(/csh/) { |
1bc71e56 |
505 | 'csh' |
b42496e0 |
506 | } else { |
1bc71e56 |
507 | 'bourne' |
508 | } |
509 | }; |
510 | |
f58534b1 |
511 | # Both Win32 and Cygwin have $ENV{COMSPEC} set. |
512 | if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') { |
53699c99 |
513 | my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'}); |
514 | $shellbin = $shell_bin_path_parts[-1]; |
515 | $shelltype = do { |
516 | local $_ = $shellbin; |
517 | if(/command\.com/) { |
e4b5a839 |
518 | 'cmd' |
53699c99 |
519 | } elsif(/cmd\.exe/) { |
e4b5a839 |
520 | 'cmd' |
53699c99 |
521 | } elsif(/4nt\.exe/) { |
e4b5a839 |
522 | 'cmd' |
53699c99 |
523 | } else { |
524 | $shelltype |
525 | } |
526 | }; |
527 | } |
c4e3c83b |
528 | return $shelltype; |
529 | } |
530 | |
0d6470a5 |
531 | 1; |
532 | __END__ |
275c9dae |
533 | |
898f36cf |
534 | =encoding utf8 |
535 | |
b5cc15f7 |
536 | =head1 NAME |
537 | |
538 | local::lib - create and use a local lib/ for perl modules with PERL5LIB |
539 | |
540 | =head1 SYNOPSIS |
541 | |
542 | In code - |
543 | |
544 | use local::lib; # sets up a local lib at ~/perl5 |
545 | |
546 | use local::lib '~/foo'; # same, but ~/foo |
547 | |
1bc71e56 |
548 | # Or... |
549 | use FindBin; |
550 | use local::lib "$FindBin::Bin/../support"; # app-local support library |
551 | |
b5cc15f7 |
552 | From the shell - |
553 | |
359329d3 |
554 | # Install LWP and its missing dependencies to the '~/perl5' directory |
555 | perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)' |
0fb70b9a |
556 | |
0fb70b9a |
557 | # Just print out useful shell commands |
b5cc15f7 |
558 | $ perl -Mlocal::lib |
e322149f |
559 | export PERL_MB_OPT='--install_base /home/username/perl5' |
c4e3c83b |
560 | export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5' |
0d6470a5 |
561 | export PERL5LIB="/home/username/perl5/lib/perl5" |
c4e3c83b |
562 | export PATH="/home/username/perl5/bin:$PATH" |
b5cc15f7 |
563 | |
322b0a0d |
564 | =head2 The bootstrapping technique |
bc30e1d5 |
565 | |
730f5dda |
566 | A typical way to install local::lib is using what is known as the |
567 | "bootstrapping" technique. You would do this if your system administrator |
568 | hasn't already installed local::lib. In this case, you'll need to install |
8522f4d5 |
569 | local::lib in your home directory. |
898f36cf |
570 | |
0ad9f83d |
571 | Even if you do have administrative privileges, you will still want to set up your |
898f36cf |
572 | environment variables, as discussed in step 4. Without this, you would still |
573 | install the modules into the system CPAN installation and also your Perl scripts |
574 | will not use the lib/ path you bootstrapped with local::lib. |
575 | |
04f8efde |
576 | By default local::lib installs itself and the CPAN modules into ~/perl5. |
577 | |
898f36cf |
578 | Windows users must also see L</Differences when using this module under Win32>. |
715c31a0 |
579 | |
730f5dda |
580 | 1. Download and unpack the local::lib tarball from CPAN (search for "Download" |
581 | on the CPAN page about local::lib). Do this as an ordinary user, not as root |
582 | or administrator. Unpack the file in your home directory or in any other |
583 | convenient location. |
715c31a0 |
584 | |
730f5dda |
585 | 2. Run this: |
715c31a0 |
586 | |
730f5dda |
587 | perl Makefile.PL --bootstrap |
715c31a0 |
588 | |
730f5dda |
589 | If the system asks you whether it should automatically configure as much |
590 | as possible, you would typically answer yes. |
591 | |
04f8efde |
592 | In order to install local::lib into a directory other than the default, you need |
593 | to specify the name of the directory when you call bootstrap, as follows: |
898f36cf |
594 | |
595 | perl Makefile.PL --bootstrap=~/foo |
596 | |
597 | 3. Run this: (local::lib assumes you have make installed on your system) |
730f5dda |
598 | |
599 | make test && make install |
600 | |
8522f4d5 |
601 | 4. Now we need to setup the appropriate environment variables, so that Perl |
898f36cf |
602 | starts using our newly generated lib/ directory. If you are using bash or |
603 | any other Bourne shells, you can add this to your shell startup script this |
604 | way: |
730f5dda |
605 | |
606 | echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc |
607 | |
608 | If you are using C shell, you can do this as follows: |
609 | |
610 | /bin/csh |
611 | echo $SHELL |
618272fe |
612 | /bin/csh |
730f5dda |
613 | perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc |
dc8ddd06 |
614 | |
0d6470a5 |
615 | If you passed to bootstrap a directory other than default, you also need to |
616 | give that as import parameter to the call of the local::lib module like this |
617 | way: |
8b1e8e69 |
618 | |
730f5dda |
619 | echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc |
618272fe |
620 | |
aab64481 |
621 | After writing your shell configuration file, be sure to re-read it to get the |
8522f4d5 |
622 | changed settings into your current shell's environment. Bourne shells use |
898f36cf |
623 | C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>. |
aab64481 |
624 | |
b9c94c15 |
625 | If you're on a slower machine, or are operating under draconian disk space |
626 | limitations, you can disable the automatic generation of manpages from POD when |
627 | installing modules by using the C<--no-manpages> argument when bootstrapping: |
628 | |
730f5dda |
629 | perl Makefile.PL --bootstrap --no-manpages |
b9c94c15 |
630 | |
8522f4d5 |
631 | To avoid doing several bootstrap for several Perl module environments on the |
632 | same account, for example if you use it for several different deployed |
633 | applications independently, you can use one bootstrapped local::lib |
898f36cf |
634 | installation to install modules in different directories directly this way: |
977a9ca3 |
635 | |
730f5dda |
636 | cd ~/mydir1 |
637 | perl -Mlocal::lib=./ |
638 | eval $(perl -Mlocal::lib=./) ### To set the environment for this shell alone |
898f36cf |
639 | printenv ### You will see that ~/mydir1 is in the PERL5LIB |
730f5dda |
640 | perl -MCPAN -e install ... ### whatever modules you want |
641 | cd ../mydir2 |
642 | ... REPEAT ... |
643 | |
480534a8 |
644 | If you are working with several C<local::lib> environments, you may want to |
645 | remove some of them from the current environment without disturbing the others. |
646 | You can deactivate one environment like this (using bourne sh): |
647 | |
648 | eval $(perl -Mlocal::lib=--deactivate,~/path) |
649 | |
650 | which will generate and run the commands needed to remove C<~/path> from your |
651 | various search paths. Whichever environment was B<activated most recently> will |
652 | remain the target for module installations. That is, if you activate |
653 | C<~/path_A> and then you activate C<~/path_B>, new modules you install will go |
654 | in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed |
655 | into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be |
656 | installed in C<~/pathB> because pathB was activated later. |
657 | |
658 | You can also ask C<local::lib> to clean itself completely out of the current |
659 | shell's environment with the C<--deactivate-all> option. |
730f5dda |
660 | For multiple environments for multiple apps you may need to include a modified |
661 | version of the C<< use FindBin >> instructions in the "In code" sample above. |
662 | If you did something like the above, you have a set of Perl modules at C<< |
663 | ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>, |
664 | you need to tell it where to find the modules you installed for it at C<< |
665 | ~/mydir1/lib >>. |
977a9ca3 |
666 | |
667 | In C<< ~/mydir1/scripts/myscript.pl >>: |
668 | |
730f5dda |
669 | use strict; |
670 | use warnings; |
671 | use local::lib "$FindBin::Bin/.."; ### points to ~/mydir1 and local::lib finds lib |
672 | use lib "$FindBin::Bin/../lib"; ### points to ~/mydir1/lib |
977a9ca3 |
673 | |
674 | Put this before any BEGIN { ... } blocks that require the modules you installed. |
675 | |
53699c99 |
676 | =head2 Differences when using this module under Win32 |
677 | |
76f30678 |
678 | To set up the proper environment variables for your current session of |
679 | C<CMD.exe>, you can use this: |
680 | |
730f5dda |
681 | C:\>perl -Mlocal::lib |
e322149f |
682 | set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5 |
730f5dda |
683 | set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5 |
0d6470a5 |
684 | set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5 |
730f5dda |
685 | set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH% |
8522f4d5 |
686 | |
898f36cf |
687 | ### To set the environment for this shell alone |
d4ccf2ea |
688 | C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat |
730f5dda |
689 | ### instead of $(perl -Mlocal::lib=./) |
53699c99 |
690 | |
691 | If you want the environment entries to persist, you'll need to add then to the |
76f30678 |
692 | Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>. |
53699c99 |
693 | |
694 | The "~" is translated to the user's profile directory (the directory named for |
695 | the user under "Documents and Settings" (Windows XP or earlier) or "Users" |
9bc0788f |
696 | (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home |
53699c99 |
697 | directory is translated to a short name (which means the directory must exist) |
698 | and the subdirectories are created. |
699 | |
730f5dda |
700 | =head1 RATIONALE |
701 | |
702 | The version of a Perl package on your machine is not always the version you |
703 | need. Obviously, the best thing to do would be to update to the version you |
704 | need. However, you might be in a situation where you're prevented from doing |
705 | this. Perhaps you don't have system administrator privileges; or perhaps you |
706 | are using a package management system such as Debian, and nobody has yet gotten |
707 | around to packaging up the version you need. |
708 | |
709 | local::lib solves this problem by allowing you to create your own directory of |
710 | Perl packages downloaded from CPAN (in a multi-user system, this would typically |
711 | be within your own home directory). The existing system Perl installation is |
712 | not affected; you simply invoke Perl with special options so that Perl uses the |
713 | packages in your own local package directory rather than the system packages. |
714 | local::lib arranges things so that your locally installed version of the Perl |
715 | packages takes precedence over the system installation. |
716 | |
717 | If you are using a package management system (such as Debian), you don't need to |
718 | worry about Debian and CPAN stepping on each other's toes. Your local version |
719 | of the packages will be written to an entirely separate directory from those |
8522f4d5 |
720 | installed by Debian. |
730f5dda |
721 | |
618272fe |
722 | =head1 DESCRIPTION |
723 | |
724 | This module provides a quick, convenient way of bootstrapping a user-local Perl |
725 | module library located within the user's home directory. It also constructs and |
726 | prints out for the user the list of environment variables using the syntax |
727 | appropriate for the user's current shell (as specified by the C<SHELL> |
730f5dda |
728 | environment variable), suitable for directly adding to one's shell |
729 | configuration file. |
730 | |
731 | More generally, local::lib allows for the bootstrapping and usage of a |
732 | directory containing Perl modules outside of Perl's C<@INC>. This makes it |
733 | easier to ship an application with an app-specific copy of a Perl module, or |
734 | collection of modules. Useful in cases like when an upstream maintainer hasn't |
735 | applied a patch to a module of theirs that you need for your application. |
1bc71e56 |
736 | |
737 | On import, local::lib sets the following environment variables to appropriate |
738 | values: |
739 | |
740 | =over 4 |
741 | |
e322149f |
742 | =item PERL_MB_OPT |
1bc71e56 |
743 | |
744 | =item PERL_MM_OPT |
745 | |
746 | =item PERL5LIB |
747 | |
748 | =item PATH |
749 | |
1bc71e56 |
750 | =back |
751 | |
0d6470a5 |
752 | When possible, these will be appended to instead of overwritten entirely. |
753 | |
1bc71e56 |
754 | These values are then available for reference by any code after import. |
755 | |
b0c48f8e |
756 | =head1 CREATING A SELF-CONTAINED SET OF MODULES |
757 | |
a949ebcd |
758 | See L<lib::core::only> for one way to do this - but note that |
d8b1a404 |
759 | there are a number of caveats, and the best approach is always to perform a |
760 | build against a clean perl (i.e. site and vendor as close to empty as possible). |
b0c48f8e |
761 | |
480534a8 |
762 | =head1 OPTIONS |
763 | |
764 | Options are values that can be passed to the C<local::lib> import besides the |
765 | directory to use. They are specified as C<use local::lib '--option'[, path];> |
766 | or C<perl -Mlocal::lib=--option[,path]>. |
767 | |
768 | =head2 --deactivate |
769 | |
770 | Remove the chosen path (or the default path) from the module search paths if it |
771 | was added by C<local::lib>, instead of adding it. |
772 | |
773 | =head2 --deactivate-all |
774 | |
775 | Remove all directories that were added to search paths by C<local::lib> from the |
776 | search paths. |
777 | |
480e6e85 |
778 | =head1 METHODS |
779 | |
a949ebcd |
780 | =head2 ensure_dir_structure_for |
480e6e85 |
781 | |
782 | =over 4 |
783 | |
a949ebcd |
784 | =item Arguments: $path |
785 | |
786 | =item Return value: None |
480e6e85 |
787 | |
788 | =back |
789 | |
790 | Attempts to create the given path, and all required parent directories. Throws |
791 | an exception on failure. |
792 | |
793 | =head2 print_environment_vars_for |
794 | |
795 | =over 4 |
796 | |
a949ebcd |
797 | =item Arguments: $path |
798 | |
799 | =item Return value: None |
480e6e85 |
800 | |
801 | =back |
802 | |
803 | Prints to standard output the variables listed above, properly set to use the |
804 | given path as the base directory. |
805 | |
a949ebcd |
806 | =head2 build_environment_vars_for |
807 | |
808 | =over 4 |
809 | |
810 | =item Arguments: $path, $interpolate |
811 | |
9f9da00a |
812 | =item Return value: %environment_vars |
a949ebcd |
813 | |
814 | =back |
815 | |
291b5a3a |
816 | Returns a hash with the variables listed above, properly set to use the |
817 | given path as the base directory. |
818 | |
480e6e85 |
819 | =head2 setup_env_hash_for |
820 | |
821 | =over 4 |
822 | |
a949ebcd |
823 | =item Arguments: $path |
824 | |
825 | =item Return value: None |
480e6e85 |
826 | |
827 | =back |
828 | |
829 | Constructs the C<%ENV> keys for the given path, by calling |
a949ebcd |
830 | L</build_environment_vars_for>. |
480e6e85 |
831 | |
5a63c13e |
832 | =head2 active_paths |
833 | |
834 | =over 4 |
835 | |
836 | =item Arguments: None |
837 | |
838 | =item Return value: @paths |
839 | |
840 | =back |
841 | |
842 | Returns a list of active C<local::lib> paths, according to the |
24351831 |
843 | C<PERL_LOCAL_LIB_ROOT> environment variable and verified against |
844 | what is really in C<@INC>. |
5a63c13e |
845 | |
480e6e85 |
846 | =head2 install_base_perl_path |
847 | |
848 | =over 4 |
849 | |
a949ebcd |
850 | =item Arguments: $path |
851 | |
852 | =item Return value: $install_base_perl_path |
480e6e85 |
853 | |
854 | =back |
855 | |
856 | Returns a path describing where to install the Perl modules for this local |
857 | library installation. Appends the directories C<lib> and C<perl5> to the given |
858 | path. |
859 | |
480e6e85 |
860 | =head2 install_base_bin_path |
861 | |
862 | =over 4 |
863 | |
a949ebcd |
864 | =item Arguments: $path |
865 | |
866 | =item Return value: $install_base_bin_path |
480e6e85 |
867 | |
868 | =back |
869 | |
870 | Returns a path describing where to install the executable programs for this |
9f9da00a |
871 | local library installation. Appends the directory C<bin> to the given path. |
480e6e85 |
872 | |
480e6e85 |
873 | =head2 resolve_empty_path |
874 | |
875 | =over 4 |
876 | |
a949ebcd |
877 | =item Arguments: $path |
878 | |
879 | =item Return value: $base_path |
480e6e85 |
880 | |
881 | =back |
882 | |
883 | Builds and returns the base path into which to set up the local module |
884 | installation. Defaults to C<~/perl5>. |
885 | |
886 | =head2 resolve_home_path |
887 | |
888 | =over 4 |
889 | |
a949ebcd |
890 | =item Arguments: $path |
891 | |
892 | =item Return value: $home_path |
480e6e85 |
893 | |
894 | =back |
895 | |
896 | Attempts to find the user's home directory. If installed, uses C<File::HomeDir> |
897 | for this purpose. If no definite answer is available, throws an exception. |
898 | |
899 | =head2 resolve_relative_path |
900 | |
901 | =over 4 |
902 | |
a949ebcd |
903 | =item Arguments: $path |
904 | |
905 | =item Return value: $absolute_path |
480e6e85 |
906 | |
907 | =back |
908 | |
909 | Translates the given path into an absolute path. |
910 | |
911 | =head2 resolve_path |
912 | |
913 | =over 4 |
914 | |
a949ebcd |
915 | =item Arguments: $path |
916 | |
917 | =item Return value: $absolute_path |
480e6e85 |
918 | |
919 | =back |
920 | |
921 | Calls the following in a pipeline, passing the result from the previous to the |
922 | next, in an attempt to find where to configure the environment for a local |
923 | library installation: L</resolve_empty_path>, L</resolve_home_path>, |
924 | L</resolve_relative_path>. Passes the given path argument to |
925 | L</resolve_empty_path> which then returns a result that is passed to |
926 | L</resolve_home_path>, which then has its result passed to |
927 | L</resolve_relative_path>. The result of this final call is returned from |
928 | L</resolve_path>. |
929 | |
0fb70b9a |
930 | =head1 A WARNING ABOUT UNINST=1 |
931 | |
932 | Be careful about using local::lib in combination with "make install UNINST=1". |
933 | The idea of this feature is that will uninstall an old version of a module |
934 | before installing a new one. However it lacks a safety check that the old |
935 | version and the new version will go in the same directory. Used in combination |
936 | with local::lib, you can potentially delete a globally accessible version of a |
381738d7 |
937 | module while installing the new version in a local place. Only combine "make |
0fb70b9a |
938 | install UNINST=1" and local::lib if you understand these possible consequences. |
939 | |
dc8ddd06 |
940 | =head1 LIMITATIONS |
941 | |
788ea146 |
942 | =over 4 |
943 | |
0d6470a5 |
944 | =item * Directory names with spaces in them are not well supported by the perl |
945 | toolchain and the programs it uses. Pure-perl distributions should support |
946 | spaces, but problems are more likely with dists that require compilation. A |
947 | workaround you can do is moving your local::lib to a directory with spaces |
948 | B<after> you installed all modules inside your local::lib bootstrap. But be |
949 | aware that you can't update or install CPAN modules after the move. |
47e70ca1 |
950 | |
788ea146 |
951 | =item * Rather basic shell detection. Right now anything with csh in its name is |
618272fe |
952 | assumed to be a C shell or something compatible, and everything else is assumed |
53699c99 |
953 | to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is |
954 | not set, a Bourne-compatible shell is assumed. |
dc8ddd06 |
955 | |
0d6470a5 |
956 | =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT. |
dc8ddd06 |
957 | |
788ea146 |
958 | =item * Should probably auto-fixup CPAN config if not already done. |
959 | |
960 | =back |
e423efce |
961 | |
dc8ddd06 |
962 | Patches very much welcome for any of the above. |
bc30e1d5 |
963 | |
788ea146 |
964 | =over 4 |
965 | |
0d6470a5 |
966 | =item * On Win32 systems, does not have a way to write the created environment |
967 | variables to the registry, so that they can persist through a reboot. |
53699c99 |
968 | |
788ea146 |
969 | =back |
970 | |
9a021b2b |
971 | =head1 TROUBLESHOOTING |
972 | |
973 | If you've configured local::lib to install CPAN modules somewhere in to your |
974 | home directory, and at some point later you try to install a module with C<cpan |
975 | -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have |
976 | permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at |
977 | /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an |
978 | error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then |
979 | you've somehow lost your updated ExtUtils::MakeMaker module. |
980 | |
981 | To remedy this situation, rerun the bootstrapping procedure documented above. |
982 | |
983 | Then, run C<rm -r ~/.cpan/build/Foo-Bar*> |
984 | |
985 | Finally, re-run C<cpan -i Foo::Bar> and it should install without problems. |
986 | |
618272fe |
987 | =head1 ENVIRONMENT |
988 | |
989 | =over 4 |
990 | |
991 | =item SHELL |
992 | |
53699c99 |
993 | =item COMSPEC |
994 | |
618272fe |
995 | local::lib looks at the user's C<SHELL> environment variable when printing out |
996 | commands to add to the shell configuration file. |
997 | |
53699c99 |
998 | On Win32 systems, C<COMSPEC> is also examined. |
999 | |
618272fe |
1000 | =back |
1001 | |
163f162c |
1002 | =head1 SEE ALSO |
1003 | |
1004 | =over 4 |
1005 | |
1006 | =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html> |
1007 | |
1008 | =back |
1009 | |
cc19e8d4 |
1010 | =head1 SUPPORT |
1011 | |
1012 | IRC: |
1013 | |
1014 | Join #local-lib on irc.perl.org. |
1015 | |
b5cc15f7 |
1016 | =head1 AUTHOR |
1017 | |
1018 | Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/ |
1019 | |
d6b71a2d |
1020 | auto_install fixes kindly sponsored by http://www.takkle.com/ |
1021 | |
b5c1154d |
1022 | =head1 CONTRIBUTORS |
1023 | |
1024 | Patches to correctly output commands for csh style shells, as well as some |
1025 | documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>. |
1026 | |
cc19e8d4 |
1027 | Doc patches for a custom local::lib directory, more cleanups in the english |
0d6470a5 |
1028 | documentation and a L<german documentation|POD2::DE::local::lib> contributed by |
1029 | Torsten Raudssus <torsten@raudssus.de>. |
8b1e8e69 |
1030 | |
be160790 |
1031 | Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring |
9a021b2b |
1032 | things will install properly, submitted a fix for the bug causing problems with |
1033 | writing Makefiles during bootstrapping, contributed an example program, and |
1034 | submitted yet another fix to ensure that local::lib can install and bootstrap |
1035 | properly. Many, many thanks! |
1036 | |
1037 | pattern of Freenode IRC contributed the beginnings of the Troubleshooting |
1038 | section. Many thanks! |
be160790 |
1039 | |
53699c99 |
1040 | Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>. |
1041 | |
03b91976 |
1042 | Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced |
1043 | by a patch from Marco Emilio Poleggi. |
1044 | |
1f8043c8 |
1045 | Mark Stosberg <mark@summersault.com> provided the code for the now deleted |
1046 | '--self-contained' option. |
1047 | |
76f30678 |
1048 | Documentation patches to make win32 usage clearer by |
1049 | David Mertens <dcmertens.perl@gmail.com> (run4flat). |
1050 | |
0d6470a5 |
1051 | Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc |
1052 | patches contributed by Breno G. de Oliveira <garu@cpan.org>. |
ccf362c0 |
1053 | |
a0b3d98a |
1054 | Improvements to stacking multiple local::lib dirs and removing them from the |
1055 | environment later on contributed by Andrew Rodland <arodland@cpan.org>. |
1056 | |
0d6470a5 |
1057 | Patch for Carp version mismatch contributed by Hakim Cassimally |
1058 | <osfameron@cpan.org>. |
cd3eb741 |
1059 | |
7c0db165 |
1060 | =head1 COPYRIGHT |
1061 | |
cc19e8d4 |
1062 | Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as |
7c0db165 |
1063 | listed above. |
1064 | |
b5cc15f7 |
1065 | =head1 LICENSE |
1066 | |
73c9a8ad |
1067 | This is free software; you can redistribute it and/or modify it under |
1068 | the same terms as the Perl 5 programming language system itself. |
b5cc15f7 |
1069 | |
1070 | =cut |