lib/Safe/Isa.pm

   1 package Safe::Isa;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5 use Scalar::Util qw(blessed);
   6 use Exporter 5.57 qw(import);
   7
   8 our $VERSION = '1.000006';
   9
  10 our @EXPORT = qw($_call_if_object $_isa $_can $_does $_DOES);
  11
  12 our $_call_if_object = sub {
  13   my ($obj, $method) = (shift, shift);
  14   # This is intentionally a truth test, not a defined test, otherwise
  15   # we gratuitously break modules like Scalar::Defer, which would be
  16   # un-perlish.
  17   return unless blessed($obj);
  18   return $obj->isa(@_) if lc($method) eq 'does' and not $obj->can($method);
  19   return $obj->$method(@_);
  20 };
  21
  22 our ($_isa, $_can, $_does, $_DOES) = map {
  23   my $method = $_;
  24   sub { my $obj = shift; $obj->$_call_if_object($method => @_) }
  25 } qw(isa can does DOES);
  26
  27 1;
  28 __END__
  29
  30 =pod
  31
  32 =head1 NAME
  33
  34 Safe::Isa - Call isa, can, does and DOES safely on things that may not be objects
  35
  36 =head1 SYNOPSIS
  37
  38   use strict;
  39   use warnings;
  40
  41   { package Foo; sub new { bless({}, $_[0]) } }
  42   { package Bar; our @ISA = qw(Foo); sub bar { 1 } }
  43
  44   my $foo = Foo->new;
  45   my $bar = Bar->new;
  46   my $blam = [ 42 ];
  47
  48   # basic isa usage -
  49
  50   $foo->isa('Foo');  # true
  51   $bar->isa('Foo');  # true
  52   $blam->isa('Foo'); # BOOM
  53
  54   $foo->can('bar');  # false
  55   $bar->can('bar');  # true
  56   $blam->can('bar'); # BOOM
  57
  58   # Safe::Isa usage -
  59
  60   use Safe::Isa;
  61
  62   $foo->$_isa('Foo');  # true
  63   $bar->$_isa('Foo');  # true
  64   $blam->$_isa('Foo'); # false, no boom today
  65
  66   $foo->$_can('bar');  # false
  67   $bar->$_can('bar');  # true
  68   $blam->$_can('bar'); # false, no boom today
  69
  70 Similarly:
  71
  72   $maybe_an_object->$_does('RoleName'); # true or false, no boom today
  73   $maybe_an_object->$_DOES('RoleName'); # true or false, no boom today
  74
  75 And just in case we missed a method:
  76
  77   $maybe_an_object->$_call_if_object(name => @args);
  78
  79 Or to re-use a previous example for purposes of explication:
  80
  81   $foo->$_call_if_object(isa => 'Foo');  # true
  82   $bar->$_call_if_object(isa => 'Foo');  # true
  83   $blam->$_call_if_object(isa => 'Foo'); # false, no boom today
  84
  85 =head1 DESCRIPTION
  86
  87 How many times have you found yourself writing:
  88
  89   if ($obj->isa('Something')) {
  90
  91 and then shortly afterwards cursing and changing it to:
  92
  93   if (Scalar::Util::blessed($obj) and $obj->isa('Something')) {
  94
  95 Right. That's why this module exists.
  96
  97 Since perl allows us to provide a subroutine reference or a method name to
  98 the -> operator when used as a method call, and a subroutine doesn't require
  99 the invocant to actually be an object, we can create safe versions of isa,
 100 can and friends by using a subroutine reference that only tries to call the
 101 method if it's used on an object. So:
 102
 103   my $isa_Foo = $maybe_an_object->$_call_if_object(isa => 'Foo');
 104
 105 is equivalent to
 106
 107   my $isa_Foo = do {
 108     if (Scalar::Util::blessed($maybe_an_object)) {
 109       $maybe_an_object->isa('Foo');
 110     } else {
 111       undef;
 112     }
 113   };
 114
 115 Note that we don't handle trying class names, because many things are valid
 116 class names that you might not want to treat as one (like say "Matt") - the
 117 C<is_module_name> function from L<Module::Runtime> is a good way to check for
 118 something you might be able to call methods on if you want to do that.
 119
 120 =head1 EXPORTS
 121
 122 =head2 $_isa
 123
 124   $maybe_an_object->$_isa('Foo');
 125
 126 If called on an object, calls C<isa> on it and returns the result, otherwise
 127 returns nothing.
 128
 129 =head2 $_can
 130
 131   $maybe_an_object->$_can('Foo');
 132
 133 If called on an object, calls C<can> on it and returns the result, otherwise
 134 returns nothing.
 135
 136 =head2 $_does
 137
 138   $maybe_an_object->$_does('Foo');
 139
 140 If called on an object, calls C<does> on it and returns the result, otherwise
 141 returns nothing.
 142
 143 =head2 $_DOES
 144
 145   $maybe_an_object->$_DOES('Foo');
 146
 147 If called on an object, calls C<DOES> on it and returns the result, otherwise
 148 returns nothing.
 149
 150 =head2 $_call_if_object
 151
 152   $maybe_an_object->$_call_if_object(method_name => @args);
 153
 154 If called on an object, calls C<method_name> on it and returns the result,
 155 otherwise returns nothing.
 156
 157 =head1 SEE ALSO
 158
 159 I gave a lightning talk on this module (and L<curry> and L<Import::Into>) at
 160 L<YAPC::NA 2013|https://www.youtube.com/watch?v=wFXWV2yY7gE&t=46m05s>.
 161
 162 =head1 AUTHOR
 163
 164 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 165
 166 =head1 CONTRIBUTORS
 167
 168 None yet. Well volunteered? :)
 169
 170 =head1 COPYRIGHT
 171
 172 Copyright (c) 2012 the Safe::Isa L</AUTHOR> and L</CONTRIBUTORS>
 173 as listed above.
 174
 175 =head1 LICENSE
 176
 177 This library is free software and may be distributed under the same terms
 178 as perl itself.
 179
 180 =cut