t/metadata.t

   1 #!/usr/bin/perl -w
   2 # -*- mode: cperl; tab-width: 8; indent-tabs-mode: nil; basic-offset: 2 -*-
   3 # vim:ts=8:sw=2:et:sta:sts=2
   4
   5 use strict;
   6 use warnings;
   7 use lib 't/lib';
   8 use Test::More;
   9 use IO::File;
  10 use MBTest;
  11
  12 my $undef;
  13
  14 # parse various module $VERSION lines
  15 # format: expected version => code snippet
  16 my @modules = (
  17   $undef => <<'---', # no $VERSION line
  18 package Simple;
  19 ---
  20   $undef => <<'---', # undefined $VERSION
  21 package Simple;
  22 our $VERSION;
  23 ---
  24   '1.23' => <<'---', # declared & defined on same line with 'our'
  25 package Simple;
  26 our $VERSION = '1.23';
  27 ---
  28   '1.23' => <<'---', # declared & defined on separate lines with 'our'
  29 package Simple;
  30 our $VERSION;
  31 $VERSION = '1.23';
  32 ---
  33   '1.23' => <<'---', # commented & defined on same line
  34 package Simple;
  35 our $VERSION = '1.23'; # our $VERSION = '4.56';
  36 ---
  37   '1.23' => <<'---', # commented & defined on separate lines
  38 package Simple;
  39 # our $VERSION = '4.56';
  40 our $VERSION = '1.23';
  41 ---
  42   '1.23' => <<'---', # use vars
  43 package Simple;
  44 use vars qw( $VERSION );
  45 $VERSION = '1.23';
  46 ---
  47   '1.23' => <<'---', # choose the right default package based on package/file name
  48 package Simple::_private;
  49 $VERSION = '0';
  50 package Simple;
  51 $VERSION = '1.23'; # this should be chosen for version
  52 ---
  53   '1.23' => <<'---', # just read the first $VERSION line
  54 package Simple;
  55 $VERSION = '1.23'; # we should see this line
  56 $VERSION = eval $VERSION; # and ignore this one
  57 ---
  58   '1.23' => <<'---', # just read the first $VERSION line in reopened package (1)
  59 package Simple;
  60 $VERSION = '1.23';
  61 package Error::Simple;
  62 $VERSION = '2.34';
  63 package Simple;
  64 ---
  65   '1.23' => <<'---', # just read the first $VERSION line in reopened package (2)
  66 package Simple;
  67 package Error::Simple;
  68 $VERSION = '2.34';
  69 package Simple;
  70 $VERSION = '1.23';
  71 ---
  72   '1.23' => <<'---', # mentions another module's $VERSION
  73 package Simple;
  74 $VERSION = '1.23';
  75 if ( $Other::VERSION ) {
  76     # whatever
  77 }
  78 ---
  79   '1.23' => <<'---', # mentions another module's $VERSION in a different package
  80 package Simple;
  81 $VERSION = '1.23';
  82 package Simple2;
  83 if ( $Simple::VERSION ) {
  84     # whatever
  85 }
  86 ---
  87   '1.23' => <<'---', # $VERSION checked only in assignments, not regexp ops
  88 package Simple;
  89 $VERSION = '1.23';
  90 if ( $VERSION =~ /1\.23/ ) {
  91     # whatever
  92 }
  93 ---
  94   '1.23' => <<'---', # $VERSION checked only in assignments, not relational ops
  95 package Simple;
  96 $VERSION = '1.23';
  97 if ( $VERSION == 3.45 ) {
  98     # whatever
  99 }
 100 ---
 101   '1.23' => <<'---', # $VERSION checked only in assignments, not relational ops
 102 package Simple;
 103 $VERSION = '1.23';
 104 package Simple2;
 105 if ( $Simple::VERSION == 3.45 ) {
 106     # whatever
 107 }
 108 ---
 109   '1.23' => <<'---', # Fully qualified $VERSION declared in package
 110 package Simple;
 111 $Simple::VERSION = 1.23;
 112 ---
 113   '1.23' => <<'---', # Differentiate fully qualified $VERSION in a package
 114 package Simple;
 115 $Simple2::VERSION = '999';
 116 $Simple::VERSION = 1.23;
 117 ---
 118   '1.23' => <<'---', # Differentiate fully qualified $VERSION and unqualified
 119 package Simple;
 120 $Simple2::VERSION = '999';
 121 $VERSION = 1.23;
 122 ---
 123   '1.23' => <<'---', # $VERSION declared as package variable from within 'main' package
 124 $Simple::VERSION = '1.23';
 125 {
 126   package Simple;
 127   $x = $y, $cats = $dogs;
 128 }
 129 ---
 130   '1.23' => <<'---', # $VERSION wrapped in parens - space inside
 131 package Simple;
 132 ( $VERSION ) = '1.23';
 133 ---
 134   '1.23' => <<'---', # $VERSION wrapped in parens - no space inside
 135 package Simple;
 136 ($VERSION) = '1.23';
 137 ---
 138   '1.23' => <<'---', # $VERSION follows a spurious 'package' in a quoted construct
 139 package Simple;
 140 __PACKAGE__->mk_accessors(qw(
 141     program socket proc
 142     package filename line codeline subroutine finished));
 143
 144 our $VERSION = "1.23";
 145 ---
 146   '1.23' => <<'---', # $VERSION using version.pm
 147   package Simple;
 148   use version; our $VERSION = version->new('1.23');
 149 ---
 150   '1.23' => <<'---', # $VERSION using version.pm and qv()
 151   package Simple;
 152   use version; our $VERSION = qv('1.230');
 153 ---
 154   '1.23' => <<'---', # Two version assignments, should ignore second one
 155   $Simple::VERSION = '1.230';
 156   $Simple::VERSION = eval $Simple::VERSION;
 157 ---
 158   '1.23' => <<'---', # declared & defined on same line with 'our'
 159 package Simple;
 160 our $VERSION = '1.23_00_00';
 161 ---
 162   '1.23' => <<'---', # package NAME VERSION
 163   package Simple 1.23;
 164 ---
 165   '1.23_01' => <<'---', # package NAME VERSION
 166   package Simple 1.23_01;
 167 ---
 168   'v1.2.3' => <<'---', # package NAME VERSION
 169   package Simple v1.2.3;
 170 ---
 171   'v1.2_3' => <<'---', # package NAME VERSION
 172   package Simple v1.2_3;
 173 ---
 174   '1.23' => <<'---', # trailing crud
 175   package Simple;
 176   our $VERSION;
 177   $VERSION = '1.23-alpha';
 178 ---
 179   '1.23' => <<'---', # trailing crud
 180   package Simple;
 181   our $VERSION;
 182   $VERSION = '1.23b';
 183 ---
 184   '1.234' => <<'---', # multi_underscore
 185   package Simple;
 186   our $VERSION;
 187   $VERSION = '1.2_3_4';
 188 ---
 189   '0' => <<'---', # non-numeric
 190   package Simple;
 191   our $VERSION;
 192   $VERSION = 'onetwothree';
 193 ---
 194   $undef => <<'---', # package NAME BLOCK, undef $VERSION
 195 package Simple {
 196   our $VERSION;
 197 }
 198 ---
 199   '1.23' => <<'---', # package NAME BLOCK, with $VERSION
 200 package Simple {
 201   our $VERSION = '1.23';
 202 }
 203 ---
 204   '1.23' => <<'---', # package NAME VERSION BLOCK
 205 package Simple 1.23 {
 206   1;
 207 }
 208 ---
 209   'v1.2.3_4' => <<'---', # package NAME VERSION BLOCK
 210 package Simple v1.2.3_4 {
 211   1;
 212 }
 213 ---
 214   '0' => <<'---', # set from separately-initialised variable
 215 package Simple;
 216   our $CVSVERSION   = '$Revision: 1.7 $';
 217   our ($VERSION)    = ($CVSVERSION =~ /(\d+\.\d+)/);
 218 }
 219 ---
 220 );
 221
 222 # format: expected package name => code snippet
 223 my @pkg_names = (
 224   [ 'Simple' ] => <<'---', # package NAME
 225 package Simple;
 226 ---
 227   [ 'Simple::Edward' ] => <<'---', # package NAME::SUBNAME
 228 package Simple::Edward;
 229 ---
 230   [ 'Simple::Edward::' ] => <<'---', # package NAME::SUBNAME::
 231 package Simple::Edward::;
 232 ---
 233   [ "Simple'Edward" ] => <<'---', # package NAME'SUBNAME
 234 package Simple'Edward;
 235 ---
 236   [ "Simple'Edward::" ] => <<'---', # package NAME'SUBNAME::
 237 package Simple'Edward::;
 238 ---
 239   [ 'Simple::::Edward' ] => <<'---', # package NAME::::SUBNAME
 240 package Simple::::Edward;
 241 ---
 242   [ '::Simple::Edward' ] => <<'---', # package ::NAME::SUBNAME
 243 package ::Simple::Edward;
 244 ---
 245   [ 'main' ] => <<'---', # package NAME:SUBNAME (fail)
 246 package Simple:Edward;
 247 ---
 248   [ 'main' ] => <<'---', # package NAME' (fail)
 249 package Simple';
 250 ---
 251   [ 'main' ] => <<'---', # package NAME::SUBNAME' (fail)
 252 package Simple::Edward';
 253 ---
 254   [ 'main' ] => <<'---', # package NAME''SUBNAME (fail)
 255 package Simple''Edward;
 256 ---
 257   [ 'main' ] => <<'---', # package NAME-SUBNAME (fail)
 258 package Simple-Edward;
 259 ---
 260 );
 261
 262 # 2 tests per each pair of @modules, @pkg_names entry
 263 plan tests => 63 + ( @modules ) + ( @pkg_names );
 264
 265 require_ok('Module::Metadata');
 266
 267 {
 268     # class method C<find_module_by_name>
 269     my $module = Module::Metadata->find_module_by_name(
 270                    'Module::Metadata' );
 271     ok( -e $module, 'find_module_by_name() succeeds' );
 272 }
 273
 274 #########################
 275
 276 my $tmp = MBTest->tmpdir;
 277
 278 use DistGen;
 279 my $dist = DistGen->new( dir => $tmp );
 280 $dist->regen;
 281
 282 $dist->chdir_in;
 283
 284 {
 285   # fail on invalid module name
 286   my $pm_info = Module::Metadata->new_from_module(
 287                   'Foo::Bar', inc => [] );
 288   ok( !defined( $pm_info ), 'fail if can\'t find module by module name' );
 289 }
 290
 291 {
 292   # fail on invalid filename
 293   my $file = File::Spec->catfile( 'Foo', 'Bar.pm' );
 294   my $pm_info = Module::Metadata->new_from_file( $file, inc => [] );
 295   ok( !defined( $pm_info ), 'fail if can\'t find module by file name' );
 296 }
 297
 298 {
 299   # construct from module filename
 300   my $file = File::Spec->catfile( 'lib', split( /::/, $dist->name ) ) . '.pm';
 301   my $pm_info = Module::Metadata->new_from_file( $file );
 302   ok( defined( $pm_info ), 'new_from_file() succeeds' );
 303
 304   # construct from filehandle
 305   my $handle = IO::File->new($file);
 306   $pm_info = Module::Metadata->new_from_handle( $handle, $file );
 307   ok( defined( $pm_info ), 'new_from_handle() succeeds' );
 308   $pm_info = Module::Metadata->new_from_handle( $handle );
 309   is( $pm_info, undef, "new_from_handle() without filename returns undef" );
 310   close($handle);
 311 }
 312
 313 {
 314   # construct from module name, using custom include path
 315   my $pm_info = Module::Metadata->new_from_module(
 316                $dist->name, inc => [ 'lib', @INC ] );
 317   ok( defined( $pm_info ), 'new_from_module() succeeds' );
 318 }
 319
 320
 321 # iterate through @modules pairwise
 322 my $test_case = 0;
 323 while (++$test_case and my ($expected_version, $code) = splice @modules, 0, 2 ) {
 324  SKIP: {
 325     skip( "No our() support until perl 5.6", 2 )
 326         if $] < 5.006 && $code =~ /\bour\b/;
 327     skip( "No package NAME VERSION support until perl 5.11.1", 2 )
 328         if $] < 5.011001 && $code =~ /package\s+[\w\:\']+\s+v?[0-9._]+/;
 329
 330     $dist->change_file( 'lib/Simple.pm', $code );
 331     $dist->regen;
 332
 333     my $warnings = '';
 334     local $SIG{__WARN__} = sub { $warnings .= $_ for @_ };
 335     my $file = File::Spec->catfile( 'lib', split( /::/, $dist->name ) ) . '.pm';
 336     my $pm_info = Module::Metadata->new_from_file( $file );
 337
 338     # Test::Builder will prematurely numify objects, so use this form
 339     my $errs;
 340     my $got = $pm_info->version;
 341
 342     is(
 343       $got,
 344       $expected_version,
 345       "case $test_case: correct module version ("
 346         . (defined $expected_version? "'$expected_version'" : 'undef')
 347         . ')'
 348     )
 349     or $errs++;
 350
 351     is( $warnings, '', "case $test_case: no warnings from parsing" ) or $errs++;
 352     diag "Got: '$got'\nModule contents:\n$code" if $errs;
 353   }
 354 }
 355
 356 # revert to pristine state
 357 $dist->regen( clean => 1 );
 358
 359 $test_case = 0;
 360 while (++$test_case and my ($expected_name, $code) = splice @pkg_names, 0, 2) {
 361     $dist->change_file( 'lib/Simple.pm', $code);
 362     $dist->regen;
 363
 364     my $warnings = '';
 365     local $SIG{__WARN__} = sub { $warnings .= $_ for @_ };
 366     my $file = File::Spec->catfile( 'lib', split( /::/, $dist->name ) ) . '.pm';
 367     my $pm_info = Module::Metadata->new_from_file( $file );
 368
 369     # Test::Builder will prematurely numify objects, so use this form
 370     my $errs;
 371     my @got = $pm_info->packages_inside();
 372     is_deeply( \@got, $expected_name,
 373                "case $test_case: correct package names (expected '" . join(', ', @$expected_name) . "')" )
 374             or $errs++;
 375     is( $warnings, '', "case $test_case: no warnings from parsing" ) or $errs++;
 376     diag "Got: '" . join(', ', @got) . "'\nModule contents:\n$code" if $errs;
 377 }
 378
 379 # revert to pristine state
 380 $dist->regen( clean => 1 );
 381
 382 {
 383   # Find each package only once
 384   $dist->change_file( 'lib/Simple.pm', <<'---' );
 385 package Simple;
 386 $VERSION = '1.23';
 387 package Error::Simple;
 388 $VERSION = '2.34';
 389 package Simple;
 390 ---
 391
 392   $dist->regen;
 393
 394   my $file = File::Spec->catfile( 'lib', split( /::/, $dist->name ) ) . '.pm';
 395   my $pm_info = Module::Metadata->new_from_file( $file );
 396
 397   my @packages = $pm_info->packages_inside;
 398   is( @packages, 2, 'record only one occurence of each package' );
 399 }
 400
 401 {
 402   # Module 'Simple.pm' does not contain package 'Simple';
 403   # constructor should not complain, no default module name or version
 404   $dist->change_file( 'lib/Simple.pm', <<'---' );
 405 package Simple::Not;
 406 $VERSION = '1.23';
 407 ---
 408
 409   $dist->regen;
 410   my $file = File::Spec->catfile( 'lib', split( /::/, $dist->name ) ) . '.pm';
 411   my $pm_info = Module::Metadata->new_from_file( $file );
 412
 413   is( $pm_info->name, undef, 'no default package' );
 414   is( $pm_info->version, undef, 'no version w/o default package' );
 415 }
 416
 417 {
 418   # Module 'Simple.pm' contains an alpha version
 419   # constructor should report first $VERSION found
 420   $dist->change_file( 'lib/Simple.pm', <<'---' );
 421 package Simple;
 422 $VERSION = '1.23_01';
 423 $VERSION = eval $VERSION;
 424 ---
 425
 426   $dist->regen;
 427   my $file = File::Spec->catfile( 'lib', split( /::/, $dist->name ) ) . '.pm';
 428   my $pm_info = Module::Metadata->new_from_file( $file );
 429
 430   is( $pm_info->version, '1.23_01', 'alpha version reported');
 431
 432   # NOTE the following test has be done this way because Test::Builder is
 433   # too smart for our own good and tries to see if the version object is a
 434   # dual-var, which breaks with alpha versions:
 435   #    Argument "1.23_0100" isn't numeric in addition (+) at
 436   #    /usr/lib/perl5/5.8.7/Test/Builder.pm line 505.
 437
 438   ok( $pm_info->version > 1.23, 'alpha version greater than non');
 439 }
 440
 441 # revert to pristine state
 442 $dist->regen( clean => 1 );
 443
 444 # parse $VERSION lines scripts for package main
 445 my @scripts = (
 446   <<'---', # package main declared
 447 #!perl -w
 448 package main;
 449 $VERSION = '0.01';
 450 ---
 451   <<'---', # on first non-comment line, non declared package main
 452 #!perl -w
 453 $VERSION = '0.01';
 454 ---
 455   <<'---', # after non-comment line
 456 #!perl -w
 457 use strict;
 458 $VERSION = '0.01';
 459 ---
 460   <<'---', # 1st declared package
 461 #!perl -w
 462 package main;
 463 $VERSION = '0.01';
 464 package _private;
 465 $VERSION = '999';
 466 ---
 467   <<'---', # 2nd declared package
 468 #!perl -w
 469 package _private;
 470 $VERSION = '999';
 471 package main;
 472 $VERSION = '0.01';
 473 ---
 474   <<'---', # split package
 475 #!perl -w
 476 package main;
 477 package _private;
 478 $VERSION = '999';
 479 package main;
 480 $VERSION = '0.01';
 481 ---
 482   <<'---', # define 'main' version from other package
 483 package _private;
 484 $::VERSION = 0.01;
 485 $VERSION = '999';
 486 ---
 487   <<'---', # define 'main' version from other package
 488 package _private;
 489 $VERSION = '999';
 490 $::VERSION = 0.01;
 491 ---
 492 );
 493
 494 my ( $i, $n ) = ( 1, scalar( @scripts ) );
 495 foreach my $script ( @scripts ) {
 496   $dist->change_file( 'bin/simple.plx', $script );
 497   $dist->regen;
 498   my $pm_info = Module::Metadata->new_from_file(
 499                File::Spec->catfile( 'bin', 'simple.plx' ) );
 500
 501   is( $pm_info->version, '0.01', "correct script version ($i of $n)" );
 502   $i++;
 503 }
 504
 505 {
 506   # examine properties of a module: name, pod, etc
 507   $dist->change_file( 'lib/Simple.pm', <<'---' );
 508 package Simple;
 509 $VERSION = '0.01';
 510 package Simple::Ex;
 511 $VERSION = '0.02';
 512
 513 =head1 NAME
 514
 515 Simple - It's easy.
 516
 517 =head1 AUTHOR
 518
 519 Simple Simon
 520
 521 You can find me on the IRC channel
 522 #simon on irc.perl.org.
 523
 524 =cut
 525 ---
 526   $dist->regen;
 527
 528   my $pm_info = Module::Metadata->new_from_module(
 529              $dist->name, inc => [ 'lib', @INC ] );
 530
 531   is( $pm_info->name, 'Simple', 'found default package' );
 532   is( $pm_info->version, '0.01', 'version for default package' );
 533
 534   # got correct version for secondary package
 535   is( $pm_info->version( 'Simple::Ex' ), '0.02',
 536       'version for secondary package' );
 537
 538   my $filename = $pm_info->filename;
 539   ok( defined( $filename ) && -e $filename,
 540       'filename() returns valid path to module file' );
 541
 542   my @packages = $pm_info->packages_inside;
 543   is( @packages, 2, 'found correct number of packages' );
 544   is( $packages[0], 'Simple', 'packages stored in order found' );
 545
 546   # we can detect presence of pod regardless of whether we are collecting it
 547   ok( $pm_info->contains_pod, 'contains_pod() succeeds' );
 548
 549   my @pod = $pm_info->pod_inside;
 550   is_deeply( \@pod, [qw(NAME AUTHOR)], 'found all pod sections' );
 551
 552   is( $pm_info->pod('NONE') , undef,
 553       'return undef() if pod section not present' );
 554
 555   is( $pm_info->pod('NAME'), undef,
 556       'return undef() if pod section not collected' );
 557
 558
 559   # collect_pod
 560   $pm_info = Module::Metadata->new_from_module(
 561                $dist->name, inc => [ 'lib', @INC ], collect_pod => 1 );
 562
 563   my %pod;
 564   for my $section (qw(NAME AUTHOR)) {
 565     my $content = $pm_info->pod( $section );
 566     if ( $content ) {
 567       $content =~ s/^\s+//;
 568       $content =~ s/\s+$//;
 569     }
 570     $pod{$section} = $content;
 571   }
 572   my %expected = (
 573     NAME   => q|Simple - It's easy.|,
 574     AUTHOR => <<'EXPECTED'
 575 Simple Simon
 576
 577 You can find me on the IRC channel
 578 #simon on irc.perl.org.
 579 EXPECTED
 580   );
 581   for my $text (values %expected) {
 582     $text =~ s/^\s+//;
 583     $text =~ s/\s+$//;
 584   }
 585   is( $pod{NAME},   $expected{NAME},   'collected NAME pod section' );
 586   is( $pod{AUTHOR}, $expected{AUTHOR}, 'collected AUTHOR pod section' );
 587 }
 588
 589 {
 590   # test things that look like POD, but aren't
 591 $dist->change_file( 'lib/Simple.pm', <<'---' );
 592 package Simple;
 593
 594 =YES THIS STARTS POD
 595
 596 our $VERSION = '999';
 597
 598 =cute
 599
 600 our $VERSION = '666';
 601
 602 =cut
 603
 604 *foo
 605 =*no_this_does_not_start_pod;
 606
 607 our $VERSION = '1.23';
 608
 609 ---
 610   $dist->regen;
 611   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
 612   is( $pm_info->name, 'Simple', 'found default package' );
 613   is( $pm_info->version, '1.23', 'version for default package' );
 614 }
 615
 616 {
 617   # Make sure processing stops after __DATA__
 618   $dist->change_file( 'lib/Simple.pm', <<'---' );
 619 package Simple;
 620 $VERSION = '0.01';
 621 __DATA__
 622 *UNIVERSAL::VERSION = sub {
 623   foo();
 624 };
 625 ---
 626   $dist->regen;
 627
 628   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
 629   is( $pm_info->name, 'Simple', 'found default package' );
 630   is( $pm_info->version, '0.01', 'version for default package' );
 631   my @packages = $pm_info->packages_inside;
 632   is_deeply(\@packages, ['Simple'], 'packages inside');
 633 }
 634
 635 {
 636   # Make sure we handle version.pm $VERSIONs well
 637   $dist->change_file( 'lib/Simple.pm', <<'---' );
 638 package Simple;
 639 $VERSION = version->new('0.60.' . (qw$Revision: 128 $)[1]);
 640 package Simple::Simon;
 641 $VERSION = version->new('0.61.' . (qw$Revision: 129 $)[1]);
 642 ---
 643   $dist->regen;
 644
 645   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
 646   is( $pm_info->name, 'Simple', 'found default package' );
 647   is( $pm_info->version, '0.60.128', 'version for default package' );
 648   my @packages = $pm_info->packages_inside;
 649   is_deeply([sort @packages], ['Simple', 'Simple::Simon'], 'packages inside');
 650   is( $pm_info->version('Simple::Simon'), '0.61.129', 'version for embedded package' );
 651 }
 652
 653 # check that package_versions_from_directory works
 654
 655 {
 656   $dist->change_file( 'lib/Simple.pm', <<'---' );
 657 package Simple;
 658 $VERSION = '0.01';
 659 package Simple::Ex;
 660 $VERSION = '0.02';
 661 {
 662   package main; # should ignore this
 663 }
 664 {
 665   package DB; # should ignore this
 666 }
 667 {
 668   package Simple::_private; # should ignore this
 669 }
 670
 671 =head1 NAME
 672
 673 Simple - It's easy.
 674
 675 =head1 AUTHOR
 676
 677 Simple Simon
 678
 679 =cut
 680 ---
 681   $dist->regen;
 682
 683   my $exp_pvfd = {
 684     'Simple' => {
 685       'file' => 'Simple.pm',
 686       'version' => '0.01'
 687     },
 688     'Simple::Ex' => {
 689       'file' => 'Simple.pm',
 690       'version' => '0.02'
 691     }
 692   };
 693
 694   my $got_pvfd = Module::Metadata->package_versions_from_directory('lib');
 695
 696   is_deeply( $got_pvfd, $exp_pvfd, "package_version_from_directory()" )
 697     or diag explain $got_pvfd;
 698
 699 {
 700   my $got_provides = Module::Metadata->provides(dir => 'lib', version => 2);
 701   my $exp_provides = {
 702     'Simple' => {
 703       'file' => 'lib/Simple.pm',
 704       'version' => '0.01'
 705     },
 706     'Simple::Ex' => {
 707       'file' => 'lib/Simple.pm',
 708       'version' => '0.02'
 709     }
 710   };
 711
 712   is_deeply( $got_provides, $exp_provides, "provides()" )
 713     or diag explain $got_provides;
 714 }
 715
 716 {
 717   my $got_provides = Module::Metadata->provides(dir => 'lib', prefix => 'other', version => 1.4);
 718   my $exp_provides = {
 719     'Simple' => {
 720       'file' => 'other/Simple.pm',
 721       'version' => '0.01'
 722     },
 723     'Simple::Ex' => {
 724       'file' => 'other/Simple.pm',
 725       'version' => '0.02'
 726     }
 727   };
 728
 729   is_deeply( $got_provides, $exp_provides, "provides()" )
 730     or diag explain $got_provides;
 731 }
 732 }
 733
 734 # Check package_versions_from_directory with regard to case-sensitivity
 735 {
 736   $dist->change_file( 'lib/Simple.pm', <<'---' );
 737 package simple;
 738 $VERSION = '0.01';
 739 ---
 740   $dist->regen;
 741
 742   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
 743   is( $pm_info->name, undef, 'no default package' );
 744   is( $pm_info->version, undef, 'version for default package' );
 745   is( $pm_info->version('simple'), '0.01', 'version for lower-case package' );
 746   is( $pm_info->version('Simple'), undef, 'version for capitalized package' );
 747   ok( $pm_info->is_indexable(), 'an indexable package is found' );
 748   ok( $pm_info->is_indexable('simple'), 'the simple package is indexable' );
 749   ok( !$pm_info->is_indexable('Simple'), 'the Simple package would not be indexed' );
 750 }
 751
 752 {
 753   $dist->change_file( 'lib/Simple.pm', <<'---' );
 754 package simple;
 755 $VERSION = '0.01';
 756 package Simple;
 757 $VERSION = '0.02';
 758 package SiMpLe;
 759 $VERSION = '0.03';
 760 ---
 761   $dist->regen;
 762
 763   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
 764   is( $pm_info->name, 'Simple', 'found default package' );
 765   is( $pm_info->version, '0.02', 'version for default package' );
 766   is( $pm_info->version('simple'), '0.01', 'version for lower-case package' );
 767   is( $pm_info->version('Simple'), '0.02', 'version for capitalized package' );
 768   is( $pm_info->version('SiMpLe'), '0.03', 'version for mixed-case package' );
 769   ok( $pm_info->is_indexable('simple'), 'the simple package is indexable' );
 770   ok( $pm_info->is_indexable('Simple'), 'the Simple package is indexable' );
 771 }
 772
 773 {
 774   $dist->change_file( 'lib/Simple.pm', <<'---' );
 775 package ## hide from PAUSE
 776    simple;
 777 $VERSION = '0.01';
 778 ---
 779
 780   $dist->regen;
 781
 782   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
 783   is( $pm_info->name, undef, 'no package names found' );
 784   ok( !$pm_info->is_indexable('simple'), 'the simple package would not be indexed' );
 785   ok( !$pm_info->is_indexable('Simple'), 'the Simple package would not be indexed' );
 786   ok( !$pm_info->is_indexable(), 'no indexable package is found' );
 787 }