X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit%2FImport-Into.git;a=blobdiff_plain;f=lib%2FImport%2FInto.pm;h=74b7358d9093c688b80beb9bb8d2c62745580e21;hp=0886ad8da52f2b5bce74cff5614b5f5a5fc6185a;hb=995d8262bd1c7cc306aee068943efa7d205605c0;hpb=aa5ad642a4febbccf2639a0a64eb61ba057b9c5d

diff --git a/lib/Import/Into.pm b/lib/Import/Into.pm
index 0886ad8..74b7358 100644
--- a/lib/Import/Into.pm
+++ b/lib/Import/Into.pm
@@ -3,18 +3,30 @@ package Import::Into;
 use strict;
 use warnings FATAL => 'all';
 
-our $VERSION = '1.000002'; # 1.0.2
+our $VERSION = '1.001001'; # 1.1.1
+
+sub _prelude {
+  my $target = shift;
+  my ($package, $file, $line)
+    = $target =~ /[^0-9]/ ? ($target) : caller($target + 2);
+  qq{package $package;\n}
+    . ($file ? "#line $line \"$file\"\n" : '')
+}
 
-my %importers;
+sub _make_action {
+  my ($action, $target) = @_;
+  eval _prelude($target).qq{sub { shift->$action(\@_) }}
+    or die "Failed to build action sub to ${action} for ${target}: $@";
+}
 
 sub import::into {
   my ($class, $target, @args) = @_;
-  $class->${\(
-    $importers{$target} ||= eval qq{
-      package $target;
-      sub { shift->import(\@_) };
-    } or die "Couldn't build importer for $target: $@"
-  )}(@args);
+  _make_action(import => $target)->($class, @args);
+}
+
+sub unimport::out_of {
+  my ($class, $target, @args) = @_;
+  _make_action(unimport => $target)->($class, @args);
 }
 
 1;
@@ -31,11 +43,13 @@ Import::Into - import packages into other packages
 
   use Thing1 ();
   use Thing2 ();
+  use Thing3 ();
 
   sub import {
     my $target = caller;
     Thing1->import::into($target);
     Thing2->import::into($target, qw(import arguments));
+    Thing3->import::into(1); # import to level
   }
 
 Note: you don't need to do anything more clever than this provided you
@@ -61,6 +75,19 @@ C<import::into> on it. This is a global method, and is callable on any
 package (and in fact on any object as well, although it's rarer that you'd
 want to do that).
 
+If you provide C<import::into> with an integer instead of a package name, it
+will be used as the number of stack frames to skip to find where to export to.
+This has the advantage of preserving the apparent filename and line number
+being exported to, which some modules (L<autodie>, L<strictures>) check.
+
+Finally, we also provide an C<unimport::out_of> to allow the exporting of the
+effect of C<no>:
+
+  # unimport::out_of was added in 1.1.0 (1.001000)
+  sub unimport {
+    Moose->unimport::out_of(scalar caller); # no MyThing == no Moose
+  }
+
 If how and why this all works is of interest to you, please read on to the
 description immediately below.
 
@@ -109,7 +136,7 @@ know if something's a pragma, and second that you can't use either of
 these approaches alone on something like L<Moose> or L<Moo> that's both
 an exporter and a pragma.
 
-So, the complete solution is:
+So, a solution for that is:
 
   my $sub = eval "package $target; sub { shift->import(\@_) }";
   $sub->($thing, @import_args);
@@ -118,6 +145,20 @@ which means that import is called from the right place for pragmas to take
 effect, and from the right package for caller checking to work - and so
 behaves correctly for all types of exporter, for pragmas, and for hybrids.
 
+Additionally, some import routines check the filename they are being imported
+to.  This can be dealt with by generating a L<#line directive|perlsyn/Plain
+Old Comments (Not!)> in the eval, which will change what C<caller> reports for
+the filename when called in the importer. The filename and line number to use
+in the directive then need to be fetched using C<caller>:
+
+  my ($target, $file, $line) = caller(1);
+  my $sub = eval qq{
+    package $target;
+  #line $line "$file"
+    sub { shift->import(\@_) }
+  };
+  $sub->($thing, @import_args);
+
 Remembering all this, however, is excessively irritating. So I wrote a module
 so I didn't have to anymore. Loading L<Import::Into> creates a global method
 C<import::into> which you can call on any package to import it into another
@@ -164,13 +205,19 @@ you're receiving this from a parameter, I recommend using L<Module::Runtime>:
 
 And that's it.
 
+=head1 ACKNOWLEDGEMENTS
+
+Thanks to Getty for asking "how can I get C<< use strict; use warnings; >>
+turned on for all consumers of my code?" and then "why is this not a
+module?!".
+
 =head1 AUTHOR
 
 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 
 =head1 CONTRIBUTORS
 
-None yet - maybe this software is perfect! (ahahahahahahahahaha)
+haarg - Graham Knop (cpan:HAARG) <haarg@haarg.org>
 
 =head1 COPYRIGHT