lib/Distar/helpers/preflight

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings FATAL => 'all';
   4 use Config;
   5 use File::Spec;
   6 use File::Find;
   7 use Getopt::Long qw(:config gnu_getopt);
   8
   9 GetOptions(
  10   "branch=s"     => \(my $branch = 'master'),
  11   "changelog=s"  => \(my $changelog = 'Changes'),
  12 ) or die("Error in command line arguments\n");
  13
  14 my $version = shift or die "version required!";
  15
  16 my $make = $Config{make};
  17 my $null = File::Spec->devnull;
  18
  19 chomp(my $head = `git symbolic-ref -q HEAD`);
  20 (my $current_branch = $head) =~ s{^refs/heads/}{};
  21 $head eq "refs/heads/$branch"
  22   or die "Current branch is $current_branch, not $branch. EEEK!\n";
  23 chomp(my $upstream = `git for-each-ref --format="%(upstream)" $head`);
  24 length $upstream
  25   or die "No upstream branch configured for $branch!\n";
  26
  27 my (undef, undef, $remote) = split qr{/}, $upstream;
  28
  29 my $push_url = `git remote get-url --push $remote`;
  30 chomp $push_url;
  31
  32 system(qq[git -c remote.$remote.url="$push_url" fetch]) == 0
  33   or exit 1;
  34
  35 if (system("git rev-parse --quiet --verify v$version >$null") == 0) {
  36   die "Tag v$version already exists!";
  37 }
  38
  39 my $base_rev = `git merge-base $upstream $head`;
  40 my $upstream_rev = `git rev-parse --verify $upstream`;
  41 $upstream_rev eq $base_rev
  42   or die "Not synced with upstream!\n";
  43
  44 for (scalar `git diff`) {
  45   length && die "Outstanding changes!\n";
  46 }
  47 my $ymd = sprintf(
  48   "%i-%02i-%02i", (gmtime)[5]+1900, (gmtime)[4]+1, (gmtime)[3]
  49 );
  50 my $changes_line = "$version - $ymd\n";
  51 my @cached = grep /^\+/, `git diff --cached -U0 --no-prefix`;
  52 @cached > 0 or die "Please add:\n\n$changes_line\nto $changelog and stage $changelog (git add $changelog)\n";
  53 @cached == 2 or die "All '$changelog' changes must be committed aside from version heading\n";
  54 $cached[0] =~ /^\+\+\+ \Q$changelog\E\n/ or die "$changelog not changed\n";
  55 $cached[1] eq "+$changes_line" or die "$changelog new line should be: \n\n$changes_line\n";