lib/Distar.pm

   1 package Distar;
   2
   3 use strictures 1;
   4 use base qw(Exporter);
   5
   6 our @EXPORT = qw(
   7   author manifest_include run_preflight
   8 );
   9
  10 sub import {
  11   strictures->import;
  12   shift->export_to_level(1,@_);
  13 }
  14
  15 sub author { our $Author = shift }
  16
  17 our @Manifest = (
  18   'lib' => '.pm',
  19   't' => '.t',
  20   't/lib' => '.pm',
  21   'xt' => '.t',
  22   'xt/lib' => '.pm',
  23   '' => '.PL',
  24   '' => qr{Changes|MANIFEST|README|META\.yml},
  25   'maint' => qr{[^.].*},
  26 );
  27
  28 sub manifest_include {
  29   push @Manifest, @_;
  30 }
  31
  32 sub write_manifest_skip {
  33   use autodie;
  34   my @files = @Manifest;
  35   my @parts;
  36   while (my ($dir, $spec) = splice(@files, 0, 2)) {
  37     my $re = ($dir ? $dir.'/' : '').
  38       ((ref($spec) eq 'Regexp')
  39         ? $spec
  40         : !ref($spec)
  41           ? ".*\Q${spec}\E"
  42             # print ref as well as stringification in case of overload ""
  43           : die "spec must be string or regexp, was: ${spec} (${\ref $spec})");
  44     push @parts, $re;
  45   }
  46   my $final = '^(?!'.join('|', map "${_}\$", @parts).')';
  47   open my $skip, '>', 'MANIFEST.SKIP';
  48   print $skip "${final}\n";
  49   close $skip;
  50 }
  51
  52 sub run_preflight {
  53   system("git fetch");
  54
  55   for (scalar `make manifest 2>&1 >/dev/null`) {
  56     $_ && die "make manifest changed:\n$_ Go check it and retry";
  57   }
  58
  59   for (scalar `git status`) {
  60     /Your branch is (behind|ahead of)/ && die "Not synced with upstream";
  61   }
  62
  63   for (scalar `git diff`) {
  64     length && die "Oustanding changes";
  65   }
  66   my $ymd = sprintf(
  67     "%i-%02i-%02i", (localtime)[5]+1900, (localtime)[4]+1, (localtime)[3]
  68   );
  69   my @cached = grep /^\+/, `git diff --cached -U0`;
  70   @cached > 0 or die "Please add:\n\n$ARGV[0] - $ymd\n\nto Changes and git add";
  71   @cached == 2 or die "Pre-commit Changes not just Changes line";
  72   $cached[0] eq "+++ b/Changes\n" or die "Changes not changed";
  73   $cached[1] eq "+$ARGV[0] - $ymd\n" or die "Changes new line should be: \n\n$ARGV[0] - $ymd\n ";
  74 }
  75
  76 sub MY::postamble { <<'END'; }
  77 preflight:
  78         perl -IDistar/lib -MDistar -erun_preflight $(VERSION)
  79 upload: preflight $(DISTVNAME).tar$(SUFFIX)
  80         cpan-upload $(DISTVNAME).tar$(SUFFIX)
  81 release: upload
  82         git commit -a -m "Release commit for $(VERSION)"
  83         git tag release_$(VERSION) -m "release $(VERSION)"
  84         git push
  85         git push --tags
  86 distdir: readmefile
  87 readmefile: create_distdir
  88         pod2text $(VERSION_FROM) >$(DISTVNAME)/README
  89         $(NOECHO) cd $(DISTVNAME) && $(ABSPERLRUN) -MExtUtils::Manifest=maniadd -e 'eval { maniadd({q{README} => q{README file (added by Distar)}}) } ' \
  90           -e '    or print "Could not add README to MANIFEST: $${'\''@'\''}\n"' --
  91 END
  92
  93 {
  94   no warnings 'redefine';
  95   sub main::WriteMakefile {
  96     my %args = @_;
  97     ExtUtils::MakeMaker::WriteMakefile(
  98       LICENSE => 'perl',
  99       @_, AUTHOR => our $Author, ABSTRACT_FROM => $args{VERSION_FROM},
 100       test => { TESTS => ($args{test}{TESTS}||'').' xt/*.t' },
 101     );
 102   }
 103 }
 104
 105 END {
 106   write_manifest_skip()
 107 }
 108
 109 1;