lib/Distar.pm

   1 package Distar;
   2 use strict;
   3 use warnings FATAL => 'all';
   4 use base qw(Exporter);
   5 use ExtUtils::MakeMaker ();
   6 use ExtUtils::MM ();
   7
   8 our $VERSION = '0.002000';
   9 $VERSION = eval $VERSION;
  10
  11 my $MM_VER = eval $ExtUtils::MakeMaker::VERSION;
  12
  13 our @EXPORT = qw(
  14   author manifest_include readme_generator
  15 );
  16
  17 sub import {
  18   strict->import;
  19   warnings->import(FATAL => 'all');
  20   shift->export_to_level(1,@_);
  21 }
  22
  23 sub author {
  24   our $Author = shift;
  25   $Author = [ $Author ]
  26     if !ref $Author;
  27 }
  28
  29 our @Manifest = (
  30   'lib' => '.pm',
  31   'lib' => '.pod',
  32   't' => '.t',
  33   't/lib' => '.pm',
  34   'xt' => '.t',
  35   'xt/lib' => '.pm',
  36   '' => qr{[^/]*\.PL},
  37   '' => qr{Changes|MANIFEST|README|LICENSE|META\.yml},
  38   'maint' => qr{[^.].*},
  39 );
  40
  41 sub manifest_include {
  42   push @Manifest, @_;
  43 }
  44
  45 sub readme_generator {
  46   die "readme_generator unsupported" if @_ && $_[0];
  47 }
  48
  49 sub write_manifest_skip {
  50   my ($mm) = @_;
  51   my @files = @Manifest;
  52   my @parts;
  53   while (my ($dir, $spec) = splice(@files, 0, 2)) {
  54     my $re = ($dir ? $dir.'/' : '').
  55       ((ref($spec) eq 'Regexp')
  56         ? $spec
  57         : !ref($spec)
  58           ? ".*\Q${spec}\E"
  59             # print ref as well as stringification in case of overload ""
  60           : die "spec must be string or regexp, was: ${spec} (${\ref $spec})");
  61     push @parts, $re;
  62   }
  63   my $dist_name = $mm->{DISTNAME};
  64   my $include = join '|', map "${_}\$", @parts;
  65   my $final = "^(?:\Q$dist_name\E-v?[0-9_.]+/|(?!$include))";
  66   open my $skip, '>', 'MANIFEST.SKIP'
  67     or die "can't open MANIFEST.SKIP: $!";
  68   print $skip "${final}\n";
  69   close $skip;
  70 }
  71
  72 {
  73   package Distar::MM;
  74   our @ISA = @MM::ISA;
  75   @MM::ISA = (__PACKAGE__);
  76
  77   sub new {
  78     my ($class, $args) = @_;
  79     return $class->SUPER::new({
  80       LICENSE => 'perl_5',
  81       MIN_PERL_VERSION => '5.006',
  82       AUTHOR => ($MM_VER >= 6.5702 ? $Distar::Author : join(', ', @$Distar::Author)),
  83       ABSTRACT_FROM => $args->{VERSION_FROM},
  84       %$args,
  85       test => { TESTS => ($args->{test}{TESTS}||'t/*.t').' xt/*.t xt/*/*.t' },
  86       realclean => { FILES => (
  87         ($args->{realclean}{FILES}||'')
  88         . ' Distar/ MANIFEST.SKIP MANIFEST MANIFEST.bak'
  89       ) },
  90     });
  91   }
  92
  93   sub flush {
  94     my $self = shift;
  95     Distar::write_manifest_skip($self);
  96     $self->SUPER::flush(@_);
  97   }
  98
  99   sub special_targets {
 100     my $self = shift;
 101     my $targets = $self->SUPER::special_targets(@_);
 102     $targets =~ s/^(\.PHONY\s*:.*)/$1 preflight releasetest release readmefile distmanicheck nextrelease refresh bump bumpmajor bumpminor/m;
 103     $targets;
 104   }
 105
 106   sub dist_test {
 107     my $self = shift;
 108     my $dist_test = $self->SUPER::dist_test(@_);
 109
 110     $dist_test .= <<"END";
 111
 112 # --- Distar section:
 113
 114 REMAKE = \$(PERLRUN) Makefile.PL @{[ map { $self->quote_literal($_) } @ARGV ]}
 115
 116 END
 117     $dist_test .= <<'END';
 118 preflight:
 119         $(ABSPERLRUN) Distar/helpers/preflight $(VERSION)
 120 releasetest:
 121         $(MAKE) disttest RELEASE_TESTING=1 TEST_FILES="$(TEST_FILES)"
 122 release: preflight releasetest
 123         $(RM_RF) $(DISTVNAME)
 124         $(MAKE) $(DISTVNAME).tar$(SUFFIX)
 125         git commit -a -m "Release commit for $(VERSION)"
 126         git tag v$(VERSION) -m "release v$(VERSION)"
 127         cpan-upload $(DISTVNAME).tar$(SUFFIX)
 128         git push origin v$(VERSION) HEAD
 129 distdir: readmefile
 130 readmefile: create_distdir $(DISTVNAME)/README
 131         $(NOECHO) cd $(DISTVNAME) && $(ABSPERLRUN) ../Distar/helpers/add-to-manifest README
 132 $(DISTVNAME)/README: $(VERSION_FROM)
 133         $(NOECHO) $(MKPATH) $(DISTVNAME)
 134         pod2text $(VERSION_FROM) >$(DISTVNAME)/README
 135 disttest: distmanicheck
 136 distmanicheck: create_distdir
 137         cd $(DISTVNAME) && $(ABSPERLRUN) "-MExtUtils::Manifest=manicheck" -e "exit manicheck"
 138 nextrelease:
 139         $(ABSPERLRUN) Distar/helpers/add-changelog-heading $(VERSION) Changes
 140         GIT_DIFF_OPTS=-u`$(ABSPERLRUN) Distar/helpers/changelog-context $(VERSION) Changes` git add -p Changes
 141 refresh:
 142         cd Distar && git pull
 143         rm Makefile
 144         $(REMAKE)
 145 END
 146
 147     my $include = '';
 148     if (open my $fh, '<', 'maint/Makefile.include') {
 149       $include = "\n# --- Makefile.include:\n" . do { local $/; <$fh> };
 150     }
 151
 152     for my $type ('', 'minor', 'major') {
 153       if ($include !~ /^bump$type:/m) {
 154         my $arg = $type || '$(V)';
 155         $dist_test .= <<"END"
 156 bump$type:
 157         \$(ABSPERLRUN) Distar/helpers/bump-version --git \$(VERSION) $arg
 158         \$(RM_F) \$(FIRST_MAKEFILE)
 159         \$(REMAKE)
 160 END
 161       }
 162     }
 163
 164     $dist_test .= $include . "\n";
 165
 166     return $dist_test;
 167   }
 168 }
 169
 170 1;