lib/Distar.pm

   1 package Distar;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5 use base qw(Exporter);
   6 use ExtUtils::MakeMaker ();
   7 use ExtUtils::MM ();
   8
   9 our $VERSION = '0.002000';
  10 $VERSION = eval $VERSION;
  11
  12 my $MM_VER = eval $ExtUtils::MakeMaker::VERSION;
  13
  14 our @EXPORT = qw(
  15   author manifest_include readme_generator
  16 );
  17
  18 sub import {
  19   strict->import;
  20   warnings->import(FATAL => 'all');
  21   shift->export_to_level(1,@_);
  22 }
  23
  24 sub author {
  25   our $Author = shift;
  26   $Author = [ $Author ]
  27     if !ref $Author;
  28 }
  29
  30 our @Manifest = (
  31   'lib' => '.pm',
  32   'lib' => '.pod',
  33   't' => '.t',
  34   't/lib' => '.pm',
  35   'xt' => '.t',
  36   'xt/lib' => '.pm',
  37   '' => qr{[^/]*\.PL},
  38   '' => qr{Changes|MANIFEST|README|LICENSE|META\.yml},
  39   'maint' => qr{[^.].*},
  40 );
  41
  42 sub manifest_include {
  43   push @Manifest, @_;
  44 }
  45
  46 sub readme_generator {
  47   die "readme_generator unsupported" if @_ && $_[0];
  48 }
  49
  50 sub write_manifest_skip {
  51   my ($mm) = @_;
  52   my @files = @Manifest;
  53   my @parts;
  54   while (my ($dir, $spec) = splice(@files, 0, 2)) {
  55     my $re = ($dir ? $dir.'/' : '').
  56       ((ref($spec) eq 'Regexp')
  57         ? $spec
  58         : !ref($spec)
  59           ? ".*\Q${spec}\E"
  60             # print ref as well as stringification in case of overload ""
  61           : die "spec must be string or regexp, was: ${spec} (${\ref $spec})");
  62     push @parts, $re;
  63   }
  64   my $dist_name = $mm->{DISTNAME};
  65   my $include = join '|', map "${_}\$", @parts;
  66   my $final = "^(?:\Q$dist_name\E-v?[0-9_.]+/|(?!$include))";
  67   open my $skip, '>', 'MANIFEST.SKIP'
  68     or die "can't open MANIFEST.SKIP: $!";
  69   print $skip "${final}\n";
  70   close $skip;
  71 }
  72
  73 {
  74   package Distar::MM;
  75   our @ISA = @MM::ISA;
  76   @MM::ISA = (__PACKAGE__);
  77
  78   sub new {
  79     my ($class, $args) = @_;
  80     return $class->SUPER::new({
  81       LICENSE => 'perl_5',
  82       MIN_PERL_VERSION => '5.006',
  83       AUTHOR => ($MM_VER >= 6.5702 ? $Distar::Author : join(', ', @$Distar::Author)),
  84       %$args,
  85       ABSTRACT_FROM => $args->{VERSION_FROM},
  86       test => { TESTS => ($args->{test}{TESTS}||'t/*.t').' xt/*.t xt/*/*.t' },
  87       realclean => { FILES => (
  88         ($args->{realclean}{FILES}||'')
  89         . ' Distar/ MANIFEST.SKIP MANIFEST MANIFEST.bak'
  90       ) },
  91     });
  92   }
  93
  94   sub flush {
  95     my $self = shift;
  96     Distar::write_manifest_skip($self);
  97     $self->SUPER::flush(@_);
  98   }
  99
 100   sub dist_test {
 101     my $self = shift;
 102     my $dist_test = $self->SUPER::dist_test(@_);
 103
 104     $dist_test .= <<"END";
 105
 106 # --- Distar section:
 107
 108 REMAKE = \$(PERLRUN) Makefile.PL @{[ map { $self->quote_literal($_) } @ARGV ]}
 109
 110 END
 111     $dist_test .= <<'END';
 112 preflight:
 113         $(ABSPERLRUN) Distar/helpers/preflight $(VERSION)
 114 releasetest:
 115         $(MAKE) disttest RELEASE_TESTING=1 TEST_FILES="$(TEST_FILES)"
 116 release: preflight releasetest
 117         $(RM_RF) $(DISTVNAME)
 118         $(MAKE) $(DISTVNAME).tar$(SUFFIX)
 119         git commit -a -m "Release commit for $(VERSION)"
 120         git tag v$(VERSION) -m "release v$(VERSION)"
 121         cpan-upload $(DISTVNAME).tar$(SUFFIX)
 122         git push origin v$(VERSION) HEAD
 123 distdir: readmefile
 124 readmefile: create_distdir $(DISTVNAME)/README
 125         $(NOECHO) cd $(DISTVNAME) && $(ABSPERLRUN) ../Distar/helpers/add-to-manifest README
 126 $(DISTVNAME)/README: $(VERSION_FROM)
 127         $(NOECHO) $(MKPATH) $(DISTVNAME)
 128         pod2text $(VERSION_FROM) >$(DISTVNAME)/README
 129 disttest: distmanicheck
 130 distmanicheck: create_distdir
 131         cd $(DISTVNAME) && $(ABSPERLRUN) "-MExtUtils::Manifest=manicheck" -e "exit manicheck"
 132 nextrelease:
 133         $(ABSPERLRUN) Distar/helpers/add-changelog-heading $(VERSION) Changes
 134         GIT_DIFF_OPTS=-u`$(ABSPERLRUN) Distar/helpers/changelog-context $(VERSION) Changes` git add -p Changes
 135 refresh:
 136         cd Distar && git pull
 137         rm Makefile
 138         $(REMAKE)
 139 END
 140
 141     my $include = '';
 142     if (open my $fh, '<', 'maint/Makefile.include') {
 143       $include = "\n# --- Makefile.include:\n" . do { local $/; <$fh> };
 144     }
 145
 146     for my $type ('', 'minor', 'major') {
 147       if ($include !~ /^bump$type:/m) {
 148         my $arg = $type || '$(V)';
 149         $dist_test .= <<"END"
 150 bump$type:
 151         \$(ABSPERLRUN) Distar/helpers/bump-version --git \$(VERSION) $arg
 152         \$(RM_F) \$(FIRST_MAKEFILE)
 153         \$(REMAKE)
 154 END
 155       }
 156     }
 157
 158     $dist_test .= $include . "\n";
 159
 160     return $dist_test;
 161   }
 162 }
 163
 164 1;