lib/Distar.pm

   1 package Distar;
   2 use strict;
   3 use warnings FATAL => 'all';
   4 use base qw(Exporter);
   5 use ExtUtils::MakeMaker ();
   6 use ExtUtils::MM ();
   7
   8 our $VERSION = '0.002000';
   9 $VERSION = eval $VERSION;
  10
  11 my $MM_VER = eval $ExtUtils::MakeMaker::VERSION;
  12
  13 our @EXPORT = qw(
  14   author manifest_include readme_generator
  15 );
  16
  17 sub import {
  18   strict->import;
  19   warnings->import(FATAL => 'all');
  20   shift->export_to_level(1,@_);
  21 }
  22
  23 sub author {
  24   our $Author = shift;
  25   $Author = [ $Author ]
  26     if !ref $Author;
  27 }
  28
  29 our @Manifest = (
  30   'lib' => '.pm',
  31   'lib' => '.pod',
  32   't' => '.t',
  33   't/lib' => '.pm',
  34   'xt' => '.t',
  35   'xt/lib' => '.pm',
  36   '' => qr{[^/]*\.PL},
  37   '' => qr{Changes|MANIFEST|README|LICENSE|META\.yml},
  38   'maint' => qr{[^.].*},
  39 );
  40
  41 sub manifest_include {
  42   push @Manifest, @_;
  43 }
  44
  45 sub readme_generator {
  46   die "readme_generator unsupported" if @_ && $_[0];
  47 }
  48
  49 sub write_manifest_skip {
  50   my ($mm) = @_;
  51   my @files = @Manifest;
  52   my @parts;
  53   while (my ($dir, $spec) = splice(@files, 0, 2)) {
  54     my $re = ($dir ? $dir.'/' : '').
  55       ((ref($spec) eq 'Regexp')
  56         ? $spec
  57         : !ref($spec)
  58           ? ".*\Q${spec}\E"
  59             # print ref as well as stringification in case of overload ""
  60           : die "spec must be string or regexp, was: ${spec} (${\ref $spec})");
  61     push @parts, $re;
  62   }
  63   my $dist_name = $mm->{DISTNAME};
  64   my $include = join '|', map "${_}\$", @parts;
  65   my $final = "^(?:\Q$dist_name\E-v?[0-9_.]+/|(?!$include))";
  66   open my $skip, '>', 'MANIFEST.SKIP'
  67     or die "can't open MANIFEST.SKIP: $!";
  68   print $skip "${final}\n";
  69   close $skip;
  70 }
  71
  72 {
  73   package Distar::MM;
  74   our @ISA = @MM::ISA;
  75   @MM::ISA = (__PACKAGE__);
  76
  77   sub new {
  78     my ($class, $args) = @_;
  79     return $class->SUPER::new({
  80       LICENSE => 'perl_5',
  81       MIN_PERL_VERSION => '5.006',
  82       AUTHOR => ($MM_VER >= 6.5702 ? $Distar::Author : join(', ', @$Distar::Author)),
  83       ABSTRACT_FROM => $args->{VERSION_FROM},
  84       %$args,
  85       test => { TESTS => ($args->{test}{TESTS}||'t/*.t').' xt/*.t xt/*/*.t' },
  86       realclean => { FILES => (
  87         ($args->{realclean}{FILES}||'')
  88         . ' Distar/ MANIFEST.SKIP MANIFEST MANIFEST.bak'
  89       ) },
  90     });
  91   }
  92
  93   sub flush {
  94     my $self = shift;
  95     Distar::write_manifest_skip($self);
  96     $self->SUPER::flush(@_);
  97   }
  98
  99   sub special_targets {
 100     my $self = shift;
 101     my $targets = $self->SUPER::special_targets(@_);
 102     my $phony_targets = join ' ', qw(
 103       preflight
 104       releasetest
 105       release
 106       readmefile
 107       distmanicheck
 108       nextrelease
 109       refresh
 110       bump
 111       bumpmajor
 112       bumpminor
 113     );
 114     $targets =~ s/^(\.PHONY *:.*)/$1 $phony_targets/m;
 115     $targets;
 116   }
 117
 118   sub dist_test {
 119     my $self = shift;
 120
 121     my $include = '';
 122     if (open my $fh, '<', 'maint/Makefile.include') {
 123       $include = "\n# --- Makefile.include:\n\n" . do { local $/; <$fh> };
 124       $include =~ s/\n?\z/\n/;
 125     }
 126
 127     my @bump_targets =
 128       grep { $include !~ /^bump$_(?: +\w+)*:/m } ('', 'minor', 'major');
 129
 130     my %vars = (
 131       REMAKE => join(' ', '$(PERLRUN)', 'Makefile.PL', map { $self->quote_literal($_) } @ARGV),
 132       BRANCH => $self->{BRANCH} ||= 'master',
 133     );
 134
 135     join('',
 136       $self->SUPER::dist_test(@_),
 137       "\n\n# --- Distar section:\n\n",
 138       (map "$_ = $vars{$_}\n", sort keys %vars),
 139       <<'END',
 140
 141 preflight:
 142         $(ABSPERLRUN) Distar/helpers/preflight $(VERSION) --branch=$(BRANCH)
 143 releasetest:
 144         $(MAKE) disttest RELEASE_TESTING=1 PASTHRU="$(PASTHRU) TEST_FILES=\"$(TEST_FILES)\""
 145 release: preflight releasetest
 146         $(RM_RF) $(DISTVNAME)
 147         $(MAKE) $(DISTVNAME).tar$(SUFFIX)
 148         git commit -a -m "Release commit for $(VERSION)"
 149         git tag v$(VERSION) -m "release v$(VERSION)"
 150         cpan-upload $(DISTVNAME).tar$(SUFFIX)
 151         git push origin v$(VERSION) HEAD
 152 distdir: readmefile
 153 readmefile: create_distdir $(DISTVNAME)/README
 154         $(NOECHO) cd $(DISTVNAME) && $(ABSPERLRUN) ../Distar/helpers/add-to-manifest README
 155 $(DISTVNAME)/README: $(VERSION_FROM)
 156         $(NOECHO) $(MKPATH) $(DISTVNAME)
 157         pod2text $(VERSION_FROM) >$(DISTVNAME)/README
 158 disttest: distmanicheck
 159 distmanicheck: create_distdir
 160         cd $(DISTVNAME) && $(ABSPERLRUN) "-MExtUtils::Manifest=manicheck" -e "exit manicheck"
 161 nextrelease:
 162         $(ABSPERLRUN) Distar/helpers/add-changelog-heading --git $(VERSION) Changes
 163 refresh:
 164         cd Distar && git pull
 165         $(RM_F) $(FIRST_MAKEFILE)
 166         $(REMAKE)
 167 END
 168       map(sprintf(<<'END', "bump$_", ($_ || '$(V)')), @bump_targets),
 169 %s:
 170         $(ABSPERLRUN) Distar/helpers/bump-version --git $(VERSION) %s
 171         $(RM_F) $(FIRST_MAKEFILE)
 172         $(REMAKE)
 173 END
 174       $include,
 175       "\n",
 176     );
 177   }
 178 }
 179
 180 1;