lib/Distar.pm

   1 package Distar;
   2 use strict;
   3 use warnings FATAL => 'all';
   4 use base qw(Exporter);
   5 use ExtUtils::MakeMaker ();
   6 use ExtUtils::MM ();
   7
   8 our $VERSION = '0.002000';
   9 $VERSION = eval $VERSION;
  10
  11 my $MM_VER = eval $ExtUtils::MakeMaker::VERSION;
  12
  13 our @EXPORT = qw(
  14   author manifest_include readme_generator
  15 );
  16
  17 sub import {
  18   strict->import;
  19   warnings->import(FATAL => 'all');
  20   shift->export_to_level(1,@_);
  21 }
  22
  23 sub author {
  24   our $Author = shift;
  25   $Author = [ $Author ]
  26     if !ref $Author;
  27 }
  28
  29 our @Manifest = (
  30   'lib' => '.pm',
  31   'lib' => '.pod',
  32   't' => '.t',
  33   't/lib' => '.pm',
  34   'xt' => '.t',
  35   'xt/lib' => '.pm',
  36   '' => qr{[^/]*\.PL},
  37   '' => qr{Changes|MANIFEST|README|LICENSE|META\.yml},
  38   'maint' => qr{[^.].*},
  39 );
  40
  41 sub manifest_include {
  42   push @Manifest, @_;
  43 }
  44
  45 sub readme_generator {
  46   die "readme_generator unsupported" if @_ && $_[0];
  47 }
  48
  49 sub write_manifest_skip {
  50   my ($mm) = @_;
  51   my @files = @Manifest;
  52   my @parts;
  53   while (my ($dir, $spec) = splice(@files, 0, 2)) {
  54     my $re = ($dir ? $dir.'/' : '').
  55       ((ref($spec) eq 'Regexp')
  56         ? $spec
  57         : !ref($spec)
  58           ? ".*\Q${spec}\E"
  59             # print ref as well as stringification in case of overload ""
  60           : die "spec must be string or regexp, was: ${spec} (${\ref $spec})");
  61     push @parts, $re;
  62   }
  63   my $dist_name = $mm->{DISTNAME};
  64   my $include = join '|', map "${_}\$", @parts;
  65   my $final = "^(?:\Q$dist_name\E-v?[0-9_.]+/|(?!$include))";
  66   open my $skip, '>', 'MANIFEST.SKIP'
  67     or die "can't open MANIFEST.SKIP: $!";
  68   print $skip "${final}\n";
  69   close $skip;
  70 }
  71
  72 {
  73   package Distar::MM;
  74   our @ISA = @MM::ISA;
  75   @MM::ISA = (__PACKAGE__);
  76
  77   sub new {
  78     my ($class, $args) = @_;
  79     return $class->SUPER::new({
  80       LICENSE => 'perl_5',
  81       MIN_PERL_VERSION => '5.006',
  82       AUTHOR => ($MM_VER >= 6.5702 ? $Distar::Author : join(', ', @$Distar::Author)),
  83       ABSTRACT_FROM => $args->{VERSION_FROM},
  84       %$args,
  85       test => { TESTS => ($args->{test}{TESTS}||'t/*.t').' xt/*.t xt/*/*.t' },
  86       realclean => { FILES => (
  87         ($args->{realclean}{FILES}||'')
  88         . ' Distar/ MANIFEST.SKIP MANIFEST MANIFEST.bak'
  89       ) },
  90     });
  91   }
  92
  93   sub flush {
  94     my $self = shift;
  95     Distar::write_manifest_skip($self);
  96     $self->SUPER::flush(@_);
  97   }
  98
  99   sub special_targets {
 100     my $self = shift;
 101     my $targets = $self->SUPER::special_targets(@_);
 102     my $phony_targets = join ' ', qw(
 103       preflight
 104       releasetest
 105       release
 106       readmefile
 107       distmanicheck
 108       nextrelease
 109       refresh
 110       bump
 111       bumpmajor
 112       bumpminor
 113     );
 114     $targets =~ s/^(\.PHONY *:.*)/$1 $phony_targets/m;
 115     $targets;
 116   }
 117
 118   sub dist_test {
 119     my $self = shift;
 120     my $dist_test = $self->SUPER::dist_test(@_);
 121
 122     $dist_test .= <<"END";
 123
 124 # --- Distar section:
 125
 126 REMAKE = \$(PERLRUN) Makefile.PL @{[ map { $self->quote_literal($_) } @ARGV ]}
 127
 128 END
 129     $dist_test .= <<'END';
 130 preflight:
 131         $(ABSPERLRUN) Distar/helpers/preflight $(VERSION)
 132 releasetest:
 133         $(MAKE) disttest RELEASE_TESTING=1 PASTHRU="$(PASTHRU) TEST_FILES=\"$(TEST_FILES)\""
 134 release: preflight releasetest
 135         $(RM_RF) $(DISTVNAME)
 136         $(MAKE) $(DISTVNAME).tar$(SUFFIX)
 137         git commit -a -m "Release commit for $(VERSION)"
 138         git tag v$(VERSION) -m "release v$(VERSION)"
 139         cpan-upload $(DISTVNAME).tar$(SUFFIX)
 140         git push origin v$(VERSION) HEAD
 141 distdir: readmefile
 142 readmefile: create_distdir $(DISTVNAME)/README
 143         $(NOECHO) cd $(DISTVNAME) && $(ABSPERLRUN) ../Distar/helpers/add-to-manifest README
 144 $(DISTVNAME)/README: $(VERSION_FROM)
 145         $(NOECHO) $(MKPATH) $(DISTVNAME)
 146         pod2text $(VERSION_FROM) >$(DISTVNAME)/README
 147 disttest: distmanicheck
 148 distmanicheck: create_distdir
 149         cd $(DISTVNAME) && $(ABSPERLRUN) "-MExtUtils::Manifest=manicheck" -e "exit manicheck"
 150 nextrelease:
 151         $(ABSPERLRUN) Distar/helpers/add-changelog-heading $(VERSION) Changes
 152         GIT_DIFF_OPTS=-u`$(ABSPERLRUN) Distar/helpers/changelog-context $(VERSION) Changes` git add -p Changes
 153 refresh:
 154         cd Distar && git pull
 155         $(RM_F) $(FIRST_MAKEFILE)
 156         $(REMAKE)
 157 END
 158
 159     my $include = '';
 160     if (open my $fh, '<', 'maint/Makefile.include') {
 161       $include = "\n# --- Makefile.include:\n" . do { local $/; <$fh> };
 162     }
 163
 164     for my $type ('', 'minor', 'major') {
 165       if ($include !~ /^bump$type:/m) {
 166         my $arg = $type || '$(V)';
 167         $dist_test .= <<"END"
 168 bump$type:
 169         \$(ABSPERLRUN) Distar/helpers/bump-version --git \$(VERSION) $arg
 170         \$(RM_F) \$(FIRST_MAKEFILE)
 171         \$(REMAKE)
 172 END
 173       }
 174     }
 175
 176     $dist_test .= $include . "\n";
 177
 178     return $dist_test;
 179   }
 180 }
 181
 182 1;