lib/Distar.pm

   1 package Distar;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5 use base qw(Exporter);
   6 use ExtUtils::MakeMaker ();
   7 use ExtUtils::MM ();
   8
   9 use Config;
  10 use File::Spec;
  11
  12 our $VERSION = '0.001000';
  13 $VERSION = eval $VERSION;
  14
  15 my $MM_VER = eval $ExtUtils::MakeMaker::VERSION;
  16
  17 our @EXPORT = qw(
  18   author manifest_include readme_generator run_preflight
  19 );
  20
  21 sub import {
  22   strict->import;
  23   warnings->import(FATAL => 'all');
  24   shift->export_to_level(1,@_);
  25 }
  26
  27 sub author {
  28   our $Author = shift;
  29   $Author = [ $Author ]
  30     if !ref $Author;
  31 }
  32
  33 our $Ran_Preflight;
  34
  35 our @Manifest = (
  36   'lib' => '.pm',
  37   'lib' => '.pod',
  38   't' => '.t',
  39   't/lib' => '.pm',
  40   'xt' => '.t',
  41   'xt/lib' => '.pm',
  42   '' => qr{[^/]*\.PL},
  43   '' => qr{Changes|MANIFEST|README|META\.yml},
  44   'maint' => qr{[^.].*},
  45 );
  46
  47 sub manifest_include {
  48   push @Manifest, @_;
  49 }
  50
  51 my $readme_generator = <<README;
  52         pod2text $(VERSION_FROM) >$(DISTVNAME)/README
  53         $(NOECHO) cd $(DISTVNAME) && $(ABSPERLRUN) ../Distar/helpers/add-readme-to-manifest
  54 README
  55 sub readme_generator {
  56     $readme_generator = shift;
  57 }
  58
  59 sub write_manifest_skip {
  60   my @files = @Manifest;
  61   my @parts;
  62   while (my ($dir, $spec) = splice(@files, 0, 2)) {
  63     my $re = ($dir ? $dir.'/' : '').
  64       ((ref($spec) eq 'Regexp')
  65         ? $spec
  66         : !ref($spec)
  67           ? ".*\Q${spec}\E"
  68             # print ref as well as stringification in case of overload ""
  69           : die "spec must be string or regexp, was: ${spec} (${\ref $spec})");
  70     push @parts, $re;
  71   }
  72   my $final = '^(?!'.join('|', map "${_}\$", @parts).')';
  73   open my $skip, '>', 'MANIFEST.SKIP'
  74     or die "can't open MANIFEST.SKIP: $!";
  75   print $skip "${final}\n";
  76   close $skip;
  77 }
  78
  79 sub run_preflight {
  80   $Ran_Preflight = 1;
  81   my $version = $ARGV[0];
  82
  83   my $make = $Config{make};
  84   my $null = File::Spec->devnull;
  85
  86   system("git fetch");
  87   if (system("git rev-parse --quiet --verify v$version >$null") == 0) {
  88     die "Tag v$version already exists!";
  89   }
  90
  91   require File::Find;
  92   File::Find::find({ no_chdir => 1, wanted => sub {
  93     return
  94       unless -f && /\.pm$/;
  95     my $file_version = MM->parse_version($_);
  96     die "Module $_ version $file_version doesn't match dist version $version"
  97       unless $file_version eq 'undef' || $file_version eq $version;
  98   }}, 'lib');
  99
 100   for (scalar `"$make" manifest 2>&1 >$null`) {
 101     $_ && die "$make manifest changed:\n$_ Go check it and retry";
 102   }
 103
 104   for (scalar `git status`) {
 105     /^(?:# )?On branch master/ || die "Not on master. EEEK";
 106     /Your branch is behind|Your branch and .*? have diverged/ && die "Not synced with upstream";
 107   }
 108
 109   for (scalar `git diff`) {
 110     length && die "Outstanding changes";
 111   }
 112   my $ymd = sprintf(
 113     "%i-%02i-%02i", (gmtime)[5]+1900, (gmtime)[4]+1, (gmtime)[3]
 114   );
 115   my $changes_line = "$version - $ymd\n";
 116   my @cached = grep /^\+/, `git diff --cached -U0`;
 117   @cached > 0 or die "Please add:\n\n$changes_line\nto Changes stage Changes (git add Changes)";
 118   @cached == 2 or die "Pre-commit Changes not just Changes line";
 119   $cached[0] =~ /^\+\+\+ .\/Changes\n/ or die "Changes not changed";
 120   $cached[1] eq "+$changes_line" or die "Changes new line should be: \n\n$changes_line ";
 121
 122   { no warnings 'exec'; `cpan-upload -h`; }
 123   $? and die "cpan-upload not available";
 124 }
 125
 126 {
 127   package Distar::MM;
 128   our @ISA = @ExtUtils::MM::ISA;
 129   @ExtUtils::MM::ISA = (__PACKAGE__);
 130
 131   sub new {
 132     my ($class, $args) = @_;
 133     return $class->SUPER::new({
 134       LICENSE => 'perl_5',
 135       MIN_PERL_VERSION => '5.006',
 136       AUTHOR => ($MM_VER >= 6.5702 ? $Distar::Author : $Distar::Author->[0]),
 137       %$args,
 138       ABSTRACT_FROM => $args->{VERSION_FROM},
 139       test => { TESTS => ($args->{test}{TESTS}||'t/*.t').' xt/*.t xt/*/*.t' },
 140     });
 141   }
 142
 143   sub dist_test {
 144     my $self = shift;
 145     my $dist_test = $self->SUPER::dist_test(@_) . <<'END'
 146
 147 # --- Distar section:
 148 preflight:
 149         perl -IDistar/lib -MDistar -erun_preflight $(VERSION)
 150 release: preflight
 151         $(MAKE) disttest
 152         rm -rf $(DISTVNAME)
 153         $(MAKE) $(DISTVNAME).tar$(SUFFIX)
 154         git commit -a -m "Release commit for $(VERSION)"
 155         git tag v$(VERSION) -m "release v$(VERSION)"
 156         cpan-upload $(DISTVNAME).tar$(SUFFIX)
 157         git push origin v$(VERSION) HEAD
 158 distdir: readmefile
 159 readmefile: create_distdir
 160 END
 161     . $readme_generator . <<'END';
 162 disttest: distmanicheck
 163 distmanicheck: create_distdir
 164         cd $(DISTVNAME) && $(ABSPERLRUN) "-MExtUtils::Manifest=manicheck" -e "exit manicheck"
 165
 166 END
 167     if (open my $fh, '<', 'maint/Makefile.include') {
 168       $dist_test .= do { local $/; <$fh> };
 169     }
 170     return $dist_test;
 171   }
 172 }
 173
 174 END {
 175   write_manifest_skip() unless $Ran_Preflight
 176 }
 177
 178 1;