lib/Devel/REPL.pm

   1 package Devel::REPL;
   2
   3 use Term::ReadLine;
   4 use Moose;
   5 use namespace::clean -except => [ 'meta' ];
   6 use 5.008001; # backwards compat, doesn't warn like 5.8.1
   7
   8 our $VERSION = '1.003009'; # 1.3.9
   9
  10 with 'MooseX::Object::Pluggable';
  11
  12 use Devel::REPL::Error;
  13
  14 has 'term' => (
  15   is => 'rw', required => 1,
  16   default => sub { Term::ReadLine->new('Perl REPL') }
  17 );
  18
  19 has 'prompt' => (
  20   is => 'rw', required => 1,
  21   default => sub { '$ ' }
  22 );
  23
  24 has 'out_fh' => (
  25   is => 'rw', required => 1, lazy => 1,
  26   default => sub { shift->term->OUT || \*STDOUT; }
  27 );
  28
  29 sub run {
  30   my ($self) = @_;
  31   while ($self->run_once_safely) {
  32     # keep looping
  33   }
  34 }
  35
  36 sub run_once_safely {
  37   my ($self, @args) = @_;
  38
  39   my $ret = eval { $self->run_once(@args) };
  40
  41   if ($@) {
  42     my $error = $@;
  43     eval { $self->print("Error! - $error\n"); };
  44     return 1;
  45   } else {
  46     return $ret;
  47   }
  48 }
  49
  50 sub run_once {
  51   my ($self) = @_;
  52
  53   my $line = $self->read;
  54   return unless defined($line); # undefined value == EOF
  55
  56   my @ret = $self->formatted_eval($line);
  57
  58   $self->print(@ret);
  59
  60   return 1;
  61 }
  62
  63 sub formatted_eval {
  64   my ( $self, @args ) = @_;
  65
  66   my @ret = $self->eval(@args);
  67
  68   return $self->format(@ret);
  69 }
  70
  71 sub format {
  72   my ( $self, @stuff ) = @_;
  73
  74   if ( $self->is_error($stuff[0]) ) {
  75     return $self->format_error(@stuff);
  76   } else {
  77     return $self->format_result(@stuff);
  78   }
  79 }
  80
  81 sub format_result {
  82   my ( $self, @stuff ) = @_;
  83
  84   return @stuff;
  85 }
  86
  87 sub format_error {
  88   my ( $self, $error ) = @_;
  89   return $error->stringify;
  90 }
  91
  92 sub is_error {
  93   my ( $self, $thingy ) = @_;
  94   blessed($thingy) and $thingy->isa("Devel::REPL::Error");
  95 }
  96
  97 sub read {
  98   my ($self) = @_;
  99   return $self->term->readline($self->prompt);
 100 }
 101
 102 sub eval {
 103   my ($self, $line) = @_;
 104   my $compiled = $self->compile($line);
 105   return $compiled unless defined($compiled) and not $self->is_error($compiled);
 106   return $self->execute($compiled);
 107 }
 108
 109 sub compile {
 110   my ( $_REPL, @args ) = @_;
 111   my $compiled = eval $_REPL->wrap_as_sub(@args);
 112   return $_REPL->error_return("Compile error", $@) if $@;
 113   return $compiled;
 114 }
 115
 116 sub wrap_as_sub {
 117   my ($self, $line, %args) = @_;
 118   return qq!sub {\n!. ( $args{no_mangling} ? $line : $self->mangle_line($line) ).qq!\n}\n!;
 119 }
 120
 121 sub mangle_line {
 122   my ($self, $line) = @_;
 123   return $line;
 124 }
 125
 126 sub execute {
 127   my ($self, $to_exec, @args) = @_;
 128   my @ret = eval { $to_exec->(@args) };
 129   return $self->error_return("Runtime error", $@) if $@;
 130   return @ret;
 131 }
 132
 133 sub error_return {
 134   my ($self, $type, $error) = @_;
 135   return Devel::REPL::Error->new( type => $type, message => $error );
 136 }
 137
 138 sub print {
 139   my ($self, @ret) = @_;
 140   my $fh = $self->out_fh;
 141   no warnings 'uninitialized';
 142   print $fh "@ret";
 143   print $fh "\n" if $self->term->ReadLine =~ /Gnu/;
 144 }
 145
 146 =head1 NAME
 147
 148 Devel::REPL - a modern perl interactive shell
 149
 150 =head1 SYNOPSIS
 151
 152   my $repl = Devel::REPL->new;
 153   $repl->load_plugin($_) for qw(History LexEnv);
 154   $repl->run
 155
 156 Alternatively, use the 're.pl' script installed with the distribution
 157
 158   system$ re.pl
 159
 160 =head1 DESCRIPTION
 161
 162 This is an interactive shell for Perl, commonly known as a REPL - Read,
 163 Evaluate, Print, Loop. The shell provides for rapid development or testing
 164 of code without the need to create a temporary source code file.
 165
 166 Through a plugin system, many features are available on demand. You can also
 167 tailor the environment through the use of profiles and run control files, for
 168 example to pre-load certain Perl modules when working on a particular project.
 169
 170 =head1 USAGE
 171
 172 To start a shell, follow one of the examples in the L</"SYNOPSIS"> above.
 173
 174 Once running, the shell accepts and will attempt to execute any code given. If
 175 the code executes successfully you'll be shown the result, otherwise an error
 176 message will be returned. Here are a few examples:
 177
 178  $_ print "Hello, world!\n"
 179  Hello, world!
 180  1
 181  $_ nosuchfunction
 182  Compile error: Bareword "nosuchfunction" not allowed while "strict subs" in use at (eval 130) line 5.
 183
 184  $_
 185
 186 In the first example above you see the output of the command (C<Hello,
 187 world!>), if any, and then the return value of the statement (C<1>). Following
 188 that example, an error is returned when the execution of some code fails.
 189
 190 Note that the lack of semicolon on the end is not a mistake - the code is
 191 run inside a Block structure (to protect the REPL in case the code blows up),
 192 which means a single statement doesn't require the semicolon. You can add one
 193 if you like, though.
 194
 195 If you followed the first example in the L</"SYNOPSIS"> above, you'll have the
 196 History and LexEnv plugins loaded (and there are many more available).
 197 Although the shell might support "up-arrow" history, the History plugin adds
 198 "bang" history to that so you can re-execute chosen commands (with e.g.
 199 C<!53>). The LexEnv plugin ensures that lexical variables declared with the
 200 C<my> keyword will automatically persist between statements executed in the
 201 REPL shell.
 202
 203 When you C<use> any Perl module, the C<import()> will work as expected - the
 204 exported functions from that module are available for immediate use:
 205
 206  $_ carp "I'm dieeeing!\n"
 207  String found where operator expected at (eval 129) line 5, near "carp "I'm dieeeing!\n""
 208          (Do you need to predeclare carp?)
 209  Compile error: syntax error at (eval 129) line 5, near "carp "I'm dieeeing!\n""
 210  BEGIN not safe after errors--compilation aborted at (eval 129) line 5.
 211
 212  $_ use Carp
 213
 214  $_ carp "I'm dieeeing!\n"
 215  I'm dieeeing!
 216   at /usr/share/perl5/Lexical/Persistence.pm line 327
 217  1
 218  $_
 219
 220 To quit from the shell, hit C<control+d> or C<control+c>.
 221
 222 =head2 Run Control Files
 223
 224 For particular projects you might well end up running the same commands each
 225 time the REPL shell starts up - loading Perl modules, setting configuration,
 226 and so on. A run control file lets you have this done automatically, and you
 227 can have multiple files for different projects.
 228
 229 By default the C<re.pl> program looks for C<< $HOME/.re.pl/repl.rc >>, and
 230 runs whatever code is in there as if you had entered it at the REPL shell
 231 yourself.
 232
 233 To set a new run control file that's also in that directory, pass it as a
 234 filename like so:
 235
 236  system$ re.pl --rcfile myproject.pc
 237
 238 If the filename happens to contain a forwardslash, then it's used absolutely,
 239 or realive to the current working directory:
 240
 241  system$ re.pl --rcfile /path/to/my/project/repl.rc
 242
 243 Within the run control file you might want to load plugins. This is covered in
 244 L</"The REPL shell object"> section, below.
 245
 246 =head2 Profiles
 247
 248 To allow for the sharing of run control files, you can fashion them into a
 249 Perl module for distribution (perhaps via the CPAN). For more information on
 250 this feature, please see the L<Devel::REPL::Profile> manual page.
 251
 252 A default profile ships with C<Devel::REPL>; it loads the following plugins:
 253
 254 =over 4
 255
 256 =item *
 257
 258 L<Devel::REPL::Plugin::History>
 259
 260 =item *
 261
 262 L<Devel::REPL::Plugin::LexEnv>
 263
 264 =item *
 265
 266 L<Devel::REPL::Plugin::DDS>
 267
 268 =item *
 269
 270 L<Devel::REPL::Plugin::Packages>
 271
 272 =item *
 273
 274 L<Devel::REPL::Plugin::Commands>
 275
 276 =item *
 277
 278 L<Devel::REPL::Plugin::MultiLine::PPI>
 279
 280 =back
 281
 282 =head2 Plugins
 283
 284 Plugins are a way to add funcionality to the REPL shell, and take advantage of
 285 C<Devel::REPL> being based on the L<Moose> object system for Perl 5. This
 286 means it's simple to 'hook into' many steps of the R-E-P-L process. Plugins
 287 can change the way commands are interpreted, or the way their results are
 288 output, or even add commands to the shell environment.
 289
 290 A number of plugins ship with C<Devel::REPL>, and more are available on the
 291 CPAN. Some of the shipped plugins are loaded in the default profile, mentioned
 292 above.
 293
 294 Writing your own plugins is not difficult, and is discussed in the
 295 L<Devel::REPL::Plugin> manual page, along with links to the manual pages of
 296 all the plugins shipped with C<Devel::REPL>.
 297
 298 =head2 The REPL shell object
 299
 300 From time to time you'll want to interact with or manipulate the
 301 C<Devel::REPL> shell object itself; that is, the instance of the shell you're
 302 currently running.
 303
 304 The object is always available through the C<$_REPL> variable. One common
 305 requirement is to load an additional plugin, after your profile and run
 306 control files have already been executed:
 307
 308  $_ $_REPL->load_plugin('Timing');
 309  1
 310  $_ print "Hello again, world!\n"
 311  Hello again, world!
 312  Took 0.00148296356201172 seconds.
 313  1
 314  $_
 315
 316 =head1 REQUIREMENTS
 317
 318 In addition to the contents of the standard Perl distribution, you will need
 319 the following:
 320
 321 =over 4
 322
 323 =item *
 324
 325 L<Moose> >= 0.64
 326
 327 =item *
 328
 329 L<MooseX::Object::Pluggable> >= 0.0009
 330
 331 =item *
 332
 333 L<MooseX::Getopt> >= 0.15
 334
 335 =item *
 336
 337 L<MooseX::AttributeHelpers> >= 0.14
 338
 339 =item *
 340
 341 L<namespace::clean>
 342
 343 =item *
 344
 345 L<File::HomeDir>
 346
 347 =item *
 348
 349 L<Task::Weaken>
 350
 351 =back
 352
 353 Optionally, some plugins if installed will require the following modules:
 354
 355 =over 4
 356
 357 =item *
 358
 359 L<PPI>
 360
 361 =item *
 362
 363 L<Data::Dump::Streamer>
 364
 365 =item *
 366
 367 L<File::Next>
 368
 369 =item *
 370
 371 L<B::Keywords>
 372
 373 =item *
 374
 375 L<Lexical::Persistence>
 376
 377 =item *
 378
 379 L<App::Nopaste>
 380
 381 =item *
 382
 383 L<Module::Refresh>
 384
 385 =back
 386
 387 =head1 AUTHOR
 388
 389 Matt S Trout - mst (at) shadowcatsystems.co.uk (L<http://www.shadowcatsystems.co.uk/>)
 390
 391 =head1 CONTRIBUTORS
 392
 393 =over 4
 394
 395 =item Stevan Little - stevan (at) iinteractive.com
 396
 397 =item Alexis Sukrieh - sukria+perl (at) sukria.net
 398
 399 =item epitaph
 400
 401 =item mgrimes - mgrimes (at) cpan dot org
 402
 403 =item Shawn M Moore - sartak (at) gmail.com
 404
 405 =item Oliver Gorwits - oliver on irc.perl.org
 406
 407 =item Andrew Moore - C<< <amoore@cpan.org> >>
 408
 409 =item Norbert Buchmuller C<< <norbi@nix.hu> >>
 410
 411 =item Dave Houston C<< <dhouston@cpan.org> >>
 412
 413 =back
 414
 415 =head1 LICENSE
 416
 417 This library is free software under the same terms as perl itself
 418
 419 =cut
 420
 421 1;