lib/Devel/GlobalDestruction.pm

   1 package Devel::GlobalDestruction;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION = '0.12';
   7
   8 use Sub::Exporter::Progressive -setup => {
   9   exports => [ qw(in_global_destruction) ],
  10   groups  => { default => [ -all ] },
  11 };
  12
  13 # we run 5.14+ - everything is in core
  14 #
  15 if (defined ${^GLOBAL_PHASE}) {
  16   eval 'sub in_global_destruction () { ${^GLOBAL_PHASE} eq q[DESTRUCT] }; 1'
  17     or die $@;
  18 }
  19 # try to load the xs version if it was compiled
  20 #
  21 elsif (eval {
  22   require Devel::GlobalDestruction::XS;
  23   no warnings 'once';
  24   *in_global_destruction = \&Devel::GlobalDestruction::XS::in_global_destruction;
  25   1;
  26 }) {
  27   # the eval already installed everything, nothing to do
  28 }
  29 else {
  30   # internally, PL_main_cv is set to Nullcv immediately before entering
  31   # global destruction and we can use B to detect that.  B::main_cv will
  32   # only ever be a B::CV or a B::SPECIAL that is a reference to 0
  33   require B;
  34   eval 'sub in_global_destruction () { ${B::main_cv()} == 0 }; 1'
  35     or die $@;
  36 }
  37
  38 1;  # keep require happy
  39
  40
  41 __END__
  42
  43 =head1 NAME
  44
  45 Devel::GlobalDestruction - Provides function returning the equivalent of
  46 C<${^GLOBAL_PHASE} eq 'DESTRUCT'> for older perls.
  47
  48 =head1 SYNOPSIS
  49
  50     package Foo;
  51     use Devel::GlobalDestruction;
  52
  53     use namespace::clean; # to avoid having an "in_global_destruction" method
  54
  55     sub DESTROY {
  56         return if in_global_destruction;
  57
  58         do_something_a_little_tricky();
  59     }
  60
  61 =head1 DESCRIPTION
  62
  63 Perl's global destruction is a little tricky to deal with WRT finalizers
  64 because it's not ordered and objects can sometimes disappear.
  65
  66 Writing defensive destructors is hard and annoying, and usually if global
  67 destruction is happening you only need the destructors that free up non
  68 process local resources to actually execute.
  69
  70 For these constructors you can avoid the mess by simply bailing out if global
  71 destruction is in effect.
  72
  73 =head1 EXPORTS
  74
  75 This module uses L<Sub::Exporter::Progressive> so the exports may be renamed,
  76 aliased, etc. if L<Sub::Exporter> is present.
  77
  78 =over 4
  79
  80 =item in_global_destruction
  81
  82 Returns true if the interpreter is in global destruction. In perl 5.14+, this
  83 returns C<${^GLOBAL_PHASE} eq 'DESTRUCT'>, and on earlier perls, detects it using
  84 the value of C<PL_main_cv> or C<PL_dirty>.
  85
  86 =back
  87
  88 =head1 AUTHORS
  89
  90 Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
  91
  92 Florian Ragwitz E<lt>rafl@debian.orgE<gt>
  93
  94 Jesse Luehrs E<lt>doy@tozt.netE<gt>
  95
  96 Peter Rabbitson E<lt>ribasushi@cpan.orgE<gt>
  97
  98 Arthur Axel 'fREW' Schmidt E<lt>frioux@gmail.comE<gt>
  99
 100 Elizabeth Mattijsen E<lt>liz@dijkmat.nlE<gt>
 101
 102 Greham Knop E<lt>haarg@haarg.orgE<gt>
 103
 104 =head1 COPYRIGHT
 105
 106     Copyright (c) 2008 Yuval Kogman. All rights reserved
 107     This program is free software; you can redistribute
 108     it and/or modify it under the same terms as Perl itself.
 109
 110 =cut