lib/Devel/Declare/MethodInstaller/Simple.pm

   1 package Devel::Declare::MethodInstaller::Simple;
   2
   3 use base 'Devel::Declare::Context::Simple';
   4
   5 use Devel::Declare ();
   6 use Sub::Name;
   7 use strict;
   8 use warnings;
   9
  10 our $VERSION = '0.003003';
  11
  12 sub install_methodhandler {
  13   my $class = shift;
  14   my %args  = @_;
  15   {
  16     no strict 'refs';
  17     *{$args{into}.'::'.$args{name}}   = sub (&) {};
  18   }
  19
  20   my $ctx = $class->new(%args);
  21   Devel::Declare->setup_for(
  22     $args{into},
  23     { $args{name} => { const => sub { $ctx->parser(@_) } } }
  24   );
  25 }
  26
  27 sub strip_attrs {
  28   my $self = shift;
  29   $self->skipspace;
  30
  31   my $linestr = Devel::Declare::get_linestr;
  32   my $attrs   = '';
  33
  34   if (substr($linestr, $self->offset, 1) eq ':') {
  35     while (substr($linestr, $self->offset, 1) ne '{') {
  36       if (substr($linestr, $self->offset, 1) eq ':') {
  37         substr($linestr, $self->offset, 1) = '';
  38         Devel::Declare::set_linestr($linestr);
  39
  40         $attrs .= ':';
  41       }
  42
  43       $self->skipspace;
  44       $linestr = Devel::Declare::get_linestr();
  45
  46       if (my $len = Devel::Declare::toke_scan_word($self->offset, 0)) {
  47         my $name = substr($linestr, $self->offset, $len);
  48         substr($linestr, $self->offset, $len) = '';
  49         Devel::Declare::set_linestr($linestr);
  50
  51         $attrs .= " ${name}";
  52
  53         if (substr($linestr, $self->offset, 1) eq '(') {
  54           my $length = Devel::Declare::toke_scan_str($self->offset);
  55           my $arg    = Devel::Declare::get_lex_stuff();
  56           Devel::Declare::clear_lex_stuff();
  57           $linestr = Devel::Declare::get_linestr();
  58           substr($linestr, $self->offset, $length) = '';
  59           Devel::Declare::set_linestr($linestr);
  60
  61           $attrs .= "(${arg})";
  62         }
  63       }
  64     }
  65
  66     $linestr = Devel::Declare::get_linestr();
  67   }
  68
  69   return $attrs;
  70 }
  71
  72 sub code_for {
  73   my ($self, $name) = @_;
  74
  75   if (defined $name) {
  76     my $pkg = $self->get_curstash_name;
  77     $name = join( '::', $pkg, $name )
  78       unless( $name =~ /::/ );
  79     return sub (&) {
  80       my $code = shift;
  81       # So caller() gets the subroutine name
  82       no strict 'refs';
  83       *{$name} = subname $name => $code;
  84       return;
  85     };
  86   } else {
  87     return sub (&) { shift };
  88   }
  89 }
  90
  91 sub install {
  92   my ($self, $name ) = @_;
  93
  94   $self->shadow( $self->code_for($name) );
  95 }
  96
  97 sub parser {
  98   my $self = shift;
  99   $self->init(@_);
 100
 101   $self->skip_declarator;
 102   my $name   = $self->strip_name;
 103   my $proto  = $self->strip_proto;
 104   my $attrs  = $self->strip_attrs;
 105   my @decl   = $self->parse_proto($proto);
 106   my $inject = $self->inject_parsed_proto(@decl);
 107   if (defined $name) {
 108     $inject = $self->scope_injector_call() . $inject;
 109   }
 110   $self->inject_if_block($inject, $attrs ? "sub ${attrs} " : '');
 111
 112   $self->install( $name );
 113
 114   return;
 115 }
 116
 117 sub parse_proto { '' }
 118
 119 sub inject_parsed_proto {
 120   return $_[1];
 121 }
 122
 123 1;
 124