lib/Data/Dumper/ToXS.pm

   1 package Data::Dumper::ToXS;
   2
   3 our (%ix, %seen);
   4
   5 sub _newix { $_[0].'['.($ix{$_[0]}++).']' }
   6 sub _getglob { \*{$_[0]} }
   7
   8 use B qw(svref_2object cstring);
   9 use Scalar::Util qw(refaddr);
  10 use Moo;
  11
  12 has target_package => (is => 'ro', required => 1);
  13
  14 has _to_generate => (is => 'ro', default => sub { [] });
  15
  16 sub add_generator {
  17   my ($self, $name, $ref) = @_;
  18   die "Generation target must be a reference" unless ref($ref);
  19   push(@{$self->_to_generate}, [ $name => $ref ]);
  20 }
  21
  22 sub xs_code {
  23   my ($self) = @_;
  24   my @do = @{$self->_to_generate};
  25   join "\n\n", $self->_preamble,
  26     (map $self->_generate_target(@$_), @do),
  27     $self->_package_start($self->target_package),
  28     (map $self->_generate_xsub($_->[0]), @do);
  29 }
  30
  31 sub _preamble {
  32   <<'END';
  33 #define PERL_NO_GET_CONTEXT
  34 #include "EXTERN.h"
  35 #include "perl.h"
  36 #include "XSUB.h"
  37
  38 END
  39 }
  40
  41 sub _package_start {
  42   my ($self, $package) = @_;
  43   <<"END";
  44 MODULE = ${package} PACKAGE = ${package}
  45
  46 PROTOTYPES: DISABLE
  47
  48 END
  49 }
  50
  51 sub _generate_xsub {
  52   my ($self, $name) = @_;
  53   <<"END";
  54 SV *
  55 ${name}()
  56   CODE:
  57     RETVAL = ${name}(aTHX);
  58   OUTPUT:
  59     RETVAL
  60 END
  61 }
  62
  63 sub _generate_target {
  64   my ($self, $name, $ref) = @_;
  65   local %ix = map +($_ => 0), qw(av hv sv);
  66   local %seen;
  67   my $first = _newix('sv');
  68   my $body = $self->_dump_svrv($first, $ref);
  69   my $vars = join '', map +(
  70     $ix{$_} ? "  ${\uc}* ${_}[$ix{$_}];\n" : ""
  71   ), qw(av hv sv);
  72   <<"END";
  73 SV * ${name} (pTHX)
  74 {
  75 ${vars}${body}  return ${first};
  76 }
  77 END
  78 }
  79
  80 sub _dump_svrv {
  81   my ($self, $ix, $ref) = @_;
  82   my $r = ref($ref);
  83   if ($seen{$ref}) {
  84     # already seen this reference so make a copy
  85     "  ${ix} = newSVsv($seen{$ref});\n";
  86   } else {
  87     $seen{$ref} = $ix;
  88     if ($r eq 'SCALAR') {
  89       my $t_ix = _newix('sv');
  90       join '',
  91         $self->_dump_sv($t_ix, $ref),
  92         "  ${ix} = newRV_noinc(${t_ix});\n";
  93     } elsif ($r eq 'HASH') {
  94       my $t_ix = _newix('hv');
  95       join '',
  96         $self->_dump_hv($t_ix, $ref),
  97         "  ${ix} = newRV_noinc((SV *)${t_ix});\n";
  98     } elsif ($r eq 'ARRAY') {
  99       my $t_ix = _newix('av');
 100       join '',
 101         $self->_dump_av($t_ix, $ref),
 102         "  ${ix} = newRV_noinc((SV *)${t_ix});\n";
 103     } elsif ($r eq 'REF') {
 104       my $t_ix = _newix('sv');
 105       join '',
 106         $self->_dump_svrv($t_ix, $$ref),
 107         "  ${ix} = newRV_noinc(${t_ix});\n";
 108     } elsif ($r eq 'CODE') {
 109       my $full_name = join '::',
 110         map $_->NAME, map +($_->GV->STASH, $_->GV), svref_2object($ref);
 111       if (*{_getglob($full_name)}{CODE}||'' eq $ref) {
 112         # GV_ADD strikes me as more likely to DWIM than to simply blow up
 113         # if the generated routine gets called before the method is declared.
 114         "  ${ix} = newRV_inc((SV *) get_cv(${\cstring $full_name}, GV_ADD));\n";
 115       } else {
 116         die "Can't find ${ref} at ${full_name}";
 117       }
 118     } else {
 119       die "Can't handle reftype ${r}";
 120     }
 121   }
 122 }
 123
 124 sub _dump_sv {
 125   my ($self, $ix, $ref) = @_;
 126   if (ref($$ref)) {
 127     $self->_dump_svrv($ix, $$ref);
 128   } else {
 129     # Not a reference. What are we dumping?
 130     my $sv = svref_2object($ref);
 131     if (!defined($$ref)) {
 132       "  ${ix} = newSVsv(&PL_sv_undef);\n";
 133     } elsif ($sv->isa('B::IV')) {
 134       "  ${ix} = newSViv(".$sv->int_value.");\n";
 135     } elsif ($sv->isa('B::NV')) {
 136       "  ${ix} = newSVnv(".$sv->NV.");\n";
 137     } elsif ($sv->isa('B::PV')) {
 138       "  ${ix} = newSVpvs(".cstring($$ref).");\n";
 139     } else {
 140       die "Unsure how to dump ".$$ref;
 141     }
 142   }
 143 }
 144
 145 sub _dump_hv {
 146   my ($self, $ix, $ref) = @_;
 147   join '',
 148     "  ${ix} = newHV();\n",
 149     map {
 150       my $t_ix = _newix('sv');
 151       ($self->_dump_sv($t_ix, \($ref->{$_})),
 152       "  hv_stores(${ix}, ${\cstring $_}, ${t_ix});\n")
 153     } sort keys %$ref;
 154 }
 155
 156 sub _dump_av {
 157   my ($self, $ix, $ref) = @_;
 158   join '',
 159     "  ${ix} = newAV();\n",
 160     map {
 161       my $t_ix = _newix('sv');
 162       $self->_dump_sv($t_ix, \($ref->[$_])),
 163       "  av_push(${ix}, ${t_ix});\n"
 164     } 0 .. $#$ref;
 165 }
 166
 167 1;