lib/Config/Any/YAML.pm

   1 package Config::Any::YAML;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Config::Any::Base';
   7
   8 use Carp ();
   9
  10 =head1 NAME
  11
  12 Config::Any::YAML - Load YAML config files
  13
  14 =head1 DESCRIPTION
  15
  16 Loads YAML files. Example:
  17
  18     ---
  19     name: TestApp
  20     Controller::Foo:
  21         foo: bar
  22     Model::Baz:
  23         qux: xyzzy
  24
  25
  26 =head1 METHODS
  27
  28 =head2 extensions( )
  29
  30 return an array of valid extensions (C<yml>, C<yaml>).
  31
  32 =cut
  33
  34 sub extensions {
  35     return qw( yml yaml );
  36 }
  37
  38 =head2 load( $file )
  39
  40 Attempts to load C<$file> as a YAML file.
  41
  42 =cut
  43
  44 sub load {
  45     my $class = shift;
  46     my $file  = shift;
  47
  48     if (eval { require YAML::XS; 1 }) {
  49         return YAML::XS::LoadFile( $file );
  50     }
  51     elsif ($] > 5.008008 && eval { require YAML::Syck; YAML::Syck->VERSION(0.70) } ) {
  52         open( my $fh, $file ) or die $!;
  53         my $content = do { local $/; <$fh> };
  54         close $fh;
  55         return YAML::Syck::Load( $content );
  56     }
  57
  58     require YAML;
  59     return YAML::LoadFile( $file );
  60 }
  61
  62 =head2 requires_any_of( )
  63
  64 Specifies that this modules requires one of L<YAML::XS>, L<YAML::Syck> (0.70) or
  65 L<YAML> in order to work.
  66
  67 =cut
  68
  69 sub requires_any_of {
  70     'YAML::XS', ( $] > 5.008008 ? [ 'YAML::Syck', '0.70' ] : ()), 'YAML';
  71 }
  72
  73 =head1 AUTHOR
  74
  75 Brian Cassidy E<lt>bricas@cpan.orgE<gt>
  76
  77 =head1 COPYRIGHT AND LICENSE
  78
  79 Copyright 2006-2016 by Brian Cassidy
  80
  81 This library is free software; you can redistribute it and/or modify
  82 it under the same terms as Perl itself.
  83
  84 =head1 SEE ALSO
  85
  86 =over 4
  87
  88 =item * L<Catalyst>
  89
  90 =item * L<Config::Any>
  91
  92 =item * L<YAML::XS>
  93
  94 =item * L<YAML>
  95
  96 =item * L<YAML::Syck>
  97
  98 =back
  99
 100 =cut
 101
 102 1;