lib/Config/Any/JSON.pm

   1 package Config::Any::JSON;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Config::Any::Base';
   7
   8 =head1 NAME
   9
  10 Config::Any::JSON - Load JSON config files
  11
  12 =head1 DESCRIPTION
  13
  14 Loads JSON files. Example:
  15
  16     {
  17         "name": "TestApp",
  18         "Controller::Foo": {
  19             "foo": "bar"
  20         },
  21         "Model::Baz": {
  22             "qux": "xyzzy"
  23         }
  24     }
  25
  26 =head1 METHODS
  27
  28 =head2 extensions( )
  29
  30 return an array of valid extensions (C<json>, C<jsn>).
  31
  32 =cut
  33
  34 sub extensions {
  35     return qw( json jsn );
  36 }
  37
  38 =head2 load( $file )
  39
  40 Attempts to load C<$file> as a JSON file.
  41
  42 =cut
  43
  44 sub load {
  45     my $class = shift;
  46     my $file  = shift;
  47
  48     open( my $fh, '<', $file ) or die $!;
  49     binmode $fh;
  50     my $content = do { local $/; <$fh> };
  51     close $fh;
  52
  53     if ( eval { require JSON::DWIW } ) {
  54         my $decoder = JSON::DWIW->new;
  55         my ( $data, $error ) = $decoder->from_json( $content );
  56         die $error if $error;
  57         return $data;
  58     }
  59     elsif ( eval { require JSON::XS } ) {
  60         my $decoder = JSON::XS->new->utf8->relaxed;
  61         return $decoder->decode( $content );
  62     }
  63     elsif ( eval { require JSON::Syck } ) {
  64         require Encode;
  65         return JSON::Syck::Load( Encode::decode('UTF-8', $content ) );
  66     }
  67     elsif ( eval { require JSON::PP; JSON::PP->VERSION( 2 ); } ) {
  68         my $decoder = JSON::PP->new->utf8->relaxed;
  69         return $decoder->decode( $content );
  70     }
  71     require JSON;
  72     if ( eval { JSON->VERSION( 2 ) } ) {
  73         return JSON::decode_json( $content );
  74     }
  75     else {
  76         return JSON::jsonToObj( $content );
  77     }
  78 }
  79
  80 =head2 requires_any_of( )
  81
  82 Specifies that this modules requires one of,  L<JSON::DWIW>, L<JSON::XS>,
  83 L<JSON::Syck> or L<JSON> in order to work.
  84
  85 =cut
  86
  87 sub requires_any_of { 'JSON::DWIW', 'JSON::XS', 'JSON::Syck', 'JSON::PP', 'JSON' }
  88
  89 =head1 AUTHOR
  90
  91 Brian Cassidy E<lt>bricas@cpan.orgE<gt>
  92
  93 =head1 COPYRIGHT AND LICENSE
  94
  95 Copyright 2006-2016 by Brian Cassidy
  96
  97 This library is free software; you can redistribute it and/or modify
  98 it under the same terms as Perl itself.
  99
 100 =head1 SEE ALSO
 101
 102 =over 4
 103
 104 =item * L<Catalyst>
 105
 106 =item * L<Config::Any>
 107
 108 =item * L<JSON::DWIW>
 109
 110 =item * L<JSON::XS>
 111
 112 =item * L<JSON::Syck>
 113
 114 =item * L<JSON>
 115
 116 =back
 117
 118 =cut
 119
 120 1;