lib/Config/Any.pm

   1 package Config::Any;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp;
   7 use Module::Pluggable::Object ();
   8
   9 our $VERSION = '0.12';
  10
  11 =head1 NAME
  12
  13 Config::Any - Load configuration from different file formats, transparently
  14
  15 =head1 SYNOPSIS
  16
  17     use Config::Any;
  18
  19     my $cfg = Config::Any->load_stems({stems => \@filepath_stems, ... });
  20     # or
  21     my $cfg = Config::Any->load_files({files => \@filepaths, ... });
  22
  23     for (@$cfg) {
  24         my ($filename, $config) = %$_;
  25         $class->config($config);
  26         warn "loaded config from file: $filename";
  27     }
  28
  29 =head1 DESCRIPTION
  30
  31 L<Config::Any|Config::Any> provides a facility for Perl applications and libraries
  32 to load configuration data from multiple different file formats. It supports XML, YAML,
  33 JSON, Apache-style configuration, Windows INI files, and even Perl code.
  34
  35 The rationale for this module is as follows: Perl programs are deployed on many different
  36 platforms and integrated with many different systems. Systems administrators and end
  37 users may prefer different configuration formats than the developers. The flexibility
  38 inherent in a multiple format configuration loader allows different users to make
  39 different choices, without generating extra work for the developers. As a developer
  40 you only need to learn a single interface to be able to use the power of different
  41 configuration formats.
  42
  43 =head1 INTERFACE
  44
  45 =cut
  46
  47 =head2 load_files( \%args )
  48
  49     Config::Any->load_files( { files => \@files } );
  50     Config::Any->load_files( { files => \@files, filter  => \&filter } );
  51     Config::Any->load_files( { files => \@files, use_ext => 1 } );
  52
  53 C<load_files()> attempts to load configuration from the list of files passed in
  54 the C<files> parameter, if the file exists.
  55
  56 If the C<filter> parameter is set, it is used as a callback to modify the configuration
  57 data before it is returned. It will be passed a single hash-reference parameter which
  58 it should modify in-place.
  59
  60 If the C<use_ext> parameter is defined, the loader will attempt to parse the file
  61 extension from each filename and will skip the file unless it matches a standard
  62 extension for the loading plugins. Only plugins whose standard extensions match the
  63 file extension will be used. For efficiency reasons, its use is encouraged, but
  64 be aware that you will lose flexibility -- for example, a file called C<myapp.cfg>
  65 containing YAML data will not be offered to the YAML plugin, whereas C<myapp.yml>
  66 or C<myapp.yaml> would be.
  67
  68 C<load_files()> also supports a 'force_plugins' parameter, whose value should be an
  69 arrayref of plugin names like C<Config::Any::INI>. Its intended use is to allow the use
  70 of a non-standard file extension while forcing it to be offered to a particular parser.
  71 It is not compatible with 'use_ext'.
  72
  73 You can supply a C<driver_args> hashref to pass special options to a particular
  74 parser object. Example:
  75
  76     Config::Any->load_files( { files => \@files, driver_args => {
  77         General => { -LowerCaseNames => 1 }
  78     } )
  79
  80 =cut
  81
  82 sub load_files {
  83     my ( $class, $args ) = @_;
  84
  85     unless ( $args && exists $args->{ files } ) {
  86         warn "No files specified!";
  87         return;
  88     }
  89
  90     return $class->_load( $args );
  91 }
  92
  93 =head2 load_stems( \%args )
  94
  95     Config::Any->load_stems( { stems => \@stems } );
  96     Config::Any->load_stems( { stems => \@stems, filter  => \&filter } );
  97     Config::Any->load_stems( { stems => \@stems, use_ext => 1 } );
  98
  99 C<load_stems()> attempts to load configuration from a list of files which it generates
 100 by combining the filename stems list passed in the C<stems> parameter with the
 101 potential filename extensions from each loader, which you can check with the
 102 C<extensions()> classmethod described below. Once this list of possible filenames is
 103 built it is treated exactly as in C<load_files()> above, as which it takes the same
 104 parameters. Please read the C<load_files()> documentation before using this method.
 105
 106 =cut
 107
 108 sub load_stems {
 109     my ( $class, $args ) = @_;
 110
 111     unless ( $args && exists $args->{ stems } ) {
 112         warn "No stems specified!";
 113         return;
 114     }
 115
 116     my $stems = delete $args->{ stems };
 117     my @files;
 118     for my $s ( @$stems ) {
 119         for my $ext ( $class->extensions ) {
 120             push @files, "$s.$ext";
 121         }
 122     }
 123
 124     $args->{ files } = \@files;
 125     return $class->_load( $args );
 126 }
 127
 128 sub _load {
 129     my ( $class, $args ) = @_;
 130     croak "_load requires a arrayref of file paths" unless $args->{ files };
 131
 132     my $force = defined $args->{ force_plugins };
 133     if ( !$force and !defined $args->{ use_ext } ) {
 134         warn
 135             "use_ext argument was not explicitly set, as of 0.09, this is true by default";
 136         $args->{ use_ext } = 1;
 137     }
 138
 139     # figure out what plugins we're using
 140     my @plugins = $force ? @{ $args->{ force_plugins } } : $class->plugins;
 141
 142     # map extensions if we have to
 143     my ( %extension_lut, $extension_re );
 144     my $use_ext_lut = !$force && $args->{ use_ext };
 145     if ( $use_ext_lut ) {
 146         for my $plugin ( @plugins ) {
 147             $extension_lut{ $_ } = $plugin for $plugin->extensions;
 148         }
 149
 150         $extension_re = join( '|', keys %extension_lut );
 151     }
 152
 153     # map args to plugins
 154     my $base_class = __PACKAGE__;
 155     my %loader_args;
 156     for my $plugin ( @plugins ) {
 157         $plugin =~ m{^$base_class\::(.+)};
 158         $loader_args{ $plugin } = $args->{ driver_args }->{ $1 } || {};
 159     }
 160
 161     my @results;
 162
 163     for my $filename ( @{ $args->{ files } } ) {
 164
 165         # don't even bother if it's not there
 166         next unless -f $filename;
 167
 168         my @try_plugins = @plugins;
 169
 170         if ( $use_ext_lut ) {
 171             $filename =~ m{\.($extension_re)\z};
 172             next unless $1;
 173             @try_plugins = $extension_lut{ $1 };
 174         }
 175
 176         for my $loader ( @try_plugins ) {
 177             next unless $loader->is_supported;
 178             my @configs
 179                 = eval { $loader->load( $filename, $loader_args{ $loader } ); };
 180
 181             # fatal error if we used extension matching
 182             croak "Error parsing $filename: $@" if $@ and $use_ext_lut;
 183             next if $@ or !@configs;
 184
 185             # post-process config with a filter callback
 186             if ( $args->{ filter } ) {
 187                 $args->{ filter }->( $_ ) for @configs;
 188             }
 189
 190             push @results,
 191                 { $filename => @configs == 1 ? $configs[ 0 ] : \@configs };
 192             last;
 193         }
 194     }
 195
 196     return \@results;
 197 }
 198
 199 =head2 finder( )
 200
 201 The C<finder()> classmethod returns the
 202 L<Module::Pluggable::Object|Module::Pluggable::Object>
 203 object which is used to load the plugins. See the documentation for that module for
 204 more information.
 205
 206 =cut
 207
 208 sub finder {
 209     my $class  = shift;
 210     my $finder = Module::Pluggable::Object->new(
 211         search_path => [ __PACKAGE__ ],
 212         require     => 1
 213     );
 214     return $finder;
 215 }
 216
 217 =head2 plugins( )
 218
 219 The C<plugins()> classmethod returns the names of configuration loading plugins as
 220 found by L<Module::Pluggable::Object|Module::Pluggable::Object>.
 221
 222 =cut
 223
 224 sub plugins {
 225     my $class = shift;
 226     return $class->finder->plugins;
 227 }
 228
 229 =head2 extensions( )
 230
 231 The C<extensions()> classmethod returns the possible file extensions which can be loaded
 232 by C<load_stems()> and C<load_files()>. This may be useful if you set the C<use_ext>
 233 parameter to those methods.
 234
 235 =cut
 236
 237 sub extensions {
 238     my $class = shift;
 239     my @ext = map { $_->extensions } $class->plugins;
 240     return wantarray ? @ext : \@ext;
 241 }
 242
 243 =head1 DIAGNOSTICS
 244
 245 =over
 246
 247 =item C<No files specified!> or C<No stems specified!>
 248
 249 The C<load_files()> and C<load_stems()> methods will issue this warning if
 250 called with an empty list of files/stems to load.
 251
 252 =item C<_load requires a arrayref of file paths>
 253
 254 This fatal error will be thrown by the internal C<_load> method. It should not occur
 255 but is specified here for completeness. If your code dies with this error, please
 256 email a failing test case to the authors below.
 257
 258 =back
 259
 260 =head1 CONFIGURATION AND ENVIRONMENT
 261
 262 Config::Any requires no configuration files or environment variables.
 263
 264 =head1 DEPENDENCIES
 265
 266 L<Module::Pluggable|Module::Pluggable>
 267
 268 And at least one of the following:
 269 L<Config::General|Config::General>
 270 L<Config::Tiny|Config::Tiny>
 271 L<JSON|JSON>
 272 L<YAML|YAML>
 273 L<JSON::Syck|JSON::Syck>
 274 L<YAML::Syck|YAML::Syck>
 275 L<XML::Simple|XML::Simple>
 276
 277 =head1 INCOMPATIBILITIES
 278
 279 None reported.
 280
 281 =head1 BUGS AND LIMITATIONS
 282
 283 No bugs have been reported.
 284
 285 Please report any bugs or feature requests to
 286 C<bug-config-any@rt.cpan.org>, or through the web interface at
 287 L<http://rt.cpan.org>.
 288
 289 =head1 AUTHOR
 290
 291 Joel Bernstein  E<lt>rataxis@cpan.orgE<gt>
 292
 293 =head1 CONTRIBUTORS
 294
 295 This module was based on the original
 296 L<Catalyst::Plugin::ConfigLoader|Catalyst::Plugin::ConfigLoader>
 297 module by Brian Cassidy C<< <bricas@cpan.org> >>.
 298
 299 With ideas and support from Matt S Trout C<< <mst@shadowcatsystems.co.uk> >>.
 300
 301 Further enhancements suggested by Evan Kaufman C<< <evank@cpan.org> >>.
 302
 303 =head1 LICENCE AND COPYRIGHT
 304
 305 Copyright (c) 2006, Portugal Telecom C<< http://www.sapo.pt/ >>. All rights reserved.
 306 Portions copyright 2007, Joel Bernstein C<< <rataxis@cpan.org> >>.
 307
 308 This module is free software; you can redistribute it and/or
 309 modify it under the same terms as Perl itself. See L<perlartistic>.
 310
 311 =head1 DISCLAIMER OF WARRANTY
 312
 313 BECAUSE THIS SOFTWARE IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
 314 FOR THE SOFTWARE, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN
 315 OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
 316 PROVIDE THE SOFTWARE "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER
 317 EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 318 WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE
 319 ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE SOFTWARE IS WITH
 320 YOU. SHOULD THE SOFTWARE PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL
 321 NECESSARY SERVICING, REPAIR, OR CORRECTION.
 322
 323 IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
 324 WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
 325 REDISTRIBUTE THE SOFTWARE AS PERMITTED BY THE ABOVE LICENCE, BE
 326 LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL,
 327 OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE
 328 THE SOFTWARE (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING
 329 RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A
 330 FAILURE OF THE SOFTWARE TO OPERATE WITH ANY OTHER SOFTWARE), EVEN IF
 331 SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF
 332 SUCH DAMAGES.
 333
 334 =head1 SEE ALSO
 335
 336 L<Catalyst::Plugin::ConfigLoader|Catalyst::Plugin::ConfigLoader>
 337 -- now a wrapper around this module.
 338
 339 =cut
 340
 341 "Drink more beer";