t/role-tiny.t

   1 use strictures 1;
   2 use Test::More;
   3 use Test::Fatal;
   4
   5 BEGIN {
   6   package MyRole;
   7
   8   use Role::Tiny;
   9
  10   requires qw(req1 req2);
  11
  12   around foo => sub { my $orig = shift; join ' ', 'role foo', $orig->(@_) };
  13
  14   sub bar { 'role bar' }
  15
  16   sub baz { 'role baz' }
  17 }
  18
  19 BEGIN {
  20   package MyClass;
  21
  22   use constant SIMPLE => 'simple';
  23   use constant REF_CONST => [ 'ref_const' ];
  24
  25   sub req1 { }
  26   sub req2 { }
  27   sub foo { 'class foo' }
  28   sub baz { 'class baz' }
  29
  30 }
  31
  32 BEGIN {
  33   package ExtraClass;
  34   sub req1 { }
  35   sub req2 { }
  36   sub req3 { }
  37   sub foo { }
  38   sub baz { 'class baz' }
  39 }
  40
  41 BEGIN {
  42   package IntermediaryRole;
  43   use Role::Tiny;
  44   requires 'req3';
  45 }
  46
  47 BEGIN {
  48   package NoMethods;
  49
  50   package OneMethod;
  51
  52   sub req1 { }
  53 }
  54
  55 sub try_apply_to {
  56   my $to = shift;
  57   exception { Role::Tiny->apply_role_to_package($to, 'MyRole') }
  58 }
  59
  60 is(try_apply_to('MyClass'), undef, 'role applies cleanly');
  61 is(MyClass->foo, 'role foo class foo', 'method modifier');
  62 is(MyClass->bar, 'role bar', 'method from role');
  63 is(MyClass->baz, 'class baz', 'method from class');
  64 ok(MyClass->does('MyRole'), 'class does role');
  65 ok(!MyClass->does('Random'), 'class does not do non-role');
  66
  67 like(try_apply_to('NoMethods'), qr/req1, req2/, 'error for both methods');
  68 like(try_apply_to('OneMethod'), qr/req2/, 'error for one method');
  69
  70 is exception {
  71   Role::Tiny->apply_role_to_package('IntermediaryRole', 'MyRole');
  72   Role::Tiny->apply_role_to_package('ExtraClass', 'IntermediaryRole');
  73 }, undef, 'No errors applying roles';
  74
  75 ok(ExtraClass->does('MyRole'), 'ExtraClass does MyRole');
  76 ok(ExtraClass->does('IntermediaryRole'), 'ExtraClass does IntermediaryRole');
  77 is(ExtraClass->bar, 'role bar', 'method from role');
  78 is(ExtraClass->baz, 'class baz', 'method from class');
  79
  80 done_testing;
  81