lib/Role/Tiny.pm

   1 package Role::Tiny;
   2
   3 sub _getglob { \*{$_[0]} }
   4 sub _getstash { \%{"$_[0]::"} }
   5
   6 use strict;
   7 use warnings FATAL => 'all';
   8
   9 our $VERSION = '1.002005'; # 1.2.5
  10 $VERSION = eval $VERSION;
  11
  12 our %INFO;
  13 our %APPLIED_TO;
  14 our %COMPOSED;
  15 our %COMPOSITE_INFO;
  16
  17 # Module state workaround totally stolen from Zefram's Module::Runtime.
  18
  19 BEGIN {
  20   *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
  21 }
  22
  23 sub Role::Tiny::__GUARD__::DESTROY {
  24   delete $INC{$_[0]->[0]} if @{$_[0]};
  25 }
  26
  27 sub _load_module {
  28   (my $proto = $_[0]) =~ s/::/\//g;
  29   $proto .= '.pm';
  30   return 1 if $INC{$proto};
  31   # can't just ->can('can') because a sub-package Foo::Bar::Baz
  32   # creates a 'Baz::' key in Foo::Bar's symbol table
  33   return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  34   my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
  35     && bless([ $proto ], 'Role::Tiny::__GUARD__');
  36   require $proto;
  37   pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  38   return 1;
  39 }
  40
  41 sub import {
  42   my $target = caller;
  43   my $me = shift;
  44   strict->import;
  45   warnings->import(FATAL => 'all');
  46   return if $INFO{$target}; # already exported into this package
  47   $INFO{$target}{is_role} = 1;
  48   # get symbol table reference
  49   my $stash = _getstash($target);
  50   # install before/after/around subs
  51   foreach my $type (qw(before after around)) {
  52     *{_getglob "${target}::${type}"} = sub {
  53       require Class::Method::Modifiers;
  54       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  55       return;
  56     };
  57   }
  58   *{_getglob "${target}::requires"} = sub {
  59     push @{$INFO{$target}{requires}||=[]}, @_;
  60     return;
  61   };
  62   *{_getglob "${target}::with"} = sub {
  63     $me->apply_roles_to_package($target, @_);
  64     return;
  65   };
  66   # grab all *non-constant* (stash slot is not a scalarref) subs present
  67   # in the symbol table and store their refaddrs (no need to forcibly
  68   # inflate constant subs into real subs) with a map to the coderefs in
  69   # case of copying or re-use
  70   my @not_methods = (map { *$_{CODE}||() } grep !ref($_), values %$stash);
  71   @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  72   # a role does itself
  73   $APPLIED_TO{$target} = { $target => undef };
  74 }
  75
  76 sub role_application_steps {
  77   qw(_install_methods _check_requires _install_modifiers _copy_applied_list);
  78 }
  79
  80 sub apply_single_role_to_package {
  81   my ($me, $to, $role) = @_;
  82
  83   _load_module($role);
  84
  85   die "This is apply_role_to_package" if ref($to);
  86   die "${role} is not a Role::Tiny" unless $INFO{$role};
  87
  88   foreach my $step ($me->role_application_steps) {
  89     $me->$step($to, $role);
  90   }
  91 }
  92
  93 sub _copy_applied_list {
  94   my ($me, $to, $role) = @_;
  95   # copy our role list into the target's
  96   @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
  97 }
  98
  99 sub apply_roles_to_object {
 100   my ($me, $object, @roles) = @_;
 101   die "No roles supplied!" unless @roles;
 102   my $class = ref($object);
 103   bless($object, $me->create_class_with_roles($class, @roles));
 104   $object;
 105 }
 106
 107 sub create_class_with_roles {
 108   my ($me, $superclass, @roles) = @_;
 109
 110   die "No roles supplied!" unless @roles;
 111
 112   _load_module($superclass);
 113   {
 114     my %seen;
 115     $seen{$_}++ for @roles;
 116     if (my @dupes = grep $seen{$_} > 1, @roles) {
 117       die "Duplicated roles: ".join(', ', @dupes);
 118     }
 119   }
 120
 121   my $new_name = join(
 122     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 123   );
 124
 125   return $new_name if $COMPOSED{class}{$new_name};
 126
 127   foreach my $role (@roles) {
 128     _load_module($role);
 129     die "${role} is not a Role::Tiny" unless $INFO{$role};
 130   }
 131
 132   if ($] >= 5.010) {
 133     require mro;
 134   } else {
 135     require MRO::Compat;
 136   }
 137
 138   my @composable = map $me->_composable_package_for($_), reverse @roles;
 139
 140   my $composite_info = $me->_composite_info_for(@roles);
 141   my %conflicts = %{$composite_info->{conflicts}};
 142   if (keys %conflicts) {
 143     my $fail =
 144       join "\n",
 145         map {
 146           "Method name conflict for '$_' between roles "
 147           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 148           .", cannot apply these simultaneously to an object."
 149         } keys %conflicts;
 150     die $fail;
 151   }
 152
 153   my @requires = grep {
 154     my $method = $_;
 155     !grep $_->can($method) && !$COMPOSED{role}{$_}{modifiers_only}{$method},
 156       @composable
 157   } @{$composite_info->{requires}};
 158
 159   $me->_check_requires(
 160     $superclass, $compose_name, \@requires
 161   );
 162
 163   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 164
 165   @{$APPLIED_TO{$new_name}||={}}{
 166     map keys %{$APPLIED_TO{$_}}, @roles
 167   } = ();
 168
 169   $COMPOSED{class}{$new_name} = 1;
 170   return $new_name;
 171 }
 172
 173 # preserved for compat, and apply_roles_to_package calls it to allow an
 174 # updated Role::Tiny to use a non-updated Moo::Role
 175
 176 sub apply_role_to_package { shift->apply_single_role_to_package(@_) }
 177
 178 sub apply_roles_to_package {
 179   my ($me, $to, @roles) = @_;
 180
 181   return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;
 182
 183   my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
 184   delete $conflicts{$_} for keys %{ $me->_concrete_methods_of($to) };
 185   if (keys %conflicts) {
 186     my $fail =
 187       join "\n",
 188         map {
 189           "Due to a method name conflict between roles "
 190           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 191           .", the method '$_' must be implemented by '${to}'"
 192         } keys %conflicts;
 193     die $fail;
 194   }
 195
 196   # the if guard here is essential since otherwise we accidentally create
 197   # a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
 198   # autovivification hates us and wants us to die()
 199   if ($INFO{$to}) {
 200     delete $INFO{$to}{methods}; # reset since we're about to add methods
 201   }
 202
 203   # backcompat: allow subclasses to use apply_single_role_to_package
 204   # to apply changes.  set a local var so ours does nothing.
 205   our %BACKCOMPAT_HACK;
 206   if($me ne __PACKAGE__
 207       and exists $BACKCOMPAT_HACK{$me} ? $BACKCOMPAT_HACK{$me} :
 208       $BACKCOMPAT_HACK{$me} =
 209         $me->can('role_application_steps')
 210           == \&role_application_steps
 211         && $me->can('apply_single_role_to_package')
 212           != \&apply_single_role_to_package
 213   ) {
 214     foreach my $role (@roles) {
 215       $me->apply_single_role_to_package($to, $role);
 216     }
 217   }
 218   else {
 219     foreach my $step ($me->role_application_steps) {
 220       foreach my $role (@roles) {
 221         $me->$step($to, $role);
 222       }
 223     }
 224   }
 225   $APPLIED_TO{$to}{join('|',@roles)} = 1;
 226 }
 227
 228 sub _composite_info_for {
 229   my ($me, @roles) = @_;
 230   $COMPOSITE_INFO{join('|', sort @roles)} ||= do {
 231     foreach my $role (@roles) {
 232       _load_module($role);
 233     }
 234     my %methods;
 235     foreach my $role (@roles) {
 236       my $this_methods = $me->_concrete_methods_of($role);
 237       $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
 238     }
 239     my %requires;
 240     @requires{map @{$INFO{$_}{requires}||[]}, @roles} = ();
 241     delete $requires{$_} for keys %methods;
 242     delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
 243     +{ conflicts => \%methods, requires => [keys %requires] }
 244   };
 245 }
 246
 247 sub _composable_package_for {
 248   my ($me, $role) = @_;
 249   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 250   return $composed_name if $COMPOSED{role}{$composed_name};
 251   $me->_install_methods($composed_name, $role);
 252   my $base_name = $composed_name.'::_BASE';
 253   # force stash to exist
 254   _getstash($base_name);
 255   # Not using _getglob, since setting @ISA via the typeglob breaks
 256   # inheritance on 5.10.0 if the stash has previously been accessed an
 257   # then a method called on the class (in that order!), which
 258   # ->_install_methods (with the help of ->_install_does) ends up doing.
 259   { no strict 'refs'; @{"${composed_name}::ISA"} = ( $base_name ); }
 260   my $modifiers = $INFO{$role}{modifiers}||[];
 261   my @mod_base;
 262   my @modifiers = grep !$composed_name->can($_),
 263     do { my %h; @h{map @{$_}[1..$#$_-1], @$modifiers} = (); keys %h };
 264   foreach my $modified (@modifiers) {
 265     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
 266   }
 267   my $e;
 268   {
 269     local $@;
 270     eval(my $code = join "\n", "package ${base_name};", @mod_base);
 271     $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
 272   }
 273   die $e if $e;
 274   $me->_install_modifiers($composed_name, $role);
 275   $COMPOSED{role}{$composed_name} = {
 276     modifiers_only => { map { $_ => 1 } @modifiers },
 277   };
 278   return $composed_name;
 279 }
 280
 281 sub _check_requires {
 282   my ($me, $to, $name, $requires) = @_;
 283   return unless my @requires = @{$requires||$INFO{$name}{requires}||[]};
 284   if (my @requires_fail = grep !$to->can($_), @requires) {
 285     # role -> role, add to requires, role -> class, error out
 286     if (my $to_info = $INFO{$to}) {
 287       push @{$to_info->{requires}||=[]}, @requires_fail;
 288     } else {
 289       die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
 290     }
 291   }
 292 }
 293
 294 sub _concrete_methods_of {
 295   my ($me, $role) = @_;
 296   my $info = $INFO{$role};
 297   # grab role symbol table
 298   my $stash = _getstash($role);
 299   # reverse so our keys become the values (captured coderefs) in case
 300   # they got copied or re-used since
 301   my $not_methods = { reverse %{$info->{not_methods}||{}} };
 302   $info->{methods} ||= +{
 303     # grab all code entries that aren't in the not_methods list
 304     map {
 305       my $code = *{$stash->{$_}}{CODE};
 306       ( ! $code or exists $not_methods->{$code} ) ? () : ($_ => $code)
 307     } grep !ref($stash->{$_}), keys %$stash
 308   };
 309 }
 310
 311 sub methods_provided_by {
 312   my ($me, $role) = @_;
 313   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 314   (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
 315 }
 316
 317 sub _install_methods {
 318   my ($me, $to, $role) = @_;
 319
 320   my $info = $INFO{$role};
 321
 322   my $methods = $me->_concrete_methods_of($role);
 323
 324   # grab target symbol table
 325   my $stash = _getstash($to);
 326
 327   # determine already extant methods of target
 328   my %has_methods;
 329   @has_methods{grep
 330     +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
 331     keys %$stash
 332   } = ();
 333
 334   foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
 335     no warnings 'once';
 336     *{_getglob "${to}::${i}"} = $methods->{$i};
 337   }
 338
 339   $me->_install_does($to);
 340 }
 341
 342 sub _install_modifiers {
 343   my ($me, $to, $name) = @_;
 344   return unless my $modifiers = $INFO{$name}{modifiers};
 345   if (my $info = $INFO{$to}) {
 346     push @{$info->{modifiers}}, @{$modifiers||[]};
 347   } else {
 348     foreach my $modifier (@{$modifiers||[]}) {
 349       $me->_install_single_modifier($to, @$modifier);
 350     }
 351   }
 352 }
 353
 354 my $vcheck_error;
 355
 356 sub _install_single_modifier {
 357   my ($me, @args) = @_;
 358   defined($vcheck_error) or $vcheck_error = do {
 359     local $@;
 360     eval { Class::Method::Modifiers->VERSION(1.05); 1 }
 361       ? 0
 362       : $@
 363   };
 364   $vcheck_error and die $vcheck_error;
 365   Class::Method::Modifiers::install_modifier(@args);
 366 }
 367
 368 my $FALLBACK = sub { 0 };
 369 sub _install_does {
 370   my ($me, $to) = @_;
 371
 372   # only add does() method to classes
 373   return if $INFO{$to};
 374
 375   # add does() only if they don't have one
 376   *{_getglob "${to}::does"} = \&does_role unless $to->can('does');
 377
 378   return if ($to->can('DOES') and $to->can('DOES') != (UNIVERSAL->can('DOES') || 0));
 379
 380   my $existing = $to->can('DOES') || $to->can('isa') || $FALLBACK;
 381   my $new_sub = sub {
 382     my ($proto, $role) = @_;
 383     Role::Tiny::does_role($proto, $role) or $proto->$existing($role);
 384   };
 385   no warnings 'redefine';
 386   *{_getglob "${to}::DOES"} = $new_sub;
 387 }
 388
 389 sub does_role {
 390   my ($proto, $role) = @_;
 391   if ($] >= 5.010) {
 392     require mro;
 393   } else {
 394     require MRO::Compat;
 395   }
 396   foreach my $class (@{mro::get_linear_isa(ref($proto)||$proto)}) {
 397     return 1 if exists $APPLIED_TO{$class}{$role};
 398   }
 399   return 0;
 400 }
 401
 402 sub is_role {
 403   my ($me, $role) = @_;
 404   return !!$INFO{$role};
 405 }
 406
 407 1;
 408
 409 =encoding utf-8
 410
 411 =head1 NAME
 412
 413 Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
 414
 415 =head1 SYNOPSIS
 416
 417  package Some::Role;
 418
 419  use Role::Tiny;
 420
 421  sub foo { ... }
 422
 423  sub bar { ... }
 424
 425  around baz => sub { ... }
 426
 427  1;
 428
 429 else where
 430
 431  package Some::Class;
 432
 433  use Role::Tiny::With;
 434
 435  # bar gets imported, but not foo
 436  with 'Some::Role';
 437
 438  sub foo { ... }
 439
 440  # baz is wrapped in the around modifier by Class::Method::Modifiers
 441  sub baz { ... }
 442
 443  1;
 444
 445 If you wanted attributes as well, look at L<Moo::Role>.
 446
 447 =head1 DESCRIPTION
 448
 449 C<Role::Tiny> is a minimalist role composition tool.
 450
 451 =head1 ROLE COMPOSITION
 452
 453 Role composition can be thought of as much more clever and meaningful multiple
 454 inheritance.  The basics of this implementation of roles is:
 455
 456 =over 2
 457
 458 =item *
 459
 460 If a method is already defined on a class, that method will not be composed in
 461 from the role.
 462
 463 =item *
 464
 465 If a method that the role L</requires> to be implemented is not implemented,
 466 role application will fail loudly.
 467
 468 =back
 469
 470 Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
 471 composition is the other way around, where the class wins. If multiple roles
 472 are applied in a single call (single with statement), then if any of their
 473 provided methods clash, an exception is raised unless the class provides
 474 a method since this conflict indicates a potential problem.
 475
 476 =head1 IMPORTED SUBROUTINES
 477
 478 =head2 requires
 479
 480  requires qw(foo bar);
 481
 482 Declares a list of methods that must be defined to compose role.
 483
 484 =head2 with
 485
 486  with 'Some::Role1';
 487
 488  with 'Some::Role1', 'Some::Role2';
 489
 490 Composes another role into the current role (or class via L<Role::Tiny::With>).
 491
 492 If you have conflicts and want to resolve them in favour of Some::Role1 you
 493 can instead write:
 494
 495  with 'Some::Role1';
 496  with 'Some::Role2';
 497
 498 If you have conflicts and want to resolve different conflicts in favour of
 499 different roles, please refactor your codebase.
 500
 501 =head2 before
 502
 503  before foo => sub { ... };
 504
 505 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 506 documentation.
 507
 508 Note that since you are not required to use method modifiers,
 509 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 510 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 511 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 512
 513 =head2 around
 514
 515  around foo => sub { ... };
 516
 517 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 518 documentation.
 519
 520 Note that since you are not required to use method modifiers,
 521 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 522 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 523 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 524
 525 =head2 after
 526
 527  after foo => sub { ... };
 528
 529 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 530 documentation.
 531
 532 Note that since you are not required to use method modifiers,
 533 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 534 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 535 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 536
 537 =head1 SUBROUTINES
 538
 539 =head2 does_role
 540
 541  if (Role::Tiny::does_role($foo, 'Some::Role')) {
 542    ...
 543  }
 544
 545 Returns true if class has been composed with role.
 546
 547 This subroutine is also installed as ->does on any class a Role::Tiny is
 548 composed into unless that class already has an ->does method, so
 549
 550   if ($foo->does('Some::Role')) {
 551     ...
 552   }
 553
 554 will work for classes but to test a role, one must use ::does_role directly.
 555
 556 Additionally, Role::Tiny will override the standard Perl C<DOES> method
 557 for your class. However, if C<any> class in your class' inheritance
 558 hierarchy provides C<DOES>, then Role::Tiny will not override it.
 559
 560 =head1 METHODS
 561
 562 =head2 apply_roles_to_package
 563
 564  Role::Tiny->apply_roles_to_package(
 565    'Some::Package', 'Some::Role', 'Some::Other::Role'
 566  );
 567
 568 Composes role with package.  See also L<Role::Tiny::With>.
 569
 570 =head2 apply_roles_to_object
 571
 572  Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
 573
 574 Composes roles in order into object directly.  Object is reblessed into the
 575 resulting class.
 576
 577 =head2 create_class_with_roles
 578
 579  Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
 580
 581 Creates a new class based on base, with the roles composed into it in order.
 582 New class is returned.
 583
 584 =head2 is_role
 585
 586  Role::Tiny->is_role('Some::Role1')
 587
 588 Returns true if the given package is a role.
 589
 590 =head1 SEE ALSO
 591
 592 L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
 593 a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
 594
 595 If you don't want method modifiers and do want to be forcibly restricted
 596 to a single role application per class, Ovid's L<Role::Basic> exists. But
 597 Stevan Little (the L<Moose> author) and I don't find the additional
 598 restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
 599 are more a guide to what you should prefer doing, to our mind, rather than
 600 something that needs to be enforced.
 601
 602 =head1 AUTHOR
 603
 604 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 605
 606 =head1 CONTRIBUTORS
 607
 608 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 609
 610 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 611
 612 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 613
 614 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 615
 616 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 617
 618 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 619
 620 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 621
 622 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 623
 624 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 625
 626 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>
 627
 628 ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>
 629
 630 tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org>
 631
 632 =head1 COPYRIGHT
 633
 634 Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
 635 as listed above.
 636
 637 =head1 LICENSE
 638
 639 This library is free software and may be distributed under the same terms
 640 as perl itself.
 641
 642 =cut