lib/Role/Tiny.pm

   1 package Role::Tiny;
   2
   3 sub _getglob { \*{$_[0]} }
   4 sub _getstash { \%{"$_[0]::"} }
   5
   6 use strict;
   7 use warnings FATAL => 'all';
   8
   9 our $VERSION = '1.003002'; # 1.3.2
  10 $VERSION = eval $VERSION;
  11
  12 our %INFO;
  13 our %APPLIED_TO;
  14 our %COMPOSED;
  15 our %COMPOSITE_INFO;
  16
  17 # Module state workaround totally stolen from Zefram's Module::Runtime.
  18
  19 BEGIN {
  20   *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
  21 }
  22
  23 sub Role::Tiny::__GUARD__::DESTROY {
  24   delete $INC{$_[0]->[0]} if @{$_[0]};
  25 }
  26
  27 sub _load_module {
  28   (my $proto = $_[0]) =~ s/::/\//g;
  29   $proto .= '.pm';
  30   return 1 if $INC{$proto};
  31   # can't just ->can('can') because a sub-package Foo::Bar::Baz
  32   # creates a 'Baz::' key in Foo::Bar's symbol table
  33   return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  34   my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
  35     && bless([ $proto ], 'Role::Tiny::__GUARD__');
  36   require $proto;
  37   pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  38   return 1;
  39 }
  40
  41 sub import {
  42   my $target = caller;
  43   my $me = shift;
  44   strict->import;
  45   warnings->import(FATAL => 'all');
  46   return if $INFO{$target}; # already exported into this package
  47   $INFO{$target}{is_role} = 1;
  48   # get symbol table reference
  49   my $stash = _getstash($target);
  50   # install before/after/around subs
  51   foreach my $type (qw(before after around)) {
  52     *{_getglob "${target}::${type}"} = sub {
  53       require Class::Method::Modifiers;
  54       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  55       return;
  56     };
  57   }
  58   *{_getglob "${target}::requires"} = sub {
  59     push @{$INFO{$target}{requires}||=[]}, @_;
  60     return;
  61   };
  62   *{_getglob "${target}::with"} = sub {
  63     $me->apply_roles_to_package($target, @_);
  64     return;
  65   };
  66   # grab all *non-constant* (stash slot is not a scalarref) subs present
  67   # in the symbol table and store their refaddrs (no need to forcibly
  68   # inflate constant subs into real subs) with a map to the coderefs in
  69   # case of copying or re-use
  70   my @not_methods = (map { *$_{CODE}||() } grep !ref($_), values %$stash);
  71   @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  72   # a role does itself
  73   $APPLIED_TO{$target} = { $target => undef };
  74 }
  75
  76 sub role_application_steps {
  77   qw(_install_methods _check_requires _install_modifiers _copy_applied_list);
  78 }
  79
  80 sub apply_single_role_to_package {
  81   my ($me, $to, $role) = @_;
  82
  83   _load_module($role);
  84
  85   die "This is apply_role_to_package" if ref($to);
  86   die "${role} is not a Role::Tiny" unless $INFO{$role};
  87
  88   foreach my $step ($me->role_application_steps) {
  89     $me->$step($to, $role);
  90   }
  91 }
  92
  93 sub _copy_applied_list {
  94   my ($me, $to, $role) = @_;
  95   # copy our role list into the target's
  96   @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
  97 }
  98
  99 sub apply_roles_to_object {
 100   my ($me, $object, @roles) = @_;
 101   die "No roles supplied!" unless @roles;
 102   my $class = ref($object);
 103   bless($object, $me->create_class_with_roles($class, @roles));
 104   $object;
 105 }
 106
 107 my $role_suffix = 'A000';
 108 sub _composite_name {
 109   my ($me, $superclass, @roles) = @_;
 110
 111   my $new_name = join(
 112     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 113   );
 114
 115   if (length($new_name) > 252) {
 116     $new_name = $COMPOSED{abbrev}{$new_name}
 117       ||= substr($new_name, 0, 250 - length $role_suffix).'__'.$role_suffix++;
 118   }
 119   return wantarray ? ($new_name, $compose_name) : $new_name;
 120 }
 121
 122 sub create_class_with_roles {
 123   my ($me, $superclass, @roles) = @_;
 124
 125   die "No roles supplied!" unless @roles;
 126
 127   _load_module($superclass);
 128   {
 129     my %seen;
 130     $seen{$_}++ for @roles;
 131     if (my @dupes = grep $seen{$_} > 1, @roles) {
 132       die "Duplicated roles: ".join(', ', @dupes);
 133     }
 134   }
 135
 136   my ($new_name, $compose_name) = $me->_composite_name($superclass, @roles);
 137
 138   return $new_name if $COMPOSED{class}{$new_name};
 139
 140   foreach my $role (@roles) {
 141     _load_module($role);
 142     die "${role} is not a Role::Tiny" unless $INFO{$role};
 143   }
 144
 145   if ($] >= 5.010) {
 146     require mro;
 147   } else {
 148     require MRO::Compat;
 149   }
 150
 151   my $composite_info = $me->_composite_info_for(@roles);
 152   my %conflicts = %{$composite_info->{conflicts}};
 153   if (keys %conflicts) {
 154     my $fail =
 155       join "\n",
 156         map {
 157           "Method name conflict for '$_' between roles "
 158           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 159           .", cannot apply these simultaneously to an object."
 160         } keys %conflicts;
 161     die $fail;
 162   }
 163
 164   my @composable = map $me->_composable_package_for($_), reverse @roles;
 165
 166   # some methods may not exist in the role, but get generated by
 167   # _composable_package_for (Moose accessors via Moo).  filter out anything
 168   # provided by the composable packages, excluding the subs we generated to
 169   # make modifiers work.
 170   my @requires = grep {
 171     my $method = $_;
 172     !grep $_->can($method) && !$COMPOSED{role}{$_}{modifiers_only}{$method},
 173       @composable
 174   } @{$composite_info->{requires}};
 175
 176   $me->_check_requires(
 177     $superclass, $compose_name, \@requires
 178   );
 179
 180   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 181
 182   @{$APPLIED_TO{$new_name}||={}}{
 183     map keys %{$APPLIED_TO{$_}}, @roles
 184   } = ();
 185
 186   $COMPOSED{class}{$new_name} = 1;
 187   return $new_name;
 188 }
 189
 190 # preserved for compat, and apply_roles_to_package calls it to allow an
 191 # updated Role::Tiny to use a non-updated Moo::Role
 192
 193 sub apply_role_to_package { shift->apply_single_role_to_package(@_) }
 194
 195 sub apply_roles_to_package {
 196   my ($me, $to, @roles) = @_;
 197
 198   return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;
 199
 200   my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
 201   my @have = grep $to->can($_), keys %conflicts;
 202   delete @conflicts{@have};
 203
 204   if (keys %conflicts) {
 205     my $fail =
 206       join "\n",
 207         map {
 208           "Due to a method name conflict between roles "
 209           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 210           .", the method '$_' must be implemented by '${to}'"
 211         } keys %conflicts;
 212     die $fail;
 213   }
 214
 215   # conflicting methods are supposed to be treated as required by the
 216   # composed role. we don't have an actual composed role, but because
 217   # we know the target class already provides them, we can instead
 218   # pretend that the roles don't do for the duration of application.
 219   my @role_methods = map $me->_concrete_methods_of($_), @roles;
 220   # separate loops, since local ..., delete ... for ...; creates a scope
 221   local @{$_}{@have} for @role_methods;
 222   delete @{$_}{@have} for @role_methods;
 223
 224   # the if guard here is essential since otherwise we accidentally create
 225   # a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
 226   # autovivification hates us and wants us to die()
 227   if ($INFO{$to}) {
 228     delete $INFO{$to}{methods}; # reset since we're about to add methods
 229   }
 230
 231   # backcompat: allow subclasses to use apply_single_role_to_package
 232   # to apply changes.  set a local var so ours does nothing.
 233   our %BACKCOMPAT_HACK;
 234   if($me ne __PACKAGE__
 235       and exists $BACKCOMPAT_HACK{$me} ? $BACKCOMPAT_HACK{$me} :
 236       $BACKCOMPAT_HACK{$me} =
 237         $me->can('role_application_steps')
 238           == \&role_application_steps
 239         && $me->can('apply_single_role_to_package')
 240           != \&apply_single_role_to_package
 241   ) {
 242     foreach my $role (@roles) {
 243       $me->apply_single_role_to_package($to, $role);
 244     }
 245   }
 246   else {
 247     foreach my $step ($me->role_application_steps) {
 248       foreach my $role (@roles) {
 249         $me->$step($to, $role);
 250       }
 251     }
 252   }
 253   $APPLIED_TO{$to}{join('|',@roles)} = 1;
 254 }
 255
 256 sub _composite_info_for {
 257   my ($me, @roles) = @_;
 258   $COMPOSITE_INFO{join('|', sort @roles)} ||= do {
 259     foreach my $role (@roles) {
 260       _load_module($role);
 261     }
 262     my %methods;
 263     foreach my $role (@roles) {
 264       my $this_methods = $me->_concrete_methods_of($role);
 265       $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
 266     }
 267     my %requires;
 268     @requires{map @{$INFO{$_}{requires}||[]}, @roles} = ();
 269     delete $requires{$_} for keys %methods;
 270     delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
 271     +{ conflicts => \%methods, requires => [keys %requires] }
 272   };
 273 }
 274
 275 sub _composable_package_for {
 276   my ($me, $role) = @_;
 277   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 278   return $composed_name if $COMPOSED{role}{$composed_name};
 279   $me->_install_methods($composed_name, $role);
 280   my $base_name = $composed_name.'::_BASE';
 281   # force stash to exist so ->can doesn't complain
 282   _getstash($base_name);
 283   # Not using _getglob, since setting @ISA via the typeglob breaks
 284   # inheritance on 5.10.0 if the stash has previously been accessed an
 285   # then a method called on the class (in that order!), which
 286   # ->_install_methods (with the help of ->_install_does) ends up doing.
 287   { no strict 'refs'; @{"${composed_name}::ISA"} = ( $base_name ); }
 288   my $modifiers = $INFO{$role}{modifiers}||[];
 289   my @mod_base;
 290   my @modifiers = grep !$composed_name->can($_),
 291     do { my %h; @h{map @{$_}[1..$#$_-1], @$modifiers} = (); keys %h };
 292   foreach my $modified (@modifiers) {
 293     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
 294   }
 295   my $e;
 296   {
 297     local $@;
 298     eval(my $code = join "\n", "package ${base_name};", @mod_base);
 299     $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
 300   }
 301   die $e if $e;
 302   $me->_install_modifiers($composed_name, $role);
 303   $COMPOSED{role}{$composed_name} = {
 304     modifiers_only => { map { $_ => 1 } @modifiers },
 305   };
 306   return $composed_name;
 307 }
 308
 309 sub _check_requires {
 310   my ($me, $to, $name, $requires) = @_;
 311   return unless my @requires = @{$requires||$INFO{$name}{requires}||[]};
 312   if (my @requires_fail = grep !$to->can($_), @requires) {
 313     # role -> role, add to requires, role -> class, error out
 314     if (my $to_info = $INFO{$to}) {
 315       push @{$to_info->{requires}||=[]}, @requires_fail;
 316     } else {
 317       die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
 318     }
 319   }
 320 }
 321
 322 sub _concrete_methods_of {
 323   my ($me, $role) = @_;
 324   my $info = $INFO{$role};
 325   # grab role symbol table
 326   my $stash = _getstash($role);
 327   # reverse so our keys become the values (captured coderefs) in case
 328   # they got copied or re-used since
 329   my $not_methods = { reverse %{$info->{not_methods}||{}} };
 330   $info->{methods} ||= +{
 331     # grab all code entries that aren't in the not_methods list
 332     map {
 333       my $code = *{$stash->{$_}}{CODE};
 334       ( ! $code or exists $not_methods->{$code} ) ? () : ($_ => $code)
 335     } grep !ref($stash->{$_}), keys %$stash
 336   };
 337 }
 338
 339 sub methods_provided_by {
 340   my ($me, $role) = @_;
 341   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 342   (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
 343 }
 344
 345 sub _install_methods {
 346   my ($me, $to, $role) = @_;
 347
 348   my $info = $INFO{$role};
 349
 350   my $methods = $me->_concrete_methods_of($role);
 351
 352   # grab target symbol table
 353   my $stash = _getstash($to);
 354
 355   # determine already extant methods of target
 356   my %has_methods;
 357   @has_methods{grep
 358     +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
 359     keys %$stash
 360   } = ();
 361
 362   foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
 363     no warnings 'once';
 364     *{_getglob "${to}::${i}"} = $methods->{$i};
 365   }
 366
 367   $me->_install_does($to);
 368 }
 369
 370 sub _install_modifiers {
 371   my ($me, $to, $name) = @_;
 372   return unless my $modifiers = $INFO{$name}{modifiers};
 373   if (my $info = $INFO{$to}) {
 374     push @{$info->{modifiers}}, @{$modifiers||[]};
 375   } else {
 376     foreach my $modifier (@{$modifiers||[]}) {
 377       $me->_install_single_modifier($to, @$modifier);
 378     }
 379   }
 380 }
 381
 382 my $vcheck_error;
 383
 384 sub _install_single_modifier {
 385   my ($me, @args) = @_;
 386   defined($vcheck_error) or $vcheck_error = do {
 387     local $@;
 388     eval { Class::Method::Modifiers->VERSION(1.05); 1 }
 389       ? 0
 390       : $@
 391   };
 392   $vcheck_error and die $vcheck_error;
 393   Class::Method::Modifiers::install_modifier(@args);
 394 }
 395
 396 my $FALLBACK = sub { 0 };
 397 sub _install_does {
 398   my ($me, $to) = @_;
 399
 400   # only add does() method to classes
 401   return if $INFO{$to};
 402
 403   # add does() only if they don't have one
 404   *{_getglob "${to}::does"} = \&does_role unless $to->can('does');
 405
 406   return if ($to->can('DOES') and $to->can('DOES') != (UNIVERSAL->can('DOES') || 0));
 407
 408   my $existing = $to->can('DOES') || $to->can('isa') || $FALLBACK;
 409   my $new_sub = sub {
 410     my ($proto, $role) = @_;
 411     Role::Tiny::does_role($proto, $role) or $proto->$existing($role);
 412   };
 413   no warnings 'redefine';
 414   *{_getglob "${to}::DOES"} = $new_sub;
 415 }
 416
 417 sub does_role {
 418   my ($proto, $role) = @_;
 419   if ($] >= 5.010) {
 420     require mro;
 421   } else {
 422     require MRO::Compat;
 423   }
 424   foreach my $class (@{mro::get_linear_isa(ref($proto)||$proto)}) {
 425     return 1 if exists $APPLIED_TO{$class}{$role};
 426   }
 427   return 0;
 428 }
 429
 430 sub is_role {
 431   my ($me, $role) = @_;
 432   return !!($INFO{$role} && $INFO{$role}{is_role});
 433 }
 434
 435 1;
 436
 437 =encoding utf-8
 438
 439 =head1 NAME
 440
 441 Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
 442
 443 =head1 SYNOPSIS
 444
 445  package Some::Role;
 446
 447  use Role::Tiny;
 448
 449  sub foo { ... }
 450
 451  sub bar { ... }
 452
 453  around baz => sub { ... }
 454
 455  1;
 456
 457 else where
 458
 459  package Some::Class;
 460
 461  use Role::Tiny::With;
 462
 463  # bar gets imported, but not foo
 464  with 'Some::Role';
 465
 466  sub foo { ... }
 467
 468  # baz is wrapped in the around modifier by Class::Method::Modifiers
 469  sub baz { ... }
 470
 471  1;
 472
 473 If you wanted attributes as well, look at L<Moo::Role>.
 474
 475 =head1 DESCRIPTION
 476
 477 C<Role::Tiny> is a minimalist role composition tool.
 478
 479 =head1 ROLE COMPOSITION
 480
 481 Role composition can be thought of as much more clever and meaningful multiple
 482 inheritance.  The basics of this implementation of roles is:
 483
 484 =over 2
 485
 486 =item *
 487
 488 If a method is already defined on a class, that method will not be composed in
 489 from the role.
 490
 491 =item *
 492
 493 If a method that the role L</requires> to be implemented is not implemented,
 494 role application will fail loudly.
 495
 496 =back
 497
 498 Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
 499 composition is the other way around, where the class wins. If multiple roles
 500 are applied in a single call (single with statement), then if any of their
 501 provided methods clash, an exception is raised unless the class provides
 502 a method since this conflict indicates a potential problem.
 503
 504 =head1 IMPORTED SUBROUTINES
 505
 506 =head2 requires
 507
 508  requires qw(foo bar);
 509
 510 Declares a list of methods that must be defined to compose role.
 511
 512 =head2 with
 513
 514  with 'Some::Role1';
 515
 516  with 'Some::Role1', 'Some::Role2';
 517
 518 Composes another role into the current role (or class via L<Role::Tiny::With>).
 519
 520 If you have conflicts and want to resolve them in favour of Some::Role1 you
 521 can instead write:
 522
 523  with 'Some::Role1';
 524  with 'Some::Role2';
 525
 526 If you have conflicts and want to resolve different conflicts in favour of
 527 different roles, please refactor your codebase.
 528
 529 =head2 before
 530
 531  before foo => sub { ... };
 532
 533 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 534 documentation.
 535
 536 Note that since you are not required to use method modifiers,
 537 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 538 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 539 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 540
 541 =head2 around
 542
 543  around foo => sub { ... };
 544
 545 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 546 documentation.
 547
 548 Note that since you are not required to use method modifiers,
 549 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 550 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 551 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 552
 553 =head2 after
 554
 555  after foo => sub { ... };
 556
 557 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 558 documentation.
 559
 560 Note that since you are not required to use method modifiers,
 561 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 562 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 563 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 564
 565 =head1 SUBROUTINES
 566
 567 =head2 does_role
 568
 569  if (Role::Tiny::does_role($foo, 'Some::Role')) {
 570    ...
 571  }
 572
 573 Returns true if class has been composed with role.
 574
 575 This subroutine is also installed as ->does on any class a Role::Tiny is
 576 composed into unless that class already has an ->does method, so
 577
 578   if ($foo->does('Some::Role')) {
 579     ...
 580   }
 581
 582 will work for classes but to test a role, one must use ::does_role directly.
 583
 584 Additionally, Role::Tiny will override the standard Perl C<DOES> method
 585 for your class. However, if C<any> class in your class' inheritance
 586 hierarchy provides C<DOES>, then Role::Tiny will not override it.
 587
 588 =head1 METHODS
 589
 590 =head2 apply_roles_to_package
 591
 592  Role::Tiny->apply_roles_to_package(
 593    'Some::Package', 'Some::Role', 'Some::Other::Role'
 594  );
 595
 596 Composes role with package.  See also L<Role::Tiny::With>.
 597
 598 =head2 apply_roles_to_object
 599
 600  Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
 601
 602 Composes roles in order into object directly.  Object is reblessed into the
 603 resulting class.
 604
 605 =head2 create_class_with_roles
 606
 607  Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
 608
 609 Creates a new class based on base, with the roles composed into it in order.
 610 New class is returned.
 611
 612 =head2 is_role
 613
 614  Role::Tiny->is_role('Some::Role1')
 615
 616 Returns true if the given package is a role.
 617
 618 =head1 SEE ALSO
 619
 620 L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
 621 a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
 622
 623 If you don't want method modifiers and do want to be forcibly restricted
 624 to a single role application per class, Ovid's L<Role::Basic> exists. But
 625 Stevan Little (the L<Moose> author) and I don't find the additional
 626 restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
 627 are more a guide to what you should prefer doing, to our mind, rather than
 628 something that needs to be enforced.
 629
 630 =head1 AUTHOR
 631
 632 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 633
 634 =head1 CONTRIBUTORS
 635
 636 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 637
 638 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 639
 640 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 641
 642 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 643
 644 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 645
 646 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 647
 648 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 649
 650 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 651
 652 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 653
 654 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>
 655
 656 ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>
 657
 658 tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org>
 659
 660 =head1 COPYRIGHT
 661
 662 Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
 663 as listed above.
 664
 665 =head1 LICENSE
 666
 667 This library is free software and may be distributed under the same terms
 668 as perl itself.
 669
 670 =cut