lib/Role/Tiny.pm

   1 package Role::Tiny;
   2
   3 sub _getglob { \*{$_[0]} }
   4 sub _getstash { \%{"$_[0]::"} }
   5
   6 use strict;
   7 use warnings FATAL => 'all';
   8
   9 our $VERSION = '1.002005'; # 1.2.5
  10 $VERSION = eval $VERSION;
  11
  12 our %INFO;
  13 our %APPLIED_TO;
  14 our %COMPOSED;
  15 our %COMPOSITE_INFO;
  16
  17 # Module state workaround totally stolen from Zefram's Module::Runtime.
  18
  19 BEGIN {
  20   *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
  21 }
  22
  23 sub Role::Tiny::__GUARD__::DESTROY {
  24   delete $INC{$_[0]->[0]} if @{$_[0]};
  25 }
  26
  27 sub _load_module {
  28   (my $proto = $_[0]) =~ s/::/\//g;
  29   $proto .= '.pm';
  30   return 1 if $INC{$proto};
  31   # can't just ->can('can') because a sub-package Foo::Bar::Baz
  32   # creates a 'Baz::' key in Foo::Bar's symbol table
  33   return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  34   my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
  35     && bless([ $proto ], 'Role::Tiny::__GUARD__');
  36   require $proto;
  37   pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  38   return 1;
  39 }
  40
  41 sub import {
  42   my $target = caller;
  43   my $me = shift;
  44   strict->import;
  45   warnings->import(FATAL => 'all');
  46   return if $INFO{$target}; # already exported into this package
  47   $INFO{$target}{is_role} = 1;
  48   # get symbol table reference
  49   my $stash = _getstash($target);
  50   # install before/after/around subs
  51   foreach my $type (qw(before after around)) {
  52     *{_getglob "${target}::${type}"} = sub {
  53       require Class::Method::Modifiers;
  54       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  55       return;
  56     };
  57   }
  58   *{_getglob "${target}::requires"} = sub {
  59     push @{$INFO{$target}{requires}||=[]}, @_;
  60     return;
  61   };
  62   *{_getglob "${target}::with"} = sub {
  63     $me->apply_roles_to_package($target, @_);
  64     return;
  65   };
  66   # grab all *non-constant* (stash slot is not a scalarref) subs present
  67   # in the symbol table and store their refaddrs (no need to forcibly
  68   # inflate constant subs into real subs) with a map to the coderefs in
  69   # case of copying or re-use
  70   my @not_methods = (map { *$_{CODE}||() } grep !ref($_), values %$stash);
  71   @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  72   # a role does itself
  73   $APPLIED_TO{$target} = { $target => undef };
  74 }
  75
  76 sub role_application_steps {
  77   qw(_install_methods _install_modifiers _check_requires _copy_applied_list);
  78 }
  79
  80 sub apply_single_role_to_package {
  81   my ($me, $to, $role) = @_;
  82
  83   _load_module($role);
  84
  85   die "This is apply_role_to_package" if ref($to);
  86   die "${role} is not a Role::Tiny" unless $INFO{$role};
  87
  88   foreach my $step ($me->role_application_steps) {
  89     $me->$step($to, $role);
  90   }
  91 }
  92
  93 sub _copy_applied_list {
  94   my ($me, $to, $role) = @_;
  95   # copy our role list into the target's
  96   @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
  97 }
  98
  99 sub apply_roles_to_object {
 100   my ($me, $object, @roles) = @_;
 101   die "No roles supplied!" unless @roles;
 102   my $class = ref($object);
 103   bless($object, $me->create_class_with_roles($class, @roles));
 104   $object;
 105 }
 106
 107 sub create_class_with_roles {
 108   my ($me, $superclass, @roles) = @_;
 109
 110   die "No roles supplied!" unless @roles;
 111
 112   _load_module($superclass);
 113   {
 114     my %seen;
 115     $seen{$_}++ for @roles;
 116     if (my @dupes = grep $seen{$_} > 1, @roles) {
 117       die "Duplicated roles: ".join(', ', @dupes);
 118     }
 119   }
 120
 121   my $new_name = join(
 122     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 123   );
 124
 125   return $new_name if $COMPOSED{class}{$new_name};
 126
 127   foreach my $role (@roles) {
 128     _load_module($role);
 129     die "${role} is not a Role::Tiny" unless $INFO{$role};
 130   }
 131
 132   if ($] >= 5.010) {
 133     require mro;
 134   } else {
 135     require MRO::Compat;
 136   }
 137
 138   my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
 139   if (keys %conflicts) {
 140     my $fail =
 141       join "\n",
 142         map {
 143           "Method name conflict for '$_' between roles "
 144           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 145           .", cannot apply these simultaneously to an object."
 146         } keys %conflicts;
 147     die $fail;
 148   }
 149
 150   my @composable = map $me->_composable_package_for($_), reverse @roles;
 151
 152   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 153
 154   my @info = map $INFO{$_}, @roles;
 155
 156   $me->_check_requires(
 157     $new_name, $compose_name,
 158     do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h }
 159   );
 160
 161   @{$APPLIED_TO{$new_name}||={}}{
 162     map keys %{$APPLIED_TO{$_}}, @roles
 163   } = ();
 164
 165   $COMPOSED{class}{$new_name} = 1;
 166   return $new_name;
 167 }
 168
 169 # preserved for compat, and apply_roles_to_package calls it to allow an
 170 # updated Role::Tiny to use a non-updated Moo::Role
 171
 172 sub apply_role_to_package { shift->apply_single_role_to_package(@_) }
 173
 174 sub apply_roles_to_package {
 175   my ($me, $to, @roles) = @_;
 176
 177   return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;
 178
 179   my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
 180   delete $conflicts{$_} for keys %{ $me->_concrete_methods_of($to) };
 181   if (keys %conflicts) {
 182     my $fail =
 183       join "\n",
 184         map {
 185           "Due to a method name conflict between roles "
 186           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 187           .", the method '$_' must be implemented by '${to}'"
 188         } keys %conflicts;
 189     die $fail;
 190   }
 191
 192   # the if guard here is essential since otherwise we accidentally create
 193   # a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
 194   # autovivification hates us and wants us to die()
 195   if ($INFO{$to}) {
 196     delete $INFO{$to}{methods}; # reset since we're about to add methods
 197   }
 198
 199   # backcompat: allow subclasses to use apply_single_role_to_package
 200   # to apply changes.  set a local var so ours does nothing.
 201   our %BACKCOMPAT_HACK;
 202   if($me ne __PACKAGE__
 203       and exists $BACKCOMPAT_HACK{$me} ? $BACKCOMPAT_HACK{$me} :
 204       $BACKCOMPAT_HACK{$me} =
 205         $me->can('role_application_steps')
 206           == \&role_application_steps
 207         && $me->can('apply_single_role_to_package')
 208           != \&apply_single_role_to_package
 209   ) {
 210     foreach my $role (@roles) {
 211       $me->apply_single_role_to_package($to, $role);
 212     }
 213   }
 214   else {
 215     foreach my $step ($me->role_application_steps) {
 216       foreach my $role (@roles) {
 217         $me->$step($to, $role);
 218       }
 219     }
 220   }
 221   $APPLIED_TO{$to}{join('|',@roles)} = 1;
 222 }
 223
 224 sub _composite_info_for {
 225   my ($me, @roles) = @_;
 226   $COMPOSITE_INFO{join('|', sort @roles)} ||= do {
 227     foreach my $role (@roles) {
 228       _load_module($role);
 229     }
 230     my %methods;
 231     foreach my $role (@roles) {
 232       my $this_methods = $me->_concrete_methods_of($role);
 233       $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
 234     }
 235     delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
 236     +{ conflicts => \%methods }
 237   };
 238 }
 239
 240 sub _composable_package_for {
 241   my ($me, $role) = @_;
 242   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 243   return $composed_name if $COMPOSED{role}{$composed_name};
 244   $me->_install_methods($composed_name, $role);
 245   my $base_name = $composed_name.'::_BASE';
 246   # Not using _getglob, since setting @ISA via the typeglob breaks
 247   # inheritance on 5.10.0 if the stash has previously been accessed an
 248   # then a method called on the class (in that order!), which
 249   # ->_install_methods (with the help of ->_install_does) ends up doing.
 250   { no strict 'refs'; @{"${composed_name}::ISA"} = ( $base_name ); }
 251   my $modifiers = $INFO{$role}{modifiers}||[];
 252   my @mod_base;
 253   foreach my $modified (
 254     do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
 255   ) {
 256     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
 257   }
 258   my $e;
 259   {
 260     local $@;
 261     eval(my $code = join "\n", "package ${base_name};", @mod_base);
 262     $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
 263   }
 264   die $e if $e;
 265   $me->_install_modifiers($composed_name, $role);
 266   $COMPOSED{role}{$composed_name} = 1;
 267   return $composed_name;
 268 }
 269
 270 sub _check_requires {
 271   my ($me, $to, $name) = @_;
 272   return unless my @requires = @{$INFO{$name}{requires}||[]};
 273   if (my @requires_fail = grep !$to->can($_), @requires) {
 274     # role -> role, add to requires, role -> class, error out
 275     if (my $to_info = $INFO{$to}) {
 276       push @{$to_info->{requires}||=[]}, @requires_fail;
 277     } else {
 278       die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
 279     }
 280   }
 281 }
 282
 283 sub _concrete_methods_of {
 284   my ($me, $role) = @_;
 285   my $info = $INFO{$role};
 286   # grab role symbol table
 287   my $stash = _getstash($role);
 288   # reverse so our keys become the values (captured coderefs) in case
 289   # they got copied or re-used since
 290   my $not_methods = { reverse %{$info->{not_methods}||{}} };
 291   $info->{methods} ||= +{
 292     # grab all code entries that aren't in the not_methods list
 293     map {
 294       my $code = *{$stash->{$_}}{CODE};
 295       ( ! $code or exists $not_methods->{$code} ) ? () : ($_ => $code)
 296     } grep !ref($stash->{$_}), keys %$stash
 297   };
 298 }
 299
 300 sub methods_provided_by {
 301   my ($me, $role) = @_;
 302   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 303   (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
 304 }
 305
 306 sub _install_methods {
 307   my ($me, $to, $role) = @_;
 308
 309   my $info = $INFO{$role};
 310
 311   my $methods = $me->_concrete_methods_of($role);
 312
 313   # grab target symbol table
 314   my $stash = _getstash($to);
 315
 316   # determine already extant methods of target
 317   my %has_methods;
 318   @has_methods{grep
 319     +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
 320     keys %$stash
 321   } = ();
 322
 323   foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
 324     no warnings 'once';
 325     *{_getglob "${to}::${i}"} = $methods->{$i};
 326   }
 327
 328   $me->_install_does($to);
 329 }
 330
 331 sub _install_modifiers {
 332   my ($me, $to, $name) = @_;
 333   return unless my $modifiers = $INFO{$name}{modifiers};
 334   if (my $info = $INFO{$to}) {
 335     push @{$info->{modifiers}}, @{$modifiers||[]};
 336   } else {
 337     foreach my $modifier (@{$modifiers||[]}) {
 338       $me->_install_single_modifier($to, @$modifier);
 339     }
 340   }
 341 }
 342
 343 my $vcheck_error;
 344
 345 sub _install_single_modifier {
 346   my ($me, @args) = @_;
 347   defined($vcheck_error) or $vcheck_error = do {
 348     local $@;
 349     eval { Class::Method::Modifiers->VERSION(1.05); 1 }
 350       ? 0
 351       : $@
 352   };
 353   $vcheck_error and die $vcheck_error;
 354   Class::Method::Modifiers::install_modifier(@args);
 355 }
 356
 357 my $FALLBACK = sub { 0 };
 358 sub _install_does {
 359   my ($me, $to) = @_;
 360
 361   # only add does() method to classes
 362   return if $INFO{$to};
 363
 364   # add does() only if they don't have one
 365   *{_getglob "${to}::does"} = \&does_role unless $to->can('does');
 366
 367   return if ($to->can('DOES') and $to->can('DOES') != (UNIVERSAL->can('DOES') || 0));
 368
 369   my $existing = $to->can('DOES') || $to->can('isa') || $FALLBACK;
 370   my $new_sub = sub {
 371     my ($proto, $role) = @_;
 372     Role::Tiny::does_role($proto, $role) or $proto->$existing($role);
 373   };
 374   no warnings 'redefine';
 375   *{_getglob "${to}::DOES"} = $new_sub;
 376 }
 377
 378 sub does_role {
 379   my ($proto, $role) = @_;
 380   if ($] >= 5.010) {
 381     require mro;
 382   } else {
 383     require MRO::Compat;
 384   }
 385   foreach my $class (@{mro::get_linear_isa(ref($proto)||$proto)}) {
 386     return 1 if exists $APPLIED_TO{$class}{$role};
 387   }
 388   return 0;
 389 }
 390
 391 sub is_role {
 392   my ($me, $role) = @_;
 393   return !!$INFO{$role};
 394 }
 395
 396 1;
 397
 398 =encoding utf-8
 399
 400 =head1 NAME
 401
 402 Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
 403
 404 =head1 SYNOPSIS
 405
 406  package Some::Role;
 407
 408  use Role::Tiny;
 409
 410  sub foo { ... }
 411
 412  sub bar { ... }
 413
 414  around baz => sub { ... }
 415
 416  1;
 417
 418 else where
 419
 420  package Some::Class;
 421
 422  use Role::Tiny::With;
 423
 424  # bar gets imported, but not foo
 425  with 'Some::Role';
 426
 427  sub foo { ... }
 428
 429  # baz is wrapped in the around modifier by Class::Method::Modifiers
 430  sub baz { ... }
 431
 432  1;
 433
 434 If you wanted attributes as well, look at L<Moo::Role>.
 435
 436 =head1 DESCRIPTION
 437
 438 C<Role::Tiny> is a minimalist role composition tool.
 439
 440 =head1 ROLE COMPOSITION
 441
 442 Role composition can be thought of as much more clever and meaningful multiple
 443 inheritance.  The basics of this implementation of roles is:
 444
 445 =over 2
 446
 447 =item *
 448
 449 If a method is already defined on a class, that method will not be composed in
 450 from the role.
 451
 452 =item *
 453
 454 If a method that the role L</requires> to be implemented is not implemented,
 455 role application will fail loudly.
 456
 457 =back
 458
 459 Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
 460 composition is the other way around, where the class wins. If multiple roles
 461 are applied in a single call (single with statement), then if any of their
 462 provided methods clash, an exception is raised unless the class provides
 463 a method since this conflict indicates a potential problem.
 464
 465 =head1 IMPORTED SUBROUTINES
 466
 467 =head2 requires
 468
 469  requires qw(foo bar);
 470
 471 Declares a list of methods that must be defined to compose role.
 472
 473 =head2 with
 474
 475  with 'Some::Role1';
 476
 477  with 'Some::Role1', 'Some::Role2';
 478
 479 Composes another role into the current role (or class via L<Role::Tiny::With>).
 480
 481 If you have conflicts and want to resolve them in favour of Some::Role1 you
 482 can instead write:
 483
 484  with 'Some::Role1';
 485  with 'Some::Role2';
 486
 487 If you have conflicts and want to resolve different conflicts in favour of
 488 different roles, please refactor your codebase.
 489
 490 =head2 before
 491
 492  before foo => sub { ... };
 493
 494 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 495 documentation.
 496
 497 Note that since you are not required to use method modifiers,
 498 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 499 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 500 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 501
 502 =head2 around
 503
 504  around foo => sub { ... };
 505
 506 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 507 documentation.
 508
 509 Note that since you are not required to use method modifiers,
 510 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 511 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 512 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 513
 514 =head2 after
 515
 516  after foo => sub { ... };
 517
 518 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 519 documentation.
 520
 521 Note that since you are not required to use method modifiers,
 522 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 523 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 524 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 525
 526 =head1 SUBROUTINES
 527
 528 =head2 does_role
 529
 530  if (Role::Tiny::does_role($foo, 'Some::Role')) {
 531    ...
 532  }
 533
 534 Returns true if class has been composed with role.
 535
 536 This subroutine is also installed as ->does on any class a Role::Tiny is
 537 composed into unless that class already has an ->does method, so
 538
 539   if ($foo->does('Some::Role')) {
 540     ...
 541   }
 542
 543 will work for classes but to test a role, one must use ::does_role directly.
 544
 545 Additionally, Role::Tiny will override the standard Perl C<DOES> method
 546 for your class. However, if C<any> class in your class' inheritance
 547 hierarchy provides C<DOES>, then Role::Tiny will not override it.
 548
 549 =head1 METHODS
 550
 551 =head2 apply_roles_to_package
 552
 553  Role::Tiny->apply_roles_to_package(
 554    'Some::Package', 'Some::Role', 'Some::Other::Role'
 555  );
 556
 557 Composes role with package.  See also L<Role::Tiny::With>.
 558
 559 =head2 apply_roles_to_object
 560
 561  Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
 562
 563 Composes roles in order into object directly.  Object is reblessed into the
 564 resulting class.
 565
 566 =head2 create_class_with_roles
 567
 568  Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
 569
 570 Creates a new class based on base, with the roles composed into it in order.
 571 New class is returned.
 572
 573 =head2 is_role
 574
 575  Role::Tiny->is_role('Some::Role1')
 576
 577 Returns true if the given package is a role.
 578
 579 =head1 SEE ALSO
 580
 581 L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
 582 a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
 583
 584 If you don't want method modifiers and do want to be forcibly restricted
 585 to a single role application per class, Ovid's L<Role::Basic> exists. But
 586 Stevan Little (the L<Moose> author) and I don't find the additional
 587 restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
 588 are more a guide to what you should prefer doing, to our mind, rather than
 589 something that needs to be enforced.
 590
 591 =head1 AUTHOR
 592
 593 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 594
 595 =head1 CONTRIBUTORS
 596
 597 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 598
 599 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 600
 601 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 602
 603 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 604
 605 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 606
 607 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 608
 609 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 610
 611 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 612
 613 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 614
 615 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>
 616
 617 ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>
 618
 619 tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org>
 620
 621 =head1 COPYRIGHT
 622
 623 Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
 624 as listed above.
 625
 626 =head1 LICENSE
 627
 628 This library is free software and may be distributed under the same terms
 629 as perl itself.
 630
 631 =cut