lib/Role/Tiny.pm

   1 package Role::Tiny;
   2
   3 sub _getglob { \*{$_[0]} }
   4 sub _getstash { \%{"$_[0]::"} }
   5
   6 use strict;
   7 use warnings FATAL => 'all';
   8
   9 our $VERSION = '1.000001'; # 1.0.1
  10 $VERSION = eval $VERSION;
  11
  12 our %INFO;
  13 our %APPLIED_TO;
  14 our %COMPOSED;
  15 our %UNION_INFO;
  16
  17 # Module state workaround totally stolen from Zefram's Module::Runtime.
  18
  19 BEGIN {
  20   *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
  21 }
  22
  23 sub Role::Tiny::__GUARD__::DESTROY {
  24   delete $INC{$_[0]->[0]} if @{$_[0]};
  25 }
  26
  27 sub _load_module {
  28   (my $proto = $_[0]) =~ s/::/\//g;
  29   $proto .= '.pm';
  30   return 1 if $INC{$proto};
  31   # can't just ->can('can') because a sub-package Foo::Bar::Baz
  32   # creates a 'Baz::' key in Foo::Bar's symbol table
  33   return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  34   my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
  35     && bless([ $proto ], 'Role::Tiny::__GUARD__');
  36   require $proto;
  37   pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  38   return 1;
  39 }
  40
  41 sub import {
  42   my $target = caller;
  43   my $me = shift;
  44   strict->import;
  45   warnings->import(FATAL => 'all');
  46   return if $INFO{$target}; # already exported into this package
  47   # get symbol table reference
  48   my $stash = do { no strict 'refs'; \%{"${target}::"} };
  49   # install before/after/around subs
  50   foreach my $type (qw(before after around)) {
  51     *{_getglob "${target}::${type}"} = sub {
  52       require Class::Method::Modifiers;
  53       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  54     };
  55   }
  56   *{_getglob "${target}::requires"} = sub {
  57     push @{$INFO{$target}{requires}||=[]}, @_;
  58   };
  59   *{_getglob "${target}::with"} = sub {
  60     $me->apply_union_of_roles_to_package($target, @_);
  61   };
  62   # grab all *non-constant* (stash slot is not a scalarref) subs present
  63   # in the symbol table and store their refaddrs (no need to forcibly
  64   # inflate constant subs into real subs) - also add '' to here (this
  65   # is used later)
  66   @{$INFO{$target}{not_methods}={}}{
  67     '', map { *$_{CODE}||() } grep !ref($_), values %$stash
  68   } = ();
  69   # a role does itself
  70   $APPLIED_TO{$target} = { $target => undef };
  71 }
  72
  73 sub apply_role_to_package {
  74   my ($me, $to, $role) = @_;
  75
  76   _load_module($role);
  77
  78   die "This is apply_role_to_package" if ref($to);
  79   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
  80
  81   $me->_check_requires($to, $role, @{$info->{requires}||[]});
  82
  83   $me->_install_methods($to, $role);
  84
  85   $me->_install_modifiers($to, $info->{modifiers});
  86
  87   # only add does() method to classes and only if they don't have one
  88   if (not $INFO{$to} and not $to->can('does')) {
  89     *{_getglob "${to}::does"} = \&does_role;
  90   }
  91
  92   # copy our role list into the target's
  93   @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
  94 }
  95
  96 sub apply_roles_to_object {
  97   my ($me, $object, @roles) = @_;
  98   die "No roles supplied!" unless @roles;
  99   my $class = ref($object);
 100   bless($object, $me->create_class_with_roles($class, @roles));
 101   $object;
 102 }
 103
 104 sub create_class_with_roles {
 105   my ($me, $superclass, @roles) = @_;
 106
 107   die "No roles supplied!" unless @roles;
 108
 109   my $new_name = join(
 110     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 111   );
 112
 113   return $new_name if $COMPOSED{class}{$new_name};
 114
 115   foreach my $role (@roles) {
 116     _load_module($role);
 117     die "${role} is not a Role::Tiny" unless $INFO{$role};
 118   }
 119
 120   if ($] >= 5.010) {
 121     require mro;
 122   } else {
 123     require MRO::Compat;
 124   }
 125
 126   my @composable = map $me->_composable_package_for($_), reverse @roles;
 127
 128   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 129
 130   my @info = map $INFO{$_}, @roles;
 131
 132   $me->_check_requires(
 133     $new_name, $compose_name,
 134     do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h }
 135   );
 136
 137   *{_getglob "${new_name}::does"} = \&does_role unless $new_name->can('does');
 138
 139   @{$APPLIED_TO{$new_name}||={}}{
 140     map keys %{$APPLIED_TO{$_}}, @roles
 141   } = ();
 142
 143   $COMPOSED{class}{$new_name} = 1;
 144   return $new_name;
 145 }
 146
 147 sub apply_union_of_roles_to_package {
 148   my ($me, $to, @roles) = @_;
 149
 150   return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;
 151
 152   my %conflicts = %{$me->_union_info_for(@roles)->{conflicts}};
 153   delete $conflicts{$_} for $me->_concrete_methods_of($to);
 154   if (keys %conflicts) {
 155     my $fail =
 156       join "\n",
 157         map {
 158           "Due to a method name conflict between roles "
 159           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 160           .", the method '$_' must be implemented by '${to}'"
 161         } keys %conflicts;
 162     die $fail;
 163   }
 164   $me->apply_role_to_package($to, $_) for @roles;
 165   $APPLIED_TO{$to}{join('|',@roles)} = 1;
 166 }
 167
 168 sub _union_info_for {
 169   my ($me, @roles) = @_;
 170   $UNION_INFO{join('|',@roles)} ||= do {
 171     _load_module($_) for @roles;
 172     my %methods;
 173     foreach my $role (@roles) {
 174       my $this_methods = $me->_concrete_methods_of($role);
 175       $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
 176     }
 177     delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
 178     +{ conflicts => \%methods }
 179   };
 180 }
 181
 182 sub _composable_package_for {
 183   my ($me, $role) = @_;
 184   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 185   return $composed_name if $COMPOSED{role}{$composed_name};
 186   $me->_install_methods($composed_name, $role);
 187   my $base_name = $composed_name.'::_BASE';
 188   *{_getglob("${composed_name}::ISA")} = [ $base_name ];
 189   my $modifiers = $INFO{$role}{modifiers}||[];
 190   my @mod_base;
 191   foreach my $modified (
 192     do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
 193   ) {
 194     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
 195   }
 196   my $e;
 197   {
 198     local $@;
 199     eval(my $code = join "\n", "package ${base_name};", @mod_base);
 200     $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
 201   }
 202   die $e if $e;
 203   $me->_install_modifiers($composed_name, $modifiers);
 204   $COMPOSED{role}{$composed_name} = 1;
 205   return $composed_name;
 206 }
 207
 208 sub _check_requires {
 209   my ($me, $to, $name, @requires) = @_;
 210   if (my @requires_fail = grep !$to->can($_), @requires) {
 211     # role -> role, add to requires, role -> class, error out
 212     if (my $to_info = $INFO{$to}) {
 213       push @{$to_info->{requires}||=[]}, @requires_fail;
 214     } else {
 215       die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
 216     }
 217   }
 218 }
 219
 220 sub _concrete_methods_of {
 221   my ($me, $role) = @_;
 222   my $info = $INFO{$role};
 223   # grab role symbol table
 224   my $stash = do { no strict 'refs'; \%{"${role}::"}};
 225   my $not_methods = $info->{not_methods};
 226   +{
 227     # grab all code entries that aren't in the not_methods list
 228     map {
 229       my $code = *{$stash->{$_}}{CODE};
 230       # rely on the '' key we added in import for "no code here"
 231       exists $not_methods->{$code||''} ? () : ($_ => $code)
 232     } grep !ref($stash->{$_}), keys %$stash
 233   };
 234 }
 235
 236 sub methods_provided_by {
 237   my ($me, $role) = @_;
 238   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 239   (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
 240 }
 241
 242 sub _install_methods {
 243   my ($me, $to, $role) = @_;
 244
 245   my $info = $INFO{$role};
 246
 247   my $methods = $me->_concrete_methods_of($role);
 248
 249   # grab target symbol table
 250   my $stash = do { no strict 'refs'; \%{"${to}::"}};
 251
 252   # determine already extant methods of target
 253   my %has_methods;
 254   @has_methods{grep
 255     +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
 256     keys %$stash
 257   } = ();
 258
 259   foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
 260     no warnings 'once';
 261     *{_getglob "${to}::${i}"} = $methods->{$i};
 262   }
 263 }
 264
 265 sub _install_modifiers {
 266   my ($me, $to, $modifiers) = @_;
 267   if (my $info = $INFO{$to}) {
 268     push @{$info->{modifiers}}, @{$modifiers||[]};
 269   } else {
 270     foreach my $modifier (@{$modifiers||[]}) {
 271       $me->_install_single_modifier($to, @$modifier);
 272     }
 273   }
 274 }
 275
 276 sub _install_single_modifier {
 277   my ($me, @args) = @_;
 278   Class::Method::Modifiers::install_modifier(@args);
 279 }
 280
 281 sub does_role {
 282   my ($proto, $role) = @_;
 283   return exists $APPLIED_TO{ref($proto)||$proto}{$role};
 284 }
 285
 286 1;
 287
 288 =head1 NAME
 289
 290 Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
 291
 292 =head1 SYNOPSIS
 293
 294  package Some::Role;
 295
 296  use Role::Tiny;
 297
 298  sub foo { ... }
 299
 300  sub bar { ... }
 301
 302  around baz => sub { ... }
 303
 304  1;
 305
 306 else where
 307
 308  package Some::Class;
 309
 310  use Role::Tiny::With;
 311
 312  # bar gets imported, but not foo
 313  with 'Some::Role';
 314
 315  sub foo { ... }
 316
 317  # baz is wrapped in the around modifier by Class::Method::Modifiers
 318  sub baz { ... }
 319
 320  1;
 321
 322 If you wanted attributes as well, look at L<Moo::Role>.
 323
 324 =head1 DESCRIPTION
 325
 326 C<Role::Tiny> is a minimalist role composition tool.
 327
 328 =head1 ROLE COMPOSITION
 329
 330 Role composition can be thought of as much more clever and meaningful multiple
 331 inheritance.  The basics of this implementation of roles is:
 332
 333 =over 2
 334
 335 =item *
 336
 337 If a method is already defined on a class, that method will not be composed in
 338 from the role.
 339
 340 =item *
 341
 342 If a method that the role L</requires> to be implemented is not implemented,
 343 role application will fail loudly.
 344
 345 =back
 346
 347 Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
 348 composition is the other way around, where first wins.  In a more complete
 349 system (see L<Moose>) roles are checked to see if they clash.  The goal of this
 350 is to be much simpler, hence disallowing composition of multiple roles at once.
 351
 352 =head1 METHODS
 353
 354 =head2 apply_role_to_package
 355
 356  Role::Tiny->apply_role_to_package('Some::Package', 'Some::Role');
 357
 358 Composes role with package.  See also L<Role::Tiny::With>.
 359
 360 =head2 apply_roles_to_object
 361
 362  Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
 363
 364 Composes roles in order into object directly.  Object is reblessed into the
 365 resulting class.
 366
 367 =head2 create_class_with_roles
 368
 369  Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
 370
 371 Creates a new class based on base, with the roles composed into it in order.
 372 New class is returned.
 373
 374 =head1 SUBROUTINES
 375
 376 =head2 does_role
 377
 378  if (Role::Tiny::does_role($foo, 'Some::Role')) {
 379    ...
 380  }
 381
 382 Returns true if class has been composed with role.
 383
 384 This subroutine is also installed as ->does on any class a Role::Tiny is
 385 composed into unless that class already has an ->does method, so
 386
 387   if ($foo->does('Some::Role')) {
 388     ...
 389   }
 390
 391 will work for classes but to test a role, one must use ::does_role directly
 392
 393 =head1 IMPORTED SUBROUTINES
 394
 395 =head2 requires
 396
 397  requires qw(foo bar);
 398
 399 Declares a list of methods that must be defined to compose role.
 400
 401 =head2 with
 402
 403  with 'Some::Role1';
 404  with 'Some::Role2';
 405
 406 Composes another role into the current role.  Only one role may be composed in
 407 at a time to allow the code to remain as simple as possible.
 408
 409 =head2 before
 410
 411  before foo => sub { ... };
 412
 413 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 414 documentation.
 415
 416 Note that since you are not required to use method modifiers,
 417 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 418 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 419 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 420
 421 =head2 around
 422
 423  around foo => sub { ... };
 424
 425 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 426 documentation.
 427
 428 Note that since you are not required to use method modifiers,
 429 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 430 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 431 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 432
 433 =head2 after
 434
 435  after foo => sub { ... };
 436
 437 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 438 documentation.
 439
 440 Note that since you are not required to use method modifiers,
 441 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 442 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 443 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 444
 445 =head1 SEE ALSO
 446
 447 L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
 448 a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
 449
 450 If you don't want method modifiers and do want to be forcibly restricted
 451 to a single role application per class, Ovid's L<Role::Basic> exists. But
 452 Stevan Little (the L<Moose> author) and I are both still convinced that
 453 he's Doing It Wrong.
 454
 455 =head1 AUTHOR
 456
 457 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 458
 459 =head1 CONTRIBUTORS
 460
 461 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 462
 463 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 464
 465 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 466
 467 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 468
 469 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 470
 471 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 472
 473 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 474
 475 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 476
 477 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 478
 479 =head1 COPYRIGHT
 480
 481 Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
 482 as listed above.
 483
 484 =head1 LICENSE
 485
 486 This library is free software and may be distributed under the same terms
 487 as perl itself.
 488
 489 =cut