lib/Role/Tiny.pm

   1 package Role::Tiny;
   2
   3 sub _getglob { \*{$_[0]} }
   4 sub _getstash { \%{"$_[0]::"} }
   5
   6 use strict;
   7 use warnings FATAL => 'all';
   8
   9 our $VERSION = '1.003002';
  10 $VERSION = eval $VERSION;
  11
  12 our %INFO;
  13 our %APPLIED_TO;
  14 our %COMPOSED;
  15 our %COMPOSITE_INFO;
  16
  17 # Module state workaround totally stolen from Zefram's Module::Runtime.
  18
  19 BEGIN {
  20   *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
  21 }
  22
  23 sub Role::Tiny::__GUARD__::DESTROY {
  24   delete $INC{$_[0]->[0]} if @{$_[0]};
  25 }
  26
  27 sub _load_module {
  28   (my $proto = $_[0]) =~ s/::/\//g;
  29   $proto .= '.pm';
  30   return 1 if $INC{$proto};
  31   # can't just ->can('can') because a sub-package Foo::Bar::Baz
  32   # creates a 'Baz::' key in Foo::Bar's symbol table
  33   return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  34   my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
  35     && bless([ $proto ], 'Role::Tiny::__GUARD__');
  36   require $proto;
  37   pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  38   return 1;
  39 }
  40
  41 sub import {
  42   my $target = caller;
  43   my $me = shift;
  44   strict->import;
  45   warnings->import(FATAL => 'all');
  46   return if $me->is_role($target); # already exported into this package
  47   $INFO{$target}{is_role} = 1;
  48   # get symbol table reference
  49   my $stash = _getstash($target);
  50   # install before/after/around subs
  51   foreach my $type (qw(before after around)) {
  52     *{_getglob "${target}::${type}"} = sub {
  53       require Class::Method::Modifiers;
  54       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  55       return;
  56     };
  57   }
  58   *{_getglob "${target}::requires"} = sub {
  59     push @{$INFO{$target}{requires}||=[]}, @_;
  60     return;
  61   };
  62   *{_getglob "${target}::with"} = sub {
  63     $me->apply_roles_to_package($target, @_);
  64     return;
  65   };
  66   # grab all *non-constant* (stash slot is not a scalarref) subs present
  67   # in the symbol table and store their refaddrs (no need to forcibly
  68   # inflate constant subs into real subs) with a map to the coderefs in
  69   # case of copying or re-use
  70   my @not_methods = (map { *$_{CODE}||() } grep !ref($_), values %$stash);
  71   @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  72   # a role does itself
  73   $APPLIED_TO{$target} = { $target => undef };
  74 }
  75
  76 sub role_application_steps {
  77   qw(_install_methods _check_requires _install_modifiers _copy_applied_list);
  78 }
  79
  80 sub apply_single_role_to_package {
  81   my ($me, $to, $role) = @_;
  82
  83   _load_module($role);
  84
  85   die "This is apply_role_to_package" if ref($to);
  86   die "${role} is not a Role::Tiny" unless $me->is_role($role);
  87
  88   foreach my $step ($me->role_application_steps) {
  89     $me->$step($to, $role);
  90   }
  91 }
  92
  93 sub _copy_applied_list {
  94   my ($me, $to, $role) = @_;
  95   # copy our role list into the target's
  96   @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
  97 }
  98
  99 sub apply_roles_to_object {
 100   my ($me, $object, @roles) = @_;
 101   die "No roles supplied!" unless @roles;
 102   my $class = ref($object);
 103   # on perl < 5.8.9, magic isn't copied to all ref copies. bless the parameter
 104   # directly, so at least the variable passed to us will get any magic applied
 105   bless($_[1], $me->create_class_with_roles($class, @roles));
 106 }
 107
 108 my $role_suffix = 'A000';
 109 sub _composite_name {
 110   my ($me, $superclass, @roles) = @_;
 111
 112   my $new_name = join(
 113     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 114   );
 115
 116   if (length($new_name) > 252) {
 117     $new_name = $COMPOSED{abbrev}{$new_name}
 118       ||= substr($new_name, 0, 250 - length $role_suffix).'__'.$role_suffix++;
 119   }
 120   return wantarray ? ($new_name, $compose_name) : $new_name;
 121 }
 122
 123 sub create_class_with_roles {
 124   my ($me, $superclass, @roles) = @_;
 125
 126   die "No roles supplied!" unless @roles;
 127
 128   _load_module($superclass);
 129   {
 130     my %seen;
 131     $seen{$_}++ for @roles;
 132     if (my @dupes = grep $seen{$_} > 1, @roles) {
 133       die "Duplicated roles: ".join(', ', @dupes);
 134     }
 135   }
 136
 137   my ($new_name, $compose_name) = $me->_composite_name($superclass, @roles);
 138
 139   return $new_name if $COMPOSED{class}{$new_name};
 140
 141   foreach my $role (@roles) {
 142     _load_module($role);
 143     die "${role} is not a Role::Tiny" unless $me->is_role($role);
 144   }
 145
 146   if ($] >= 5.010) {
 147     require mro;
 148   } else {
 149     require MRO::Compat;
 150   }
 151
 152   my $composite_info = $me->_composite_info_for(@roles);
 153   my %conflicts = %{$composite_info->{conflicts}};
 154   if (keys %conflicts) {
 155     my $fail =
 156       join "\n",
 157         map {
 158           "Method name conflict for '$_' between roles "
 159           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 160           .", cannot apply these simultaneously to an object."
 161         } keys %conflicts;
 162     die $fail;
 163   }
 164
 165   my @composable = map $me->_composable_package_for($_), reverse @roles;
 166
 167   # some methods may not exist in the role, but get generated by
 168   # _composable_package_for (Moose accessors via Moo).  filter out anything
 169   # provided by the composable packages, excluding the subs we generated to
 170   # make modifiers work.
 171   my @requires = grep {
 172     my $method = $_;
 173     !grep $_->can($method) && !$COMPOSED{role}{$_}{modifiers_only}{$method},
 174       @composable
 175   } @{$composite_info->{requires}};
 176
 177   $me->_check_requires(
 178     $superclass, $compose_name, \@requires
 179   );
 180
 181   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 182
 183   @{$APPLIED_TO{$new_name}||={}}{
 184     map keys %{$APPLIED_TO{$_}}, @roles
 185   } = ();
 186
 187   $COMPOSED{class}{$new_name} = 1;
 188   return $new_name;
 189 }
 190
 191 # preserved for compat, and apply_roles_to_package calls it to allow an
 192 # updated Role::Tiny to use a non-updated Moo::Role
 193
 194 sub apply_role_to_package { shift->apply_single_role_to_package(@_) }
 195
 196 sub apply_roles_to_package {
 197   my ($me, $to, @roles) = @_;
 198
 199   return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;
 200
 201   my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
 202   my @have = grep $to->can($_), keys %conflicts;
 203   delete @conflicts{@have};
 204
 205   if (keys %conflicts) {
 206     my $fail =
 207       join "\n",
 208         map {
 209           "Due to a method name conflict between roles "
 210           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 211           .", the method '$_' must be implemented by '${to}'"
 212         } keys %conflicts;
 213     die $fail;
 214   }
 215
 216   # conflicting methods are supposed to be treated as required by the
 217   # composed role. we don't have an actual composed role, but because
 218   # we know the target class already provides them, we can instead
 219   # pretend that the roles don't do for the duration of application.
 220   my @role_methods = map $me->_concrete_methods_of($_), @roles;
 221   # separate loops, since local ..., delete ... for ...; creates a scope
 222   local @{$_}{@have} for @role_methods;
 223   delete @{$_}{@have} for @role_methods;
 224
 225   # the if guard here is essential since otherwise we accidentally create
 226   # a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
 227   # autovivification hates us and wants us to die()
 228   if ($INFO{$to}) {
 229     delete $INFO{$to}{methods}; # reset since we're about to add methods
 230   }
 231
 232   # backcompat: allow subclasses to use apply_single_role_to_package
 233   # to apply changes.  set a local var so ours does nothing.
 234   our %BACKCOMPAT_HACK;
 235   if($me ne __PACKAGE__
 236       and exists $BACKCOMPAT_HACK{$me} ? $BACKCOMPAT_HACK{$me} :
 237       $BACKCOMPAT_HACK{$me} =
 238         $me->can('role_application_steps')
 239           == \&role_application_steps
 240         && $me->can('apply_single_role_to_package')
 241           != \&apply_single_role_to_package
 242   ) {
 243     foreach my $role (@roles) {
 244       $me->apply_single_role_to_package($to, $role);
 245     }
 246   }
 247   else {
 248     foreach my $step ($me->role_application_steps) {
 249       foreach my $role (@roles) {
 250         $me->$step($to, $role);
 251       }
 252     }
 253   }
 254   $APPLIED_TO{$to}{join('|',@roles)} = 1;
 255 }
 256
 257 sub _composite_info_for {
 258   my ($me, @roles) = @_;
 259   $COMPOSITE_INFO{join('|', sort @roles)} ||= do {
 260     foreach my $role (@roles) {
 261       _load_module($role);
 262     }
 263     my %methods;
 264     foreach my $role (@roles) {
 265       my $this_methods = $me->_concrete_methods_of($role);
 266       $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
 267     }
 268     my %requires;
 269     @requires{map @{$INFO{$_}{requires}||[]}, @roles} = ();
 270     delete $requires{$_} for keys %methods;
 271     delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
 272     +{ conflicts => \%methods, requires => [keys %requires] }
 273   };
 274 }
 275
 276 sub _composable_package_for {
 277   my ($me, $role) = @_;
 278   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 279   return $composed_name if $COMPOSED{role}{$composed_name};
 280   $me->_install_methods($composed_name, $role);
 281   my $base_name = $composed_name.'::_BASE';
 282   # force stash to exist so ->can doesn't complain
 283   _getstash($base_name);
 284   # Not using _getglob, since setting @ISA via the typeglob breaks
 285   # inheritance on 5.10.0 if the stash has previously been accessed an
 286   # then a method called on the class (in that order!), which
 287   # ->_install_methods (with the help of ->_install_does) ends up doing.
 288   { no strict 'refs'; @{"${composed_name}::ISA"} = ( $base_name ); }
 289   my $modifiers = $INFO{$role}{modifiers}||[];
 290   my @mod_base;
 291   my @modifiers = grep !$composed_name->can($_),
 292     do { my %h; @h{map @{$_}[1..$#$_-1], @$modifiers} = (); keys %h };
 293   foreach my $modified (@modifiers) {
 294     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
 295   }
 296   my $e;
 297   {
 298     local $@;
 299     eval(my $code = join "\n", "package ${base_name};", @mod_base);
 300     $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
 301   }
 302   die $e if $e;
 303   $me->_install_modifiers($composed_name, $role);
 304   $COMPOSED{role}{$composed_name} = {
 305     modifiers_only => { map { $_ => 1 } @modifiers },
 306   };
 307   return $composed_name;
 308 }
 309
 310 sub _check_requires {
 311   my ($me, $to, $name, $requires) = @_;
 312   return unless my @requires = @{$requires||$INFO{$name}{requires}||[]};
 313   if (my @requires_fail = grep !$to->can($_), @requires) {
 314     # role -> role, add to requires, role -> class, error out
 315     if (my $to_info = $INFO{$to}) {
 316       push @{$to_info->{requires}||=[]}, @requires_fail;
 317     } else {
 318       die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
 319     }
 320   }
 321 }
 322
 323 sub _concrete_methods_of {
 324   my ($me, $role) = @_;
 325   my $info = $INFO{$role};
 326   # grab role symbol table
 327   my $stash = _getstash($role);
 328   # reverse so our keys become the values (captured coderefs) in case
 329   # they got copied or re-used since
 330   my $not_methods = { reverse %{$info->{not_methods}||{}} };
 331   $info->{methods} ||= +{
 332     # grab all code entries that aren't in the not_methods list
 333     map {
 334       my $code = *{$stash->{$_}}{CODE};
 335       ( ! $code or exists $not_methods->{$code} ) ? () : ($_ => $code)
 336     } grep !ref($stash->{$_}), keys %$stash
 337   };
 338 }
 339
 340 sub methods_provided_by {
 341   my ($me, $role) = @_;
 342   die "${role} is not a Role::Tiny" unless $me->is_role($role);
 343   (keys %{$me->_concrete_methods_of($role)}, @{$INFO{$role}->{requires}||[]});
 344 }
 345
 346 sub _install_methods {
 347   my ($me, $to, $role) = @_;
 348
 349   my $info = $INFO{$role};
 350
 351   my $methods = $me->_concrete_methods_of($role);
 352
 353   # grab target symbol table
 354   my $stash = _getstash($to);
 355
 356   # determine already extant methods of target
 357   my %has_methods;
 358   @has_methods{grep
 359     +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
 360     keys %$stash
 361   } = ();
 362
 363   foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
 364     no warnings 'once';
 365     my $glob = _getglob "${to}::${i}";
 366     *$glob = $methods->{$i};
 367
 368     # overloads using method names have the method stored in the scalar slot
 369     # and &overload::nil in the code slot.
 370     next
 371       unless $i =~ /^\(/
 372         && defined &overload::nil
 373         && $methods->{$i} == \&overload::nil;
 374
 375     my $overload = ${ *{_getglob "${role}::${i}"}{SCALAR} };
 376     next
 377       unless defined $overload;
 378
 379     *$glob = \$overload;
 380   }
 381
 382   $me->_install_does($to);
 383 }
 384
 385 sub _install_modifiers {
 386   my ($me, $to, $name) = @_;
 387   return unless my $modifiers = $INFO{$name}{modifiers};
 388   if (my $info = $INFO{$to}) {
 389     push @{$info->{modifiers}}, @{$modifiers||[]};
 390   } else {
 391     foreach my $modifier (@{$modifiers||[]}) {
 392       $me->_install_single_modifier($to, @$modifier);
 393     }
 394   }
 395 }
 396
 397 my $vcheck_error;
 398
 399 sub _install_single_modifier {
 400   my ($me, @args) = @_;
 401   defined($vcheck_error) or $vcheck_error = do {
 402     local $@;
 403     eval { Class::Method::Modifiers->VERSION(1.05); 1 }
 404       ? 0
 405       : $@
 406   };
 407   $vcheck_error and die $vcheck_error;
 408   Class::Method::Modifiers::install_modifier(@args);
 409 }
 410
 411 my $FALLBACK = sub { 0 };
 412 sub _install_does {
 413   my ($me, $to) = @_;
 414
 415   # only add does() method to classes
 416   return if $me->is_role($to);
 417
 418   # add does() only if they don't have one
 419   *{_getglob "${to}::does"} = \&does_role unless $to->can('does');
 420
 421   return
 422     if $to->can('DOES') and $to->can('DOES') != (UNIVERSAL->can('DOES') || 0);
 423
 424   my $existing = $to->can('DOES') || $to->can('isa') || $FALLBACK;
 425   my $new_sub = sub {
 426     my ($proto, $role) = @_;
 427     Role::Tiny::does_role($proto, $role) or $proto->$existing($role);
 428   };
 429   no warnings 'redefine';
 430   *{_getglob "${to}::DOES"} = $new_sub;
 431 }
 432
 433 sub does_role {
 434   my ($proto, $role) = @_;
 435   if ($] >= 5.010) {
 436     require mro;
 437   } else {
 438     require MRO::Compat;
 439   }
 440   foreach my $class (@{mro::get_linear_isa(ref($proto)||$proto)}) {
 441     return 1 if exists $APPLIED_TO{$class}{$role};
 442   }
 443   return 0;
 444 }
 445
 446 sub is_role {
 447   my ($me, $role) = @_;
 448   return !!($INFO{$role} && $INFO{$role}{is_role});
 449 }
 450
 451 1;
 452
 453 =encoding utf-8
 454
 455 =head1 NAME
 456
 457 Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
 458
 459 =head1 SYNOPSIS
 460
 461  package Some::Role;
 462
 463  use Role::Tiny;
 464
 465  sub foo { ... }
 466
 467  sub bar { ... }
 468
 469  around baz => sub { ... }
 470
 471  1;
 472
 473 else where
 474
 475  package Some::Class;
 476
 477  use Role::Tiny::With;
 478
 479  # bar gets imported, but not foo
 480  with 'Some::Role';
 481
 482  sub foo { ... }
 483
 484  # baz is wrapped in the around modifier by Class::Method::Modifiers
 485  sub baz { ... }
 486
 487  1;
 488
 489 If you wanted attributes as well, look at L<Moo::Role>.
 490
 491 =head1 DESCRIPTION
 492
 493 C<Role::Tiny> is a minimalist role composition tool.
 494
 495 =head1 ROLE COMPOSITION
 496
 497 Role composition can be thought of as much more clever and meaningful multiple
 498 inheritance.  The basics of this implementation of roles is:
 499
 500 =over 2
 501
 502 =item *
 503
 504 If a method is already defined on a class, that method will not be composed in
 505 from the role.
 506
 507 =item *
 508
 509 If a method that the role L</requires> to be implemented is not implemented,
 510 role application will fail loudly.
 511
 512 =back
 513
 514 Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
 515 composition is the other way around, where the class wins. If multiple roles
 516 are applied in a single call (single with statement), then if any of their
 517 provided methods clash, an exception is raised unless the class provides
 518 a method since this conflict indicates a potential problem.
 519
 520 =head1 IMPORTED SUBROUTINES
 521
 522 =head2 requires
 523
 524  requires qw(foo bar);
 525
 526 Declares a list of methods that must be defined to compose role.
 527
 528 =head2 with
 529
 530  with 'Some::Role1';
 531
 532  with 'Some::Role1', 'Some::Role2';
 533
 534 Composes another role into the current role (or class via L<Role::Tiny::With>).
 535
 536 If you have conflicts and want to resolve them in favour of Some::Role1 you
 537 can instead write:
 538
 539  with 'Some::Role1';
 540  with 'Some::Role2';
 541
 542 If you have conflicts and want to resolve different conflicts in favour of
 543 different roles, please refactor your codebase.
 544
 545 =head2 before
 546
 547  before foo => sub { ... };
 548
 549 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 550 documentation.
 551
 552 Note that since you are not required to use method modifiers,
 553 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 554 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 555 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 556
 557 =head2 around
 558
 559  around foo => sub { ... };
 560
 561 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 562 documentation.
 563
 564 Note that since you are not required to use method modifiers,
 565 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 566 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 567 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 568
 569 =head2 after
 570
 571  after foo => sub { ... };
 572
 573 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 574 documentation.
 575
 576 Note that since you are not required to use method modifiers,
 577 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 578 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 579 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 580
 581 =head2 Strict and Warnings
 582
 583 In addition to importing subroutines, using C<Role::Tiny> applies L<strict> and
 584 L<fatal warnings|perllexwarn/Fatal Warnings> to the caller.  It's possible to
 585 disable these if desired:
 586
 587  use Role::Tiny;
 588  use warnings NONFATAL => 'all';
 589
 590 =head1 SUBROUTINES
 591
 592 =head2 does_role
 593
 594  if (Role::Tiny::does_role($foo, 'Some::Role')) {
 595    ...
 596  }
 597
 598 Returns true if class has been composed with role.
 599
 600 This subroutine is also installed as ->does on any class a Role::Tiny is
 601 composed into unless that class already has an ->does method, so
 602
 603   if ($foo->does('Some::Role')) {
 604     ...
 605   }
 606
 607 will work for classes but to test a role, one must use ::does_role directly.
 608
 609 Additionally, Role::Tiny will override the standard Perl C<DOES> method
 610 for your class. However, if C<any> class in your class' inheritance
 611 hierarchy provides C<DOES>, then Role::Tiny will not override it.
 612
 613 =head1 METHODS
 614
 615 =head2 apply_roles_to_package
 616
 617  Role::Tiny->apply_roles_to_package(
 618    'Some::Package', 'Some::Role', 'Some::Other::Role'
 619  );
 620
 621 Composes role with package.  See also L<Role::Tiny::With>.
 622
 623 =head2 apply_roles_to_object
 624
 625  Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
 626
 627 Composes roles in order into object directly.  Object is reblessed into the
 628 resulting class.
 629
 630 =head2 create_class_with_roles
 631
 632  Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
 633
 634 Creates a new class based on base, with the roles composed into it in order.
 635 New class is returned.
 636
 637 =head2 is_role
 638
 639  Role::Tiny->is_role('Some::Role1')
 640
 641 Returns true if the given package is a role.
 642
 643 =head1 CAVEATS
 644
 645 =over 4
 646
 647 =item * On perl 5.8.8 and earlier, applying a role to an object won't apply any
 648 overloads from the role to all copies of the object.
 649
 650 =head1 SEE ALSO
 651
 652 L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
 653 a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
 654
 655 If you don't want method modifiers and do want to be forcibly restricted
 656 to a single role application per class, Ovid's L<Role::Basic> exists. But
 657 Stevan Little (the L<Moose> author) and I don't find the additional
 658 restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
 659 are more a guide to what you should prefer doing, to our mind, rather than
 660 something that needs to be enforced.
 661
 662 =head1 AUTHOR
 663
 664 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 665
 666 =head1 CONTRIBUTORS
 667
 668 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 669
 670 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 671
 672 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 673
 674 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 675
 676 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 677
 678 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 679
 680 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 681
 682 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 683
 684 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 685
 686 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>
 687
 688 ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>
 689
 690 tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org>
 691
 692 haarg - Graham Knop (cpan:HAARG) <haarg@haarg.org>
 693
 694 =head1 COPYRIGHT
 695
 696 Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
 697 as listed above.
 698
 699 =head1 LICENSE
 700
 701 This library is free software and may be distributed under the same terms
 702 as perl itself.
 703
 704 =cut