lib/Role/Tiny.pm

   1 package Role::Tiny;
   2
   3 sub _getglob { \*{$_[0]} }
   4 sub _getstash { \%{"$_[0]::"} }
   5
   6 use strict;
   7 use warnings FATAL => 'all';
   8
   9 our $VERSION = '1.000_900'; # 1.0.900
  10 $VERSION = eval $VERSION;
  11
  12 our %INFO;
  13 our %APPLIED_TO;
  14 our %COMPOSED;
  15 our %COMPOSITE_INFO;
  16
  17 # Module state workaround totally stolen from Zefram's Module::Runtime.
  18
  19 BEGIN {
  20   *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
  21 }
  22
  23 sub Role::Tiny::__GUARD__::DESTROY {
  24   delete $INC{$_[0]->[0]} if @{$_[0]};
  25 }
  26
  27 sub _load_module {
  28   (my $proto = $_[0]) =~ s/::/\//g;
  29   $proto .= '.pm';
  30   return 1 if $INC{$proto};
  31   # can't just ->can('can') because a sub-package Foo::Bar::Baz
  32   # creates a 'Baz::' key in Foo::Bar's symbol table
  33   return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  34   my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
  35     && bless([ $proto ], 'Role::Tiny::__GUARD__');
  36   require $proto;
  37   pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  38   return 1;
  39 }
  40
  41 sub import {
  42   my $target = caller;
  43   my $me = shift;
  44   strict->import;
  45   warnings->import(FATAL => 'all');
  46   return if $INFO{$target}; # already exported into this package
  47   # get symbol table reference
  48   my $stash = do { no strict 'refs'; \%{"${target}::"} };
  49   # install before/after/around subs
  50   foreach my $type (qw(before after around)) {
  51     *{_getglob "${target}::${type}"} = sub {
  52       require Class::Method::Modifiers;
  53       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  54     };
  55   }
  56   *{_getglob "${target}::requires"} = sub {
  57     push @{$INFO{$target}{requires}||=[]}, @_;
  58   };
  59   *{_getglob "${target}::with"} = sub {
  60     $me->apply_roles_to_package($target, @_);
  61   };
  62   # grab all *non-constant* (stash slot is not a scalarref) subs present
  63   # in the symbol table and store their refaddrs (no need to forcibly
  64   # inflate constant subs into real subs) - also add '' to here (this
  65   # is used later)
  66   @{$INFO{$target}{not_methods}={}}{
  67     '', map { *$_{CODE}||() } grep !ref($_), values %$stash
  68   } = ();
  69   # a role does itself
  70   $APPLIED_TO{$target} = { $target => undef };
  71 }
  72
  73 sub apply_single_role_to_package {
  74   my ($me, $to, $role) = @_;
  75
  76   _load_module($role);
  77
  78   die "This is apply_role_to_package" if ref($to);
  79   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
  80
  81   $me->_check_requires($to, $role, @{$info->{requires}||[]});
  82
  83   $me->_install_methods($to, $role);
  84
  85   $me->_install_modifiers($to, $info->{modifiers});
  86
  87   # only add does() method to classes and only if they don't have one
  88   if (not $INFO{$to} and not $to->can('does')) {
  89     *{_getglob "${to}::does"} = \&does_role;
  90   }
  91
  92   # copy our role list into the target's
  93   @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
  94 }
  95
  96 sub apply_roles_to_object {
  97   my ($me, $object, @roles) = @_;
  98   die "No roles supplied!" unless @roles;
  99   my $class = ref($object);
 100   bless($object, $me->create_class_with_roles($class, @roles));
 101   $object;
 102 }
 103
 104 sub create_class_with_roles {
 105   my ($me, $superclass, @roles) = @_;
 106
 107   die "No roles supplied!" unless @roles;
 108
 109   {
 110     my %seen;
 111     $seen{$_}++ for @roles;
 112     if (my @dupes = grep $seen{$_} > 1, @roles) {
 113       die "Duplicated roles: ".join(', ', @dupes);
 114     }
 115   }
 116
 117   my $new_name = join(
 118     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 119   );
 120
 121   return $new_name if $COMPOSED{class}{$new_name};
 122
 123   foreach my $role (@roles) {
 124     _load_module($role);
 125     die "${role} is not a Role::Tiny" unless $INFO{$role};
 126   }
 127
 128   if ($] >= 5.010) {
 129     require mro;
 130   } else {
 131     require MRO::Compat;
 132   }
 133
 134   my @composable = map $me->_composable_package_for($_), reverse @roles;
 135
 136   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 137
 138   my @info = map $INFO{$_}, @roles;
 139
 140   $me->_check_requires(
 141     $new_name, $compose_name,
 142     do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h }
 143   );
 144
 145   *{_getglob "${new_name}::does"} = \&does_role unless $new_name->can('does');
 146
 147   @{$APPLIED_TO{$new_name}||={}}{
 148     map keys %{$APPLIED_TO{$_}}, @roles
 149   } = ();
 150
 151   $COMPOSED{class}{$new_name} = 1;
 152   return $new_name;
 153 }
 154
 155 sub apply_role_to_package { shift->apply_single_role_to_package(@_) }
 156
 157 sub apply_roles_to_package {
 158   my ($me, $to, @roles) = @_;
 159
 160   return $me->apply_single_role_to_package($to, $roles[0]) if @roles == 1;
 161
 162   my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
 163   delete $conflicts{$_} for $me->_concrete_methods_of($to);
 164   if (keys %conflicts) {
 165     my $fail =
 166       join "\n",
 167         map {
 168           "Due to a method name conflict between roles "
 169           ."'".join(' and ', sort values %{$conflicts{$_}})."'"
 170           .", the method '$_' must be implemented by '${to}'"
 171         } keys %conflicts;
 172     die $fail;
 173   }
 174   delete $INFO{$to}{methods}; # reset since we're about to add methods
 175   $me->apply_single_role_to_package($to, $_) for @roles;
 176   $APPLIED_TO{$to}{join('|',@roles)} = 1;
 177 }
 178
 179 sub _composite_info_for {
 180   my ($me, @roles) = @_;
 181   $COMPOSITE_INFO{join('|', sort @roles)} ||= do {
 182     _load_module($_) for @roles;
 183     my %methods;
 184     foreach my $role (@roles) {
 185       my $this_methods = $me->_concrete_methods_of($role);
 186       $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
 187     }
 188     delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
 189     +{ conflicts => \%methods }
 190   };
 191 }
 192
 193 sub _composable_package_for {
 194   my ($me, $role) = @_;
 195   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 196   return $composed_name if $COMPOSED{role}{$composed_name};
 197   $me->_install_methods($composed_name, $role);
 198   my $base_name = $composed_name.'::_BASE';
 199   *{_getglob("${composed_name}::ISA")} = [ $base_name ];
 200   my $modifiers = $INFO{$role}{modifiers}||[];
 201   my @mod_base;
 202   foreach my $modified (
 203     do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
 204   ) {
 205     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
 206   }
 207   my $e;
 208   {
 209     local $@;
 210     eval(my $code = join "\n", "package ${base_name};", @mod_base);
 211     $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
 212   }
 213   die $e if $e;
 214   $me->_install_modifiers($composed_name, $modifiers);
 215   $COMPOSED{role}{$composed_name} = 1;
 216   return $composed_name;
 217 }
 218
 219 sub _check_requires {
 220   my ($me, $to, $name, @requires) = @_;
 221   if (my @requires_fail = grep !$to->can($_), @requires) {
 222     # role -> role, add to requires, role -> class, error out
 223     if (my $to_info = $INFO{$to}) {
 224       push @{$to_info->{requires}||=[]}, @requires_fail;
 225     } else {
 226       die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
 227     }
 228   }
 229 }
 230
 231 sub _concrete_methods_of {
 232   my ($me, $role) = @_;
 233   my $info = $INFO{$role};
 234   # grab role symbol table
 235   my $stash = do { no strict 'refs'; \%{"${role}::"}};
 236   my $not_methods = $info->{not_methods};
 237   $info->{methods} ||= +{
 238     # grab all code entries that aren't in the not_methods list
 239     map {
 240       my $code = *{$stash->{$_}}{CODE};
 241       # rely on the '' key we added in import for "no code here"
 242       exists $not_methods->{$code||''} ? () : ($_ => $code)
 243     } grep !ref($stash->{$_}), keys %$stash
 244   };
 245 }
 246
 247 sub methods_provided_by {
 248   my ($me, $role) = @_;
 249   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 250   (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
 251 }
 252
 253 sub _install_methods {
 254   my ($me, $to, $role) = @_;
 255
 256   my $info = $INFO{$role};
 257
 258   my $methods = $me->_concrete_methods_of($role);
 259
 260   # grab target symbol table
 261   my $stash = do { no strict 'refs'; \%{"${to}::"}};
 262
 263   # determine already extant methods of target
 264   my %has_methods;
 265   @has_methods{grep
 266     +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
 267     keys %$stash
 268   } = ();
 269
 270   foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
 271     no warnings 'once';
 272     *{_getglob "${to}::${i}"} = $methods->{$i};
 273   }
 274 }
 275
 276 sub _install_modifiers {
 277   my ($me, $to, $modifiers) = @_;
 278   if (my $info = $INFO{$to}) {
 279     push @{$info->{modifiers}}, @{$modifiers||[]};
 280   } else {
 281     foreach my $modifier (@{$modifiers||[]}) {
 282       $me->_install_single_modifier($to, @$modifier);
 283     }
 284   }
 285 }
 286
 287 sub _install_single_modifier {
 288   my ($me, @args) = @_;
 289   Class::Method::Modifiers::install_modifier(@args);
 290 }
 291
 292 sub does_role {
 293   my ($proto, $role) = @_;
 294   return exists $APPLIED_TO{ref($proto)||$proto}{$role};
 295 }
 296
 297 1;
 298
 299 =head1 NAME
 300
 301 Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
 302
 303 =head1 SYNOPSIS
 304
 305  package Some::Role;
 306
 307  use Role::Tiny;
 308
 309  sub foo { ... }
 310
 311  sub bar { ... }
 312
 313  around baz => sub { ... }
 314
 315  1;
 316
 317 else where
 318
 319  package Some::Class;
 320
 321  use Role::Tiny::With;
 322
 323  # bar gets imported, but not foo
 324  with 'Some::Role';
 325
 326  sub foo { ... }
 327
 328  # baz is wrapped in the around modifier by Class::Method::Modifiers
 329  sub baz { ... }
 330
 331  1;
 332
 333 If you wanted attributes as well, look at L<Moo::Role>.
 334
 335 =head1 DESCRIPTION
 336
 337 C<Role::Tiny> is a minimalist role composition tool.
 338
 339 =head1 ROLE COMPOSITION
 340
 341 Role composition can be thought of as much more clever and meaningful multiple
 342 inheritance.  The basics of this implementation of roles is:
 343
 344 =over 2
 345
 346 =item *
 347
 348 If a method is already defined on a class, that method will not be composed in
 349 from the role.
 350
 351 =item *
 352
 353 If a method that the role L</requires> to be implemented is not implemented,
 354 role application will fail loudly.
 355
 356 =back
 357
 358 Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
 359 composition is the other way around, where the class wins. If multiple roles
 360 are applied in a single call (single with statement), then if any of their
 361 provided methods clash, an exception is raised unless the class provides
 362 a method since this conflict indicates a potential problem.
 363
 364 =head1 METHODS
 365
 366 =head2 apply_roles_to_package
 367
 368  Role::Tiny->apply_roles_to_package(
 369    'Some::Package', 'Some::Role', 'Some::Other::Role'
 370  );
 371
 372 Composes role with package.  See also L<Role::Tiny::With>.
 373
 374 =head2 apply_roles_to_object
 375
 376  Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
 377
 378 Composes roles in order into object directly.  Object is reblessed into the
 379 resulting class.
 380
 381 =head2 create_class_with_roles
 382
 383  Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
 384
 385 Creates a new class based on base, with the roles composed into it in order.
 386 New class is returned.
 387
 388 =head1 SUBROUTINES
 389
 390 =head2 does_role
 391
 392  if (Role::Tiny::does_role($foo, 'Some::Role')) {
 393    ...
 394  }
 395
 396 Returns true if class has been composed with role.
 397
 398 This subroutine is also installed as ->does on any class a Role::Tiny is
 399 composed into unless that class already has an ->does method, so
 400
 401   if ($foo->does('Some::Role')) {
 402     ...
 403   }
 404
 405 will work for classes but to test a role, one must use ::does_role directly
 406
 407 =head1 IMPORTED SUBROUTINES
 408
 409 =head2 requires
 410
 411  requires qw(foo bar);
 412
 413 Declares a list of methods that must be defined to compose role.
 414
 415 =head2 with
 416
 417  with 'Some::Role1';
 418
 419  with 'Some::Role1', 'Some::Role2';
 420
 421 Composes another role into the current role (or class via L<Role::Tiny::With>).
 422
 423 If you have conflicts and want to resolve them in favour of Some::Role1 you
 424 can instead write:
 425
 426  with 'Some::Role1';
 427  with 'Some::Role2';
 428
 429 If you have conflicts and want to resolve different conflicts in favour of
 430 different roles, please refactor your codebase.
 431
 432 =head2 before
 433
 434  before foo => sub { ... };
 435
 436 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 437 documentation.
 438
 439 Note that since you are not required to use method modifiers,
 440 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 441 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 442 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 443
 444 =head2 around
 445
 446  around foo => sub { ... };
 447
 448 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 449 documentation.
 450
 451 Note that since you are not required to use method modifiers,
 452 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 453 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 454 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 455
 456 =head2 after
 457
 458  after foo => sub { ... };
 459
 460 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 461 documentation.
 462
 463 Note that since you are not required to use method modifiers,
 464 L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
 465 a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
 466 both L<Class::Method::Modifiers> and L<Role::Tiny>.
 467
 468 =head1 SEE ALSO
 469
 470 L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
 471 a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
 472
 473 If you don't want method modifiers and do want to be forcibly restricted
 474 to a single role application per class, Ovid's L<Role::Basic> exists. But
 475 Stevan Little (the L<Moose> author) don't find the additional restrictions
 476 to be amazingly helpful in most cases; L<Role::Basic>'s choices are more
 477 a guide to what you should prefer doing, to our mind, rather than something
 478 that needs to be enforced.
 479
 480 =head1 AUTHOR
 481
 482 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 483
 484 =head1 CONTRIBUTORS
 485
 486 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 487
 488 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 489
 490 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 491
 492 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 493
 494 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 495
 496 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 497
 498 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 499
 500 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 501
 502 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 503
 504 =head1 COPYRIGHT
 505
 506 Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
 507 as listed above.
 508
 509 =head1 LICENSE
 510
 511 This library is free software and may be distributed under the same terms
 512 as perl itself.
 513
 514 =cut