lib/Method/Generate/BuildAll.pm

   1 package Method::Generate::BuildAll;
   2
   3 use strictures 1;
   4 use base qw(Moo::Object);
   5 use Sub::Quote;
   6 use Moo::_mro;
   7 use Moo::_Utils;
   8 use B 'perlstring';
   9
  10 sub generate_method {
  11   my ($self, $into) = @_;
  12   quote_sub "${into}::BUILDALL", join '',
  13            $self->_handle_subbuild($into),
  14     qq{    my \$self = shift;\n},
  15            $self->buildall_body_for($into, '$self', '@_'),
  16     qq{    return \$self\n};
  17 }
  18
  19 sub _handle_subbuild {
  20   my ($self, $into) = @_;
  21   '    if (ref($_[0]) ne '.perlstring($into).') {'."\n".
  22   '      return shift->Moo::Object::BUILDALL(@_)'.";\n".
  23   '    }'."\n";
  24 }
  25
  26 sub buildall_body_for {
  27   my ($self, $into, $me, $args) = @_;
  28   my @builds =
  29     grep *{_getglob($_)}{CODE},
  30     map "${_}::BUILD",
  31     reverse @{mro::get_linear_isa($into)};
  32   join '', map qq{    ${me}->${_}(${args});\n}, @builds;
  33 }
  34
  35 1;