lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Class::Tiny::_Utils;
   5 use base qw(Class::Tiny::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8
   9 sub generate_method {
  10   my ($self, $into, $name, $spec, $quote_opts) = @_;
  11   die "Must have an is" unless my $is = $spec->{is};
  12   local $self->{captures} = {};
  13   my $body = do {
  14     if ($is eq 'ro') {
  15       $self->_generate_get($name)
  16     } elsif ($is eq 'rw') {
  17       $self->_generate_getset($name, $spec)
  18     } else {
  19       die "Unknown is ${is}";
  20     }
  21   };
  22   quote_sub
  23     "${into}::${name}" => '    '.$body."\n",
  24     $self->{captures}, $quote_opts||{}
  25   ;
  26 }
  27
  28 sub _generate_get {
  29   my ($self, $name) = @_;
  30   $self->_generate_simple_get('$_[0]', $name);
  31 }
  32
  33 sub generate_simple_get {
  34   shift->_generate_simple_get(@_);
  35 }
  36
  37 sub _generate_simple_get {
  38   my ($self, $me, $name) = @_;
  39   my $name_str = perlstring $name;
  40   "${me}->{${name_str}}";
  41 }
  42
  43 sub _generate_set {
  44   my ($self, $name, $value, $spec) = @_;
  45   my $simple = $self->_generate_simple_set($name, $value);
  46   my ($trigger, $isa_check) = @{$spec}{qw(trigger isa)};
  47   return $simple unless $trigger or $isa_check;
  48   my $code = 'do {';
  49   if ($isa_check) {
  50     $code .= ' '.$self->_generate_isa_check($name, '$_[1]', $isa_check).';';
  51   }
  52   if ($trigger) {
  53     my $fire = $self->_generate_trigger($name, '$_[0]', '$value', $trigger);
  54     $code .=
  55       ' my $value = '.$simple.'; '.$fire.'; '
  56       .'$value';
  57   } else {
  58     $code .= ' '.$simple;
  59   }
  60   $code .= ' }';
  61   return $code;
  62 }
  63
  64 sub generate_trigger {
  65   my $self = shift;
  66   local $self->{captures} = {};
  67   my $code = $self->_generate_trigger(@_);
  68   return ($code, $self->{captures});
  69 }
  70
  71 sub _generate_trigger {
  72   my ($self, $name, $obj, $value, $trigger) = @_;
  73   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
  74 }
  75
  76 sub generate_isa_check {
  77   my $self = shift;
  78   local $self->{captures} = {};
  79   my $code = $self->_generate_isa_check(@_);
  80   return ($code, $self->{captures});
  81 }
  82
  83 sub _generate_isa_check {
  84   my ($self, $name, $value, $check) = @_;
  85   $self->_generate_call_code($name, 'isa_check', $value, $check);
  86 }
  87
  88 sub _generate_call_code {
  89   my ($self, $name, $type, $values, $sub) = @_;
  90   if (my $quoted = quoted_from_sub($sub)) {
  91     my $code = $quoted->[1];
  92     my $at_ = 'local @_ = ('.$values.');';
  93     if (my $captures = $quoted->[2]) {
  94       my $cap_name = qq{\$${type}_captures_for_${name}};
  95       $self->{captures}->{$cap_name} = \$captures;
  96       return "do {\n".'      '.$at_."\n"
  97         .Sub::Quote::capture_unroll($cap_name, $captures, 6)
  98         ."     ${code}\n    }";
  99     }
 100     return 'do { local @_ = ('.$values.'); '.$code.' }';
 101   }
 102   my $cap_name = qq{\$${type}_for_${name}};
 103   $self->{captures}->{$cap_name} = \$sub;
 104   return "${cap_name}->(${values})";
 105 }
 106
 107 sub _generate_simple_set {
 108   my ($self, $name, $value) = @_;
 109   my $name_str = perlstring $name;
 110   "\$_[0]->{${name_str}} = ${value}";
 111 }
 112
 113 sub _generate_getset {
 114   my ($self, $name, $spec) = @_;
 115   q{(@_ > 1 ? }.$self->_generate_set($name, q{$_[1]}, $spec)
 116     .' : '.$self->_generate_get($name).')';
 117 }
 118
 119 1;