lib/Package/Stash/PP.pm

   1 package Package::Stash::PP;
   2 use strict;
   3 use warnings;
   4 # ABSTRACT: pure perl implementation of the Package::Stash API
   5
   6 use B;
   7 use Carp qw(confess);
   8 use Scalar::Util qw(blessed reftype weaken);
   9 use Symbol;
  10 # before 5.12, assigning to the ISA glob would make it lose its magical ->isa
  11 # powers
  12 use constant BROKEN_ISA_ASSIGNMENT => ($] < 5.012);
  13 # before 5.10, stashes don't ever seem to drop to a refcount of zero, so
  14 # weakening them isn't helpful
  15 use constant BROKEN_WEAK_STASH     => ($] < 5.010);
  16 # before 5.10, the scalar slot was always treated as existing if the
  17 # glob existed
  18 use constant BROKEN_SCALAR_INITIALIZATION => ($] < 5.010);
  19
  20 =head1 SYNOPSIS
  21
  22   use Package::Stash;
  23
  24 =head1 DESCRIPTION
  25
  26 This is a backend for L<Package::Stash> implemented in pure perl, for those without a compiler or who would like to use this inline in scripts.
  27
  28 =cut
  29
  30 sub new {
  31     my $class = shift;
  32     my ($package) = @_;
  33
  34     if (!defined($package) || (ref($package) && ref($package) ne 'HASH')) {
  35         confess "Package::Stash->new must be passed the name of the "
  36               . "package to access";
  37     }
  38     elsif (ref($package) eq 'HASH') {
  39         confess "The pure perl implementation of Package::Stash doesn't "
  40               . "currently support anonymous stashes. You should install "
  41               . "Package::Stash::XS";
  42     }
  43     elsif ($package !~ /\A[0-9A-Z_a-z]+(?:::[0-9A-Z_a-z]+)*\z/) {
  44         confess "$package is not a module name";
  45     }
  46
  47     return bless {
  48         'package' => $package,
  49     }, $class;
  50 }
  51
  52 sub name {
  53     confess "Can't call name as a class method"
  54         unless blessed($_[0]);
  55     return $_[0]->{package};
  56 }
  57
  58 sub namespace {
  59     confess "Can't call namespace as a class method"
  60         unless blessed($_[0]);
  61
  62     if (BROKEN_WEAK_STASH) {
  63         no strict 'refs';
  64         return \%{$_[0]->name . '::'};
  65     }
  66     else {
  67         return $_[0]->{namespace} if defined $_[0]->{namespace};
  68
  69         {
  70             no strict 'refs';
  71             $_[0]->{namespace} = \%{$_[0]->name . '::'};
  72         }
  73
  74         weaken($_[0]->{namespace});
  75
  76         return $_[0]->{namespace};
  77     }
  78 }
  79
  80 {
  81     my %SIGIL_MAP = (
  82         '$' => 'SCALAR',
  83         '@' => 'ARRAY',
  84         '%' => 'HASH',
  85         '&' => 'CODE',
  86         ''  => 'IO',
  87     );
  88
  89     sub _deconstruct_variable_name {
  90         my ($self, $variable) = @_;
  91
  92         (defined $variable && length $variable)
  93             || confess "You must pass a variable name";
  94
  95         # XXX in pure perl, this will access things in inner packages,
  96         # in xs, this will segfault - probably look more into this at
  97         # some point
  98         ($variable !~ /::/)
  99             || confess "Variable names may not contain ::";
 100
 101         my $sigil = substr($variable, 0, 1, '');
 102
 103         if (exists $SIGIL_MAP{$sigil}) {
 104             return ($variable, $sigil, $SIGIL_MAP{$sigil});
 105         }
 106         else {
 107             return ("${sigil}${variable}", '', $SIGIL_MAP{''});
 108         }
 109     }
 110 }
 111
 112 sub _valid_for_type {
 113     my $self = shift;
 114     my ($value, $type) = @_;
 115     if ($type eq 'HASH' || $type eq 'ARRAY'
 116      || $type eq 'IO'   || $type eq 'CODE') {
 117         return reftype($value) eq $type;
 118     }
 119     else {
 120         my $ref = reftype($value);
 121         return !defined($ref) || $ref eq 'SCALAR' || $ref eq 'REF' || $ref eq 'LVALUE' || $ref eq 'REGEXP' || $ref eq 'VSTRING';
 122     }
 123 }
 124
 125 sub add_symbol {
 126     my ($self, $variable, $initial_value, %opts) = @_;
 127
 128     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 129         ? @{$variable}{qw[name sigil type]}
 130         : $self->_deconstruct_variable_name($variable);
 131
 132     my $pkg = $self->name;
 133
 134     if (@_ > 2) {
 135         $self->_valid_for_type($initial_value, $type)
 136             || confess "$initial_value is not of type $type";
 137
 138         # cheap fail-fast check for PERLDBf_SUBLINE and '&'
 139         if ($^P and $^P & 0x10 && $sigil eq '&') {
 140             my $filename = $opts{filename};
 141             my $first_line_num = $opts{first_line_num};
 142
 143             (undef, $filename, $first_line_num) = caller
 144                 if not defined $filename;
 145
 146             my $last_line_num = $opts{last_line_num} || ($first_line_num ||= 0);
 147
 148             # http://perldoc.perl.org/perldebguts.html#Debugger-Internals
 149             $DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
 150         }
 151     }
 152
 153     no strict 'refs';
 154     no warnings 'redefine', 'misc', 'prototype';
 155     *{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
 156 }
 157
 158 sub remove_glob {
 159     my ($self, $name) = @_;
 160     delete $self->namespace->{$name};
 161 }
 162
 163 sub has_symbol {
 164     my ($self, $variable) = @_;
 165
 166     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 167         ? @{$variable}{qw[name sigil type]}
 168         : $self->_deconstruct_variable_name($variable);
 169
 170     my $namespace = $self->namespace;
 171
 172     return unless exists $namespace->{$name};
 173
 174     my $entry_ref = \$namespace->{$name};
 175     if (reftype($entry_ref) eq 'GLOB') {
 176         if ($type eq 'SCALAR') {
 177             if (BROKEN_SCALAR_INITIALIZATION) {
 178                 return defined ${ *{$entry_ref}{$type} };
 179             }
 180             else {
 181                 return B::svref_2object($entry_ref)->SV->isa('B::SV');
 182             }
 183         }
 184         else {
 185             return defined *{$entry_ref}{$type};
 186         }
 187     }
 188     else {
 189         # a symbol table entry can be -1 (stub), string (stub with prototype),
 190         # or reference (constant)
 191         return $type eq 'CODE';
 192     }
 193 }
 194
 195 sub get_symbol {
 196     my ($self, $variable, %opts) = @_;
 197
 198     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 199         ? @{$variable}{qw[name sigil type]}
 200         : $self->_deconstruct_variable_name($variable);
 201
 202     my $namespace = $self->namespace;
 203
 204     if (!exists $namespace->{$name}) {
 205         if ($opts{vivify}) {
 206             if ($type eq 'ARRAY') {
 207                 if (BROKEN_ISA_ASSIGNMENT) {
 208                     $self->add_symbol(
 209                         $variable,
 210                         $name eq 'ISA' ? () : ([])
 211                     );
 212                 }
 213                 else {
 214                     $self->add_symbol($variable, []);
 215                 }
 216             }
 217             elsif ($type eq 'HASH') {
 218                 $self->add_symbol($variable, {});
 219             }
 220             elsif ($type eq 'SCALAR') {
 221                 $self->add_symbol($variable);
 222             }
 223             elsif ($type eq 'IO') {
 224                 $self->add_symbol($variable, Symbol::geniosym);
 225             }
 226             elsif ($type eq 'CODE') {
 227                 confess "Don't know how to vivify CODE variables";
 228             }
 229             else {
 230                 confess "Unknown type $type in vivication";
 231             }
 232         }
 233         else {
 234             return undef;
 235         }
 236     }
 237
 238     my $entry_ref = \$namespace->{$name};
 239
 240     if (ref($entry_ref) eq 'GLOB') {
 241         return *{$entry_ref}{$type};
 242     }
 243     else {
 244         if ($type eq 'CODE') {
 245             no strict 'refs';
 246             return \&{ $self->name . '::' . $name };
 247         }
 248         else {
 249             return undef;
 250         }
 251     }
 252 }
 253
 254 sub get_or_add_symbol {
 255     my $self = shift;
 256     $self->get_symbol(@_, vivify => 1);
 257 }
 258
 259 sub remove_symbol {
 260     my ($self, $variable) = @_;
 261
 262     my ($name, $sigil, $type) = ref $variable eq 'HASH'
 263         ? @{$variable}{qw[name sigil type]}
 264         : $self->_deconstruct_variable_name($variable);
 265
 266     # FIXME:
 267     # no doubt this is grossly inefficient and
 268     # could be done much easier and faster in XS
 269
 270     my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
 271         { sigil => '$', type => 'SCALAR', name => $name },
 272         { sigil => '@', type => 'ARRAY',  name => $name },
 273         { sigil => '%', type => 'HASH',   name => $name },
 274         { sigil => '&', type => 'CODE',   name => $name },
 275         { sigil => '',  type => 'IO',     name => $name },
 276     );
 277
 278     my ($scalar, $array, $hash, $code, $io);
 279     if ($type eq 'SCALAR') {
 280         $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
 281         $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
 282         $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
 283         $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
 284     }
 285     elsif ($type eq 'ARRAY') {
 286         $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
 287         $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
 288         $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
 289         $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
 290     }
 291     elsif ($type eq 'HASH') {
 292         $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
 293         $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
 294         $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
 295         $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
 296     }
 297     elsif ($type eq 'CODE') {
 298         $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
 299         $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
 300         $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
 301         $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
 302     }
 303     elsif ($type eq 'IO') {
 304         $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
 305         $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
 306         $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
 307         $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
 308     }
 309     else {
 310         confess "This should never ever ever happen";
 311     }
 312
 313     $self->remove_glob($name);
 314
 315     $self->add_symbol($scalar_desc => $scalar) if defined $scalar;
 316     $self->add_symbol($array_desc  => $array)  if defined $array;
 317     $self->add_symbol($hash_desc   => $hash)   if defined $hash;
 318     $self->add_symbol($code_desc   => $code)   if defined $code;
 319     $self->add_symbol($io_desc     => $io)     if defined $io;
 320 }
 321
 322 sub list_all_symbols {
 323     my ($self, $type_filter) = @_;
 324
 325     my $namespace = $self->namespace;
 326     return keys %{$namespace} unless defined $type_filter;
 327
 328     # NOTE:
 329     # or we can filter based on
 330     # type (SCALAR|ARRAY|HASH|CODE)
 331     if ($type_filter eq 'CODE') {
 332         return grep {
 333             # any non-typeglob in the symbol table is a constant or stub
 334             ref(\$namespace->{$_}) ne 'GLOB'
 335                 # regular subs are stored in the CODE slot of the typeglob
 336                 || defined(*{$namespace->{$_}}{CODE})
 337         } keys %{$namespace};
 338     }
 339     elsif ($type_filter eq 'SCALAR') {
 340         return grep {
 341             BROKEN_SCALAR_INITIALIZATION
 342                 ? (ref(\$namespace->{$_}) eq 'GLOB'
 343                       && defined(${*{$namespace->{$_}}{'SCALAR'}}))
 344                 : (do {
 345                       my $entry = \$namespace->{$_};
 346                       ref($entry) eq 'GLOB'
 347                           && B::svref_2object($entry)->SV->isa('B::SV')
 348                   })
 349         } keys %{$namespace};
 350     }
 351     else {
 352         return grep {
 353             ref(\$namespace->{$_}) eq 'GLOB'
 354                 && defined(*{$namespace->{$_}}{$type_filter})
 355         } keys %{$namespace};
 356     }
 357 }
 358
 359 sub get_all_symbols {
 360     my ($self, $type_filter) = @_;
 361
 362     my $namespace = $self->namespace;
 363     return { %{$namespace} } unless defined $type_filter;
 364
 365     return {
 366         map { $_ => $self->get_symbol({name => $_, type => $type_filter}) }
 367             $self->list_all_symbols($type_filter)
 368     }
 369 }
 370
 371 =head1 BUGS
 372
 373 =over 4
 374
 375 =item * remove_symbol also replaces the associated typeglob
 376
 377 This can cause unexpected behavior when doing manipulation at compile time -
 378 removing subroutines will still allow them to be called from within the package
 379 as subroutines (although they will not be available as methods). This can be
 380 considered a feature in some cases (this is how L<namespace::clean> works, for
 381 instance), but should not be relied upon - use C<remove_glob> directly if you
 382 want this behavior.
 383
 384 =item * Some minor memory leaks
 385
 386 The pure perl implementation has a couple minor memory leaks (see the TODO
 387 tests in t/20-leaks.t) that I'm having a hard time tracking down - these may be
 388 core perl bugs, it's hard to tell.
 389
 390 =back
 391
 392 Please report any bugs through RT: email
 393 C<bug-package-stash at rt.cpan.org>, or browse to
 394 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.
 395
 396 =head1 SEE ALSO
 397
 398 =over 4
 399
 400 =item * L<Class::MOP::Package>
 401
 402 This module is a factoring out of code that used to live here
 403
 404 =back
 405
 406 =head1 SUPPORT
 407
 408 You can find this documentation for this module with the perldoc command.
 409
 410     perldoc Package::Stash
 411
 412 You can also look for information at:
 413
 414 =over 4
 415
 416 =item * AnnoCPAN: Annotated CPAN documentation
 417
 418 L<http://annocpan.org/dist/Package-Stash>
 419
 420 =item * CPAN Ratings
 421
 422 L<http://cpanratings.perl.org/d/Package-Stash>
 423
 424 =item * RT: CPAN's request tracker
 425
 426 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>
 427
 428 =item * Search CPAN
 429
 430 L<http://search.cpan.org/dist/Package-Stash>
 431
 432 =back
 433
 434 =head1 AUTHOR
 435
 436 Jesse Luehrs <doy at tozt dot net>
 437
 438 Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
 439 Moose Cabal.
 440
 441 =begin Pod::Coverage
 442
 443 BROKEN_ISA_ASSIGNMENT
 444 add_symbol
 445 get_all_symbols
 446 get_or_add_symbol
 447 get_symbol
 448 has_symbol
 449 list_all_symbols
 450 name
 451 namespace
 452 new
 453 remove_glob
 454
 455 =end Pod::Coverage
 456
 457 =cut
 458
 459 1;