[gitmo/Package-Stash.git] / lib / Package / Stash / PP.pm

package Package::Stash::PP;
use strict;
use warnings;
# ABSTRACT: pure perl implementation of the Package::Stash API

use Carp qw(confess);
use Scalar::Util qw(blessed reftype weaken);
use Symbol;
# before 5.12, assigning to the ISA glob would make it lose its magical ->isa
# powers
use constant BROKEN_ISA_ASSIGNMENT => ($] < 5.012);

=head1 SYNOPSIS

  use Package::Stash;

=head1 DESCRIPTION

This is a backend for L<Package::Stash> implemented in pure perl, for those without a compiler or who would like to use this inline in scripts.

=cut

sub new {
    my $class = shift;
    my ($package) = @_;
    my $namespace;
    return bless {
        'package' => $package,
    }, $class;
}

sub name {
    confess "Can't call name as a class method"
        unless blessed($_[0]);
    return $_[0]->{package};
}

sub namespace {
    confess "Can't call namespace as a class method"
        unless blessed($_[0]);
    return $_[0]->{namespace} if defined $_[0]->{namespace};

    {
        no strict 'refs';
        # supposedly this caused a bug in earlier perls, but I can't reproduce
        # it, so re-enabling the caching
        $_[0]->{namespace} = \%{$_[0]->name . '::'};
    }

    weaken($_[0]->{namespace});

    return $_[0]->{namespace};
}

{
    my %SIGIL_MAP = (
        '$' => 'SCALAR',
        '@' => 'ARRAY',
        '%' => 'HASH',
        '&' => 'CODE',
        ''  => 'IO',
    );

    sub _deconstruct_variable_name {
        my ($self, $variable) = @_;

        (defined $variable && length $variable)
            || confess "You must pass a variable name";

        my $sigil = substr($variable, 0, 1, '');

        if (exists $SIGIL_MAP{$sigil}) {
            return ($variable, $sigil, $SIGIL_MAP{$sigil});
        }
        else {
            return ("${sigil}${variable}", '', $SIGIL_MAP{''});
        }
    }
}

sub _valid_for_type {
    my $self = shift;
    my ($value, $type) = @_;
    if ($type eq 'HASH' || $type eq 'ARRAY'
     || $type eq 'IO'   || $type eq 'CODE') {
        return reftype($value) eq $type;
    }
    else {
        my $ref = reftype($value);
        return !defined($ref) || $ref eq 'SCALAR' || $ref eq 'REF' || $ref eq 'LVALUE';
    }
}

sub add_symbol {
    my ($self, $variable, $initial_value, %opts) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $pkg = $self->name;

    if (@_ > 2) {
        $self->_valid_for_type($initial_value, $type)
            || confess "$initial_value is not of type $type";

        # cheap fail-fast check for PERLDBf_SUBLINE and '&'
        if ($^P and $^P & 0x10 && $sigil eq '&') {
            my $filename = $opts{filename};
            my $first_line_num = $opts{first_line_num};

            (undef, $filename, $first_line_num) = caller
                if not defined $filename;

            my $last_line_num = $opts{last_line_num} || ($first_line_num ||= 0);

            # http://perldoc.perl.org/perldebguts.html#Debugger-Internals
            $DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
        }
    }

    no strict 'refs';
    no warnings 'redefine', 'misc', 'prototype';
    *{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
}

sub remove_glob {
    my ($self, $name) = @_;
    no strict 'refs';
    delete ${$self->name . '::'}{$name};
}

sub has_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    return unless exists $namespace->{$name};

    my $entry_ref = \$namespace->{$name};
    if (reftype($entry_ref) eq 'GLOB') {
        # XXX: assigning to any typeglob slot also initializes the SCALAR slot,
        # and saying that an undef scalar variable doesn't exist is probably
        # vaguely less surprising than a scalar variable popping into existence
        # without anyone defining it
        if ($type eq 'SCALAR') {
            return defined ${ *{$entry_ref}{$type} };
        }
        else {
            return defined *{$entry_ref}{$type};
        }
    }
    else {
        # a symbol table entry can be -1 (stub), string (stub with prototype),
        # or reference (constant)
        return $type eq 'CODE';
    }
}

sub get_symbol {
    my ($self, $variable, %opts) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    if (!exists $namespace->{$name}) {
        if ($opts{vivify}) {
            if ($type eq 'ARRAY') {
                if (BROKEN_ISA_ASSIGNMENT) {
                    $self->add_symbol(
                        $variable,
                        $name eq 'ISA' ? () : ([])
                    );
                }
                else {
                    $self->add_symbol($variable, []);
                }
            }
            elsif ($type eq 'HASH') {
                $self->add_symbol($variable, {});
            }
            elsif ($type eq 'SCALAR') {
                $self->add_symbol($variable);
            }
            elsif ($type eq 'IO') {
                $self->add_symbol($variable, Symbol::geniosym);
            }
            elsif ($type eq 'CODE') {
                confess "Don't know how to vivify CODE variables";
            }
            else {
                confess "Unknown type $type in vivication";
            }
        }
        else {
            return undef;
        }
    }

    my $entry_ref = \$namespace->{$name};

    if (ref($entry_ref) eq 'GLOB') {
        return *{$entry_ref}{$type};
    }
    else {
        if ($type eq 'CODE') {
            no strict 'refs';
            return \&{ $self->name . '::' . $name };
        }
        else {
            return undef;
        }
    }
}

sub get_or_add_symbol {
    my $self = shift;
    $self->get_symbol(@_, vivify => 1);
}

sub remove_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    # FIXME:
    # no doubt this is grossly inefficient and
    # could be done much easier and faster in XS

    my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
        { sigil => '$', type => 'SCALAR', name => $name },
        { sigil => '@', type => 'ARRAY',  name => $name },
        { sigil => '%', type => 'HASH',   name => $name },
        { sigil => '&', type => 'CODE',   name => $name },
        { sigil => '',  type => 'IO',     name => $name },
    );

    my ($scalar, $array, $hash, $code, $io);
    if ($type eq 'SCALAR') {
        $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
        $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
        $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
        $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
    }
    elsif ($type eq 'ARRAY') {
        $scalar = $self->get_symbol($scalar_desc);
        $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
        $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
        $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
    }
    elsif ($type eq 'HASH') {
        $scalar = $self->get_symbol($scalar_desc);
        $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
        $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
        $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
    }
    elsif ($type eq 'CODE') {
        $scalar = $self->get_symbol($scalar_desc);
        $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
        $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
        $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
    }
    elsif ($type eq 'IO') {
        $scalar = $self->get_symbol($scalar_desc);
        $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
        $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
        $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
    }
    else {
        confess "This should never ever ever happen";
    }

    $self->remove_glob($name);

    $self->add_symbol($scalar_desc => $scalar);
    $self->add_symbol($array_desc  => $array)  if defined $array;
    $self->add_symbol($hash_desc   => $hash)   if defined $hash;
    $self->add_symbol($code_desc   => $code)   if defined $code;
    $self->add_symbol($io_desc     => $io)     if defined $io;
}

sub list_all_symbols {
    my ($self, $type_filter) = @_;

    my $namespace = $self->namespace;
    return keys %{$namespace} unless defined $type_filter;

    # NOTE:
    # or we can filter based on
    # type (SCALAR|ARRAY|HASH|CODE)
    if ($type_filter eq 'CODE') {
        return grep {
            # any non-typeglob in the symbol table is a constant or stub
            ref(\$namespace->{$_}) ne 'GLOB'
                # regular subs are stored in the CODE slot of the typeglob
                || defined(*{$namespace->{$_}}{CODE})
        } keys %{$namespace};
    }
    elsif ($type_filter eq 'SCALAR') {
        return grep {
            ref(\$namespace->{$_}) eq 'GLOB'
                && defined(${*{$namespace->{$_}}{'SCALAR'}})
        } keys %{$namespace};
    }
    else {
        return grep {
            ref(\$namespace->{$_}) eq 'GLOB'
                && defined(*{$namespace->{$_}}{$type_filter})
        } keys %{$namespace};
    }
}

sub get_all_symbols {
    my ($self, $type_filter) = @_;

    my $namespace = $self->namespace;
    return { %{$namespace} } unless defined $type_filter;

    return {
        map { $_ => $self->get_symbol({name => $_, type => $type_filter}) }
            $self->list_all_symbols($type_filter)
    }
}

=head1 BUGS

=over 4

=item * Scalar slots are only considered to exist if they are defined

This is due to a shortcoming within perl itself. See
L<perlref/Making References> point 7 for more information.

=item * remove_symbol also replaces the associated typeglob

This can cause unexpected behavior when doing manipulation at compile time -
removing subroutines will still allow them to be called from within the package
as subroutines (although they will not be available as methods). This can be
considered a feature in some cases (this is how L<namespace::clean> works, for
instance), but should not be relied upon - use C<remove_glob> directly if you
want this behavior.

=item * Some minor memory leaks

The pure perl implementation has a couple minor memory leaks (see the TODO
tests in t/20-leaks.t) that I'm having a hard time tracking down - these may be
core perl bugs, it's hard to tell.

=back

Please report any bugs through RT: email
C<bug-package-stash at rt.cpan.org>, or browse to
L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.

=head1 SEE ALSO

=over 4

=item * L<Class::MOP::Package>

This module is a factoring out of code that used to live here

=back

=head1 SUPPORT

You can find this documentation for this module with the perldoc command.

    perldoc Package::Stash

You can also look for information at:

=over 4

=item * AnnoCPAN: Annotated CPAN documentation

L<http://annocpan.org/dist/Package-Stash>

=item * CPAN Ratings

L<http://cpanratings.perl.org/d/Package-Stash>

=item * RT: CPAN's request tracker

L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>

=item * Search CPAN

L<http://search.cpan.org/dist/Package-Stash>

=back

=head1 AUTHOR

Jesse Luehrs <doy at tozt dot net>

Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
Moose Cabal.

=begin Pod::Coverage

BROKEN_ISA_ASSIGNMENT
add_symbol
get_all_symbols
get_or_add_symbol
get_symbol
has_symbol
list_all_symbols
name
namespace
new
remove_glob

=end Pod::Coverage

=cut

1;
Commit	Line	Data
2905fb35	1	package Package::Stash::PP;
f10f6217	2	use strict;
f10f6217	3	use warnings;
2905fb35	4	# ABSTRACT: pure perl implementation of the Package::Stash API
f10f6217	5
f10f6217	6	use Carp qw(confess);
eb53b1bd	7	use Scalar::Util qw(blessed reftype weaken);
dc378b60	8	use Symbol;
	9	# before 5.12, assigning to the ISA glob would make it lose its magical ->isa
	10	# powers
	11	use constant BROKEN_ISA_ASSIGNMENT => ($] < 5.012);
f4979588	12
f4979588	13	=head1 SYNOPSIS
f4979588	14
2905fb35	15	use Package::Stash;
f4979588	16
	17	=head1 DESCRIPTION
	18
2905fb35	19	This is a backend for L<Package::Stash> implemented in pure perl, for those without a compiler or who would like to use this inline in scripts.
f4979588	20
	21	=cut
	22
f10f6217	23	sub new {
f10f6217	24	my $class = shift;
e55970bc	25	my ($package) = @_;
e55970bc	26	my $namespace;
e55970bc	27	return bless {
eb53b1bd	28	'package' => $package,
e55970bc	29	}, $class;
f10f6217	30	}
	31
	32	sub name {
2905fb35	33	confess "Can't call name as a class method"
2905fb35	34	unless blessed($_[0]);
f10f6217	35	return $_[0]->{package};
	36	}
	37
	38	sub namespace {
2905fb35	39	confess "Can't call namespace as a class method"
2905fb35	40	unless blessed($_[0]);
eb53b1bd	41	return $_[0]->{namespace} if defined $_[0]->{namespace};
	42
	43	{
	44	no strict 'refs';
	45	# supposedly this caused a bug in earlier perls, but I can't reproduce
	46	# it, so re-enabling the caching
	47	$_[0]->{namespace} = \%{$_[0]->name . '::'};
	48	}
	49
	50	weaken($_[0]->{namespace});
	51
e55970bc	52	return $_[0]->{namespace};
f10f6217	53	}
	54
	55	{
	56	my %SIGIL_MAP = (
	57	'$' => 'SCALAR',
	58	'@' => 'ARRAY',
	59	'%' => 'HASH',
	60	'&' => 'CODE',
56a29840	61	'' => 'IO',
f10f6217	62	);
	63
	64	sub _deconstruct_variable_name {
	65	my ($self, $variable) = @_;
	66
56a29840	67	(defined $variable && length $variable)
f10f6217	68	\|\| confess "You must pass a variable name";
	69
	70	my $sigil = substr($variable, 0, 1, '');
	71
56a29840	72	if (exists $SIGIL_MAP{$sigil}) {
	73	return ($variable, $sigil, $SIGIL_MAP{$sigil});
	74	}
	75	else {
	76	return ("${sigil}${variable}", '', $SIGIL_MAP{''});
	77	}
f10f6217	78	}
	79	}
	80
3634ce60	81	sub _valid_for_type {
	82	my $self = shift;
	83	my ($value, $type) = @_;
	84	if ($type eq 'HASH' \|\| $type eq 'ARRAY'
	85	\|\| $type eq 'IO' \|\| $type eq 'CODE') {
	86	return reftype($value) eq $type;
	87	}
	88	else {
	89	my $ref = reftype($value);
	90	return !defined($ref) \|\| $ref eq 'SCALAR' \|\| $ref eq 'REF' \|\| $ref eq 'LVALUE';
	91	}
	92	}
	93
2905fb35	94	sub add_symbol {
640de369	95	my ($self, $variable, $initial_value, %opts) = @_;
f10f6217	96
	97	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	98	? @{$variable}{qw[name sigil type]}
	99	: $self->_deconstruct_variable_name($variable);
	100
4ada57e0	101	my $pkg = $self->name;
4ada57e0	102
3634ce60	103	if (@_ > 2) {
	104	$self->_valid_for_type($initial_value, $type)
	105	\|\| confess "$initial_value is not of type $type";
3634ce60	106
4ada57e0	107	# cheap fail-fast check for PERLDBf_SUBLINE and '&'
4ada57e0	108	if ($^P and $^P & 0x10 && $sigil eq '&') {
640de369	109	my $filename = $opts{filename};
640de369	110	my $first_line_num = $opts{first_line_num};
4ada57e0	111
640de369	112	(undef, $filename, $first_line_num) = caller
4ada57e0	113	if not defined $filename;
640de369	114
640de369	115	my $last_line_num = $opts{last_line_num} \|\| ($first_line_num \|\|= 0);
4ada57e0	116
4ada57e0	117	# http://perldoc.perl.org/perldebguts.html#Debugger-Internals
640de369	118	$DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
4ada57e0	119	}
4ada57e0	120	}
f10f6217	121
	122	no strict 'refs';
	123	no warnings 'redefine', 'misc', 'prototype';
	124	*{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
	125	}
	126
2905fb35	127	sub remove_glob {
f10f6217	128	my ($self, $name) = @_;
	129	no strict 'refs';
	130	delete ${$self->name . '::'}{$name};
	131	}
	132
2905fb35	133	sub has_symbol {
f10f6217	134	my ($self, $variable) = @_;
	135
	136	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	137	? @{$variable}{qw[name sigil type]}
	138	: $self->_deconstruct_variable_name($variable);
	139
	140	my $namespace = $self->namespace;
	141
	142	return unless exists $namespace->{$name};
	143
	144	my $entry_ref = \$namespace->{$name};
	145	if (reftype($entry_ref) eq 'GLOB') {
f7543739	146	# XXX: assigning to any typeglob slot also initializes the SCALAR slot,
	147	# and saying that an undef scalar variable doesn't exist is probably
	148	# vaguely less surprising than a scalar variable popping into existence
	149	# without anyone defining it
	150	if ($type eq 'SCALAR') {
	151	return defined ${ *{$entry_ref}{$type} };
	152	}
	153	else {
	154	return defined *{$entry_ref}{$type};
	155	}
f10f6217	156	}
	157	else {
	158	# a symbol table entry can be -1 (stub), string (stub with prototype),
	159	# or reference (constant)
	160	return $type eq 'CODE';
	161	}
	162	}
	163
2905fb35	164	sub get_symbol {
e55803fc	165	my ($self, $variable, %opts) = @_;
f10f6217	166
	167	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	168	? @{$variable}{qw[name sigil type]}
	169	: $self->_deconstruct_variable_name($variable);
	170
	171	my $namespace = $self->namespace;
	172
7486ccf3	173	if (!exists $namespace->{$name}) {
dc378b60	174	if ($opts{vivify}) {
	175	if ($type eq 'ARRAY') {
	176	if (BROKEN_ISA_ASSIGNMENT) {
2905fb35	177	$self->add_symbol(
dc378b60	178	$variable,
	179	$name eq 'ISA' ? () : ([])
	180	);
	181	}
	182	else {
2905fb35	183	$self->add_symbol($variable, []);
dc378b60	184	}
	185	}
	186	elsif ($type eq 'HASH') {
2905fb35	187	$self->add_symbol($variable, {});
dc378b60	188	}
dc378b60	189	elsif ($type eq 'SCALAR') {
2905fb35	190	$self->add_symbol($variable);
dc378b60	191	}
dc378b60	192	elsif ($type eq 'IO') {
2905fb35	193	$self->add_symbol($variable, Symbol::geniosym);
dc378b60	194	}
	195	elsif ($type eq 'CODE') {
	196	confess "Don't know how to vivify CODE variables";
	197	}
	198	else {
	199	confess "Unknown type $type in vivication";
	200	}
5d3589c8	201	}
e55803fc	202	else {
4723417a	203	return undef;
e55803fc	204	}
30d1a098	205	}
f10f6217	206
	207	my $entry_ref = \$namespace->{$name};
	208
	209	if (ref($entry_ref) eq 'GLOB') {
	210	return *{$entry_ref}{$type};
	211	}
	212	else {
	213	if ($type eq 'CODE') {
	214	no strict 'refs';
	215	return \&{ $self->name . '::' . $name };
	216	}
	217	else {
	218	return undef;
	219	}
	220	}
	221	}
	222
2905fb35	223	sub get_or_add_symbol {
e55803fc	224	my $self = shift;
2905fb35	225	$self->get_symbol(@_, vivify => 1);
e55803fc	226	}
e55803fc	227
2905fb35	228	sub remove_symbol {
f10f6217	229	my ($self, $variable) = @_;
	230
	231	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	232	? @{$variable}{qw[name sigil type]}
	233	: $self->_deconstruct_variable_name($variable);
	234
	235	# FIXME:
9a3d1390	236	# no doubt this is grossly inefficient and
f10f6217	237	# could be done much easier and faster in XS
f10f6217	238
b1a00d0e	239	my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
f10f6217	240	{ sigil => '$', type => 'SCALAR', name => $name },
	241	{ sigil => '@', type => 'ARRAY', name => $name },
	242	{ sigil => '%', type => 'HASH', name => $name },
	243	{ sigil => '&', type => 'CODE', name => $name },
b1a00d0e	244	{ sigil => '', type => 'IO', name => $name },
f10f6217	245	);
f10f6217	246
b1a00d0e	247	my ($scalar, $array, $hash, $code, $io);
f10f6217	248	if ($type eq 'SCALAR') {
2905fb35	249	$array = $self->get_symbol($array_desc) if $self->has_symbol($array_desc);
	250	$hash = $self->get_symbol($hash_desc) if $self->has_symbol($hash_desc);
	251	$code = $self->get_symbol($code_desc) if $self->has_symbol($code_desc);
	252	$io = $self->get_symbol($io_desc) if $self->has_symbol($io_desc);
f10f6217	253	}
f10f6217	254	elsif ($type eq 'ARRAY') {
2905fb35	255	$scalar = $self->get_symbol($scalar_desc);
	256	$hash = $self->get_symbol($hash_desc) if $self->has_symbol($hash_desc);
	257	$code = $self->get_symbol($code_desc) if $self->has_symbol($code_desc);
	258	$io = $self->get_symbol($io_desc) if $self->has_symbol($io_desc);
f10f6217	259	}
f10f6217	260	elsif ($type eq 'HASH') {
2905fb35	261	$scalar = $self->get_symbol($scalar_desc);
	262	$array = $self->get_symbol($array_desc) if $self->has_symbol($array_desc);
	263	$code = $self->get_symbol($code_desc) if $self->has_symbol($code_desc);
	264	$io = $self->get_symbol($io_desc) if $self->has_symbol($io_desc);
f10f6217	265	}
f10f6217	266	elsif ($type eq 'CODE') {
2905fb35	267	$scalar = $self->get_symbol($scalar_desc);
	268	$array = $self->get_symbol($array_desc) if $self->has_symbol($array_desc);
	269	$hash = $self->get_symbol($hash_desc) if $self->has_symbol($hash_desc);
	270	$io = $self->get_symbol($io_desc) if $self->has_symbol($io_desc);
b1a00d0e	271	}
b1a00d0e	272	elsif ($type eq 'IO') {
2905fb35	273	$scalar = $self->get_symbol($scalar_desc);
	274	$array = $self->get_symbol($array_desc) if $self->has_symbol($array_desc);
	275	$hash = $self->get_symbol($hash_desc) if $self->has_symbol($hash_desc);
	276	$code = $self->get_symbol($code_desc) if $self->has_symbol($code_desc);
f10f6217	277	}
	278	else {
	279	confess "This should never ever ever happen";
	280	}
	281
2905fb35	282	$self->remove_glob($name);
f10f6217	283
2905fb35	284	$self->add_symbol($scalar_desc => $scalar);
	285	$self->add_symbol($array_desc => $array) if defined $array;
	286	$self->add_symbol($hash_desc => $hash) if defined $hash;
	287	$self->add_symbol($code_desc => $code) if defined $code;
	288	$self->add_symbol($io_desc => $io) if defined $io;
f10f6217	289	}
f10f6217	290
2905fb35	291	sub list_all_symbols {
f10f6217	292	my ($self, $type_filter) = @_;
	293
	294	my $namespace = $self->namespace;
	295	return keys %{$namespace} unless defined $type_filter;
	296
	297	# NOTE:
9a3d1390	298	# or we can filter based on
f10f6217	299	# type (SCALAR\|ARRAY\|HASH\|CODE)
	300	if ($type_filter eq 'CODE') {
	301	return grep {
25c87f5c	302	# any non-typeglob in the symbol table is a constant or stub
	303	ref(\$namespace->{$_}) ne 'GLOB'
	304	# regular subs are stored in the CODE slot of the typeglob
d1f721b3	305	\|\| defined(*{$namespace->{$_}}{CODE})
	306	} keys %{$namespace};
	307	}
	308	elsif ($type_filter eq 'SCALAR') {
	309	return grep {
	310	ref(\$namespace->{$_}) eq 'GLOB'
	311	&& defined(${*{$namespace->{$_}}{'SCALAR'}})
	312	} keys %{$namespace};
	313	}
	314	else {
	315	return grep {
	316	ref(\$namespace->{$_}) eq 'GLOB'
	317	&& defined(*{$namespace->{$_}}{$type_filter})
f10f6217	318	} keys %{$namespace};
f10f6217	319	}
f10f6217	320	}
f4979588	321
2905fb35	322	sub get_all_symbols {
	323	my ($self, $type_filter) = @_;
	324
	325	my $namespace = $self->namespace;
	326	return { %{$namespace} } unless defined $type_filter;
	327
	328	return {
	329	map { $_ => $self->get_symbol({name => $_, type => $type_filter}) }
	330	$self->list_all_symbols($type_filter)
	331	}
	332	}
	333
0992f4ec	334	=head1 BUGS
0992f4ec	335
2905fb35	336	=over 4
	337
	338	=item * Scalar slots are only considered to exist if they are defined
	339
	340	This is due to a shortcoming within perl itself. See
	341	L<perlref/Making References> point 7 for more information.
	342
	343	=item * remove_symbol also replaces the associated typeglob
	344
	345	This can cause unexpected behavior when doing manipulation at compile time -
	346	removing subroutines will still allow them to be called from within the package
	347	as subroutines (although they will not be available as methods). This can be
	348	considered a feature in some cases (this is how L<namespace::clean> works, for
	349	instance), but should not be relied upon - use C<remove_glob> directly if you
	350	want this behavior.
	351
cdb543b5	352	=item * Some minor memory leaks
	353
	354	The pure perl implementation has a couple minor memory leaks (see the TODO
	355	tests in t/20-leaks.t) that I'm having a hard time tracking down - these may be
	356	core perl bugs, it's hard to tell.
	357
2905fb35	358	=back
0992f4ec	359
	360	Please report any bugs through RT: email
	361	C<bug-package-stash at rt.cpan.org>, or browse to
	362	L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.
	363
f4979588	364	=head1 SEE ALSO
f4979588	365
f4979588	366	=over 4
f4979588	367
988beb41	368	=item * L<Class::MOP::Package>
f4979588	369
988beb41	370	This module is a factoring out of code that used to live here
f4979588	371
	372	=back
	373
0992f4ec	374	=head1 SUPPORT
	375
	376	You can find this documentation for this module with the perldoc command.
	377
	378	perldoc Package::Stash
	379
	380	You can also look for information at:
	381
	382	=over 4
	383
	384	=item * AnnoCPAN: Annotated CPAN documentation
	385
	386	L<http://annocpan.org/dist/Package-Stash>
	387
	388	=item * CPAN Ratings
	389
	390	L<http://cpanratings.perl.org/d/Package-Stash>
	391
	392	=item * RT: CPAN's request tracker
	393
	394	L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>
	395
	396	=item * Search CPAN
	397
	398	L<http://search.cpan.org/dist/Package-Stash>
	399
	400	=back
	401
	402	=head1 AUTHOR
	403
	404	Jesse Luehrs <doy at tozt dot net>
	405
	406	Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
	407	Moose Cabal.
	408
a912fc4b	409	=begin Pod::Coverage
	410
	411	BROKEN_ISA_ASSIGNMENT
	412	add_symbol
	413	get_all_symbols
	414	get_or_add_symbol
	415	get_symbol
	416	has_symbol
	417	list_all_symbols
	418	name
	419	namespace
	420	new
	421	remove_glob
	422
	423	=end Pod::Coverage
	424
f4979588	425	=cut
	426
	427	1;