t/01-basic.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Fatal;
   6
   7 use Package::Stash;
   8
   9 like(exception { Package::Stash->name }, qr/Can't call name as a class method/,
  10    q{... can't call name() as a class method});
  11
  12 {
  13     package Foo;
  14
  15     use constant SOME_CONSTANT => 1;
  16 }
  17
  18 # ----------------------------------------------------------------------
  19 ## tests adding a HASH
  20
  21 my $foo_stash = Package::Stash->new('Foo');
  22 ok(!defined($Foo::{foo}), '... the %foo slot has not been created yet');
  23 ok(!$foo_stash->has_symbol('%foo'), '... the object agrees');
  24 ok(!defined($Foo::{foo}), '... checking doesn\' vivify');
  25
  26 is(exception {
  27     $foo_stash->add_symbol('%foo' => { one => 1 });
  28 }, undef, '... created %Foo::foo successfully');
  29
  30 # ... scalar should NOT be created here
  31
  32 ok(!$foo_stash->has_symbol('$foo'), '... SCALAR shouldnt have been created too');
  33 ok(!$foo_stash->has_symbol('@foo'), '... ARRAY shouldnt have been created too');
  34 ok(!$foo_stash->has_symbol('&foo'), '... CODE shouldnt have been created too');
  35
  36 ok(defined($Foo::{foo}), '... the %foo slot was created successfully');
  37 ok($foo_stash->has_symbol('%foo'), '... the meta agrees');
  38
  39 # check the value ...
  40
  41 {
  42     no strict 'refs';
  43     ok(exists ${'Foo::foo'}{one}, '... our %foo was initialized correctly');
  44     is(${'Foo::foo'}{one}, 1, '... our %foo was initialized correctly');
  45 }
  46
  47 my $foo = $foo_stash->get_symbol('%foo');
  48 is_deeply({ one => 1 }, $foo, '... got the right package variable back');
  49
  50 # ... make sure changes propogate up
  51
  52 $foo->{two} = 2;
  53
  54 {
  55     no strict 'refs';
  56     is(\%{'Foo::foo'}, $foo_stash->get_symbol('%foo'), '... our %foo is the same as the metas');
  57
  58     ok(exists ${'Foo::foo'}{two}, '... our %foo was updated correctly');
  59     is(${'Foo::foo'}{two}, 2, '... our %foo was updated correctly');
  60 }
  61
  62 # ----------------------------------------------------------------------
  63 ## test adding an ARRAY
  64
  65 ok(!defined($Foo::{bar}), '... the @bar slot has not been created yet');
  66
  67 is(exception {
  68     $foo_stash->add_symbol('@bar' => [ 1, 2, 3 ]);
  69 }, undef, '... created @Foo::bar successfully');
  70
  71 ok(defined($Foo::{bar}), '... the @bar slot was created successfully');
  72 ok($foo_stash->has_symbol('@bar'), '... the meta agrees');
  73
  74 # ... why does this not work ...
  75
  76 ok(!$foo_stash->has_symbol('$bar'), '... SCALAR shouldnt have been created too');
  77 ok(!$foo_stash->has_symbol('%bar'), '... HASH shouldnt have been created too');
  78 ok(!$foo_stash->has_symbol('&bar'), '... CODE shouldnt have been created too');
  79
  80 # check the value itself
  81
  82 {
  83     no strict 'refs';
  84     is(scalar @{'Foo::bar'}, 3, '... our @bar was initialized correctly');
  85     is(${'Foo::bar'}[1], 2, '... our @bar was initialized correctly');
  86 }
  87
  88 # ----------------------------------------------------------------------
  89 ## test adding a SCALAR
  90
  91 ok(!defined($Foo::{baz}), '... the $baz slot has not been created yet');
  92
  93 is(exception {
  94     $foo_stash->add_symbol('$baz' => 10);
  95 }, undef, '... created $Foo::baz successfully');
  96
  97 ok(defined($Foo::{baz}), '... the $baz slot was created successfully');
  98 ok($foo_stash->has_symbol('$baz'), '... the meta agrees');
  99
 100 ok(!$foo_stash->has_symbol('@baz'), '... ARRAY shouldnt have been created too');
 101 ok(!$foo_stash->has_symbol('%baz'), '... HASH shouldnt have been created too');
 102 ok(!$foo_stash->has_symbol('&baz'), '... CODE shouldnt have been created too');
 103
 104 is(${$foo_stash->get_symbol('$baz')}, 10, '... got the right value back');
 105
 106 {
 107     no strict 'refs';
 108     ${'Foo::baz'} = 1;
 109
 110     is(${'Foo::baz'}, 1, '... our $baz was assigned to correctly');
 111     is(${$foo_stash->get_symbol('$baz')}, 1, '... the meta agrees');
 112 }
 113
 114 # ----------------------------------------------------------------------
 115 ## test adding a CODE
 116
 117 ok(!defined($Foo::{funk}), '... the &funk slot has not been created yet');
 118
 119 is(exception {
 120     $foo_stash->add_symbol('&funk' => sub { "Foo::funk" });
 121 }, undef, '... created &Foo::funk successfully');
 122
 123 ok(defined($Foo::{funk}), '... the &funk slot was created successfully');
 124 ok($foo_stash->has_symbol('&funk'), '... the meta agrees');
 125
 126 ok(!$foo_stash->has_symbol('$funk'), '... SCALAR shouldnt have been created too');
 127 ok(!$foo_stash->has_symbol('@funk'), '... ARRAY shouldnt have been created too');
 128 ok(!$foo_stash->has_symbol('%funk'), '... HASH shouldnt have been created too');
 129
 130 {
 131     no strict 'refs';
 132     ok(defined &{'Foo::funk'}, '... our &funk exists');
 133 }
 134
 135 is(Foo->funk(), 'Foo::funk', '... got the right value from the function');
 136
 137 # ----------------------------------------------------------------------
 138 ## test multiple slots in the glob
 139
 140 my $ARRAY = [ 1, 2, 3 ];
 141 my $CODE = sub { "Foo::foo" };
 142
 143 is(exception {
 144     $foo_stash->add_symbol('@foo' => $ARRAY);
 145 }, undef, '... created @Foo::foo successfully');
 146
 147 ok($foo_stash->has_symbol('@foo'), '... the @foo slot was added successfully');
 148 is($foo_stash->get_symbol('@foo'), $ARRAY, '... got the right values for @Foo::foo');
 149
 150 is(exception {
 151     $foo_stash->add_symbol('&foo' => $CODE);
 152 }, undef, '... created &Foo::foo successfully');
 153
 154 ok($foo_stash->has_symbol('&foo'), '... the meta agrees');
 155 is($foo_stash->get_symbol('&foo'), $CODE, '... got the right value for &Foo::foo');
 156
 157 is(exception {
 158     $foo_stash->add_symbol('$foo' => 'Foo::foo');
 159 }, undef, '... created $Foo::foo successfully');
 160
 161 ok($foo_stash->has_symbol('$foo'), '... the meta agrees');
 162 my $SCALAR = $foo_stash->get_symbol('$foo');
 163 is($$SCALAR, 'Foo::foo', '... got the right scalar value back');
 164
 165 {
 166     no strict 'refs';
 167     is(${'Foo::foo'}, 'Foo::foo', '... got the right value from the scalar');
 168 }
 169
 170 is(exception {
 171     $foo_stash->remove_symbol('%foo');
 172 }, undef, '... removed %Foo::foo successfully');
 173
 174 ok(!$foo_stash->has_symbol('%foo'), '... the %foo slot was removed successfully');
 175 ok($foo_stash->has_symbol('@foo'), '... the @foo slot still exists');
 176 ok($foo_stash->has_symbol('&foo'), '... the &foo slot still exists');
 177 ok($foo_stash->has_symbol('$foo'), '... the $foo slot still exists');
 178
 179 is($foo_stash->get_symbol('@foo'), $ARRAY, '... got the right values for @Foo::foo');
 180 is($foo_stash->get_symbol('&foo'), $CODE, '... got the right value for &Foo::foo');
 181 is($foo_stash->get_symbol('$foo'), $SCALAR, '... got the right value for $Foo::foo');
 182
 183 {
 184     no strict 'refs';
 185     ok(!defined(*{"Foo::foo"}{HASH}), '... the %foo slot has been removed successfully');
 186     ok(defined(*{"Foo::foo"}{ARRAY}), '... the @foo slot has NOT been removed');
 187     ok(defined(*{"Foo::foo"}{CODE}), '... the &foo slot has NOT been removed');
 188     ok(defined(${"Foo::foo"}), '... the $foo slot has NOT been removed');
 189 }
 190
 191 is(exception {
 192     $foo_stash->remove_symbol('&foo');
 193 }, undef, '... removed &Foo::foo successfully');
 194
 195 ok(!$foo_stash->has_symbol('&foo'), '... the &foo slot no longer exists');
 196
 197 ok($foo_stash->has_symbol('@foo'), '... the @foo slot still exists');
 198 ok($foo_stash->has_symbol('$foo'), '... the $foo slot still exists');
 199
 200 is($foo_stash->get_symbol('@foo'), $ARRAY, '... got the right values for @Foo::foo');
 201 is($foo_stash->get_symbol('$foo'), $SCALAR, '... got the right value for $Foo::foo');
 202
 203 {
 204     no strict 'refs';
 205     ok(!defined(*{"Foo::foo"}{HASH}), '... the %foo slot has been removed successfully');
 206     ok(!defined(*{"Foo::foo"}{CODE}), '... the &foo slot has now been removed');
 207     ok(defined(*{"Foo::foo"}{ARRAY}), '... the @foo slot has NOT been removed');
 208     ok(defined(${"Foo::foo"}), '... the $foo slot has NOT been removed');
 209 }
 210
 211 is(exception {
 212     $foo_stash->remove_symbol('$foo');
 213 }, undef, '... removed $Foo::foo successfully');
 214
 215 ok(!$foo_stash->has_symbol('$foo'), '... the $foo slot no longer exists');
 216
 217 ok($foo_stash->has_symbol('@foo'), '... the @foo slot still exists');
 218
 219 is($foo_stash->get_symbol('@foo'), $ARRAY, '... got the right values for @Foo::foo');
 220
 221 {
 222     no strict 'refs';
 223     ok(!defined(*{"Foo::foo"}{HASH}), '... the %foo slot has been removed successfully');
 224     ok(!defined(*{"Foo::foo"}{CODE}), '... the &foo slot has now been removed');
 225     ok(!defined(${"Foo::foo"}), '... the $foo slot has now been removed');
 226     ok(defined(*{"Foo::foo"}{ARRAY}), '... the @foo slot has NOT been removed');
 227 }
 228
 229 {
 230     my $syms = $foo_stash->get_all_symbols;
 231     is_deeply(
 232         [ sort keys %{ $syms } ],
 233         [ sort $foo_stash->list_all_symbols ],
 234         '... the fetched symbols are the same as the listed ones'
 235     );
 236 }
 237
 238 {
 239     my $syms = $foo_stash->get_all_symbols('CODE');
 240
 241     is_deeply(
 242         [ sort keys %{ $syms } ],
 243         [ sort $foo_stash->list_all_symbols('CODE') ],
 244         '... the fetched symbols are the same as the listed ones'
 245     );
 246
 247     foreach my $symbol (keys %{ $syms }) {
 248         is($syms->{$symbol}, $foo_stash->get_symbol('&' . $symbol), '... got the right symbol');
 249     }
 250 }
 251
 252 {
 253     $foo_stash->add_symbol('%zork');
 254
 255     my $syms = $foo_stash->get_all_symbols('HASH');
 256
 257     is_deeply(
 258         [ sort keys %{ $syms } ],
 259         [ sort $foo_stash->list_all_symbols('HASH') ],
 260         '... the fetched symbols are the same as the listed ones'
 261     );
 262
 263     foreach my $symbol (keys %{ $syms }) {
 264         is($syms->{$symbol}, $foo_stash->get_symbol('%' . $symbol), '... got the right symbol');
 265     }
 266
 267     no warnings 'once';
 268     is_deeply(
 269         $syms,
 270         { zork => \%Foo::zork },
 271         "got the right ones",
 272     );
 273 }
 274
 275 # check some errors
 276
 277 like(exception {
 278     $foo_stash->add_symbol('@bar', {})
 279 }, qr/HASH.*is not of type ARRAY/, "can't initialize a slot with the wrong type of value");
 280
 281 like(exception {
 282     $foo_stash->add_symbol('bar', [])
 283 }, qr/ARRAY.*is not of type IO/, "can't initialize a slot with the wrong type of value");
 284
 285 like(exception {
 286     $foo_stash->add_symbol('$bar', sub { })
 287 }, qr/CODE.*is not of type SCALAR/, "can't initialize a slot with the wrong type of value");
 288
 289 {
 290     package Bar;
 291     open *foo, '<', $0;
 292 }
 293
 294 like(exception {
 295     $foo_stash->add_symbol('$bar', *Bar::foo{IO})
 296 }, qr/IO.*is not of type SCALAR/, "can't initialize a slot with the wrong type of value");
 297
 298 # check compile time manipulation
 299
 300 {
 301     package Baz;
 302
 303     our $foo = 23;
 304     our @foo = "bar";
 305     our %foo = (baz => 1);
 306     sub foo { }
 307     open *foo, '<', $0;
 308     BEGIN { Package::Stash->new(__PACKAGE__)->remove_symbol('&foo') }
 309 }
 310
 311 {
 312     my $stash = Package::Stash->new('Baz');
 313     is(${ $stash->get_symbol('$foo') }, 23, "got \$foo");
 314     is_deeply($stash->get_symbol('@foo'), ['bar'], "got \@foo");
 315     is_deeply($stash->get_symbol('%foo'), {baz => 1}, "got \%foo");
 316     ok(!$stash->has_symbol('&foo'), "got \&foo");
 317     is($stash->get_symbol('foo'), *Baz::foo{IO}, "got foo");
 318 }
 319
 320 {
 321     package Quux;
 322
 323     our $foo = 23;
 324     our @foo = "bar";
 325     our %foo = (baz => 1);
 326     sub foo { }
 327     open *foo, '<', $0;
 328 }
 329
 330 {
 331     my $stash = Package::Stash->new('Quux');
 332
 333     my %expect = (
 334         '$foo' => \23,
 335         '@foo' => ["bar"],
 336         '%foo' => { baz => 1 },
 337         '&foo' => \&Quux::foo,
 338         'foo'  => *Quux::foo{IO},
 339     );
 340
 341     for my $sym ( sort keys %expect ) {
 342         is_deeply(
 343             $stash->get_symbol($sym),
 344             $expect{$sym},
 345             "got expected value for $sym"
 346         );
 347     }
 348
 349     $stash->add_symbol('%bar' => {x => 42});
 350
 351     $expect{'%bar'} = {x => 42};
 352
 353     for my $sym ( sort keys %expect ) {
 354         is_deeply(
 355             $stash->get_symbol($sym),
 356             $expect{$sym},
 357             "got expected value for $sym"
 358         );
 359     }
 360
 361     $stash->add_symbol('%bar' => {x => 43});
 362
 363     $expect{'%bar'} = {x => 43};
 364
 365     for my $sym ( sort keys %expect ) {
 366         is_deeply(
 367             $stash->get_symbol($sym),
 368             $expect{$sym},
 369             "got expected value for $sym"
 370         );
 371     }
 372 }
 373
 374 {
 375     package Quuux;
 376     our $foo;
 377     our @foo;
 378     our @bar;
 379     our %baz;
 380     sub baz { }
 381     use constant quux => 1;
 382     use constant quuux => [];
 383     sub quuuux;
 384 }
 385
 386 {
 387     my $quuux = Package::Stash->new('Quuux');
 388     is_deeply(
 389         [sort $quuux->list_all_symbols],
 390         [qw(BEGIN bar baz foo quuuux quuux quux)],
 391         "list_all_symbols",
 392     );
 393     { local $TODO = $] < 5.010 ? "undef scalars aren't visible on 5.8" : undef;
 394     is_deeply(
 395         [sort $quuux->list_all_symbols('SCALAR')],
 396         [qw(foo)],
 397         "list_all_symbols SCALAR",
 398     );
 399     }
 400     is_deeply(
 401         [sort $quuux->list_all_symbols('ARRAY')],
 402         [qw(bar foo)],
 403         "list_all_symbols ARRAY",
 404     );
 405     is_deeply(
 406         [sort $quuux->list_all_symbols('HASH')],
 407         [qw(baz)],
 408         "list_all_symbols HASH",
 409     );
 410     is_deeply(
 411         [sort $quuux->list_all_symbols('CODE')],
 412         [qw(baz quuuux quuux quux)],
 413         "list_all_symbols CODE",
 414     );
 415 }
 416
 417 done_testing;