[gitmo/Package-Stash-PP.git] / lib / Package / Stash.pm

package Package::Stash;
use strict;
use warnings;
# ABSTRACT: routines for manipulating stashes

use Carp qw(confess);
use Scalar::Util qw(reftype);
use Symbol;
# before 5.12, assigning to the ISA glob would make it lose its magical ->isa
# powers
use constant BROKEN_ISA_ASSIGNMENT => ($] < 5.012);

=head1 SYNOPSIS

  my $stash = Package::Stash->new('Foo');
  $stash->add_package_symbol('%foo', {bar => 1});
  # $Foo::foo{bar} == 1
  $stash->has_package_symbol('$foo') # false
  my $namespace = $stash->namespace;
  *{ $namespace->{foo} }{HASH} # {bar => 1}

=head1 DESCRIPTION

Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
incredibly messy, and easy to get wrong. This module hides all of that behind a
simple API.

NOTE: Most methods in this class require a variable specification that includes
a sigil. If this sigil is absent, it is assumed to represent the IO slot.

=method new $package_name

Creates a new C<Package::Stash> object, for the package given as the only
argument.

=cut

sub new {
    my $class = shift;
    my ($package) = @_;
    my $namespace;
    {
        no strict 'refs';
        # supposedly this caused a bug in earlier perls, but I can't reproduce
        # it, so re-enabling the caching
        $namespace = \%{$package . '::'};
    }
    return bless {
        'package'   => $package,
        'namespace' => $namespace,
    }, $class;
}

=method name

Returns the name of the package that this object represents.

=cut

sub name {
    return $_[0]->{package};
}

=method namespace

Returns the raw stash itself.

=cut

sub namespace {
    return $_[0]->{namespace};
}

{
    my %SIGIL_MAP = (
        '$' => 'SCALAR',
        '@' => 'ARRAY',
        '%' => 'HASH',
        '&' => 'CODE',
        ''  => 'IO',
    );

    sub _deconstruct_variable_name {
        my ($self, $variable) = @_;

        (defined $variable && length $variable)
            || confess "You must pass a variable name";

        my $sigil = substr($variable, 0, 1, '');

        if (exists $SIGIL_MAP{$sigil}) {
            return ($variable, $sigil, $SIGIL_MAP{$sigil});
        }
        else {
            return ("${sigil}${variable}", '', $SIGIL_MAP{''});
        }
    }
}

=method add_package_symbol $variable $value %opts

Adds a new package symbol, for the symbol given as C<$variable>, and optionally
gives it an initial value of C<$value>. C<$variable> should be the name of
variable including the sigil, so

  Package::Stash->new('Foo')->add_package_symbol('%foo')

will create C<%Foo::foo>.

Valid options (all optional) are C<filename>, C<first_line_num>, and
C<last_line_num>.

C<$opts{filename}>, C<$opts{first_line_num}>, and C<$opts{last_line_num}> can
be used to indicate where the symbol should be regarded as having been defined.
Currently these values are only used if the symbol is a subroutine ('C<&>'
sigil) and only if C<$^P & 0x10> is true, in which case the special C<%DB::sub>
hash is updated to record the values of C<filename>, C<first_line_num>, and
C<last_line_num> for the subroutine. If these are not passed, their values are
inferred (as much as possible) from C<caller> information.

This is especially useful for debuggers and profilers, which use C<%DB::sub> to
determine where the source code for a subroutine can be found.  See
L<http://perldoc.perl.org/perldebguts.html#Debugger-Internals> for more
information about C<%DB::sub>.

=cut

sub _valid_for_type {
    my $self = shift;
    my ($value, $type) = @_;
    if ($type eq 'HASH' || $type eq 'ARRAY'
     || $type eq 'IO'   || $type eq 'CODE') {
        return reftype($value) eq $type;
    }
    else {
        my $ref = reftype($value);
        return !defined($ref) || $ref eq 'SCALAR' || $ref eq 'REF' || $ref eq 'LVALUE';
    }
}

sub add_package_symbol {
    my ($self, $variable, $initial_value, %opts) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $pkg = $self->name;

    if (@_ > 2) {
        $self->_valid_for_type($initial_value, $type)
            || confess "$initial_value is not of type $type";

        # cheap fail-fast check for PERLDBf_SUBLINE and '&'
        if ($^P and $^P & 0x10 && $sigil eq '&') {
            my $filename = $opts{filename};
            my $first_line_num = $opts{first_line_num};

            (undef, $filename, $first_line_num) = caller
                if not defined $filename;

            my $last_line_num = $opts{last_line_num} || ($first_line_num ||= 0);

            # http://perldoc.perl.org/perldebguts.html#Debugger-Internals
            $DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
        }
    }

    no strict 'refs';
    no warnings 'redefine', 'misc', 'prototype';
    *{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
}

=method remove_package_glob $name

Removes all package variables with the given name, regardless of sigil.

=cut

sub remove_package_glob {
    my ($self, $name) = @_;
    no strict 'refs';
    delete ${$self->name . '::'}{$name};
}

# ... these functions deal with stuff on the namespace level

=method has_package_symbol $variable

Returns whether or not the given package variable (including sigil) exists.

=cut

sub has_package_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    return unless exists $namespace->{$name};

    my $entry_ref = \$namespace->{$name};
    if (reftype($entry_ref) eq 'GLOB') {
        return defined *{$entry_ref}{$type};
    }
    else {
        # a symbol table entry can be -1 (stub), string (stub with prototype),
        # or reference (constant)
        return $type eq 'CODE';
    }
}

=method get_package_symbol $variable

Returns the value of the given package variable (including sigil).

=cut

sub get_package_symbol {
    my ($self, $variable, %opts) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    if (!exists $namespace->{$name}) {
        if ($opts{vivify}) {
            if ($type eq 'ARRAY') {
                if (BROKEN_ISA_ASSIGNMENT) {
                    $self->add_package_symbol(
                        $variable,
                        $name eq 'ISA' ? () : ([])
                    );
                }
                else {
                    $self->add_package_symbol($variable, []);
                }
            }
            elsif ($type eq 'HASH') {
                $self->add_package_symbol($variable, {});
            }
            elsif ($type eq 'SCALAR') {
                $self->add_package_symbol($variable);
            }
            elsif ($type eq 'IO') {
                $self->add_package_symbol($variable, Symbol::geniosym);
            }
            elsif ($type eq 'CODE') {
                confess "Don't know how to vivify CODE variables";
            }
            else {
                confess "Unknown type $type in vivication";
            }
        }
        else {
            if ($type eq 'CODE') {
                # this effectively "de-vivifies" the code slot. if we don't do
                # this, referencing the coderef at the end of this function
                # will cause perl to auto-vivify a stub coderef in the slot,
                # which isn't what we want
                $self->add_package_symbol($variable);
            }
        }
    }

    my $entry_ref = \$namespace->{$name};

    if (ref($entry_ref) eq 'GLOB') {
        return *{$entry_ref}{$type};
    }
    else {
        if ($type eq 'CODE') {
            no strict 'refs';
            return \&{ $self->name . '::' . $name };
        }
        else {
            return undef;
        }
    }
}

=method get_or_add_package_symbol $variable

Like C<get_package_symbol>, except that it will return an empty hashref or
arrayref if the variable doesn't exist.

=cut

sub get_or_add_package_symbol {
    my $self = shift;
    $self->get_package_symbol(@_, vivify => 1);
}

=method remove_package_symbol $variable

Removes the package variable described by C<$variable> (which includes the
sigil); other variables with the same name but different sigils will be
untouched.

=cut

sub remove_package_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    # FIXME:
    # no doubt this is grossly inefficient and
    # could be done much easier and faster in XS

    my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
        { sigil => '$', type => 'SCALAR', name => $name },
        { sigil => '@', type => 'ARRAY',  name => $name },
        { sigil => '%', type => 'HASH',   name => $name },
        { sigil => '&', type => 'CODE',   name => $name },
        { sigil => '',  type => 'IO',     name => $name },
    );

    my ($scalar, $array, $hash, $code, $io);
    if ($type eq 'SCALAR') {
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'ARRAY') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'HASH') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'CODE') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'IO') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
    }
    else {
        confess "This should never ever ever happen";
    }

    $self->remove_package_glob($name);

    $self->add_package_symbol($scalar_desc => $scalar);
    $self->add_package_symbol($array_desc  => $array)  if defined $array;
    $self->add_package_symbol($hash_desc   => $hash)   if defined $hash;
    $self->add_package_symbol($code_desc   => $code)   if defined $code;
    $self->add_package_symbol($io_desc     => $io)     if defined $io;
}

=method list_all_package_symbols $type_filter

Returns a list of package variable names in the package, without sigils. If a
C<type_filter> is passed, it is used to select package variables of a given
type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
etc).

=cut

sub list_all_package_symbols {
    my ($self, $type_filter) = @_;

    my $namespace = $self->namespace;
    return keys %{$namespace} unless defined $type_filter;

    # NOTE:
    # or we can filter based on
    # type (SCALAR|ARRAY|HASH|CODE)
    if ($type_filter eq 'CODE') {
        return grep {
            # any non-typeglob in the symbol table is a constant or stub
            ref(\$namespace->{$_}) ne 'GLOB'
                # regular subs are stored in the CODE slot of the typeglob
                || defined(*{$namespace->{$_}}{CODE});
        } keys %{$namespace};
    } else {
        return grep { *{$namespace->{$_}}{$type_filter} } keys %{$namespace};
    }
}

=head1 BUGS

No known bugs.

Please report any bugs through RT: email
C<bug-package-stash at rt.cpan.org>, or browse to
L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.

=head1 SEE ALSO

=over 4

=item * L<Class::MOP::Package>

This module is a factoring out of code that used to live here

=back

=head1 SUPPORT

You can find this documentation for this module with the perldoc command.

    perldoc Package::Stash

You can also look for information at:

=over 4

=item * AnnoCPAN: Annotated CPAN documentation

L<http://annocpan.org/dist/Package-Stash>

=item * CPAN Ratings

L<http://cpanratings.perl.org/d/Package-Stash>

=item * RT: CPAN's request tracker

L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>

=item * Search CPAN

L<http://search.cpan.org/dist/Package-Stash>

=back

=head1 AUTHOR

Jesse Luehrs <doy at tozt dot net>

Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
Moose Cabal.

=cut

1;
Commit	Line	Data
e94260da	1	package Package::Stash;
f10f6217	2	use strict;
f10f6217	3	use warnings;
988beb41	4	# ABSTRACT: routines for manipulating stashes
f10f6217	5
	6	use Carp qw(confess);
	7	use Scalar::Util qw(reftype);
dc378b60	8	use Symbol;
	9	# before 5.12, assigning to the ISA glob would make it lose its magical ->isa
	10	# powers
	11	use constant BROKEN_ISA_ASSIGNMENT => ($] < 5.012);
f4979588	12
f4979588	13	=head1 SYNOPSIS
f4979588	14
e94260da	15	my $stash = Package::Stash->new('Foo');
683542f5	16	$stash->add_package_symbol('%foo', {bar => 1});
	17	# $Foo::foo{bar} == 1
	18	$stash->has_package_symbol('$foo') # false
	19	my $namespace = $stash->namespace;
	20	*{ $namespace->{foo} }{HASH} # {bar => 1}
f4979588	21
	22	=head1 DESCRIPTION
	23
683542f5	24	Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
	25	incredibly messy, and easy to get wrong. This module hides all of that behind a
	26	simple API.
	27
56a29840	28	NOTE: Most methods in this class require a variable specification that includes
	29	a sigil. If this sigil is absent, it is assumed to represent the IO slot.
	30
988beb41	31	=method new $package_name
683542f5	32
e94260da	33	Creates a new C<Package::Stash> object, for the package given as the only
683542f5	34	argument.
f4979588	35
	36	=cut
	37
f10f6217	38	sub new {
f10f6217	39	my $class = shift;
e55970bc	40	my ($package) = @_;
	41	my $namespace;
	42	{
	43	no strict 'refs';
	44	# supposedly this caused a bug in earlier perls, but I can't reproduce
	45	# it, so re-enabling the caching
	46	$namespace = \%{$package . '::'};
	47	}
	48	return bless {
	49	'package' => $package,
	50	'namespace' => $namespace,
	51	}, $class;
f10f6217	52	}
f10f6217	53
988beb41	54	=method name
683542f5	55
	56	Returns the name of the package that this object represents.
	57
	58	=cut
	59
f10f6217	60	sub name {
	61	return $_[0]->{package};
	62	}
	63
988beb41	64	=method namespace
683542f5	65
	66	Returns the raw stash itself.
	67
	68	=cut
	69
f10f6217	70	sub namespace {
e55970bc	71	return $_[0]->{namespace};
f10f6217	72	}
	73
	74	{
	75	my %SIGIL_MAP = (
	76	'$' => 'SCALAR',
	77	'@' => 'ARRAY',
	78	'%' => 'HASH',
	79	'&' => 'CODE',
56a29840	80	'' => 'IO',
f10f6217	81	);
	82
	83	sub _deconstruct_variable_name {
	84	my ($self, $variable) = @_;
	85
56a29840	86	(defined $variable && length $variable)
f10f6217	87	\|\| confess "You must pass a variable name";
	88
	89	my $sigil = substr($variable, 0, 1, '');
	90
56a29840	91	if (exists $SIGIL_MAP{$sigil}) {
	92	return ($variable, $sigil, $SIGIL_MAP{$sigil});
	93	}
	94	else {
	95	return ("${sigil}${variable}", '', $SIGIL_MAP{''});
	96	}
f10f6217	97	}
	98	}
	99
988beb41	100	=method add_package_symbol $variable $value %opts
683542f5	101
	102	Adds a new package symbol, for the symbol given as C<$variable>, and optionally
	103	gives it an initial value of C<$value>. C<$variable> should be the name of
	104	variable including the sigil, so
	105
e94260da	106	Package::Stash->new('Foo')->add_package_symbol('%foo')
683542f5	107
	108	will create C<%Foo::foo>.
	109
c61010aa	110	Valid options (all optional) are C<filename>, C<first_line_num>, and
	111	C<last_line_num>.
	112
	113	C<$opts{filename}>, C<$opts{first_line_num}>, and C<$opts{last_line_num}> can
	114	be used to indicate where the symbol should be regarded as having been defined.
4ada57e0	115	Currently these values are only used if the symbol is a subroutine ('C<&>'
c61010aa	116	sigil) and only if C<$^P & 0x10> is true, in which case the special C<%DB::sub>
	117	hash is updated to record the values of C<filename>, C<first_line_num>, and
	118	C<last_line_num> for the subroutine. If these are not passed, their values are
	119	inferred (as much as possible) from C<caller> information.
4ada57e0	120
	121	This is especially useful for debuggers and profilers, which use C<%DB::sub> to
	122	determine where the source code for a subroutine can be found. See
	123	L<http://perldoc.perl.org/perldebguts.html#Debugger-Internals> for more
	124	information about C<%DB::sub>.
	125
683542f5	126	=cut
683542f5	127
3634ce60	128	sub _valid_for_type {
	129	my $self = shift;
	130	my ($value, $type) = @_;
	131	if ($type eq 'HASH' \|\| $type eq 'ARRAY'
	132	\|\| $type eq 'IO' \|\| $type eq 'CODE') {
	133	return reftype($value) eq $type;
	134	}
	135	else {
	136	my $ref = reftype($value);
	137	return !defined($ref) \|\| $ref eq 'SCALAR' \|\| $ref eq 'REF' \|\| $ref eq 'LVALUE';
	138	}
	139	}
	140
f10f6217	141	sub add_package_symbol {
640de369	142	my ($self, $variable, $initial_value, %opts) = @_;
f10f6217	143
	144	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	145	? @{$variable}{qw[name sigil type]}
	146	: $self->_deconstruct_variable_name($variable);
	147
4ada57e0	148	my $pkg = $self->name;
4ada57e0	149
3634ce60	150	if (@_ > 2) {
	151	$self->_valid_for_type($initial_value, $type)
	152	\|\| confess "$initial_value is not of type $type";
3634ce60	153
4ada57e0	154	# cheap fail-fast check for PERLDBf_SUBLINE and '&'
4ada57e0	155	if ($^P and $^P & 0x10 && $sigil eq '&') {
640de369	156	my $filename = $opts{filename};
640de369	157	my $first_line_num = $opts{first_line_num};
4ada57e0	158
640de369	159	(undef, $filename, $first_line_num) = caller
4ada57e0	160	if not defined $filename;
640de369	161
640de369	162	my $last_line_num = $opts{last_line_num} \|\| ($first_line_num \|\|= 0);
4ada57e0	163
4ada57e0	164	# http://perldoc.perl.org/perldebguts.html#Debugger-Internals
640de369	165	$DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
4ada57e0	166	}
4ada57e0	167	}
f10f6217	168
	169	no strict 'refs';
	170	no warnings 'redefine', 'misc', 'prototype';
	171	*{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
	172	}
	173
988beb41	174	=method remove_package_glob $name
683542f5	175
	176	Removes all package variables with the given name, regardless of sigil.
	177
	178	=cut
	179
f10f6217	180	sub remove_package_glob {
	181	my ($self, $name) = @_;
	182	no strict 'refs';
	183	delete ${$self->name . '::'}{$name};
	184	}
	185
	186	# ... these functions deal with stuff on the namespace level
	187
988beb41	188	=method has_package_symbol $variable
683542f5	189
	190	Returns whether or not the given package variable (including sigil) exists.
	191
	192	=cut
	193
f10f6217	194	sub has_package_symbol {
	195	my ($self, $variable) = @_;
	196
	197	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	198	? @{$variable}{qw[name sigil type]}
	199	: $self->_deconstruct_variable_name($variable);
	200
	201	my $namespace = $self->namespace;
	202
	203	return unless exists $namespace->{$name};
	204
	205	my $entry_ref = \$namespace->{$name};
	206	if (reftype($entry_ref) eq 'GLOB') {
25c87f5c	207	return defined *{$entry_ref}{$type};
f10f6217	208	}
	209	else {
	210	# a symbol table entry can be -1 (stub), string (stub with prototype),
	211	# or reference (constant)
	212	return $type eq 'CODE';
	213	}
	214	}
	215
988beb41	216	=method get_package_symbol $variable
683542f5	217
	218	Returns the value of the given package variable (including sigil).
	219
	220	=cut
	221
f10f6217	222	sub get_package_symbol {
e55803fc	223	my ($self, $variable, %opts) = @_;
f10f6217	224
	225	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	226	? @{$variable}{qw[name sigil type]}
	227	: $self->_deconstruct_variable_name($variable);
	228
	229	my $namespace = $self->namespace;
	230
7486ccf3	231	if (!exists $namespace->{$name}) {
dc378b60	232	if ($opts{vivify}) {
	233	if ($type eq 'ARRAY') {
	234	if (BROKEN_ISA_ASSIGNMENT) {
	235	$self->add_package_symbol(
	236	$variable,
	237	$name eq 'ISA' ? () : ([])
	238	);
	239	}
	240	else {
	241	$self->add_package_symbol($variable, []);
	242	}
	243	}
	244	elsif ($type eq 'HASH') {
	245	$self->add_package_symbol($variable, {});
	246	}
	247	elsif ($type eq 'SCALAR') {
	248	$self->add_package_symbol($variable);
	249	}
	250	elsif ($type eq 'IO') {
	251	$self->add_package_symbol($variable, Symbol::geniosym);
	252	}
	253	elsif ($type eq 'CODE') {
	254	confess "Don't know how to vivify CODE variables";
	255	}
	256	else {
	257	confess "Unknown type $type in vivication";
	258	}
5d3589c8	259	}
e55803fc	260	else {
dc378b60	261	if ($type eq 'CODE') {
	262	# this effectively "de-vivifies" the code slot. if we don't do
	263	# this, referencing the coderef at the end of this function
	264	# will cause perl to auto-vivify a stub coderef in the slot,
	265	# which isn't what we want
	266	$self->add_package_symbol($variable);
	267	}
e55803fc	268	}
30d1a098	269	}
f10f6217	270
	271	my $entry_ref = \$namespace->{$name};
	272
	273	if (ref($entry_ref) eq 'GLOB') {
	274	return *{$entry_ref}{$type};
	275	}
	276	else {
	277	if ($type eq 'CODE') {
	278	no strict 'refs';
	279	return \&{ $self->name . '::' . $name };
	280	}
	281	else {
	282	return undef;
	283	}
	284	}
	285	}
	286
988beb41	287	=method get_or_add_package_symbol $variable
e55803fc	288
	289	Like C<get_package_symbol>, except that it will return an empty hashref or
	290	arrayref if the variable doesn't exist.
	291
	292	=cut
	293
	294	sub get_or_add_package_symbol {
	295	my $self = shift;
	296	$self->get_package_symbol(@_, vivify => 1);
	297	}
	298
988beb41	299	=method remove_package_symbol $variable
683542f5	300
	301	Removes the package variable described by C<$variable> (which includes the
	302	sigil); other variables with the same name but different sigils will be
	303	untouched.
	304
	305	=cut
	306
f10f6217	307	sub remove_package_symbol {
	308	my ($self, $variable) = @_;
	309
	310	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	311	? @{$variable}{qw[name sigil type]}
	312	: $self->_deconstruct_variable_name($variable);
	313
	314	# FIXME:
9a3d1390	315	# no doubt this is grossly inefficient and
f10f6217	316	# could be done much easier and faster in XS
f10f6217	317
b1a00d0e	318	my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
f10f6217	319	{ sigil => '$', type => 'SCALAR', name => $name },
	320	{ sigil => '@', type => 'ARRAY', name => $name },
	321	{ sigil => '%', type => 'HASH', name => $name },
	322	{ sigil => '&', type => 'CODE', name => $name },
b1a00d0e	323	{ sigil => '', type => 'IO', name => $name },
f10f6217	324	);
f10f6217	325
b1a00d0e	326	my ($scalar, $array, $hash, $code, $io);
f10f6217	327	if ($type eq 'SCALAR') {
	328	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
	329	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
	330	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	331	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	332	}
f10f6217	333	elsif ($type eq 'ARRAY') {
42fa5cfc	334	$scalar = $self->get_package_symbol($scalar_desc);
f10f6217	335	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
f10f6217	336	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	337	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	338	}
f10f6217	339	elsif ($type eq 'HASH') {
42fa5cfc	340	$scalar = $self->get_package_symbol($scalar_desc);
f10f6217	341	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
f10f6217	342	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	343	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	344	}
f10f6217	345	elsif ($type eq 'CODE') {
42fa5cfc	346	$scalar = $self->get_package_symbol($scalar_desc);
f10f6217	347	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
f10f6217	348	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
b1a00d0e	349	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
	350	}
	351	elsif ($type eq 'IO') {
42fa5cfc	352	$scalar = $self->get_package_symbol($scalar_desc);
b1a00d0e	353	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
	354	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
	355	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
f10f6217	356	}
	357	else {
	358	confess "This should never ever ever happen";
	359	}
	360
	361	$self->remove_package_glob($name);
	362
42fa5cfc	363	$self->add_package_symbol($scalar_desc => $scalar);
f10f6217	364	$self->add_package_symbol($array_desc => $array) if defined $array;
	365	$self->add_package_symbol($hash_desc => $hash) if defined $hash;
	366	$self->add_package_symbol($code_desc => $code) if defined $code;
b1a00d0e	367	$self->add_package_symbol($io_desc => $io) if defined $io;
f10f6217	368	}
f10f6217	369
988beb41	370	=method list_all_package_symbols $type_filter
683542f5	371
	372	Returns a list of package variable names in the package, without sigils. If a
	373	C<type_filter> is passed, it is used to select package variables of a given
	374	type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
	375	etc).
	376
	377	=cut
	378
f10f6217	379	sub list_all_package_symbols {
	380	my ($self, $type_filter) = @_;
	381
	382	my $namespace = $self->namespace;
	383	return keys %{$namespace} unless defined $type_filter;
	384
	385	# NOTE:
9a3d1390	386	# or we can filter based on
f10f6217	387	# type (SCALAR\|ARRAY\|HASH\|CODE)
	388	if ($type_filter eq 'CODE') {
	389	return grep {
25c87f5c	390	# any non-typeglob in the symbol table is a constant or stub
	391	ref(\$namespace->{$_}) ne 'GLOB'
	392	# regular subs are stored in the CODE slot of the typeglob
	393	\|\| defined(*{$namespace->{$_}}{CODE});
f10f6217	394	} keys %{$namespace};
	395	} else {
	396	return grep { *{$namespace->{$_}}{$type_filter} } keys %{$namespace};
	397	}
	398	}
f4979588	399
0992f4ec	400	=head1 BUGS
	401
	402	No known bugs.
	403
	404	Please report any bugs through RT: email
	405	C<bug-package-stash at rt.cpan.org>, or browse to
	406	L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.
	407
f4979588	408	=head1 SEE ALSO
f4979588	409
f4979588	410	=over 4
f4979588	411
988beb41	412	=item * L<Class::MOP::Package>
f4979588	413
988beb41	414	This module is a factoring out of code that used to live here
f4979588	415
	416	=back
	417
0992f4ec	418	=head1 SUPPORT
	419
	420	You can find this documentation for this module with the perldoc command.
	421
	422	perldoc Package::Stash
	423
	424	You can also look for information at:
	425
	426	=over 4
	427
	428	=item * AnnoCPAN: Annotated CPAN documentation
	429
	430	L<http://annocpan.org/dist/Package-Stash>
	431
	432	=item * CPAN Ratings
	433
	434	L<http://cpanratings.perl.org/d/Package-Stash>
	435
	436	=item * RT: CPAN's request tracker
	437
	438	L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>
	439
	440	=item * Search CPAN
	441
	442	L<http://search.cpan.org/dist/Package-Stash>
	443
	444	=back
	445
	446	=head1 AUTHOR
	447
	448	Jesse Luehrs <doy at tozt dot net>
	449
	450	Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
	451	Moose Cabal.
	452
f4979588	453	=cut
	454
	455	1;