-#!/usr/bin/env perl
package Mouse::Util;
-use strict;
-use warnings;
-use base 'Exporter';
-use Carp;
+use Mouse::Exporter; # enables strict and warnings
-BEGIN {
- our %dependencies = (
- 'Scalar::Util' => {
-
-# VVVVV CODE TAKEN FROM SCALAR::UTIL VVVVV
- 'blessed' => do {
- *UNIVERSAL::a_sub_not_likely_to_be_here = sub {
- my $ref = ref($_[0]);
-
- # deviation from Scalar::Util
- # XS returns undef, PP returns GLOB.
- # let's make that more consistent by having PP return
- # undef if it's a GLOB. :/
-
- # \*STDOUT would be allowed as an object in PP blessed
- # but not XS
- return $ref eq 'GLOB' ? undef : $ref;
- };
-
- sub {
- local($@, $SIG{__DIE__}, $SIG{__WARN__});
- length(ref($_[0]))
- ? eval { $_[0]->a_sub_not_likely_to_be_here }
- : undef;
- },
- },
- 'looks_like_number' => sub {
- local $_ = shift;
-
- # checks from perlfaq4
- return 0 if !defined($_) or ref($_);
- return 1 if (/^[+-]?\d+$/); # is a +/- integer
- return 1 if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/); # a C float
- return 1 if ($] >= 5.008 and /^(Inf(inity)?|NaN)$/i) or ($] >= 5.006001 and /^Inf$/i);
-
- 0;
- },
- 'reftype' => sub {
- local($@, $SIG{__DIE__}, $SIG{__WARN__});
- my $r = shift;
- my $t;
-
- length($t = ref($r)) or return undef;
-
- # This eval will fail if the reference is not blessed
- eval { $r->a_sub_not_likely_to_be_here; 1 }
- ? do {
- $t = eval {
- # we have a GLOB or an IO. Stringify a GLOB gives it's name
- my $q = *$r;
- $q =~ /^\*/ ? "GLOB" : "IO";
- }
- or do {
- # OK, if we don't have a GLOB what parts of
- # a glob will it populate.
- # NOTE: A glob always has a SCALAR
- local *glob = $r;
- defined *glob{ARRAY} && "ARRAY"
- or defined *glob{HASH} && "HASH"
- or defined *glob{CODE} && "CODE"
- or length(ref(${$r})) ? "REF" : "SCALAR";
- }
- }
- : $t
- },
- 'openhandle' => sub {
- my $fh = shift;
- my $rt = reftype($fh) || '';
+sub get_linear_isa($;$); # must be here
- return defined(fileno($fh)) ? $fh : undef
- if $rt eq 'IO';
+BEGIN{
+ # This is used in Mouse::PurePerl
+ Mouse::Exporter->setup_import_methods(
+ as_is => [qw(
+ find_meta
+ does_role
+ resolve_metaclass_alias
+ apply_all_roles
+ english_list
- if (reftype(\$fh) eq 'GLOB') { # handle openhandle(*DATA)
- $fh = \(my $tmp=$fh);
- }
- elsif ($rt ne 'GLOB') {
- return undef;
- }
+ load_class
+ is_class_loaded
- (tied(*$fh) or defined(fileno($fh)))
- ? $fh : undef;
- },
- weaken => {
- loaded => \&Scalar::Util::weaken,
- not_loaded => sub { die "Scalar::Util required for weak reference support" },
- },
-# ^^^^^ CODE TAKEN FROM SCALAR::UTIL ^^^^^
- },
- 'MRO::Compat' => {
-# VVVVV CODE TAKEN FROM MRO::COMPAT VVVVV
- 'get_linear_isa' => {
- loaded => \&mro::get_linear_isa,
- not_loaded => do {
- # this recurses so it isn't pretty
- my $code;
- $code = sub {
- no strict 'refs';
-
- my $classname = shift;
-
- my @lin = ($classname);
- my %stored;
- foreach my $parent (@{"$classname\::ISA"}) {
- my $plin = $code->($parent);
- foreach (@$plin) {
- next if exists $stored{$_};
- push(@lin, $_);
- $stored{$_} = 1;
- }
- }
- return \@lin;
- }
- },
- },
-# ^^^^^ CODE TAKEN FROM MRO::COMPAT ^^^^^
- },
-# VVVVV CODE TAKEN FROM TEST::EXCEPTION VVVVV
- 'Test::Exception' => do {
-
- my $Tester;
-
- my $is_exception = sub {
- my $exception = shift;
- return ref $exception || $exception ne '';
- };
-
- my $exception_as_string = sub {
- my ( $prefix, $exception ) = @_;
- return "$prefix normal exit" unless $is_exception->( $exception );
- my $class = ref $exception;
- $exception = "$class ($exception)"
- if $class && "$exception" !~ m/^\Q$class/;
- chomp $exception;
- return "$prefix $exception";
- };
- my $try_as_caller = sub {
- my $coderef = shift;
- eval { $coderef->() };
- $@;
- };
-
- {
- 'throws_ok' => sub (&$;$) {
- my ( $coderef, $expecting, $description ) = @_;
- Carp::croak "throws_ok: must pass exception class/object or regex"
- unless defined $expecting;
- $description = $exception_as_string->( "threw", $expecting )
- unless defined $description;
- my $exception = $try_as_caller->($coderef);
-
- $Tester ||= Test::Builder->new;
-
- my $regex = $Tester->maybe_regex( $expecting );
- my $ok = $regex
- ? ( $exception =~ m/$regex/ )
- : eval {
- $exception->isa( ref $expecting ? ref $expecting : $expecting )
- };
- $Tester->ok( $ok, $description );
- unless ( $ok ) {
- $Tester->diag( $exception_as_string->( "expecting:", $expecting ) );
- $Tester->diag( $exception_as_string->( "found:", $exception ) );
- };
- $@ = $exception;
- return $ok;
- },
- 'lives_ok' => sub (&;$) {
- my ( $coderef, $description ) = @_;
- my $exception = $try_as_caller->( $coderef );
-
- $Tester ||= Test::Builder->new;
-
- my $ok = $Tester->ok( ! $is_exception->( $exception ), $description );
- $Tester->diag( $exception_as_string->( "died:", $exception ) ) unless $ok;
- $@ = $exception;
- return $ok;
- },
- },
+ get_linear_isa
+ get_code_info
+
+ get_code_package
+ get_code_ref
+
+ not_supported
+
+ does meta dump
+ )],
+ groups => {
+ default => [], # export no functions by default
+
+ # The ':meta' group is 'use metaclass' for Mouse
+ meta => [qw(does meta dump)],
},
);
- our %loaded;
- our @EXPORT_OK = map { keys %$_ } values %dependencies;
- our %EXPORT_TAGS = (
- all => \@EXPORT_OK,
- test => [qw/throws_ok lives_ok/],
- );
+ # Because Mouse::Util is loaded first in all the Mouse sub-modules,
+ # XS loader is placed here, not in Mouse.pm.
- for my $module_name (keys %dependencies) {
- my $loaded = do {
- local $SIG{__DIE__} = 'DEFAULT';
- eval "require $module_name; 1";
+ our $VERSION = '0.40_09';
+
+ my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
+
+ if($xs){
+ # XXX: XSLoader tries to get the object path from caller's file name
+ # $hack_mouse_file fools its mechanism
+
+ (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
+ $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
+ require XSLoader;
+ XSLoader::load('Mouse', $VERSION);
+ Mouse::Util->import({ into => 'Mouse::Meta::Method::Constructor::XS' }, ':meta');
+ Mouse::Util->import({ into => 'Mouse::Meta::Method::Destructor::XS' }, ':meta');
+ Mouse::Util->import({ into => 'Mouse::Meta::Method::Accessor::XS' }, ':meta');
+ return 1;
};
+ #warn $@ if $@;
+ }
- $loaded{$module_name} = $loaded;
+ if(!$xs){
+ require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
+ }
+
+ *MOUSE_XS = sub(){ $xs };
+}
+
+use Carp ();
+use Scalar::Util ();
+
+use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
+
+# aliases as public APIs
+# it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
+require Mouse::Meta::Module; # for the entities of metaclass cache utilities
+
+BEGIN {
+ *class_of = \&Mouse::Meta::Module::_class_of;
+ *get_metaclass_by_name = \&Mouse::Meta::Module::_get_metaclass_by_name;
+ *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
+ *get_all_metaclass_names = \&Mouse::Meta::Module::_get_all_metaclass_names;
+
+ # is-a predicates
+ generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
+ generate_isa_predicate_for('Mouse::Meta::Class' => 'is_a_metaclass');
+ generate_isa_predicate_for('Mouse::Meta::Role' => 'is_a_metarole');
+}
+
+our $in_global_destruction = 0;
+END{ $in_global_destruction = 1 }
+
+# Moose::Util compatible utilities
+
+sub find_meta{
+ return class_of( $_[0] );
+}
+
+sub does_role{
+ my ($class_or_obj, $role_name) = @_;
- for my $method_name (keys %{ $dependencies{ $module_name } }) {
- my $producer = $dependencies{$module_name}{$method_name};
- my $implementation;
+ my $meta = class_of($class_or_obj);
- if (ref($producer) eq 'HASH') {
- $implementation = $loaded
- ? $producer->{loaded}
- : $producer->{not_loaded};
+ (defined $role_name)
+ || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
+
+ return defined($meta) && $meta->does_role($role_name);
+}
+
+BEGIN {
+ my $get_linear_isa;
+ if ($] >= 5.009_005) {
+ require mro;
+ $get_linear_isa = \&mro::get_linear_isa;
+ } else {
+# VVVVV CODE TAKEN FROM MRO::COMPAT VVVVV
+ my $_get_linear_isa_dfs; # this recurses so it isn't pretty
+ $_get_linear_isa_dfs = sub {
+ my($classname) = @_;
+
+ my @lin = ($classname);
+ my %stored;
+
+ no strict 'refs';
+ foreach my $parent (@{"$classname\::ISA"}) {
+ my $plin = $_get_linear_isa_dfs->($parent);
+ foreach my $p(@$plin) {
+ next if exists $stored{$p};
+ push(@lin, $p);
+ $stored{$p} = 1;
+ }
}
- else {
- $implementation = $loaded
- ? $module_name->can($method_name)
- : $producer;
+ return \@lin;
+ };
+# ^^^^^ CODE TAKEN FROM MRO::COMPAT ^^^^^
+
+ eval{ require Class::C3 };
+
+ # MRO::Compat::__get_linear_isa has no prototype, so
+ # we define a prototyped version for compatibility with core's
+ # See also MRO::Compat::__get_linear_isa.
+ $get_linear_isa = sub ($;$){
+ my($classname, $type) = @_;
+ if(!defined $type){
+ package Class::C3;
+ our %MRO;
+ $type = exists $MRO{$classname} ? 'c3' : 'dfs';
}
+ return $type eq 'c3'
+ ? [Class::C3::calculateMRO($classname)]
+ : $_get_linear_isa_dfs->($classname);\r
+ };
+ }
- no strict 'refs';
- *{ __PACKAGE__ . '::' . $method_name } = $implementation;
+ *get_linear_isa = $get_linear_isa;
+}
+
+
+# taken from Mouse::Util (0.90)
+{
+ my %cache;
+
+ sub resolve_metaclass_alias {
+ my ( $type, $metaclass_name, %options ) = @_;
+
+ my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
+
+ return $cache{$cache_key}{$metaclass_name} ||= do{
+
+ my $possible_full_name = join '::',
+ 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
+ ;
+
+ my $loaded_class = load_first_existing_class(
+ $possible_full_name,
+ $metaclass_name
+ );
+
+ $loaded_class->can('register_implementation')
+ ? $loaded_class->register_implementation
+ : $loaded_class;
+ };
+ }
+}
+
+# Utilities from Class::MOP
+
+sub get_code_info;
+sub get_code_package;
+
+# taken from Class/MOP.pm
+sub is_valid_class_name {
+ my $class = shift;
+
+ return 0 if ref($class);
+ return 0 unless defined($class);
+
+ return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
+
+ return 0;
+}
+
+# taken from Class/MOP.pm
+sub load_first_existing_class {
+ my @classes = @_
+ or return;
+
+ my %exceptions;
+ for my $class (@classes) {
+ my $e = _try_load_one_class($class);
+
+ if ($e) {
+ $exceptions{$class} = $e;
+ }
+ else {
+ return $class;
}
}
+
+ # not found
+ Carp::confess join(
+ "\n",
+ map {
+ sprintf( "Could not load class (%s) because : %s",
+ $_, $exceptions{$_} )
+ } @classes
+ );
}
-1;
+# taken from Class/MOP.pm
+my %is_class_loaded_cache;
+sub _try_load_one_class {
+ my $class = shift;
+
+ unless ( is_valid_class_name($class) ) {
+ my $display = defined($class) ? $class : 'undef';
+ Carp::confess "Invalid class name ($display)";
+ }
+
+ return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
+
+ my $file = $class . '.pm';
+ $file =~ s{::}{/}g;
+
+ return do {
+ local $@;
+ eval { require($file) };
+ $@;
+ };
+}
+
+
+sub load_class {
+ my $class = shift;
+ my $e = _try_load_one_class($class);
+ Carp::confess "Could not load class ($class) because : $e" if $e;
+
+ return 1;
+}
+
+sub is_class_loaded;
+
+sub apply_all_roles {
+ my $applicant = Scalar::Util::blessed($_[0])
+ ? shift # instance
+ : Mouse::Meta::Class->initialize(shift); # class or role name
+
+ my @roles;
+
+ # Basis of Data::OptList
+ my $max = scalar(@_);
+ for (my $i = 0; $i < $max ; $i++) {
+ if ($i + 1 < $max && ref($_[$i + 1])) {
+ push @roles, [ $_[$i] => $_[++$i] ];
+ } else {
+ push @roles, [ $_[$i] => undef ];
+ }
+ my $role_name = $roles[-1][0];
+ load_class($role_name);
+
+ is_a_metarole( get_metaclass_by_name($role_name) )
+ || $applicant->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
+ }
+
+ if ( scalar @roles == 1 ) {
+ my ( $role_name, $params ) = @{ $roles[0] };
+ get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
+ }
+ else {
+ Mouse::Meta::Role->combine(@roles)->apply($applicant);
+ }
+ return;
+}
+
+# taken from Moose::Util 0.90
+sub english_list {
+ return $_[0] if @_ == 1;
+
+ my @items = sort @_;
+
+ return "$items[0] and $items[1]" if @items == 2;
+
+ my $tail = pop @items;
+ return join q{, }, @items, "and $tail";
+}
+
+# common utilities
+
+sub not_supported{
+ my($feature) = @_;
+
+ $feature ||= ( caller(1) )[3]; # subroutine name
+
+ local $Carp::CarpLevel = $Carp::CarpLevel + 1;
+ Carp::confess("Mouse does not currently support $feature");
+}
+
+# general meta() method
+sub meta :method{
+ return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
+}
+
+# general dump() method
+sub dump :method {
+ my($self, $maxdepth) = @_;
+
+ require 'Data/Dumper.pm'; # we don't want to create its namespace
+ my $dd = Data::Dumper->new([$self]);
+ $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
+ $dd->Indent(1);
+ return $dd->Dump();
+}
+
+# general does() method
+sub does :method;
+*does = \&does_role; # alias
+
+1;
__END__
=head1 NAME
-Mouse::Util - features, with or without their dependencies
+Mouse::Util - Features, with or without their dependencies
+
+=head1 VERSION
+
+This document describes Mouse version 0.40_09
=head1 IMPLEMENTATIONS FOR
-=head2 L<MRO::Compat>
+=head2 Moose::Util
+
+=head3 C<find_meta>
+
+=head3 C<does_role>
+
+=head3 C<resolve_metaclass_alias>
+
+=head3 C<apply_all_roles>
+
+=head3 C<english_list>
+
+=head2 Class::MOP
+
+=head3 C<< is_class_loaded(ClassName) -> Bool >>
+
+Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
+involves checking for the existence of C<$VERSION>, C<@ISA>, and any
+locally-defined method.
+
+=head3 C<< load_class(ClassName) >>
+
+This will load a given C<ClassName> (or die if it is not loadable).
+This function can be used in place of tricks like
+C<eval "use $module"> or using C<require>.
+
+=head3 C<< Mouse::Util::class_of(ClassName or Object) >>
+
+=head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
+
+=head3 C<< Mouse::Util::get_all_metaclass_instances() >>
+
+=head3 C<< Mouse::Util::get_all_metaclass_names() >>
+
+=head2 MRO::Compat
+
+=head3 C<get_linear_isa>
-=head3 get_linear_isa
+=head2 Sub::Identify
-=head2 L<Scalar::Util>
+=head3 C<get_code_info>
-=head3 blessed
+=head1 Mouse specific utilities
-=head3 looks_like_number
+=head3 C<not_supported>
-=head3 reftype
+=head3 C<get_code_package>
-=head3 openhandle
+=head3 C<get_code_ref>
-=head3 weaken
+=head1 SEE ALSO
-C<weaken> I<must> be implemented in XS. If the user tries to use C<weaken>
-without L<Scalar::Util>, an error is thrown.
+L<Moose::Util>
-=head2 Test::Exception
+L<Class::MOP>
-=head3 throws_ok
+L<Sub::Identify>
-=head3 lives_ok
+L<MRO::Compat>
=cut
projects / gitmo/Mouse.git / blobdiff