tool/generate-mouse-tiny.pl

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings;
   4 use File::Find;
   5 use Fatal qw(open close);
   6 #use File::Slurp 'slurp';
   7 #use List::MoreUtils 'uniq';
   8 #use autodie;
   9
  10 print "Generate Mouse::Tiny ...\n";
  11
  12 sub slurp {
  13     open my $in, '<', $_[0];
  14     local $/;
  15     return scalar <$in>;
  16 }
  17 sub uniq{
  18     my %seen;
  19     return grep{ !$seen{$_}++ } @_;
  20 }
  21
  22 require 'lib/Mouse/Spec.pm';
  23
  24 my $MouseTinyFile = shift || 'lib/Mouse/Tiny.pm';
  25
  26 my @files;
  27
  28 find({
  29     wanted => sub {
  30         push @files, $_
  31             if -f $_
  32             &&  /\.pm$/
  33             && !/Squirrel/
  34             && !/Tiny/
  35             && !/Spec/         # has no functionality
  36             && !/TypeRegistry/ # deprecated
  37             && !/\bouse/       # ouse.pm
  38     },
  39     no_chdir => 1,
  40 }, 'lib');
  41
  42 my $mouse_tiny = '';
  43
  44 for my $file (uniq
  45         'lib/Mouse/PurePerl.pm',
  46         'lib/Mouse/Exporter.pm',
  47         'lib/Mouse/Util.pm',
  48         'lib/Mouse/Meta/TypeConstraint.pm',
  49         'lib/Mouse/Util/TypeConstraints.pm',
  50             sort @files) {
  51
  52     my $contents = slurp $file;
  53
  54     $contents =~ s/__END__\b.*//s;          # remove documentation
  55     $contents =~ s/1;\n*$//;                # remove success indicator
  56
  57     $mouse_tiny .= "BEGIN{ # $file\n";
  58     $mouse_tiny .= $contents;
  59     $mouse_tiny .= "}\n";
  60 }
  61
  62 open my $handle, ">$MouseTinyFile";
  63
  64 print { $handle } << "EOF";
  65 # This file was generated by $0 from Mouse $Mouse::Spec::VERSION.
  66 #
  67 # ANY CHANGES MADE HERE WILL BE LOST!
  68
  69 EOF
  70
  71 print { $handle } << 'EOF';
  72 # if regular Mouse is loaded, bail out
  73 unless ($INC{'Mouse.pm'}) {
  74     # tell Perl we already have all of the Mouse files loaded:
  75 EOF
  76
  77 for my $file (@files) {
  78     (my $inc = $file) =~ s{^lib/}{};
  79     printf { $handle } "%-45s = __FILE__;\n", "\$INC{'$inc'}";
  80 }
  81
  82 print { $handle } << 'EOF';
  83 eval sprintf("#line %d %s\n", __LINE__, __FILE__) . <<'END_OF_TINY';
  84 EOF
  85
  86 print { $handle } "\n# and now their contents\n\n";
  87
  88 print { $handle } $mouse_tiny;
  89
  90 print { $handle } << 'EOF';
  91 END_OF_TINY
  92     die $@ if $@;
  93 } # unless Mouse.pm is loaded
  94 EOF
  95
  96 print { $handle } << 'EOF';
  97 package Mouse::Tiny;
  98
  99 Mouse::Exporter->setup_import_methods(also => 'Mouse');
 100
 101 1;
 102 EOF
 103
 104 close $handle;
 105
 106 print "done.\n";