t/030_roles/003_apply_role.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More tests => 86;
   7 use Test::Exception;
   8
   9 {
  10     package FooRole;
  11     use Mouse::Role;
  12
  13     has 'bar' => ( is => 'rw', isa => 'FooClass' );
  14     has 'baz' => ( is => 'ro' );
  15
  16     sub goo {'FooRole::goo'}
  17     sub foo {'FooRole::foo'}
  18
  19     override 'boo' => sub { 'FooRole::boo -> ' . super() };
  20
  21     around 'blau' => sub {
  22         my $c = shift;
  23         'FooRole::blau -> ' . $c->();
  24     };
  25 }
  26
  27 {
  28     package BarRole;
  29     use Mouse::Role;
  30     sub woot {'BarRole::woot'}
  31 }
  32
  33 {
  34     package BarClass;
  35     use Mouse;
  36
  37     sub boo {'BarClass::boo'}
  38     sub foo {'BarClass::foo'}    # << the role overrides this ...
  39 }
  40
  41 {
  42     package FooClass;
  43     use Mouse;
  44
  45     extends 'BarClass';
  46     with 'FooRole';
  47
  48     sub blau {'FooClass::blau'}    # << the role wraps this ...
  49
  50     sub goo {'FooClass::goo'}      # << overrides the one from the role ...
  51 }
  52
  53 {
  54     package FooBarClass;
  55     use Mouse;
  56
  57     extends 'FooClass';
  58     with 'FooRole', 'BarRole';
  59 }
  60
  61 my $foo_class_meta = FooClass->meta;
  62 isa_ok( $foo_class_meta, 'Mouse::Meta::Class' );
  63
  64 my $foobar_class_meta = FooBarClass->meta;
  65 isa_ok( $foobar_class_meta, 'Mouse::Meta::Class' );
  66
  67 dies_ok {
  68     $foo_class_meta->does_role();
  69 }
  70 '... does_role requires a role name';
  71
  72 dies_ok {
  73     $foo_class_meta->add_role();
  74 }
  75 '... apply_role requires a role';
  76
  77 dies_ok {
  78     $foo_class_meta->add_role( bless( {} => 'Fail' ) );
  79 }
  80 '... apply_role requires a role';
  81
  82 ok( $foo_class_meta->does_role('FooRole'),
  83     '... the FooClass->meta does_role FooRole' );
  84 ok( !$foo_class_meta->does_role('OtherRole'),
  85     '... the FooClass->meta !does_role OtherRole' );
  86
  87 ok( $foobar_class_meta->does_role('FooRole'),
  88     '... the FooBarClass->meta does_role FooRole' );
  89 ok( $foobar_class_meta->does_role('BarRole'),
  90     '... the FooBarClass->meta does_role BarRole' );
  91 ok( !$foobar_class_meta->does_role('OtherRole'),
  92     '... the FooBarClass->meta !does_role OtherRole' );
  93
  94 foreach my $method_name (qw(bar baz foo boo blau goo)) {
  95     #use Data::Dumper; $Data::Dumper::Maxdepth=1; diag(Dumper $foo_class_meta->{methods});
  96     ok( $foo_class_meta->has_method($method_name),
  97         '... FooClass has the method ' . $method_name );
  98     ok( $foobar_class_meta->has_method($method_name),
  99         '... FooBarClass has the method ' . $method_name );
 100 }
 101
 102 ok( !$foo_class_meta->has_method('woot'),
 103     '... FooClass lacks the method woot' );
 104 ok( $foobar_class_meta->has_method('woot'),
 105     '... FooBarClass has the method woot' );
 106
 107 foreach my $attr_name (qw(bar baz)) {
 108     ok( $foo_class_meta->has_attribute($attr_name),
 109         '... FooClass has the attribute ' . $attr_name );
 110     ok( $foobar_class_meta->has_attribute($attr_name),
 111         '... FooBarClass has the attribute ' . $attr_name );
 112 }
 113
 114 can_ok( 'FooClass', 'does' );
 115 ok( FooClass->does('FooRole'),    '... the FooClass does FooRole' );
 116 ok( !FooClass->does('BarRole'),   '... the FooClass does not do BarRole' );
 117 ok( !FooClass->does('OtherRole'), '... the FooClass does not do OtherRole' );
 118
 119 can_ok( 'FooBarClass', 'does' );
 120 ok( FooBarClass->does('FooRole'), '... the FooClass does FooRole' );
 121 ok( FooBarClass->does('BarRole'), '... the FooBarClass does FooBarRole' );
 122 ok( !FooBarClass->does('OtherRole'),
 123     '... the FooBarClass does not do OtherRole' );
 124
 125 my $foo = FooClass->new();
 126 isa_ok( $foo, 'FooClass' );
 127
 128 my $foobar = FooBarClass->new();
 129 isa_ok( $foobar, 'FooBarClass' );
 130
 131 is( $foo->goo,    'FooClass::goo', '... got the right value of goo' );
 132 is( $foobar->goo, 'FooRole::goo',  '... got the right value of goo' );
 133
 134 is( $foo->boo, 'FooRole::boo -> BarClass::boo',
 135     '... got the right value from ->boo' );
 136 is( $foobar->boo, 'FooRole::boo -> FooRole::boo -> BarClass::boo',
 137     '... got the right value from ->boo (double wrapped)' );
 138
 139 is( $foo->blau, 'FooRole::blau -> FooClass::blau',
 140     '... got the right value from ->blau' );
 141 is( $foobar->blau, 'FooRole::blau -> FooRole::blau -> FooClass::blau',
 142     '... got the right value from ->blau' );
 143
 144 foreach my $foo ( $foo, $foobar ) {
 145     can_ok( $foo, 'does' );
 146     ok( $foo->does('FooRole'), '... an instance of FooClass does FooRole' );
 147     ok( !$foo->does('OtherRole'),
 148         '... and instance of FooClass does not do OtherRole' );
 149
 150     can_ok( $foobar, 'does' );
 151     ok( $foobar->does('FooRole'),
 152         '... an instance of FooBarClass does FooRole' );
 153     ok( $foobar->does('BarRole'),
 154         '... an instance of FooBarClass does BarRole' );
 155     ok( !$foobar->does('OtherRole'),
 156         '... and instance of FooBarClass does not do OtherRole' );
 157
 158     for my $method (qw/bar baz foo boo goo blau/) {
 159         can_ok( $foo, $method );
 160     }
 161
 162     is( $foo->foo, 'FooRole::foo', '... got the right value of foo' );
 163
 164     ok( !defined( $foo->baz ), '... $foo->baz is undefined' );
 165     ok( !defined( $foo->bar ), '... $foo->bar is undefined' );
 166
 167     dies_ok {
 168         $foo->baz(1);
 169     }
 170     '... baz is a read-only accessor';
 171
 172     dies_ok {
 173         $foo->bar(1);
 174     }
 175     '... bar is a read-write accessor with a type constraint';
 176
 177     my $foo2 = FooClass->new();
 178     isa_ok( $foo2, 'FooClass' );
 179
 180     lives_ok {
 181         $foo->bar($foo2);
 182     }
 183     '... bar is a read-write accessor with a type constraint';
 184
 185     is( $foo->bar, $foo2, '... got the right value for bar now' );
 186 }