lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 BEGIN{
   5     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
   6     # XS loader is placed here, not in Mouse.pm.
   7
   8     our $VERSION = '0.40_03';
   9
  10     my $need_pp = !!$ENV{MOUSE_PUREPERL};
  11
  12     if(!$need_pp && !exists $INC{'Mouse/PurePerl.pm'}){
  13         local $@;
  14
  15         # XXX: XSLoader tries to get the object path from caller's file name
  16         #      $hack_mouse_file fools its mechanism
  17
  18         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  19         $need_pp = !eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  20             require XSLoader;
  21             XSLoader::load('Mouse', $VERSION);
  22         };
  23         #warn $@ if $@;
  24     }
  25
  26     if($need_pp){
  27         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  28     }
  29 }
  30
  31
  32 use Carp         ();
  33 use Scalar::Util ();
  34
  35 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  36
  37 Mouse::Exporter->setup_import_methods(
  38     as_is => [qw(
  39         find_meta
  40         does_role
  41         resolve_metaclass_alias
  42         apply_all_roles
  43         english_list
  44
  45         load_class
  46         is_class_loaded
  47
  48         get_linear_isa
  49         get_code_info
  50
  51         get_code_package
  52         get_code_ref
  53
  54         not_supported
  55
  56         does meta dump
  57         _MOUSE_VERBOSE
  58     )],
  59     groups => {
  60         default => [], # export no functions by default
  61
  62         # The ':meta' group is 'use metaclass' for Mouse
  63         meta    => [qw(does meta dump _MOUSE_VERBOSE)],
  64     },
  65 );
  66
  67 # aliases as public APIs
  68 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  69 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  70
  71 BEGIN {
  72     *class_of                    = \&Mouse::Meta::Module::class_of;
  73     *get_metaclass_by_name       = \&Mouse::Meta::Module::get_metaclass_by_name;
  74     *get_all_metaclass_instances = \&Mouse::Meta::Module::get_all_metaclass_instances;
  75     *get_all_metaclass_names     = \&Mouse::Meta::Module::get_all_metaclass_names;
  76
  77     # is-a predicates
  78     _generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
  79     _generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
  80     _generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
  81 }
  82
  83
  84 # Moose::Util compatible utilities
  85
  86 sub find_meta{
  87     return class_of( $_[0] );
  88 }
  89
  90 sub does_role{
  91     my ($class_or_obj, $role_name) = @_;
  92
  93     my $meta = class_of($class_or_obj);
  94
  95     (defined $role_name)
  96         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
  97
  98     return defined($meta) && $meta->does_role($role_name);
  99 }
 100
 101 BEGIN {
 102     my $impl;
 103     if ($] >= 5.009_005) {
 104         require mro;
 105         $impl = \&mro::get_linear_isa;
 106     } else {
 107         my $e = do {
 108             local $@;
 109             eval { require MRO::Compat };
 110             $@;
 111         };
 112         if (!$e) {
 113             $impl = \&mro::get_linear_isa;
 114         } else {
 115 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 116             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 117             $_get_linear_isa_dfs = sub {
 118                 no strict 'refs';
 119
 120                 my $classname = shift;
 121
 122                 my @lin = ($classname);
 123                 my %stored;
 124                 foreach my $parent (@{"$classname\::ISA"}) {
 125                     my $plin = $_get_linear_isa_dfs->($parent);
 126                     foreach  my $p(@$plin) {
 127                         next if exists $stored{$p};
 128                         push(@lin, $p);
 129                         $stored{$p} = 1;
 130                     }
 131                 }
 132                 return \@lin;
 133             };
 134 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 135             $impl = $_get_linear_isa_dfs;
 136         }
 137     }
 138
 139
 140     no warnings 'once';
 141     *get_linear_isa = $impl;
 142 }
 143
 144
 145 # taken from Mouse::Util (0.90)
 146 {
 147     my %cache;
 148
 149     sub resolve_metaclass_alias {
 150         my ( $type, $metaclass_name, %options ) = @_;
 151
 152         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 153
 154         return $cache{$cache_key}{$metaclass_name} ||= do{
 155
 156             my $possible_full_name = join '::',
 157                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 158             ;
 159
 160             my $loaded_class = load_first_existing_class(
 161                 $possible_full_name,
 162                 $metaclass_name
 163             );
 164
 165             $loaded_class->can('register_implementation')
 166                 ? $loaded_class->register_implementation
 167                 : $loaded_class;
 168         };
 169     }
 170 }
 171
 172 # Utilities from Class::MOP
 173
 174 sub get_code_info;
 175 sub get_code_package;
 176
 177 # taken from Class/MOP.pm
 178 sub is_valid_class_name {
 179     my $class = shift;
 180
 181     return 0 if ref($class);
 182     return 0 unless defined($class);
 183
 184     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 185
 186     return 0;
 187 }
 188
 189 # taken from Class/MOP.pm
 190 sub load_first_existing_class {
 191     my @classes = @_
 192       or return;
 193
 194     my %exceptions;
 195     for my $class (@classes) {
 196         my $e = _try_load_one_class($class);
 197
 198         if ($e) {
 199             $exceptions{$class} = $e;
 200         }
 201         else {
 202             return $class;
 203         }
 204     }
 205
 206     # not found
 207     Carp::confess join(
 208         "\n",
 209         map {
 210             sprintf( "Could not load class (%s) because : %s",
 211                 $_, $exceptions{$_} )
 212           } @classes
 213     );
 214 }
 215
 216 # taken from Class/MOP.pm
 217 my %is_class_loaded_cache;
 218 sub _try_load_one_class {
 219     my $class = shift;
 220
 221     unless ( is_valid_class_name($class) ) {
 222         my $display = defined($class) ? $class : 'undef';
 223         Carp::confess "Invalid class name ($display)";
 224     }
 225
 226     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 227
 228     my $file = $class . '.pm';
 229     $file =~ s{::}{/}g;
 230
 231     return do {
 232         local $@;
 233         eval { require($file) };
 234         $@;
 235     };
 236 }
 237
 238
 239 sub load_class {
 240     my $class = shift;
 241     my $e = _try_load_one_class($class);
 242     Carp::confess "Could not load class ($class) because : $e" if $e;
 243
 244     return 1;
 245 }
 246
 247 sub is_class_loaded;
 248
 249
 250 sub apply_all_roles {
 251     my $applicant = Scalar::Util::blessed($_[0])
 252         ?                                shift   # instance
 253         : Mouse::Meta::Class->initialize(shift); # class or role name
 254
 255     my @roles;
 256
 257     # Basis of Data::OptList
 258     my $max = scalar(@_);
 259     for (my $i = 0; $i < $max ; $i++) {
 260         if ($i + 1 < $max && ref($_[$i + 1])) {
 261             push @roles, [ $_[$i] => $_[++$i] ];
 262         } else {
 263             push @roles, [ $_[$i] => undef ];
 264         }
 265         my $role_name = $roles[-1][0];
 266         load_class($role_name);
 267
 268         is_a_metarole( get_metaclass_by_name($role_name) )
 269             || $applicant->meta->throw_error("You can only consume roles, $role_name(".$role_name->meta.") is not a Mouse role");
 270     }
 271
 272     if ( scalar @roles == 1 ) {
 273         my ( $role_name, $params ) = @{ $roles[0] };
 274         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 275     }
 276     else {
 277         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 278     }
 279     return;
 280 }
 281
 282 # taken from Moose::Util 0.90
 283 sub english_list {
 284     return $_[0] if @_ == 1;
 285
 286     my @items = sort @_;
 287
 288     return "$items[0] and $items[1]" if @items == 2;
 289
 290     my $tail = pop @items;
 291
 292     return join q{, }, @items, "and $tail";
 293 }
 294
 295
 296 # common utilities
 297
 298 sub not_supported{
 299     my($feature) = @_;
 300
 301     $feature ||= ( caller(1) )[3]; # subroutine name
 302
 303     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 304     Carp::confess("Mouse does not currently support $feature");
 305 }
 306
 307 # general meta() method
 308 sub meta :method{
 309     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 310 }
 311
 312 # general dump() method
 313 sub dump :method {
 314     my($self, $maxdepth) = @_;
 315
 316     require 'Data/Dumper.pm'; # we don't want to create its namespace
 317     my $dd = Data::Dumper->new([$self]);
 318     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 319     $dd->Indent(1);
 320     return $dd->Dump();
 321 }
 322
 323 # general does() method
 324 sub does :method;
 325 *does = \&does_role; # alias
 326
 327 1;
 328
 329 __END__
 330
 331 =head1 NAME
 332
 333 Mouse::Util - Features, with or without their dependencies
 334
 335 =head1 VERSION
 336
 337 This document describes Mouse version 0.40_03
 338
 339 =head1 IMPLEMENTATIONS FOR
 340
 341 =head2 Moose::Util
 342
 343 =head3 C<find_meta>
 344
 345 =head3 C<does_role>
 346
 347 =head3 C<resolve_metaclass_alias>
 348
 349 =head3 C<apply_all_roles>
 350
 351 =head3 C<english_list>
 352
 353 =head2 Class::MOP
 354
 355 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 356
 357 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 358 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 359 locally-defined method.
 360
 361 =head3 C<< load_class(ClassName) >>
 362
 363 This will load a given C<ClassName> (or die if it is not loadable).
 364 This function can be used in place of tricks like
 365 C<eval "use $module"> or using C<require>.
 366
 367 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 368
 369 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 370
 371 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 372
 373 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 374
 375 =head2 MRO::Compat
 376
 377 =head3 C<get_linear_isa>
 378
 379 =head2 Sub::Identify
 380
 381 =head3 C<get_code_info>
 382
 383 =head1 UTILITIES FOR MOUSE
 384
 385 =head3 C<not_supported>
 386
 387 =head1 SEE ALSO
 388
 389 L<Moose::Util>
 390
 391 L<Class::MOP>
 392
 393 L<Sub::Identify>
 394
 395 L<MRO::Compat>
 396
 397 =cut
 398