lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 BEGIN{
   7     # This is used in Mouse::PurePerl
   8     Mouse::Exporter->setup_import_methods(
   9         as_is => [qw(
  10             find_meta
  11             does_role
  12             resolve_metaclass_alias
  13             apply_all_roles
  14             english_list
  15
  16             load_class
  17             is_class_loaded
  18
  19             get_linear_isa
  20             get_code_info
  21
  22             get_code_package
  23             get_code_ref
  24
  25             not_supported
  26
  27             does meta dump
  28         )],
  29         groups => {
  30             default => [], # export no functions by default
  31
  32             # The ':meta' group is 'use metaclass' for Mouse
  33             meta    => [qw(does meta dump)],
  34         },
  35     );
  36
  37
  38     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  39     # XS loader is placed here, not in Mouse.pm.
  40
  41     our $VERSION = '0.40_07';
  42
  43     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  44
  45     if($xs){
  46         local $@;
  47
  48         # XXX: XSLoader tries to get the object path from caller's file name
  49         #      $hack_mouse_file fools its mechanism
  50
  51         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  52         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  53             require XSLoader;
  54             XSLoader::load('Mouse', $VERSION);
  55
  56             *Mouse::Meta::Method::Constructor::XS::meta = \&meta;
  57             *Mouse::Meta::Method::Destructor::XS::meta  = \&meta;
  58         };
  59         #warn $@ if $@;
  60     }
  61
  62     if(!$xs){
  63         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  64     }
  65
  66     *MOUSE_XS = sub(){ $xs };
  67 }
  68
  69
  70 use Carp         ();
  71 use Scalar::Util ();
  72
  73 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  74
  75 # aliases as public APIs
  76 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  77 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  78
  79 BEGIN {
  80     *class_of                    = \&Mouse::Meta::Module::_class_of;
  81     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  82     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  83     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  84
  85     # is-a predicates
  86     generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
  87     generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
  88     generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
  89 }
  90
  91
  92 # Moose::Util compatible utilities
  93
  94 sub find_meta{
  95     return class_of( $_[0] );
  96 }
  97
  98 sub does_role{
  99     my ($class_or_obj, $role_name) = @_;
 100
 101     my $meta = class_of($class_or_obj);
 102
 103     (defined $role_name)
 104         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 105
 106     return defined($meta) && $meta->does_role($role_name);
 107 }
 108
 109 BEGIN {
 110     my $get_linear_isa;
 111     if ($] >= 5.009_005) {
 112         require mro;
 113         $get_linear_isa = \&mro::get_linear_isa;
 114     } else {
 115         my $e = do {
 116             local $@;
 117             eval { require MRO::Compat };
 118             $@;
 119         };
 120         if (!$e) {
 121             $get_linear_isa = \&mro::get_linear_isa;
 122         } else {
 123 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 124             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 125             $_get_linear_isa_dfs = sub ($;$){
 126                 no strict 'refs';
 127
 128                 my $classname = shift;
 129
 130                 my @lin = ($classname);
 131                 my %stored;
 132                 foreach my $parent (@{"$classname\::ISA"}) {
 133                     my $plin = $_get_linear_isa_dfs->($parent);
 134                     foreach  my $p(@$plin) {
 135                         next if exists $stored{$p};
 136                         push(@lin, $p);
 137                         $stored{$p} = 1;
 138                     }
 139                 }
 140                 return \@lin;
 141             };
 142 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 143             $get_linear_isa = $_get_linear_isa_dfs;
 144         }
 145     }
 146
 147     *get_linear_isa = $get_linear_isa;
 148 }
 149
 150
 151 # taken from Mouse::Util (0.90)
 152 {
 153     my %cache;
 154
 155     sub resolve_metaclass_alias {
 156         my ( $type, $metaclass_name, %options ) = @_;
 157
 158         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 159
 160         return $cache{$cache_key}{$metaclass_name} ||= do{
 161
 162             my $possible_full_name = join '::',
 163                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 164             ;
 165
 166             my $loaded_class = load_first_existing_class(
 167                 $possible_full_name,
 168                 $metaclass_name
 169             );
 170
 171             $loaded_class->can('register_implementation')
 172                 ? $loaded_class->register_implementation
 173                 : $loaded_class;
 174         };
 175     }
 176 }
 177
 178 # Utilities from Class::MOP
 179
 180 sub get_code_info;
 181 sub get_code_package;
 182
 183 # taken from Class/MOP.pm
 184 sub is_valid_class_name {
 185     my $class = shift;
 186
 187     return 0 if ref($class);
 188     return 0 unless defined($class);
 189
 190     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
 191
 192     return 0;
 193 }
 194
 195 # taken from Class/MOP.pm
 196 sub load_first_existing_class {
 197     my @classes = @_
 198       or return;
 199
 200     my %exceptions;
 201     for my $class (@classes) {
 202         my $e = _try_load_one_class($class);
 203
 204         if ($e) {
 205             $exceptions{$class} = $e;
 206         }
 207         else {
 208             return $class;
 209         }
 210     }
 211
 212     # not found
 213     Carp::confess join(
 214         "\n",
 215         map {
 216             sprintf( "Could not load class (%s) because : %s",
 217                 $_, $exceptions{$_} )
 218           } @classes
 219     );
 220 }
 221
 222 # taken from Class/MOP.pm
 223 my %is_class_loaded_cache;
 224 sub _try_load_one_class {
 225     my $class = shift;
 226
 227     unless ( is_valid_class_name($class) ) {
 228         my $display = defined($class) ? $class : 'undef';
 229         Carp::confess "Invalid class name ($display)";
 230     }
 231
 232     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 233
 234     my $file = $class . '.pm';
 235     $file =~ s{::}{/}g;
 236
 237     return do {
 238         local $@;
 239         eval { require($file) };
 240         $@;
 241     };
 242 }
 243
 244
 245 sub load_class {
 246     my $class = shift;
 247     my $e = _try_load_one_class($class);
 248     Carp::confess "Could not load class ($class) because : $e" if $e;
 249
 250     return 1;
 251 }
 252
 253 sub is_class_loaded;
 254
 255
 256 sub apply_all_roles {
 257     my $applicant = Scalar::Util::blessed($_[0])
 258         ?                                shift   # instance
 259         : Mouse::Meta::Class->initialize(shift); # class or role name
 260
 261     my @roles;
 262
 263     # Basis of Data::OptList
 264     my $max = scalar(@_);
 265     for (my $i = 0; $i < $max ; $i++) {
 266         if ($i + 1 < $max && ref($_[$i + 1])) {
 267             push @roles, [ $_[$i] => $_[++$i] ];
 268         } else {
 269             push @roles, [ $_[$i] => undef ];
 270         }
 271         my $role_name = $roles[-1][0];
 272         load_class($role_name);
 273
 274         is_a_metarole( get_metaclass_by_name($role_name) )
 275             || $applicant->meta->throw_error("You can only consume roles, $role_name(".$role_name->meta.") is not a Mouse role");
 276     }
 277
 278     if ( scalar @roles == 1 ) {
 279         my ( $role_name, $params ) = @{ $roles[0] };
 280         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 281     }
 282     else {
 283         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 284     }
 285     return;
 286 }
 287
 288 # taken from Moose::Util 0.90
 289 sub english_list {
 290     return $_[0] if @_ == 1;
 291
 292     my @items = sort @_;
 293
 294     return "$items[0] and $items[1]" if @items == 2;
 295
 296     my $tail = pop @items;
 297
 298     return join q{, }, @items, "and $tail";
 299 }
 300
 301
 302 # common utilities
 303
 304 sub not_supported{
 305     my($feature) = @_;
 306
 307     $feature ||= ( caller(1) )[3]; # subroutine name
 308
 309     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 310     Carp::confess("Mouse does not currently support $feature");
 311 }
 312
 313 # general meta() method
 314 sub meta :method{
 315     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 316 }
 317
 318 # general dump() method
 319 sub dump :method {
 320     my($self, $maxdepth) = @_;
 321
 322     require 'Data/Dumper.pm'; # we don't want to create its namespace
 323     my $dd = Data::Dumper->new([$self]);
 324     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 325     $dd->Indent(1);
 326     return $dd->Dump();
 327 }
 328
 329 # general does() method
 330 sub does :method;
 331 *does = \&does_role; # alias
 332
 333 1;
 334
 335 __END__
 336
 337 =head1 NAME
 338
 339 Mouse::Util - Features, with or without their dependencies
 340
 341 =head1 VERSION
 342
 343 This document describes Mouse version 0.40_07
 344
 345 =head1 IMPLEMENTATIONS FOR
 346
 347 =head2 Moose::Util
 348
 349 =head3 C<find_meta>
 350
 351 =head3 C<does_role>
 352
 353 =head3 C<resolve_metaclass_alias>
 354
 355 =head3 C<apply_all_roles>
 356
 357 =head3 C<english_list>
 358
 359 =head2 Class::MOP
 360
 361 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 362
 363 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 364 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 365 locally-defined method.
 366
 367 =head3 C<< load_class(ClassName) >>
 368
 369 This will load a given C<ClassName> (or die if it is not loadable).
 370 This function can be used in place of tricks like
 371 C<eval "use $module"> or using C<require>.
 372
 373 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 374
 375 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 376
 377 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 378
 379 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 380
 381 =head2 MRO::Compat
 382
 383 =head3 C<get_linear_isa>
 384
 385 =head2 Sub::Identify
 386
 387 =head3 C<get_code_info>
 388
 389 =head1 UTILITIES FOR MOUSE
 390
 391 =head3 C<not_supported>
 392
 393 =head1 SEE ALSO
 394
 395 L<Moose::Util>
 396
 397 L<Class::MOP>
 398
 399 L<Sub::Identify>
 400
 401 L<MRO::Compat>
 402
 403 =cut
 404