lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 sub install_subroutines { # must be here
   7     my $into = shift;
   8
   9     while(my($name, $code) = splice @_, 0, 2){
  10         no strict 'refs';
  11         no warnings 'once', 'redefine';
  12         use warnings FATAL => 'uninitialized';
  13         *{$into . '::' . $name} = \&{$code};
  14     }
  15     return;
  16 }
  17
  18 BEGIN{
  19     # This is used in Mouse::PurePerl
  20     Mouse::Exporter->setup_import_methods(
  21         as_is => [qw(
  22             find_meta
  23             does_role
  24             resolve_metaclass_alias
  25             apply_all_roles
  26             english_list
  27
  28             load_class
  29             is_class_loaded
  30
  31             get_linear_isa
  32             get_code_info
  33
  34             get_code_package
  35             get_code_ref
  36
  37             not_supported
  38
  39             does meta dump
  40         )],
  41         groups => {
  42             default => [], # export no functions by default
  43
  44             # The ':meta' group is 'use metaclass' for Mouse
  45             meta    => [qw(does meta dump)],
  46         },
  47     );
  48
  49
  50     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  51     # XS loader is placed here, not in Mouse.pm.
  52
  53     our $VERSION = '0.50_03';
  54
  55     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  56
  57     if($xs){
  58         # XXX: XSLoader tries to get the object path from caller's file name
  59         #      $hack_mouse_file fools its mechanism
  60
  61         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  62         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  63             local $^W = 0; # work around 'redefine' warning to &install_subroutines
  64             require XSLoader;
  65             XSLoader::load('Mouse', $VERSION);
  66             Mouse::Util->import({ into => 'Mouse::Meta::Method::Constructor::XS' }, ':meta');
  67             Mouse::Util->import({ into => 'Mouse::Meta::Method::Destructor::XS'  }, ':meta');
  68             Mouse::Util->import({ into => 'Mouse::Meta::Method::Accessor::XS'    }, ':meta');
  69             return 1;
  70         } || 0;
  71         #warn $@ if $@;
  72     }
  73
  74     if(!$xs){
  75         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  76     }
  77
  78     *MOUSE_XS = sub(){ $xs };
  79 }
  80
  81 use Carp         ();
  82 use Scalar::Util ();
  83
  84 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  85
  86 # aliases as public APIs
  87 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  88 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  89
  90 # aliases
  91 {
  92     *class_of                    = \&Mouse::Meta::Module::_class_of;
  93     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  94     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  95     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  96
  97     *Mouse::load_class           = \&load_class;
  98     *Mouse::is_class_loaded      = \&is_class_loaded;
  99
 100     # is-a predicates
 101     #generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
 102     #generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
 103     #generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
 104
 105     # duck type predicates
 106     generate_can_predicate_for(['_compiled_type_constraint']  => 'is_a_type_constraint');
 107     generate_can_predicate_for(['create_anon_class']          => 'is_a_metaclass');
 108     generate_can_predicate_for(['create_anon_role']           => 'is_a_metarole');
 109 }
 110
 111 our $in_global_destruction = 0;
 112 END{ $in_global_destruction = 1 }
 113
 114 # Moose::Util compatible utilities
 115
 116 sub find_meta{
 117     return class_of( $_[0] );
 118 }
 119
 120 sub does_role{
 121     my ($class_or_obj, $role_name) = @_;
 122
 123     my $meta = class_of($class_or_obj);
 124
 125     (defined $role_name)
 126         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 127
 128     return defined($meta) && $meta->does_role($role_name);
 129 }
 130
 131 BEGIN {
 132     my $get_linear_isa;
 133     if ($] >= 5.009_005) {
 134         require mro;
 135         $get_linear_isa = \&mro::get_linear_isa;
 136     } else {
 137         # this code is based on MRO::Compat::__get_linear_isa
 138         my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 139         $_get_linear_isa_dfs = sub {
 140             my($classname) = @_;
 141
 142             my @lin = ($classname);
 143             my %stored;
 144
 145             no strict 'refs';
 146             foreach my $parent (@{"$classname\::ISA"}) {
 147                 foreach  my $p(@{ $_get_linear_isa_dfs->($parent) }) {
 148                     next if exists $stored{$p};
 149                     push(@lin, $p);
 150                     $stored{$p} = 1;
 151                 }
 152             }
 153             return \@lin;
 154         };
 155
 156         {
 157             package # hide from PAUSE
 158                 Class::C3;
 159             our %MRO; # work around 'once' warnings
 160         }
 161
 162         # MRO::Compat::__get_linear_isa has no prototype, so
 163         # we define a prototyped version for compatibility with core's
 164         # See also MRO::Compat::__get_linear_isa.
 165         $get_linear_isa = sub ($;$){
 166             my($classname, $type) = @_;
 167
 168             if(!defined $type){
 169                 $type = exists $Class::C3::MRO{$classname} ? 'c3' : 'dfs';
 170             }
 171             if($type eq 'c3'){
 172                 require Class::C3;
 173                 return [Class::C3::calculateMRO($classname)];
 174             }
 175             else{
 176                 return $_get_linear_isa_dfs->($classname);
 177             }
 178         };
 179     }
 180
 181     *get_linear_isa = $get_linear_isa;
 182 }
 183
 184
 185 # taken from Mouse::Util (0.90)
 186 {
 187     my %cache;
 188
 189     sub resolve_metaclass_alias {
 190         my ( $type, $metaclass_name, %options ) = @_;
 191
 192         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 193
 194         return $cache{$cache_key}{$metaclass_name} ||= do{
 195
 196             my $possible_full_name = join '::',
 197                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 198             ;
 199
 200             my $loaded_class = load_first_existing_class(
 201                 $possible_full_name,
 202                 $metaclass_name
 203             );
 204
 205             $loaded_class->can('register_implementation')
 206                 ? $loaded_class->register_implementation
 207                 : $loaded_class;
 208         };
 209     }
 210 }
 211
 212 # Utilities from Class::MOP
 213
 214 sub get_code_info;
 215 sub get_code_package;
 216
 217 sub is_valid_class_name;
 218
 219 # taken from Class/MOP.pm
 220 sub load_first_existing_class {
 221     my @classes = @_
 222       or return;
 223
 224     my %exceptions;
 225     for my $class (@classes) {
 226         my $e = _try_load_one_class($class);
 227
 228         if ($e) {
 229             $exceptions{$class} = $e;
 230         }
 231         else {
 232             return $class;
 233         }
 234     }
 235
 236     # not found
 237     Carp::confess join(
 238         "\n",
 239         map {
 240             sprintf( "Could not load class (%s) because : %s",
 241                 $_, $exceptions{$_} )
 242           } @classes
 243     );
 244 }
 245
 246 # taken from Class/MOP.pm
 247 my %is_class_loaded_cache;
 248 sub _try_load_one_class {
 249     my $class = shift;
 250
 251     unless ( is_valid_class_name($class) ) {
 252         my $display = defined($class) ? $class : 'undef';
 253         Carp::confess "Invalid class name ($display)";
 254     }
 255
 256     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 257
 258     $class  =~ s{::}{/}g;
 259     $class .= '.pm';
 260
 261     return do {
 262         local $@;
 263         eval { require $class };
 264         $@;
 265     };
 266 }
 267
 268
 269 sub load_class {
 270     my $class = shift;
 271     my $e = _try_load_one_class($class);
 272     Carp::confess "Could not load class ($class) because : $e" if $e;
 273
 274     return $class;
 275 }
 276
 277 sub is_class_loaded;
 278
 279 sub apply_all_roles {
 280     my $consumer = Scalar::Util::blessed($_[0])
 281         ?                                shift   # instance
 282         : Mouse::Meta::Class->initialize(shift); # class or role name
 283
 284     my @roles;
 285
 286     # Basis of Data::OptList
 287     my $max = scalar(@_);
 288     for (my $i = 0; $i < $max ; $i++) {
 289         if ($i + 1 < $max && ref($_[$i + 1])) {
 290             push @roles, [ $_[$i] => $_[++$i] ];
 291         } else {
 292             push @roles, [ $_[$i] => undef ];
 293         }
 294         my $role_name = $roles[-1][0];
 295         load_class($role_name);
 296
 297         is_a_metarole( get_metaclass_by_name($role_name) )
 298             || $consumer->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
 299     }
 300
 301     if ( scalar @roles == 1 ) {
 302         my ( $role_name, $params ) = @{ $roles[0] };
 303         get_metaclass_by_name($role_name)->apply( $consumer, defined $params ? $params : () );
 304     }
 305     else {
 306         Mouse::Meta::Role->combine(@roles)->apply($consumer);
 307     }
 308     return;
 309 }
 310
 311 # taken from Moose::Util 0.90
 312 sub english_list {
 313     return $_[0] if @_ == 1;
 314
 315     my @items = sort @_;
 316
 317     return "$items[0] and $items[1]" if @items == 2;
 318
 319     my $tail = pop @items;
 320
 321     return join q{, }, @items, "and $tail";
 322 }
 323
 324 sub quoted_english_list {
 325     return english_list(map { qq{'$_'} } @_);
 326 }
 327
 328 # common utilities
 329
 330 sub not_supported{
 331     my($feature) = @_;
 332
 333     $feature ||= ( caller(1) )[3]; # subroutine name
 334
 335     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 336     Carp::confess("Mouse does not currently support $feature");
 337 }
 338
 339 # general meta() method
 340 sub meta :method{
 341     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 342 }
 343
 344 # general dump() method
 345 sub dump :method {
 346     my($self, $maxdepth) = @_;
 347
 348     require 'Data/Dumper.pm'; # we don't want to create its namespace
 349     my $dd = Data::Dumper->new([$self]);
 350     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 3);
 351     $dd->Indent(1);
 352     return $dd->Dump();
 353 }
 354
 355 # general does() method
 356 sub does :method {
 357     goto &does_role;
 358 }
 359
 360 1;
 361 __END__
 362
 363 =head1 NAME
 364
 365 Mouse::Util - Features, with or without their dependencies
 366
 367 =head1 VERSION
 368
 369 This document describes Mouse version 0.50_03
 370
 371 =head1 IMPLEMENTATIONS FOR
 372
 373 =head2 Moose::Util
 374
 375 =head3 C<find_meta>
 376
 377 =head3 C<does_role>
 378
 379 =head3 C<resolve_metaclass_alias>
 380
 381 =head3 C<apply_all_roles>
 382
 383 =head3 C<english_list>
 384
 385 =head2 Class::MOP
 386
 387 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 388
 389 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 390 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 391 locally-defined method.
 392
 393 =head3 C<< load_class(ClassName) >>
 394
 395 This will load a given C<ClassName> (or die if it is not loadable).
 396 This function can be used in place of tricks like
 397 C<eval "use $module"> or using C<require>.
 398
 399 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 400
 401 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 402
 403 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 404
 405 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 406
 407 =head2 MRO::Compat
 408
 409 =head3 C<get_linear_isa>
 410
 411 =head2 Sub::Identify
 412
 413 =head3 C<get_code_info>
 414
 415 =head1 Mouse specific utilities
 416
 417 =head3 C<not_supported>
 418
 419 =head3 C<get_code_package>
 420
 421 =head3 C<get_code_ref>
 422
 423 =head1 SEE ALSO
 424
 425 L<Moose::Util>
 426
 427 L<Class::MOP>
 428
 429 L<Sub::Identify>
 430
 431 L<MRO::Compat>
 432
 433 =cut
 434