lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 use Carp qw(confess);
   5 use B ();
   6
   7 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
   8
   9 Mouse::Exporter->setup_import_methods(
  10     as_is => [qw(
  11         find_meta
  12         does_role
  13         resolve_metaclass_alias
  14         apply_all_roles
  15         english_list
  16
  17         load_class
  18         is_class_loaded
  19
  20         get_linear_isa
  21         get_code_info
  22
  23         get_code_package
  24
  25         not_supported
  26
  27         does meta dump
  28         _MOUSE_VERBOSE
  29     )],
  30     groups => {
  31         default => [], # export no functions by default
  32         meta    => [qw(does meta dump _MOUSE_VERBOSE)],
  33     },
  34     _export_to_main => 1,
  35 );
  36
  37 # aliases as public APIs
  38 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  39 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  40
  41 BEGIN {
  42     *class_of                    = \&Mouse::Meta::Module::class_of;
  43     *get_metaclass_by_name       = \&Mouse::Meta::Module::get_metaclass_by_name;
  44     *get_all_metaclass_instances = \&Mouse::Meta::Module::get_all_metaclass_instances;
  45     *get_all_metaclass_names     = \&Mouse::Meta::Module::get_all_metaclass_names;
  46 }
  47
  48 # Moose::Util compatible utilities
  49
  50 sub find_meta{
  51     return class_of( $_[0] );
  52 }
  53
  54 sub does_role{
  55     my ($class_or_obj, $role_name) = @_;
  56
  57     my $meta = class_of($class_or_obj);
  58
  59     (defined $role_name)
  60         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
  61
  62     return defined($meta) && $meta->does_role($role_name);
  63 }
  64
  65 BEGIN {
  66     my $impl;
  67     if ($] >= 5.009_005) {
  68         require mro;
  69         $impl = \&mro::get_linear_isa;
  70     } else {
  71         my $e = do {
  72             local $@;
  73             eval { require MRO::Compat };
  74             $@;
  75         };
  76         if (!$e) {
  77             $impl = \&mro::get_linear_isa;
  78         } else {
  79 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
  80             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
  81             $_get_linear_isa_dfs = sub {
  82                 no strict 'refs';
  83
  84                 my $classname = shift;
  85
  86                 my @lin = ($classname);
  87                 my %stored;
  88                 foreach my $parent (@{"$classname\::ISA"}) {
  89                     my $plin = $_get_linear_isa_dfs->($parent);
  90                     foreach  my $p(@$plin) {
  91                         next if exists $stored{$p};
  92                         push(@lin, $p);
  93                         $stored{$p} = 1;
  94                     }
  95                 }
  96                 return \@lin;
  97             };
  98 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
  99             $impl = $_get_linear_isa_dfs;
 100         }
 101     }
 102
 103
 104     no warnings 'once';
 105     *get_linear_isa = $impl;
 106 }
 107
 108 { # taken from Sub::Identify
 109     sub get_code_info($) {
 110         my ($coderef) = @_;
 111         ref($coderef) or return;
 112
 113         my $cv = B::svref_2object($coderef);
 114         $cv->isa('B::CV') or return;
 115
 116         my $gv = $cv->GV;
 117         $gv->isa('B::GV') or return;
 118
 119         return ($gv->STASH->NAME, $gv->NAME);
 120     }
 121
 122     sub get_code_package{
 123         my($coderef) = @_;
 124
 125         my $cv = B::svref_2object($coderef);
 126         $cv->isa('B::CV') or return '';
 127
 128         my $gv = $cv->GV;
 129         $gv->isa('B::GV') or return '';
 130
 131         return $gv->STASH->NAME;
 132     }
 133 }
 134
 135 # taken from Mouse::Util (0.90)
 136 {
 137     my %cache;
 138
 139     sub resolve_metaclass_alias {
 140         my ( $type, $metaclass_name, %options ) = @_;
 141
 142         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 143
 144         return $cache{$cache_key}{$metaclass_name} ||= do{
 145
 146             my $possible_full_name = join '::',
 147                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 148             ;
 149
 150             my $loaded_class = load_first_existing_class(
 151                 $possible_full_name,
 152                 $metaclass_name
 153             );
 154
 155             $loaded_class->can('register_implementation')
 156                 ? $loaded_class->register_implementation
 157                 : $loaded_class;
 158         };
 159     }
 160 }
 161
 162 # Utilities from Class::MOP
 163
 164
 165 # taken from Class/MOP.pm
 166 sub is_valid_class_name {
 167     my $class = shift;
 168
 169     return 0 if ref($class);
 170     return 0 unless defined($class);
 171
 172     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 173
 174     return 0;
 175 }
 176
 177 # taken from Class/MOP.pm
 178 sub load_first_existing_class {
 179     my @classes = @_
 180       or return;
 181
 182     my %exceptions;
 183     for my $class (@classes) {
 184         my $e = _try_load_one_class($class);
 185
 186         if ($e) {
 187             $exceptions{$class} = $e;
 188         }
 189         else {
 190             return $class;
 191         }
 192     }
 193
 194     # not found
 195     confess join(
 196         "\n",
 197         map {
 198             sprintf( "Could not load class (%s) because : %s",
 199                 $_, $exceptions{$_} )
 200           } @classes
 201     );
 202 }
 203
 204 # taken from Class/MOP.pm
 205 my %is_class_loaded_cache;
 206 sub _try_load_one_class {
 207     my $class = shift;
 208
 209     unless ( is_valid_class_name($class) ) {
 210         my $display = defined($class) ? $class : 'undef';
 211         confess "Invalid class name ($display)";
 212     }
 213
 214     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 215
 216     my $file = $class . '.pm';
 217     $file =~ s{::}{/}g;
 218
 219     return do {
 220         local $@;
 221         eval { require($file) };
 222         $@;
 223     };
 224 }
 225
 226
 227 sub load_class {
 228     my $class = shift;
 229     my $e = _try_load_one_class($class);
 230     confess "Could not load class ($class) because : $e" if $e;
 231
 232     return 1;
 233 }
 234
 235
 236 sub is_class_loaded {
 237     my $class = shift;
 238
 239     return 0 if ref($class) || !defined($class) || !length($class);
 240
 241     # walk the symbol table tree to avoid autovififying
 242     # \*{${main::}{"Foo::"}} == \*main::Foo::
 243
 244     my $pack = \%::;
 245     foreach my $part (split('::', $class)) {
 246         my $entry = \$pack->{$part . '::'};
 247         return 0 if ref($entry) ne 'GLOB';
 248         $pack = *{$entry}{HASH} or return 0;
 249     }
 250
 251     # check for $VERSION or @ISA
 252     return 1 if exists $pack->{VERSION}
 253              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
 254     return 1 if exists $pack->{ISA}
 255              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
 256
 257     # check for any method
 258     foreach my $name( keys %{$pack} ) {
 259         my $entry = \$pack->{$name};
 260         return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
 261     }
 262
 263     # fail
 264     return 0;
 265 }
 266
 267
 268 sub apply_all_roles {
 269     my $meta = Mouse::Meta::Class->initialize(shift);
 270
 271     my @roles;
 272
 273     # Basis of Data::OptList
 274     my $max = scalar(@_);
 275     for (my $i = 0; $i < $max ; $i++) {
 276         if ($i + 1 < $max && ref($_[$i + 1])) {
 277             push @roles, [ $_[$i++] => $_[$i] ];
 278         } else {
 279             push @roles, [ $_[$i]   => undef ];
 280         }
 281         my $role_name = $roles[-1][0];
 282         load_class($role_name);
 283         ( $role_name->can('meta') && $role_name->meta->isa('Mouse::Meta::Role') )
 284             || $meta->throw_error("You can only consume roles, $role_name(".$role_name->meta.") is not a Mouse role");
 285     }
 286
 287     if ( scalar @roles == 1 ) {
 288         my ( $role, $params ) = @{ $roles[0] };
 289         $role->meta->apply( $meta, ( defined $params ? %$params : () ) );
 290     }
 291     else {
 292         Mouse::Meta::Role->combine_apply($meta, @roles);
 293     }
 294     return;
 295 }
 296
 297 # taken from Moose::Util 0.90
 298 sub english_list {
 299     return $_[0] if @_ == 1;
 300
 301     my @items = sort @_;
 302
 303     return "$items[0] and $items[1]" if @items == 2;
 304
 305     my $tail = pop @items;
 306
 307     return join q{, }, @items, "and $tail";
 308 }
 309
 310
 311 # common utilities
 312
 313 sub not_supported{
 314     my($feature) = @_;
 315
 316     $feature ||= ( caller(1) )[3]; # subroutine name
 317
 318     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 319     Carp::confess("Mouse does not currently support $feature");
 320 }
 321
 322 sub meta{
 323     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 324 }
 325
 326 sub dump {
 327     my($self, $maxdepth) = @_;
 328
 329     require 'Data/Dumper.pm'; # we don't want to create its namespace
 330     my $dd = Data::Dumper->new([$self]);
 331     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 332     $dd->Indent(1);
 333     return $dd->Dump();
 334 }
 335
 336 sub does :method;
 337 *does = \&does_role; # alias
 338
 339 1;
 340
 341 __END__
 342
 343 =head1 NAME
 344
 345 Mouse::Util - Features, with or without their dependencies
 346
 347 =head1 IMPLEMENTATIONS FOR
 348
 349 =head2 Moose::Util
 350
 351 =head3 C<find_meta>
 352
 353 =head3 C<does_role>
 354
 355 =head3 C<resolve_metaclass_alias>
 356
 357 =head3 C<apply_all_roles>
 358
 359 =head3 C<english_list>
 360
 361 =head2 Class::MOP
 362
 363 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 364
 365 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 366 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 367 locally-defined method.
 368
 369 =head3 C<< load_class(ClassName) >>
 370
 371 This will load a given C<ClassName> (or die if it is not loadable).
 372 This function can be used in place of tricks like
 373 C<eval "use $module"> or using C<require>.
 374
 375 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 376
 377 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 378
 379 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 380
 381 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 382
 383 =head2 MRO::Compat
 384
 385 =head3 C<get_linear_isa>
 386
 387 =head2 Sub::Identify
 388
 389 =head3 C<get_code_info>
 390
 391 =head1 UTILITIES FOR MOUSE
 392
 393 =head3 C<not_supported>
 394
 395 =head1 SEE ALSO
 396
 397 L<Moose::Util>
 398
 399 L<Class::MOP>
 400
 401 L<Sub::Identify>
 402
 403 L<MRO::Compat>
 404
 405 =cut
 406