lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 BEGIN{
   7     # This is used in Mouse::PurePerl
   8     Mouse::Exporter->setup_import_methods(
   9         as_is => [qw(
  10             find_meta
  11             does_role
  12             resolve_metaclass_alias
  13             apply_all_roles
  14             english_list
  15
  16             load_class
  17             is_class_loaded
  18
  19             get_linear_isa
  20             get_code_info
  21
  22             get_code_package
  23             get_code_ref
  24
  25             not_supported
  26
  27             does meta dump
  28         )],
  29         groups => {
  30             default => [], # export no functions by default
  31
  32             # The ':meta' group is 'use metaclass' for Mouse
  33             meta    => [qw(does meta dump)],
  34         },
  35     );
  36
  37
  38     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  39     # XS loader is placed here, not in Mouse.pm.
  40
  41     our $VERSION = '0.40_07';
  42
  43     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  44
  45     if($xs){
  46         local $@;
  47
  48         # XXX: XSLoader tries to get the object path from caller's file name
  49         #      $hack_mouse_file fools its mechanism
  50
  51         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  52         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  53             require XSLoader;
  54             XSLoader::load('Mouse', $VERSION);
  55         };
  56         #warn $@ if $@;
  57     }
  58
  59     if(!$xs){
  60         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  61     }
  62
  63     *_MOUSE_XS = sub(){ $xs };
  64 }
  65
  66
  67 use Carp         ();
  68 use Scalar::Util ();
  69
  70 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  71
  72 # aliases as public APIs
  73 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  74 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  75
  76 BEGIN {
  77     *class_of                    = \&Mouse::Meta::Module::_class_of;
  78     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  79     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  80     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  81
  82     # is-a predicates
  83     generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
  84     generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
  85     generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
  86 }
  87
  88
  89 # Moose::Util compatible utilities
  90
  91 sub find_meta{
  92     return class_of( $_[0] );
  93 }
  94
  95 sub does_role{
  96     my ($class_or_obj, $role_name) = @_;
  97
  98     my $meta = class_of($class_or_obj);
  99
 100     (defined $role_name)
 101         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 102
 103     return defined($meta) && $meta->does_role($role_name);
 104 }
 105
 106 BEGIN {
 107     my $get_linear_isa;
 108     if ($] >= 5.009_005) {
 109         require mro;
 110         $get_linear_isa = \&mro::get_linear_isa;
 111     } else {
 112         my $e = do {
 113             local $@;
 114             eval { require MRO::Compat };
 115             $@;
 116         };
 117         if (!$e) {
 118             $get_linear_isa = \&mro::get_linear_isa;
 119         } else {
 120 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 121             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 122             $_get_linear_isa_dfs = sub ($;$){
 123                 no strict 'refs';
 124
 125                 my $classname = shift;
 126
 127                 my @lin = ($classname);
 128                 my %stored;
 129                 foreach my $parent (@{"$classname\::ISA"}) {
 130                     my $plin = $_get_linear_isa_dfs->($parent);
 131                     foreach  my $p(@$plin) {
 132                         next if exists $stored{$p};
 133                         push(@lin, $p);
 134                         $stored{$p} = 1;
 135                     }
 136                 }
 137                 return \@lin;
 138             };
 139 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 140             $get_linear_isa = $_get_linear_isa_dfs;
 141         }
 142     }
 143
 144     *get_linear_isa = $get_linear_isa;
 145 }
 146
 147
 148 # taken from Mouse::Util (0.90)
 149 {
 150     my %cache;
 151
 152     sub resolve_metaclass_alias {
 153         my ( $type, $metaclass_name, %options ) = @_;
 154
 155         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 156
 157         return $cache{$cache_key}{$metaclass_name} ||= do{
 158
 159             my $possible_full_name = join '::',
 160                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 161             ;
 162
 163             my $loaded_class = load_first_existing_class(
 164                 $possible_full_name,
 165                 $metaclass_name
 166             );
 167
 168             $loaded_class->can('register_implementation')
 169                 ? $loaded_class->register_implementation
 170                 : $loaded_class;
 171         };
 172     }
 173 }
 174
 175 # Utilities from Class::MOP
 176
 177 sub get_code_info;
 178 sub get_code_package;
 179
 180 # taken from Class/MOP.pm
 181 sub is_valid_class_name {
 182     my $class = shift;
 183
 184     return 0 if ref($class);
 185     return 0 unless defined($class);
 186
 187     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
 188
 189     return 0;
 190 }
 191
 192 # taken from Class/MOP.pm
 193 sub load_first_existing_class {
 194     my @classes = @_
 195       or return;
 196
 197     my %exceptions;
 198     for my $class (@classes) {
 199         my $e = _try_load_one_class($class);
 200
 201         if ($e) {
 202             $exceptions{$class} = $e;
 203         }
 204         else {
 205             return $class;
 206         }
 207     }
 208
 209     # not found
 210     Carp::confess join(
 211         "\n",
 212         map {
 213             sprintf( "Could not load class (%s) because : %s",
 214                 $_, $exceptions{$_} )
 215           } @classes
 216     );
 217 }
 218
 219 # taken from Class/MOP.pm
 220 my %is_class_loaded_cache;
 221 sub _try_load_one_class {
 222     my $class = shift;
 223
 224     unless ( is_valid_class_name($class) ) {
 225         my $display = defined($class) ? $class : 'undef';
 226         Carp::confess "Invalid class name ($display)";
 227     }
 228
 229     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 230
 231     my $file = $class . '.pm';
 232     $file =~ s{::}{/}g;
 233
 234     return do {
 235         local $@;
 236         eval { require($file) };
 237         $@;
 238     };
 239 }
 240
 241
 242 sub load_class {
 243     my $class = shift;
 244     my $e = _try_load_one_class($class);
 245     Carp::confess "Could not load class ($class) because : $e" if $e;
 246
 247     return 1;
 248 }
 249
 250 sub is_class_loaded;
 251
 252
 253 sub apply_all_roles {
 254     my $applicant = Scalar::Util::blessed($_[0])
 255         ?                                shift   # instance
 256         : Mouse::Meta::Class->initialize(shift); # class or role name
 257
 258     my @roles;
 259
 260     # Basis of Data::OptList
 261     my $max = scalar(@_);
 262     for (my $i = 0; $i < $max ; $i++) {
 263         if ($i + 1 < $max && ref($_[$i + 1])) {
 264             push @roles, [ $_[$i] => $_[++$i] ];
 265         } else {
 266             push @roles, [ $_[$i] => undef ];
 267         }
 268         my $role_name = $roles[-1][0];
 269         load_class($role_name);
 270
 271         is_a_metarole( get_metaclass_by_name($role_name) )
 272             || $applicant->meta->throw_error("You can only consume roles, $role_name(".$role_name->meta.") is not a Mouse role");
 273     }
 274
 275     if ( scalar @roles == 1 ) {
 276         my ( $role_name, $params ) = @{ $roles[0] };
 277         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 278     }
 279     else {
 280         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 281     }
 282     return;
 283 }
 284
 285 # taken from Moose::Util 0.90
 286 sub english_list {
 287     return $_[0] if @_ == 1;
 288
 289     my @items = sort @_;
 290
 291     return "$items[0] and $items[1]" if @items == 2;
 292
 293     my $tail = pop @items;
 294
 295     return join q{, }, @items, "and $tail";
 296 }
 297
 298
 299 # common utilities
 300
 301 sub not_supported{
 302     my($feature) = @_;
 303
 304     $feature ||= ( caller(1) )[3]; # subroutine name
 305
 306     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 307     Carp::confess("Mouse does not currently support $feature");
 308 }
 309
 310 # general meta() method
 311 sub meta :method{
 312     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 313 }
 314
 315 # general dump() method
 316 sub dump :method {
 317     my($self, $maxdepth) = @_;
 318
 319     require 'Data/Dumper.pm'; # we don't want to create its namespace
 320     my $dd = Data::Dumper->new([$self]);
 321     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 322     $dd->Indent(1);
 323     return $dd->Dump();
 324 }
 325
 326 # general does() method
 327 sub does :method;
 328 *does = \&does_role; # alias
 329
 330 1;
 331
 332 __END__
 333
 334 =head1 NAME
 335
 336 Mouse::Util - Features, with or without their dependencies
 337
 338 =head1 VERSION
 339
 340 This document describes Mouse version 0.40_07
 341
 342 =head1 IMPLEMENTATIONS FOR
 343
 344 =head2 Moose::Util
 345
 346 =head3 C<find_meta>
 347
 348 =head3 C<does_role>
 349
 350 =head3 C<resolve_metaclass_alias>
 351
 352 =head3 C<apply_all_roles>
 353
 354 =head3 C<english_list>
 355
 356 =head2 Class::MOP
 357
 358 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 359
 360 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 361 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 362 locally-defined method.
 363
 364 =head3 C<< load_class(ClassName) >>
 365
 366 This will load a given C<ClassName> (or die if it is not loadable).
 367 This function can be used in place of tricks like
 368 C<eval "use $module"> or using C<require>.
 369
 370 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 371
 372 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 373
 374 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 375
 376 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 377
 378 =head2 MRO::Compat
 379
 380 =head3 C<get_linear_isa>
 381
 382 =head2 Sub::Identify
 383
 384 =head3 C<get_code_info>
 385
 386 =head1 UTILITIES FOR MOUSE
 387
 388 =head3 C<not_supported>
 389
 390 =head1 SEE ALSO
 391
 392 L<Moose::Util>
 393
 394 L<Class::MOP>
 395
 396 L<Sub::Identify>
 397
 398 L<MRO::Compat>
 399
 400 =cut
 401