lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 BEGIN{
   5     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
   6     # XS loader is placed here, not in Mouse.pm.
   7
   8     our $VERSION = '0.40';
   9
  10     my $need_pp = !!$ENV{MOUSE_PUREPERL};
  11
  12     if(!$need_pp && !exists $INC{'Mouse/PurePerl.pm'}){
  13         local $@;
  14         $need_pp = !eval{
  15             require XSLoader;
  16             XSLoader::load('Mouse', $VERSION);
  17         };
  18         warn $@ if $@; # for DEBUGGING
  19     }
  20
  21     if($need_pp){
  22         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  23     }
  24 }
  25
  26
  27 use Carp qw(confess);
  28 use Scalar::Util qw(blessed);
  29
  30 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  31
  32 Mouse::Exporter->setup_import_methods(
  33     as_is => [qw(
  34         find_meta
  35         does_role
  36         resolve_metaclass_alias
  37         apply_all_roles
  38         english_list
  39
  40         load_class
  41         is_class_loaded
  42
  43         get_linear_isa
  44         get_code_info
  45
  46         get_code_package
  47         get_code_ref
  48
  49         not_supported
  50
  51         does meta dump
  52         _MOUSE_VERBOSE
  53     )],
  54     groups => {
  55         default => [], # export no functions by default
  56
  57         # The ':meta' group is 'use metaclass' for Mouse
  58         meta    => [qw(does meta dump _MOUSE_VERBOSE)],
  59     },
  60 );
  61
  62 # aliases as public APIs
  63 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  64 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  65
  66 BEGIN {
  67     *class_of                    = \&Mouse::Meta::Module::class_of;
  68     *get_metaclass_by_name       = \&Mouse::Meta::Module::get_metaclass_by_name;
  69     *get_all_metaclass_instances = \&Mouse::Meta::Module::get_all_metaclass_instances;
  70     *get_all_metaclass_names     = \&Mouse::Meta::Module::get_all_metaclass_names;
  71 }
  72
  73 # Moose::Util compatible utilities
  74
  75 sub find_meta{
  76     return class_of( $_[0] );
  77 }
  78
  79 sub does_role{
  80     my ($class_or_obj, $role_name) = @_;
  81
  82     my $meta = class_of($class_or_obj);
  83
  84     (defined $role_name)
  85         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
  86
  87     return defined($meta) && $meta->does_role($role_name);
  88 }
  89
  90 BEGIN {
  91     my $impl;
  92     if ($] >= 5.009_005) {
  93         require mro;
  94         $impl = \&mro::get_linear_isa;
  95     } else {
  96         my $e = do {
  97             local $@;
  98             eval { require MRO::Compat };
  99             $@;
 100         };
 101         if (!$e) {
 102             $impl = \&mro::get_linear_isa;
 103         } else {
 104 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 105             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 106             $_get_linear_isa_dfs = sub {
 107                 no strict 'refs';
 108
 109                 my $classname = shift;
 110
 111                 my @lin = ($classname);
 112                 my %stored;
 113                 foreach my $parent (@{"$classname\::ISA"}) {
 114                     my $plin = $_get_linear_isa_dfs->($parent);
 115                     foreach  my $p(@$plin) {
 116                         next if exists $stored{$p};
 117                         push(@lin, $p);
 118                         $stored{$p} = 1;
 119                     }
 120                 }
 121                 return \@lin;
 122             };
 123 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 124             $impl = $_get_linear_isa_dfs;
 125         }
 126     }
 127
 128
 129     no warnings 'once';
 130     *get_linear_isa = $impl;
 131 }
 132
 133
 134 # taken from Mouse::Util (0.90)
 135 {
 136     my %cache;
 137
 138     sub resolve_metaclass_alias {
 139         my ( $type, $metaclass_name, %options ) = @_;
 140
 141         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 142
 143         return $cache{$cache_key}{$metaclass_name} ||= do{
 144
 145             my $possible_full_name = join '::',
 146                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 147             ;
 148
 149             my $loaded_class = load_first_existing_class(
 150                 $possible_full_name,
 151                 $metaclass_name
 152             );
 153
 154             $loaded_class->can('register_implementation')
 155                 ? $loaded_class->register_implementation
 156                 : $loaded_class;
 157         };
 158     }
 159 }
 160
 161 # Utilities from Class::MOP
 162
 163 sub get_code_info;
 164 sub get_code_package;
 165
 166 # taken from Class/MOP.pm
 167 sub is_valid_class_name {
 168     my $class = shift;
 169
 170     return 0 if ref($class);
 171     return 0 unless defined($class);
 172
 173     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 174
 175     return 0;
 176 }
 177
 178 # taken from Class/MOP.pm
 179 sub load_first_existing_class {
 180     my @classes = @_
 181       or return;
 182
 183     my %exceptions;
 184     for my $class (@classes) {
 185         my $e = _try_load_one_class($class);
 186
 187         if ($e) {
 188             $exceptions{$class} = $e;
 189         }
 190         else {
 191             return $class;
 192         }
 193     }
 194
 195     # not found
 196     confess join(
 197         "\n",
 198         map {
 199             sprintf( "Could not load class (%s) because : %s",
 200                 $_, $exceptions{$_} )
 201           } @classes
 202     );
 203 }
 204
 205 # taken from Class/MOP.pm
 206 my %is_class_loaded_cache;
 207 sub _try_load_one_class {
 208     my $class = shift;
 209
 210     unless ( is_valid_class_name($class) ) {
 211         my $display = defined($class) ? $class : 'undef';
 212         confess "Invalid class name ($display)";
 213     }
 214
 215     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 216
 217     my $file = $class . '.pm';
 218     $file =~ s{::}{/}g;
 219
 220     return do {
 221         local $@;
 222         eval { require($file) };
 223         $@;
 224     };
 225 }
 226
 227
 228 sub load_class {
 229     my $class = shift;
 230     my $e = _try_load_one_class($class);
 231     confess "Could not load class ($class) because : $e" if $e;
 232
 233     return 1;
 234 }
 235
 236 sub is_class_loaded;
 237
 238
 239 sub apply_all_roles {
 240     my $applicant = blessed($_[0]) ? shift : Mouse::Meta::Class->initialize(shift);
 241
 242     my @roles;
 243
 244     # Basis of Data::OptList
 245     my $max = scalar(@_);
 246     for (my $i = 0; $i < $max ; $i++) {
 247         if ($i + 1 < $max && ref($_[$i + 1])) {
 248             push @roles, [ $_[$i] => $_[++$i] ];
 249         } else {
 250             push @roles, [ $_[$i] => undef ];
 251         }
 252         my $role_name = $roles[-1][0];
 253         load_class($role_name);
 254
 255         my $metarole = get_metaclass_by_name($role_name);
 256         ( $metarole && $metarole->isa('Mouse::Meta::Role') )
 257             || $applicant->meta->throw_error("You can only consume roles, $role_name(".$role_name->meta.") is not a Mouse role");
 258     }
 259
 260     if ( scalar @roles == 1 ) {
 261         my ( $role_name, $params ) = @{ $roles[0] };
 262         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 263     }
 264     else {
 265         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 266     }
 267     return;
 268 }
 269
 270 # taken from Moose::Util 0.90
 271 sub english_list {
 272     return $_[0] if @_ == 1;
 273
 274     my @items = sort @_;
 275
 276     return "$items[0] and $items[1]" if @items == 2;
 277
 278     my $tail = pop @items;
 279
 280     return join q{, }, @items, "and $tail";
 281 }
 282
 283
 284 # common utilities
 285
 286 sub not_supported{
 287     my($feature) = @_;
 288
 289     $feature ||= ( caller(1) )[3]; # subroutine name
 290
 291     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 292     Carp::confess("Mouse does not currently support $feature");
 293 }
 294
 295 # general meta() method
 296 sub meta :method{
 297     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 298 }
 299
 300 # general dump() method
 301 sub dump :method {
 302     my($self, $maxdepth) = @_;
 303
 304     require 'Data/Dumper.pm'; # we don't want to create its namespace
 305     my $dd = Data::Dumper->new([$self]);
 306     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 307     $dd->Indent(1);
 308     return $dd->Dump();
 309 }
 310
 311 # general does() method
 312 sub does :method;
 313 *does = \&does_role; # alias
 314
 315 1;
 316
 317 __END__
 318
 319 =head1 NAME
 320
 321 Mouse::Util - Features, with or without their dependencies
 322
 323 =head1 VERSION
 324
 325 This document describes Mouse version 0.40
 326
 327 =head1 IMPLEMENTATIONS FOR
 328
 329 =head2 Moose::Util
 330
 331 =head3 C<find_meta>
 332
 333 =head3 C<does_role>
 334
 335 =head3 C<resolve_metaclass_alias>
 336
 337 =head3 C<apply_all_roles>
 338
 339 =head3 C<english_list>
 340
 341 =head2 Class::MOP
 342
 343 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 344
 345 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 346 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 347 locally-defined method.
 348
 349 =head3 C<< load_class(ClassName) >>
 350
 351 This will load a given C<ClassName> (or die if it is not loadable).
 352 This function can be used in place of tricks like
 353 C<eval "use $module"> or using C<require>.
 354
 355 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 356
 357 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 358
 359 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 360
 361 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 362
 363 =head2 MRO::Compat
 364
 365 =head3 C<get_linear_isa>
 366
 367 =head2 Sub::Identify
 368
 369 =head3 C<get_code_info>
 370
 371 =head1 UTILITIES FOR MOUSE
 372
 373 =head3 C<not_supported>
 374
 375 =head1 SEE ALSO
 376
 377 L<Moose::Util>
 378
 379 L<Class::MOP>
 380
 381 L<Sub::Identify>
 382
 383 L<MRO::Compat>
 384
 385 =cut
 386